sword-old/PKGBUILD

   1 # Maintainer: Tobias T. <OldShatterhand at gmx-topmail dot de>
   2
   3 pkgname=sword-old
   4 pkgver=1.6.2
   5 pkgrel=2
   6 pkgdesc="Libraries for Bible programs"
   7 arch=('i686' 'x86_64')
   8 url="http://www.crosswire.org/sword/index.jsp"
   9 license=('GPL')
  10 depends=('curl' 'clucene-old' 'swig')
  11 makedepends=('cmake')
  12 conflicts=('sword')
  13 provides=('sword=1.6.2')
  14 backup=('etc/sword.conf')
  15 source=("http://www.crosswire.org/ftpmirror/pub/sword/source/v1.6/sword-${pkgver}.tar.gz" curl.patch)
  16 md5sums=('a7dc4456e20e915fec46d774b690e305'
  17          'e84a226ce3697af33b9fdd9a22884a2a')
  18
  19 build() {
  20   cd "${srcdir}"/sword-$pkgver
  21   patch -p1 < $srcdir/curl.patch
  22   cd $srcdir
  23   [[ -d build ]] || mkdir build
  24   cd build
  25   cmake ../sword-${pkgver} \
  26     -DCMAKE_INSTALL_PREFIX=/usr \
  27     -DCMAKE_BUILD_TYPE=Release
  28   make
  29 }
  30
  31 package() {
  32   cd "${srcdir}"/build
  33   make DESTDIR="${pkgdir}" install
  34
  35   # Ugly workarounds to fix a weird cmakelists.txt
  36   install -d "${pkgdir}"/usr/lib/sword
  37   #mv "${pkgdir}"/usr/lib/1.6.2_icu_4.8 "${pkgdir}"/usr/lib/sword/
  38
  39   cd "${srcdir}"/sword-${pkgver}/locales.d/
  40   for file in *.conf; do
  41     install -Dm644 $file "${pkgdir}"/usr/share/sword/locales.d/$file
  42   done
  43
  44   cd ../include
  45   install -d "${pkgdir}"/usr/include/sword
  46   install -Dm644 canon_{catholic{,2},synodalp}.h "${pkgdir}"/usr/include/sword
  47
  48   cd ../samples
  49   install -Dm644 mods.d/globals.conf "${pkgdir}"/usr/share/sword/mods.d/globals.conf
  50   install -Dm644 recommended/sword.conf "${pkgdir}"/etc/sword.conf
  51 }