songbird-bin/PKGBUILD

   1 # Maintainer: Vithon <ratm@archlinux.us>
   2 # Contributor: Julien <julroy67 [at] gmail.com>
   3 # Contributor: sironitomas@gmail.com
   4
   5 pkgname=songbird-bin
   6 pkgver=1.10.1
   7 _pkgver=2160
   8 pkgrel=1
   9 pkgdesc="Digital desktop media player (jukebox) mashed-up with web browser, powered by Mozilla (contributed build binary)."
  10 url="http://www.getsongbird.com/"
  11 license=('GPL2')
  12 arch=('i686')
  13 depends=('libxmu' 'gstreamer0.10-base' 'gstreamer0.10-good-plugins' 'gstreamer0.10-python')
  14 optdepends=('gstreamer0.10-bad-plugins' 'gstreamer0.10-ugly-plugins')
  15 conflicts=('songbird' 'songbird-nightly' 'songbird-svn')
  16 provides=('songbird')
  17 source=(http://download.songbirdnest.com/installer/linux/$CARCH/Songbird_$pkgver-${_pkgver}_linux-i686.tar.gz
  18 songbird.desktop
  19 songbird-launcher.sh
  20 $pkgname-1.4.3-symlink.patch)
  21 md5sums=('2e3f9dabc1bb140dd26f8d1fd7b4c128'
  22          '094c05874ed5ca4351b3b2f35785b6e7'
  23          '377b899f900a70c04d265e6a45454843'
  24          'c75457bfc67dc8624fab8201eb22a909')
  25
  26 package() {
  27         cd $srcdir
  28
  29         # Apply the symlink patch
  30         patch -Np0 -i $pkgname-1.4.3-symlink.patch || return 1
  31
  32         # Create directory and copy everything
  33         install -d $pkgdir/opt/songbird
  34         cp -a $srcdir/Songbird/* $pkgdir/opt/songbird || return 1
  35
  36         # Fix permissions
  37         find $pkgdir/opt/songbird -type d -exec chmod 755 {} +
  38         find $pkgdir/opt/songbird -type f -exec chmod 644 {} +
  39         chmod 755 $pkgdir/opt/songbird/songbird{,-bin}
  40         chmod 755 $pkgdir/opt/songbird/xulrunner/xulrunner{,-bin}
  41
  42         # Install bin, icon and desktop
  43         install -Dm 755 $srcdir/songbird-launcher.sh $pkgdir/usr/bin/songbird
  44         install -Dm 644 $srcdir/Songbird/chrome/icons/default/default.xpm \
  45         $pkgdir/usr/share/pixmaps/Songbird.xpm
  46         install -Dm 644 $srcdir/songbird.desktop \
  47         $pkgdir/usr/share/applications/Songbird.desktop
  48 }