lib32-oxygen-gtk2/PKGBUILD

   1 # Maintainer: Hyacinthe Cartiaux <hyacinthe.cartiaux@free.fr>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: birdflesh <antkoul at gmail dot com>
   4 # Contributor: Zephyr
   5
   6 _pkgbasename=oxygen-gtk2
   7 pkgname=lib32-${_pkgbasename}
   8 pkgver=1.2.0
   9 pkgrel=1
  10 pkgdesc="Port of the default KDE widget theme (Oxygen) to GTK2"
  11 arch=('i686' 'x86_64')
  12 url="http://kde-look.org/content/show.php/?content=136216"
  13 license=('LGPL')
  14 depends=('lib32-gtk2' "${_pkgbasename}" 'lib32-dbus-glib')
  15 conflicts=('lib32-oxygen-gtk')
  16 replaces=('lib32-oxygen-gtk')
  17 makedepends=('cmake' 'gcc-multilib')
  18 source=(ftp://ftp.kde.org/pub/kde/stable/${_pkgbasename}/${pkgver}/src/${_pkgbasename}-${pkgver}.tar.bz2)
  19 md5sums=('975dfef679436c849a649c9d5d9ae0d3')
  20
  21 build() {
  22   cd ${srcdir}
  23   mkdir build
  24   cd build
  25
  26   export CC="gcc -m32"
  27   export CXX="g++ -m32"
  28   export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  29
  30   cmake ../${_pkgbasename}-${pkgver} \
  31     -DCMAKE_BUILD_TYPE=Release \
  32     -DCMAKE_INSTALL_PREFIX=/usr \
  33     -DINSTALL_PATH_GTK_ENGINES=/usr/lib32/gtk-2.0/2.10.0/engines
  34   make
  35 }
  36
  37 package() {
  38   cd ${srcdir}/build
  39   make DESTDIR=${pkgdir} install
  40
  41   #Clean up directories provided by x86_64 package
  42   rm -rf ${pkgdir}/usr/bin
  43   rm -rf ${pkgdir}/usr/share
  44 }