wxgtk-2.9/PKGBUILD

   1 # Maintainer:  TDY <tdy@gmx.com>
   2 # Contributor: bunder <budner : t-25 : ru>
   3 # Note: wxgtk-2.9 can coexist with extra/wxgtk (a la extra/wxgtk-2.6)
   4
   5 pkgname=wxgtk-2.9
   6 pkgver=2.9.2
   7 pkgrel=1
   8 pkgdesc="A GTK+ implementation of wxWidgets API for GUI"
   9 arch=('i686' 'x86_64')
  10 url="http://wxwidgets.org/"
  11 license=('custom:wxWindows')
  12 depends=('gstreamer0.10-base' 'gtk2>=2.10' 'mesa')
  13 makedepends=('gstreamer0.10-good-plugins' 'libgnomeprintui' 'pkgconfig>=0.9.0')
  14 source=(http://downloads.sourceforge.net/wxwindows/wxWidgets-$pkgver.tar.bz2)
  15 md5sums=('d6cec5bd331ba90b74c1e2fcb0563620')
  16
  17 build() {
  18   cd "$srcdir/wxWidgets-$pkgver"
  19   sed -i 's,/usr/$wx_cv_std_libpath,& /usr/lib,' configure
  20   ./configure --prefix=/usr --libdir=/usr/lib \
  21       --with-gtk=2          \
  22       --with-opengl         \
  23       --with-gnomeprint     \
  24       --enable-graphics_ctx \
  25       --enable-mediactrl    \
  26       --disable-optimise
  27   make
  28   make -C locale allmo
  29 }
  30
  31 package() {
  32   cd "$srcdir/wxWidgets-$pkgver"
  33   make DESTDIR="$pkgdir" install
  34   install -Dm644 docs/licence.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  35
  36   # provide compatibility with extra/wxgtk
  37   ln -sf /usr/lib/wx/config/gtk2-unicode-2.9 "$pkgdir/usr/bin/wx-config-2.9"
  38   rm -f "$pkgdir/usr/bin/wx-config"
  39   rm -f "$pkgdir/usr/bin/wxrc"
  40   rm -rf "$pkgdir/usr/share/bakefile"
  41   find "$pkgdir/usr/share/locale" -name wxmsw.mo -delete
  42   for _mo in "$pkgdir"/usr/share/locale/*/LC_MESSAGES/wxstd.mo; do
  43     mv $_mo ${_mo/wxstd.mo/compat-wxstd29.mo}
  44   done
  45   mv "$pkgdir/usr/share/aclocal/wxwin.m4" "$pkgdir/usr/share/aclocal/wxwin-2.9.m4"
  46 }