lib/aur-graph

   1 #!/bin/awk -f
   2 # aur-graph - print package/dependency pairs
   3
   4 # < 0 : if ver1 < ver2
   5 # = 0 : if ver1 == ver2
   6 # > 0 : if ver1 > ver2
   7 function get_vercmp(ver1, ver2, op) {
   8     command = ("vercmp " ver1 " " ver2)
   9
  10     if (op == "-" || ver2 == "-") {
  11         return "true" # dependency is unversioned
  12     } else if (op == "=") {
  13         return (ver1 == ver2) # common case
  14     } else if (op == "<") {
  15         command | getline
  16         close(command)
  17         return ($1 < 0)
  18     } else if (op == ">") {
  19         command | getline
  20         close(command)
  21         return ($1 > 0)
  22     } else if (op == "<=") {
  23         command | getline
  24         close(command)
  25         return ($1 <= 0)
  26     } else if (op == ">=") {
  27         command | getline
  28         close(command)
  29         return ($1 >= 0)
  30     } else {
  31         printf("invalid operation\n") > "/dev/stderr"
  32         exit 1
  33     }
  34 }
  35
  36 /pkgbase/ {
  37     in_split_pkg = 0
  38     pkgbase = $3
  39     pkgver  = ""
  40
  41     # track both the pkgbases themselves and their number of deps
  42     dep_counts[pkgbase] = 0
  43 }
  44
  45 /^\tpkgver/ {
  46     if (!in_split_pkg) {
  47         pkgver = $3
  48     }
  49 }
  50
  51 /^\tdepends/ {
  52     if ((!length(DEPENDS) || DEPENDS == 1) && !in_split_pkg)
  53         pkg_deps[pkgbase, ++dep_counts[pkgbase]] = $3 # versioned
  54 }
  55
  56 /^\tmakedepends/ {
  57     if ((!length(MAKEDEPENDS) || MAKEDEPENDS == 1) && !in_split_pkg)
  58         pkg_deps[pkgbase, ++dep_counts[pkgbase]] = $3
  59 }
  60
  61 /^\tcheckdepends/ {
  62     if ((!length(CHECKDEPENDS) || CHECKDEPENDS == 1) && !in_split_pkg)
  63         pkg_deps[pkgbase, ++dep_counts[pkgbase]] = $3
  64 }
  65
  66 /^\toptdepends/ {
  67     if (OPTDEPENDS == 1 && !in_split_pkg) {
  68         pkg_deps[pkgbase, ++dep_counts[pkgbase]] = $3
  69     }
  70 }
  71
  72 /^$/ {
  73     in_split_pkg = 1
  74 }
  75
  76 /pkgname/ {
  77     pkg_map[$3] = pkgbase # node
  78     ver_map[$3] = pkgver  # weight
  79 }
  80
  81 /^\tprovides/ {
  82     split($3, prov, "=")
  83
  84     # if provider is unversioned, use pkgver
  85     if ("2" in prov)
  86         ver_map[prov[1]] = prov[2]
  87     else
  88         ver_map[prov[1]] = pkgver
  89
  90     # append node
  91     pkg_map[prov[1]] = pkgbase
  92 }
  93
  94 END {
  95     _vercmp_exit = 0
  96
  97     for (pkgbase in dep_counts) {
  98         # add a loop to isolated nodes (#402)
  99         printf("%s\t%s\n", pkgbase, pkgbase)
 100
 101         for (dep = 1; dep <= dep_counts[pkgbase]; dep++) {
 102             dep_op = "-" # unversioned / no comparison
 103
 104             # valid operators (important: <= before <)
 105             split("<=|>=|<|=|>", cmp, "|")
 106
 107             # split: fourth argument is gawk extension
 108             for (i in cmp) {
 109                 split(pkg_deps[pkgbase, dep], dep_split, cmp[i])
 110
 111                 if ("2" in dep_split) {
 112                     dep_op = cmp[i]
 113                     break
 114                 }
 115             }
 116
 117             if ("1" in dep_split)
 118                 dep_pkgname = dep_split[1]
 119             else
 120                 exit 2
 121
 122             if ("2" in dep_split)
 123                 dep_pkgver = dep_split[2]
 124             else
 125                 dep_pkgver = "-"
 126
 127             # only print dependency if it was encountered before
 128             if (dep_pkgname in pkg_map == 0)
 129                 continue
 130
 131             # run vercmp with provider and versioned dependency
 132             if (get_vercmp(ver_map[dep_pkgname], dep_pkgver, dep_op)) {
 133                 printf("%s\t%s\n", pkgbase, pkg_map[dep_pkgname])
 134             } else {
 135                 printf("invalid node: %s %s (required: %s%s)\n",
 136                        dep_pkgname, ver_map[dep_pkgname], dep_op, dep_pkgver) > "/dev/stderr"
 137                 close("/dev/stderr")
 138
 139                 # delay mismatches to loop end
 140                 _vercmp_exit = 1
 141             }
 142         }
 143     }
 144
 145     if (_vercmp_exit)
 146         exit _vercmp_exit
 147 }