configure.ac

   1 #                                                       -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1992-1995, 1999-2016 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_PREREQ([2.62])
  20
  21 AC_INIT([GNU Autoconf],
  22         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  23         [bug-autoconf@gnu.org])
  24 AC_CONFIG_SRCDIR([lib/autoconf/autoconf.m4])
  25
  26 AC_CONFIG_AUX_DIR([build-aux])
  27
  28 AM_INIT_AUTOMAKE([1.11 dist-xz readme-alpha no-texinfo.tex std-options])
  29
  30 # Keep this on a line of its own, since it must be found and processed
  31 # by the 'update-release-year' rule in our Makefile.
  32 RELEASE_YEAR=2016
  33 AC_SUBST([RELEASE_YEAR])
  34
  35 AB_INIT
  36
  37 # We use '/bin/sh -n script' to check that there are no syntax errors
  38 # in the scripts.  Although incredible, there are /bin/sh that go into
  39 # endless loops with '-n', e.g., SunOS's:
  40 #
  41 #   $ uname -a
  42 #   SunOS ondine 4.1.3 2 sun4m unknown
  43 #   $ cat endless.sh
  44 #   while false
  45 #   do
  46 #     :
  47 #   done
  48 #   exit 0
  49 #   $ time sh endless.sh
  50 #   sh endless.sh  0,02s user 0,03s system 78% cpu 0,064 total
  51 #   $ time sh -nx endless.sh
  52 #   ^Csh -nx endless.sh  3,67s user 0,03s system 63% cpu 5,868 total
  53 #
  54 # Also, some implementations of /bin/sh (e.g., Solaris 8) are soooo slow
  55 # that they are unusable on large scripts like our testsuite.
  56
  57 # So before using '/bin/sh -n' to check our scripts, we first check
  58 # that '/bin/sh -n' is known to not have these problems.
  59
  60 AC_CACHE_CHECK([whether /bin/sh -n is known to work], [ac_cv_sh_n_works],
  61 [if (
  62     unset BASH_VERSION ZSH_VERSION
  63     /bin/sh -c '
  64       test ${BASH_VERSION+y} || # Bash
  65       test ${KSH_VERSION+y} || # pdksh
  66       test ${ZSH_VERSION+y} || # zsh
  67       test -n "${.sh.version}" # ksh93; put this last since its syntax is dodgy
  68     '
  69   ) 2>/dev/null
  70 then ac_cv_sh_n_works=yes
  71 else ac_cv_sh_n_works=no
  72 fi
  73 ])
  74 AC_SUBST([ac_cv_sh_n_works])
  75
  76 AC_MSG_CHECKING([for characters that cannot appear in file names])
  77 AC_CACHE_VAL([ac_cv_unsupported_fs_chars],
  78 [ac_cv_unsupported_fs_chars=
  79 for c in '\\' \" '<' '>' '*' '?' '|'
  80 do
  81   touch "conftest.t${c}t" 2>/dev/null
  82   test -f "conftest.t${c}t" && rm -f "conftest.t${c}t" && continue
  83   # $c cannot be used in a file name.
  84   ac_cv_unsupported_fs_chars=$ac_cv_unsupported_fs_chars$c
  85 done
  86 ])
  87 if test -n "$ac_cv_unsupported_fs_chars"; then
  88   AC_MSG_RESULT([$ac_cv_unsupported_fs_chars])
  89 else
  90   AC_MSG_RESULT([none])
  91 fi
  92
  93 AC_SUBST([ac_cv_unsupported_fs_chars])
  94
  95 AC_CACHE_CHECK([whether directories can have trailing spaces],
  96                [ac_cv_dir_trailing_space],
  97 [rm -rf 'conftest.d ' && mkdir 'conftest.d ' && touch 'conftest.d /tfile' 2>/dev/null
  98 stat=$?
  99 rm -rf 'conftest.d '
 100 case $stat$? in #(
 101    00) ac_cv_dir_trailing_space=yes ;; #(
 102    *) ac_cv_dir_trailing_space=no ;;
 103 esac
 104 ])
 105 AC_SUBST([ac_cv_dir_trailing_space])
 106
 107 # Initialize the test suite.
 108 AC_CONFIG_TESTDIR([tests])
 109 AC_CONFIG_FILES([tests/atlocal])
 110 AC_PATH_PROG([EXPR], [expr])
 111
 112
 113 ## ---- ##
 114 ## M4.  ##
 115 ## ---- ##
 116
 117 # We use an absolute name for GNU m4 so even if users have another m4 first in
 118 # their path, the installer can configure with a path that has GNU m4
 119 # on it and get that path embedded in the installed autoconf and
 120 # autoheader scripts.
 121 AC_PROG_GNU_M4
 122
 123 ## ----------- ##
 124 ## Man pages.  ##
 125 ## ----------- ##
 126
 127 AM_MISSING_PROG([HELP2MAN], [help2man])
 128
 129
 130 ## ------ ##
 131 ## Perl.  ##
 132 ## ------ ##
 133
 134 # We use an absolute name for perl so the #! line in autoscan will work.
 135 AC_PATH_PROG([PERL], [perl], [no])
 136 AC_SUBST([PERL])dnl
 137 if test "$PERL" = no; then
 138   AC_MSG_ERROR([perl is not found])
 139 fi
 140 $PERL -e 'require 5.006;' || {
 141    AC_MSG_ERROR([Perl 5.006 or better is required])
 142 }
 143
 144 # Find out whether the system supports flock
 145 # Note this test does not try to find out whether it works with this
 146 # particular file system.  It merely avoids us running flock on systems
 147 # where that bails out.
 148 AC_CACHE_CHECK([whether $PERL Fcntl::flock is implemented],
 149   [ac_cv_perl_flock_implemented],
 150   [echo lock me > conftest.fil
 151    if $PERL -e 'use Fcntl ":flock"; flock("conftest.fil", LOCK_EX); 1;'; then
 152      ac_cv_perl_flock_implemented=yes
 153    else
 154      ac_cv_perl_flock_implemented=no
 155    fi
 156    rm -f conftest.fil
 157   ])
 158 AC_SUBST([PERL_FLOCK], [$ac_cv_perl_flock_implemented])
 159
 160
 161 ## ------- ##
 162 ## Emacs.  ##
 163 ## ------- ##
 164
 165 TEST_EMACS=$EMACS
 166 test x"$TEST_EMACS" = xt && TEST_EMACS=
 167 AC_CHECK_PROGS([TEST_EMACS], [emacs xemacs], [no])
 168
 169 # autoconf-mode.el and autotest-mode.el do not work with older version of
 170 # Emacs (i.e. 18.x.x).  During byte-compilation, Emacs complains:
 171 # "Variable (broken nil) seen on pass 2 of byte compiler but not pass 1"
 172 # We detect this problem here.
 173 AS_IF([test "$TEST_EMACS" != no],
 174   [AC_CACHE_CHECK([whether $TEST_EMACS is sufficiently recent],
 175     [ac_cv_prog_emacs_ok],
 176     [# Note: The quoted "EOF" is intentional.  It protects the ` in the text.
 177     cat >conftest.el << "EOF"
 178       (defvar broken)
 179       (defun broken-mode () (setq broken-defaults `(broken nil)))
 180 EOF
 181     AS_IF([AC_RUN_LOG(
 182       [$TEST_EMACS -batch -q -f batch-byte-compile conftest.el 1>&2])],
 183       [ac_cv_prog_emacs_ok=yes], [ac_cv_prog_emacs_ok=no])
 184     rm -f conftest.el conftest.elc])
 185   AS_IF([test $ac_cv_prog_emacs_ok = no], [TEST_EMACS=no])])
 186
 187 AC_SUBST([EMACS], [$TEST_EMACS])
 188
 189 AM_PATH_LISPDIR
 190
 191
 192 ## ------------ ##
 193 ## Grep & sed.  ##
 194 ## ------------ ##
 195 AC_PROG_GREP
 196 AC_PROG_EGREP
 197 AC_PROG_SED
 198
 199
 200 ## ----- ##
 201 ## Make. ##
 202 ## ----- ##
 203 AC_PROG_MAKE_CASE_SENSITIVE
 204
 205
 206 ## ------------ ##
 207 ## Conclusion.  ##
 208 ## ------------ ##
 209
 210 dnl Allow maintainer rules under GNU make even in VPATH builds.
 211 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 212
 213 AC_CONFIG_FILES([Makefile])
 214
 215 AC_OUTPUT
 216 # Report the state of this version of Autoconf if this is a beta.
 217 m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-a-z]],
 218 [    cat <<EOF
 219
 220 You are about to use an experimental version of Autoconf.  Be sure to
 221 read the relevant mailing lists, most importantly <autoconf@gnu.org>.
 222
 223 Below you will find information on the status of this version of Autoconf.
 224
 225 EOF
 226     sed -n '/^\* Status/,$p' $srcdir/BUGS
 227 echo
 228 ])dnl