m4/m4.m4

   1 # m4.m4 serial 13
   2
   3 # Copyright (C) 2000, 2006-2017, 2020-2024 Free Software Foundation,
   4 # Inc.
   5
   6 # Copying and distribution of this file, with or without modification,
   7 # are permitted in any medium without royalty provided the copyright
   8 # notice and this notice are preserved.  This file is offered as-is,
   9 # without warranty of any kind.
  10
  11 # AC_PROG_GNU_M4
  12 # --------------
  13 # Check for GNU M4, at least 1.4.8 (all earlier versions had bugs in
  14 # trace support and regexp support):
  15 # https://lists.gnu.org/archive/html/bug-gnu-utils/2006-11/msg00096.html
  16 # https://lists.gnu.org/archive/html/bug-autoconf/2009-07/msg00023.html
  17 # Also, check whether --error-output (through 1.4.x) or --debugfile (2.0)
  18 # is supported, and AC_SUBST M4_DEBUGFILE accordingly.
  19 # Also avoid versions of m4 that trigger strstr bugs.
  20 AC_DEFUN([AC_PROG_GNU_M4],
  21   [AC_ARG_VAR([M4], [Location of GNU M4 1.4.8 or later.  Defaults to the first
  22     program of 'm4', 'gm4', or 'gnum4' on PATH that meets Autoconf needs.])
  23   AC_CACHE_CHECK([for GNU M4 that supports accurate traces], [ac_cv_path_M4],
  24     [rm -f conftest.m4f
  25 ac_had_posixly_correct=${POSIXLY_CORRECT:+yes}
  26 AS_UNSET([POSIXLY_CORRECT])
  27 AC_PATH_PROGS_FEATURE_CHECK([M4], [m4 gm4 gnum4],
  28       [dnl Creative quoting here to avoid raw dnl and ifdef in configure.
  29       # Root out GNU M4 1.4.5, as well as non-GNU m4 that ignore -t, -F.
  30       # Root out GNU M4 1.4.15 with buggy false negative replacement strstr.
  31       # Root out Glibc 2.9 - 2.12 and GNU M4 1.4.11 - 1.4.15 with buggy
  32       # false positive strstr.
  33       ac_snippet=change'quote(<,>)in''dir(<if''def>,mac,bug)'
  34       ac_snippet=${ac_snippet}pat'subst(a,\(b\)\|\(a\),\1)d'nl
  35       ac_snippet=${ac_snippet}${as_nl}if'else(in''dex(..wi.d.,.d.),-1,bug)'
  36       ac_snippet=${ac_snippet}${as_nl}if'else(in''dex(dnl
  37 ;:11-:12-:12-:12-:12-:12-:12-:12-:12.:12.:12.:12.:12.:12.:12.:12.:12-,dnl
  38 :12-:12-:12-:12-:12-:12-:12-:12-),-1,,strstr-bug2)'
  39       # Root out M4 1.4.6 and 1.4.7, which do not implement --debug=aflq
  40       # correctly for macros invoked from m4wrap.
  41       ac_snip2=change'quote(<,>)def''ine(<T>,<>)d'nl
  42       ac_snip2=${ac_snip2}${as_nl}def'ine(<F>,<T(<traced>)>)d'nl
  43       ac_snip2=${ac_snip2}${as_nl}m4'wrap(<F>)d'nl
  44       AS_ECHO(["$as_me:${as_lineno-$LINENO}: trying $ac_path_M4"]) \
  45           >&AS_MESSAGE_LOG_FD
  46       test -z "`$ac_path_M4 -F conftest.m4f </dev/null 2>&1`" \
  47       && test -z "`AS_ECHO(["$ac_snippet"]) | $ac_path_M4 --trace=mac 2>&1`" \
  48       && test -f conftest.m4f \
  49       && test x"`AS_ECHO(["$ac_snip2"]) | \
  50                 $ac_path_M4 --trace=T --debug=aflq 2>&1`" = \
  51               x'm4trace:stdin:3: -1- T(<traced>)' \
  52       && ac_cv_path_M4=$ac_path_M4 ac_path_M4_found=:
  53       rm -f conftest.m4f],
  54       [AC_MSG_ERROR([no acceptable m4 could be found in \$PATH.
  55 GNU M4 1.4.8 or later is required; 1.4.16 or newer is recommended.
  56 GNU M4 1.4.15 uses a buggy replacement strstr on some systems.
  57 Glibc 2.9 - 2.12 and GNU M4 1.4.11 - 1.4.15 have another strstr bug.])])])
  58   M4=$ac_cv_path_M4
  59   AC_CACHE_CHECK([whether $ac_cv_path_M4 accepts --gnu],
  60     [ac_cv_prog_gnu_m4_gnu],
  61     [case `$M4 --help < /dev/null 2>&1` in
  62       *--gnu*) ac_cv_prog_gnu_m4_gnu=yes ;;
  63       *) ac_cv_prog_gnu_m4_gnu=no ;;
  64     esac])
  65   if test "$ac_cv_prog_gnu_m4_gnu" = yes; then
  66     M4_GNU=--gnu
  67   else
  68     M4_GNU=
  69   fi
  70   AC_SUBST([M4_GNU])
  71   if test x$ac_had_posixly_correct = xyes; then
  72     POSIXLY_CORRECT=:
  73     if test $ac_cv_prog_gnu_m4_gnu = no; then
  74       AC_MSG_WARN([the version of M4 that was found does not support -g])
  75       AC_MSG_WARN([using it with POSIXLY_CORRECT set may cause problems])
  76     fi
  77   fi
  78   AC_CACHE_CHECK([how m4 supports trace files], [ac_cv_prog_gnu_m4_debugfile],
  79     [case `$M4 --help < /dev/null 2>&1` in
  80       *debugfile*) ac_cv_prog_gnu_m4_debugfile=--debugfile ;;
  81       *) ac_cv_prog_gnu_m4_debugfile=--error-output ;;
  82     esac])
  83   AC_SUBST([M4_DEBUGFILE], [$ac_cv_prog_gnu_m4_debugfile])
  84 ])