configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2025 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <https://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.17.0.91], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([bin/automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([-Wall -Werror dist-xz filename-length-max=99
  43                   no-define no-dependencies])
  44
  45 # Keep this on a line of its own, since it must be found and processed
  46 # by the 'update-copyright' rule in our Makefile.
  47 RELEASE_YEAR=2025
  48 AC_SUBST([RELEASE_YEAR])
  49
  50 # The API version is the base version.  We must guarantee
  51 # compatibility for all releases with the same API version.
  52 APIVERSION=1.17
  53 AC_SUBST([APIVERSION])
  54
  55 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  56 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  57 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  58 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  59 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  60
  61 # Our build system is bootstrapped with the bleeding-edge versions of
  62 # aclocal and automake, hence the remake rules must use those versions
  63 # as well.  The extra quoting is to cater to cases when the build
  64 # directory contains whitespace or shell metacharacters.
  65 ACLOCAL="\"`pwd`/pre-inst-env\" aclocal-$APIVERSION"
  66 AUTOMAKE="\"`pwd`/pre-inst-env\" automake-$APIVERSION"
  67
  68 AC_PROG_LN_S
  69
  70 AC_PATH_PROG([PERL], [perl])
  71 case $PERL in
  72  '')
  73    AC_MSG_ERROR([perl not found])
  74    ;;
  75  *' '* | *'     '*)
  76   AC_MSG_WARN([The path to your Perl contains spaces or tabs.
  77 This will likely cause build failures later or unusable programs.
  78 Unless you're specifying a full string for a #! line,
  79 as in "/usr/bin/env perl",
  80 please use a path without spaces and try again.])
  81   ;;
  82 esac
  83
  84 # Save details about the selected perl interpreter in config.log.
  85 AM_RUN_LOG([$PERL --version])
  86 $PERL -e 'require 5.006;' || {
  87    AC_MSG_ERROR(
  88 [perl 5.6 or better is required; perl 5.10 or better
  89 is recommended.  If you have several perl versions
  90 installed, select the one Automake should use using
  91   ./configure PERL=/path/to/perl])
  92 }
  93
  94 # The test suite will skip some tests if tex is absent.
  95 AC_CHECK_PROG([TEX], [tex], [tex])
  96 # Save details about the selected TeX program in config.log.
  97 # Redirect input from /dev/null, as TeX might otherwise hang waiting
  98 # for input from the terminal.
  99 AM_RUN_LOG([$TEX --version </dev/null])
 100
 101 # The test suite will skip some tests if no lex or yacc program is
 102 # available.
 103 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 104 #  1. we don't want flex (resp. bison) to be preferred to system lex
 105 #     (resp. system yacc);
 106 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 107 #     by default;
 108 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 109 #     LEXLIB to be calculated and/or AC_SUBST'd;
 110 #  4. we prefer that the YACC and LEX variables are not reported in the
 111 #     configure help screen.
 112 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 113 AC_CHECK_PROGS([LEX], [lex flex], [false])
 114
 115 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 116 # deletion of any files created (such as those added to
 117 # autom4te.cache).  We used to perform only the last of the three
 118 # following tests, but some users were unable to figure out that their
 119 # installation was broken since --version appeared to work.
 120
 121 AC_SUBST([required_autoconf_version], [2.65])
 122 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 123 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 124 then
 125   am_cv_autoconf_installed=yes
 126 else
 127   am_cv_autoconf_installed=no
 128 fi])
 129 if test "$am_cv_autoconf_installed" = no; then
 130   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 131     Please make sure it is installed and in your PATH.])
 132 fi
 133
 134 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 135 [mkdir conftest
 136 printf '%s\n' > conftest/conftest.ac \
 137   'AC''_INIT([smoke-test], [1])' \
 138   'AC''_OUTPUT'
 139 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 140 then
 141   am_cv_autoconf_works=yes
 142 else
 143   am_cv_autoconf_works=no
 144 fi
 145 rm -rf conftest])
 146 if test "$am_cv_autoconf_works" = no; then
 147   AC_MSG_ERROR([The installed version of autoconf does not work.
 148     Please check config.log for error messages before this one.])
 149 fi
 150
 151 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 152 [mkdir conftest
 153 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 154 printf '%s\n' > conftest/conftest.ac \
 155   'AC'"_PREREQ([[$required_autoconf_version]])" \
 156   'AC''_INIT([smoke-test], [1])' \
 157   'AC''_OUTPUT'
 158 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 159 then
 160   am_cv_autoconf_version=yes
 161 else
 162   am_cv_autoconf_version=no
 163 fi
 164 rm -rf conftest])
 165 if test "$am_cv_autoconf_version" = no; then
 166   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 167 fi
 168
 169 # Test for ln.  We need use it to install the versioned binaries.
 170 AC_MSG_CHECKING([whether ln works])
 171 AC_CACHE_VAL([am_cv_prog_ln], [
 172 rm -f conftest conftest.file
 173 : >conftest.file
 174 if ln conftest.file conftest 2>/dev/null; then
 175   am_cv_prog_ln=ln
 176 else
 177   am_cv_prog_ln='cp -p'
 178 fi
 179 rm -f conftest conftest.file])
 180 AC_SUBST([LN], [$am_cv_prog_ln])
 181 result=no
 182 test "x$am_cv_prog_ln" = xln && result=yes
 183 AC_MSG_RESULT([$result])
 184
 185 ## ------------------------------------------- ##
 186 ##  Test for things needed by the test suite.  ##
 187 ## ------------------------------------------- ##
 188
 189 AC_PROG_EGREP
 190 AC_PROG_FGREP
 191
 192 # The test suite needs to know the resolution of timestamps
 193 # supported by the filesystem hosting the build.  The value
 194 # will be acceptable to 'sleep' on this system.
 195 MTIME_RESOLUTION=$am_cv_filesystem_timestamp_resolution
 196 if test -z "$MTIME_RESOLUTION"; then
 197   AC_MSG_NOTICE(am_cv_filesystem_timestamp_resolution strangely not set; using 1)
 198   MTIME_RESOLUTION=1
 199 fi
 200 AC_SUBST([MTIME_RESOLUTION])
 201
 202 dnl FIXME: could we extract this in a simpler way through autoconf
 203 dnl FIXME: idioms or internals?
 204 AC_DEFUN(
 205   [_AM_INIT_BOURNE_COMPATIBLE_VAR],
 206   [am_bourne_compatible="AS_ESCAPE(_m4_expand([AS_BOURNE_COMPATIBLE]))"])
 207
 208 dnl
 209 dnl Arguments to this macro:
 210 dnl
 211 dnl   $1 - shell to test
 212 dnl   $2 - description of the tested feature
 213 dnl   $3 - shell code used to check the feature; to indicate success,
 214 dnl        it can either exit with status 77, or have the last command
 215 dnl        returning with exit status of zero
 216 dnl   $4 - shell code to execute if the check on the shell is successful
 217 dnl        (defaults to nothing)
 218 dnl   $5 - shell code to execute if the check on the shell is not
 219 dnl        successful (defaults to nothing)
 220 dnl
 221 AC_DEFUN([_AM_CHECK_SHELL_FEATURE],
 222   [AC_REQUIRE([_AM_INIT_BOURNE_COMPATIBLE_VAR])
 223   AC_MSG_CHECKING([whether $1 $2])
 224   if { $1 -c "$am_bourne_compatible
 225 AS_ESCAPE([$3])
 226 test \$? -eq 0 || exit 1
 227 # Use 77 to indicate success (rather than 0), in case some shell
 228 # acts like Solaris 10's /bin/sh, exiting successfully on some
 229 # syntax errors.
 230 exit 77" >&AS_MESSAGE_LOG_FD 2>&1; test $? -eq 77; }
 231   then
 232     AC_MSG_RESULT([yes])
 233     $4
 234   else
 235     AC_MSG_RESULT([no])
 236     $5
 237   fi])
 238
 239 # AM_CHECK_CANDIDATE_TEST_SHELL(SHELL-PATH)
 240 # -----------------------------------------
 241 #
 242 # Check if the given shell is good enough to run our test scripts.
 243 # Inspired to gnulib's 'tests/init.sh'.
 244 #
 245 # We require POSIX and XSI features (e.g., '$(...)' for command
 246 # substitutions, '$((...))' for shell arithmetic, and support for
 247 # '${var#...}' and '${var%...}' parameter expansions).
 248 #
 249 # We require that the shell can correctly trap EXIT when 'set -e' is in
 250 # effect (OSF1/Tru64 sh failed to do so, see commit v1.10b-52-g9fe8259).
 251 #
 252 # We want to able to define shell aliases with the same name of shell
 253 # builtins.
 254 #
 255 # We also prefer shells that, when 'set -x' is in effect, do not also
 256 # redirect traces upon stderr redirections.  For example,
 257 #  $ set -x; echo x 2>file
 258 # would emit "+ echo x" into file with older zsh versions.  Similarly,
 259 #   $ set -x; P=1 true 2>file
 260 # would emit "P=1" into file with /usr/xpg4/bin/sh from Solaris 10 and
 261 # /bin/sh from SunOS 5.11 and OpenBSD 4.7.
 262 #
 263 # Use '$am_score' to indicate the degree of acceptability of the shell.
 264 # A score of "10" means that the shell is good enough for our needs;
 265 # a score of "9" means that the shell has some minor bugs or limitation,
 266 # but is still (barely) acceptable for our uses.  Any other score means
 267 # that the shell is broken or unfit.
 268 #
 269 AC_DEFUN([_AM_CHECK_CANDIDATE_SHELL],
 270   [am_score=10
 271   while :; do
 272
 273     _AM_CHECK_SHELL_FEATURE([$1],
 274       [supports \$(cmd)],
 275       [test "$(echo x)" = x],
 276       [], [am_score=1; break])
 277
 278     _AM_CHECK_SHELL_FEATURE([$1],
 279       [supports \$((expr))],
 280       [test $((1 + 2 * 3)) = 7],
 281       [], [am_score=1; break])
 282
 283     _AM_CHECK_SHELL_FEATURE([$1],
 284       [supports \${@%:@var}],
 285       [zero='' one='x' twelve=' foobar baz!' \
 286         && test ${@%:@zero} -eq 0 \
 287         && test ${@%:@one} -eq 1 \
 288         && test ${@%:@twelve} -eq 12],
 289       [], [am_score=1; break])
 290
 291     _AM_CHECK_SHELL_FEATURE([$1],
 292       [supports \${var@%:@glob} and \${var%glob}],
 293       [v=a/b/c \
 294         && test ${v@%:@*/} = b/c \
 295         && test ${v@%:@@%:@*/} = c \
 296         && test ${v%/*} = a/b \
 297         && test ${v%%/*} = a],
 298       [], [am_score=1; break])
 299
 300     _AM_CHECK_SHELL_FEATURE([$1],
 301       [preserves exit traps with "set -e"],
 302       [set -e; trap 'exit $?' 0; (exit 77); exit 77],
 303       [], [am_score=1; break])
 304
 305     _AM_CHECK_SHELL_FEATURE([$1],
 306       [can define exit traps in a shell function],
 307       [fail=0 && foo() { trap 'fail=1' 0; } && foo && test $fail = 0],
 308       [], [am_score=1; break])
 309
 310     _AM_CHECK_SHELL_FEATURE([$1],
 311       [corrupts stderr with "set -x"],
 312       [(set -x; P=1 true 2>&3) 3>&1 2>/dev/null | grep P=1],
 313       [am_score=9], [])
 314
 315     echo 'return 34' > conftest-return.sh
 316     echo 'ok=no' >> conftest-return.sh
 317     _AM_CHECK_SHELL_FEATURE([$1],
 318       [can return early from "dot-sourced" files],
 319       [ok=yes; . ./conftest-return.sh; test $? -eq 34 && test $ok = yes],
 320       [rm -f conftest-return.sh],
 321       [rm -f conftest-return.sh; am_score=1; break])
 322
 323     echo 'alias false=echo' > conftest-alias.sh
 324     echo 'false && test "$(false 97)" = 97' >> conftest-alias.sh
 325     _AM_CHECK_SHELL_FEATURE([$1],
 326       [supports alias named like shell builtins],
 327       [. ./conftest-alias.sh],
 328       [rm -f conftest-alias.sh],
 329       [rm -f conftest-alias.sh; am_score=1; break])
 330
 331     _AM_CHECK_SHELL_FEATURE([$1],
 332       [supports "test -e"],
 333       [test -e config.log && test -e . && test ! -e nonesuch],
 334       [], [am_score=1; break])
 335
 336     break
 337   done])
 338
 339 # These messages only goes to the config.log file.
 340 AC_MSG_NOTICE([will now look for a sturdy POSIX shell, for our testsuite])
 341
 342 AC_CACHE_VAL(
 343   [ac_cv_AM_TEST_RUNNER_SHELL],
 344   [if test "$AM_TEST_RUNNER_SHELL"; then
 345     # Let the user override it.
 346     ac_cv_AM_TEST_RUNNER_SHELL=$AM_TEST_RUNNER_SHELL
 347   else
 348     ac_cv_AM_TEST_RUNNER_SHELL=no
 349     am_candidate_shells=${CONFIG_SHELL-}
 350     # For the benefit of Solaris.
 351     am_PATH=$PATH$PATH_SEPARATOR/usr/xpg6/bin$PATH_SEPARATOR/usr/xpg4/bin
 352     for am_sh in sh sh5 dash ash bash zsh ksh pdksh; do
 353       AC_PATH_PROG([am_candidate_sh], [$am_sh], [], [$am_PATH])
 354       if test -n "$am_candidate_sh"; then
 355         am_candidate_shells="$am_candidate_shells $am_candidate_sh"
 356       fi
 357       AM_SUBST_NOTMAKE([am_candidate_sh])
 358       # Must nullify these in order not to interfere with the checks in
 359       # the next loop.
 360       AS_UNSET([am_candidate_sh])
 361       AS_UNSET([ac_cv_path_am_candidate_sh])
 362     done
 363     AS_UNSET([am_PATH]) # Not required anymore
 364     for am_sh in $am_candidate_shells; do
 365       am_score=0
 366       _AM_CHECK_CANDIDATE_SHELL([$am_sh])
 367       if test $am_score -eq 9; then
 368         # The shell is barely acceptable for our needs.  We might
 369         # still find one that is even better, so continue looking.
 370         AC_MSG_NOTICE([shell $am_sh is acceptable, but we might do better])
 371         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 372       elif test $am_score -eq 10; then
 373         AC_MSG_NOTICE([shell $am_sh is good enough, stop looking])
 374         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 375         break
 376       fi
 377     done
 378   fi
 379   AM_TEST_RUNNER_SHELL=$ac_cv_AM_TEST_RUNNER_SHELL])
 380
 381 if test $AM_TEST_RUNNER_SHELL = no; then
 382   AC_MSG_FAILURE([m4_normalize([no POSIX shell found that is good
 383                                 enough to be used in our testsuite])])
 384 else
 385   AC_MSG_NOTICE([will use $AM_TEST_RUNNER_SHELL as the testsuite shell])
 386 fi
 387
 388 AC_ARG_VAR([AM_TEST_RUNNER_SHELL],
 389            [a sturdy POSIX shell for our testsuite])
 390
 391
 392 ###########################################################################
 393
 394 # Look for C, C++ and fortran compilers to be used in the testsuite.
 395
 396 dnl We don't want to abort our configuration script if no C compiler is
 397 dnl available, as such a compiler is only required to run part of the
 398 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 399 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 400 dnl easy way to obtain this behavior, so we'll need a few hacks.
 401
 402 dnl We want the body of this macro to expand as a single shell statement,
 403 dnl thus we wrap it into { ... } brackets.
 404 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 405   AC_MSG_WARN([$1])
 406   am__failed=yes
 407   break
 408 } ])
 409
 410 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 411   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 412   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 413   am__failed=no
 414   while :; do
 415      $1
 416      break
 417   done
 418   AS_IF([test $am__failed = yes], [$2])
 419   # We have to clear these cache variables, so that future checks on
 420   # compilers for different languages won't be confused.
 421   unset ac_cv_objext ac_cv_exeext
 422   # We also need to meddle with the autoconf internals to ensure that
 423   # checks to find object and executable extensions will be run anew.
 424   # FIXME: In the long run, the better thing to do would be to fix
 425   # FIXME: autoconf instead ...
 426   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 427   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 428   m4_popdef([AC_MSG_FAILURE])
 429   m4_popdef([AC_MSG_ERROR])
 430 ])
 431
 432 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 433   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 434
 435 # Prefer generic compilers to GNU ones when possible.  This will ensure
 436 # more testsuite coverage "in the wild".
 437 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 438 # deliberate; for more discussion and rationale, see:
 439 # <https://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 440
 441 AC_MSG_NOTICE([will now look for generic compilers])
 442
 443 # C compiler.
 444 _AM_COMPILER_CAN_FAIL(dnl
 445   [AC_PROG_CC([cc gcc])],
 446   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 447
 448 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 449
 450 # On case-insensitive file systems (seen e.g. on Cygwin and Mac OS X)
 451 # we must avoid looking for 'CC', because that would be the same as
 452 # 'cc', and could cause $CXX to point to the C compiler, instead of
 453 # to a C++ compiler as expected (see automake bugs #11893 and #10766).
 454 # Similarly, we must avoid looking for 'RCC', as that can point to the
 455 # Qt4 "Resource Compiler": <http://doc.qt.digia.com/4.2/rcc.html>
 456 # And we avoid looking for 'KCC' as that can be a kerberos tool under
 457 # macOS systems.
 458 if test -f /bIn/rMdIr || test -f /uSr/bIn/rMdIr; then
 459   # Case-insensitive file system, don't look for CC.
 460   am_CC= am_RCC= am_KCC=
 461 else
 462   am_CC=CC am_RCC=RCC am_KCC=KCC
 463 fi
 464
 465 # The list of C++ compilers here has been copied, pasted and edited
 466 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 467 # Keep it in sync, or better again, find out a way to avoid this code
 468 # duplication.
 469 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 470   [aCC $am_CC FCC $am_KCC $am_RCC xlC_r xlC c++ cxx cc++ gpp g++ clang++])],
 471   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 472
 473 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 474
 475 # The lists of Fortran compilers here has been copied, pasted and edited
 476 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 477 # Keep it in sync, or better again, find out a way to avoid this code
 478 # duplication.
 479
 480 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 481   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 482   [xlf90 f90 armflang flang pgf90 pghpf epcf90 g95 gfortran])],
 483   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 484
 485 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 486
 487 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 488   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 armflang flang gfortran])],
 489   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 490
 491 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 492
 493 # Some tests will need the GNU compilers.  Searching for them here would
 494 # be overkill, since our testsuite already handles their search and setup
 495 # pretty well.  But in case the compilers already found are the GNU ones,
 496 # we want to use them in the testsuite where GNU compilers are required.
 497 # Also, in case the compilers detected above (at configure time) are not
 498 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 499 # FFLAGS detected for them with the GNU compilers too, since it's likely
 500 # they won't be compatible.  So we allow the user to define variants of
 501 # these variables for the GNU compilers separately.
 502
 503 AC_MSG_NOTICE([will now look for GNU compilers])
 504
 505 # GNU C compiler.
 506 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 507 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 508 if test $am_CC_is_GNU = yes; then
 509   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 510   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 511 else
 512   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 513 fi
 514 if test "$GNU_CC" != false; then
 515   AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 516         [AC_MSG_WARN([botched installation for GNU C compiler])
 517          _AM_SKIP_COMP_TESTS([GNU C])])
 518 fi
 519
 520 # GNU C++ compiler.
 521 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 522 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 523 if test $am_CXX_is_GNU = yes; then
 524   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 525   GNU_CXX=$CXX
 526   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 527 else
 528   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 529 fi
 530 if test "$GNU_CXX" != false; then
 531   AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 532         [AC_MSG_WARN([botched installation for GNU C++ compiler])
 533          _AM_SKIP_COMP_TESTS([GNU C++])])
 534 fi
 535
 536 # GNU Fortran compiler.
 537 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 538 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 539 if test $am_FC_is_GNU = yes; then
 540   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 541   GNU_FC=$FC
 542   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 543 else
 544   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 545 fi
 546 if test "$GNU_FC" != false; then
 547   AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 548         [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 549          _AM_SKIP_COMP_TESTS([GNU Fortran])])
 550 fi
 551
 552 # GNU Fortran 77 compiler.
 553 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 554 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 555 if test $am_F77_is_GNU = yes; then
 556   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 557   GNU_F77=$F77
 558   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 559 else
 560   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 561 fi
 562 if test "$GNU_F77" != false; then
 563   AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 564         [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 565         _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 566 fi
 567
 568 # GNU Java compiler.
 569 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 570 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 571 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 572 if test "$GNU_GCJ" != false; then
 573   AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 574         [AC_MSG_WARN([botched installation for GNU Java compiler])
 575         _AM_SKIP_COMP_TESTS([GNU Java])])
 576 fi
 577
 578 # If we have been able to find at least a working compiler above, we
 579 # know what the object and executable extensions for this platform are.
 580 OBJEXT=${ac_cv_objext-UNKNOWN}
 581 EXEEXT=${ac_cv_exeext-UNKNOWN}
 582 AC_SUBST([OBJEXT])
 583 AC_SUBST([EXEEXT])
 584
 585 ###########################################################################
 586
 587 ## ---------------------- ##
 588 ##  Create output files.  ##
 589 ## ---------------------- ##
 590
 591 AC_CONFIG_FILES([Makefile])
 592 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 593 AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
 594 AC_OUTPUT
 595
 596 # Inform the user if this version of automake is a beta release or
 597 # a development snapshot. Except, as of 1.17 (January 2024), don't bother.
 598 # Just call all pretests development snapshots.
 599 #
 600 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 601
 602 # This won't match anything as of 1.17, since we switched to
 603 # .90-numbered test releases. But if we wanted to, according to HACKING,
 604 # the version of a development snapshot should end with an odd number
 605 # (91, 93, ...) and a beta release should end with an even number (90,
 606 # 92, ...).
 607 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]" # no match
 608
 609 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 610   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 611   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 612   { print \"development snapshot\"; }"]`
 613
 614 # '$silent' is set to yes if configure is passed the '--quiet' option.
 615 test "$am_release_type" = stable || test "$silent" = yes || cat <<EOF
 616
 617 WARNING: You are about to use a $am_release_type of automake.
 618 WARNING: It could well suffer from new bugs or regressions.
 619 WARNING: You are strongly advised not to use it in production code.
 620
 621 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>,
 622 since that is the whole point of a test release.
 623 EOF
 624
 625 AS_EXIT([0])