docs/meson.build

   1 subdir('graphics')
   2
   3 xml_insert = find_program(
   4   xml_insert_file,
   5   native: true
   6 )
   7
   8 index_static_html = configure_file(
   9   input : 'index-static.html.in',
  10   output: 'index-static.html',
  11   configuration: conf,
  12 )
  13
  14 babl_css = configure_file(
  15   input : 'babl.css',
  16   output : 'babl.css',
  17   copy: true
  18 )
  19
  20 index_html_tmp_env = [
  21   'BABL_PATH=' + babl_extensions_build_dir,
  22 ]
  23
  24 # Don't build babl ref if cannot run compiled objects in this env
  25 if env_bin.found() and can_run_host_binaries
  26   index_html_tmp = custom_target('index.html.tmp',
  27     input : babl_html_dump,
  28     output:'index.html.tmp',
  29     command: [
  30       env_bin,
  31       index_html_tmp_env,
  32       babl_html_dump
  33     ],
  34     capture: true,
  35   )
  36 else
  37   warning('Cannot create babl reference in this environment')
  38   index_html_tmp = 'index.html.tmp'
  39 endif
  40
  41 TOC = files('toc')
  42 html_files = {
  43   'index': ['index-static.html.in', [
  44     ['AUTHORS', authors_file],
  45     ['TODO',    todo_file],
  46     ['NEWS',    news_file],
  47     ['TOC',     TOC],
  48   ]],
  49   'Reference': ['auto', [
  50     ['BablBase', index_html_tmp],
  51     ['TOC',      TOC],
  52   ]],
  53   'CMYK': ['auto', [
  54     ['TOC', TOC]
  55   ]],
  56   'OldNews': ['auto', [
  57     ['TOC', TOC],
  58   ]],
  59   'Glossary': ['auto', [
  60     ['TOC', TOC],
  61   ]],
  62   'ColorManagement': ['auto', [
  63     ['TOC', TOC],
  64   ]],
  65   'UnifiedAlpha': ['auto', [
  66     ['TOC', TOC],
  67   ]],
  68 }
  69
  70 foreach _file, _parms : html_files
  71   if '@0@'.format(_parms[0]) == 'auto'
  72     _in = '@0@-static.html'.format(_file)
  73   else
  74     _in = _parms[0]
  75   endif
  76   _out = '@0@.html'.format(_file)
  77
  78   inserts = []
  79   foreach _parm : _parms[1]
  80     inserts += ['--insert', _parm[0], _parm[1]]
  81   endforeach
  82
  83   _tgt = custom_target(_out,
  84     input: _in,
  85     output: _out,
  86     command: [
  87       xml_insert,
  88       '--output' , '@OUTPUT@',
  89       inserts,
  90       '@INPUT@',
  91     ],
  92     build_by_default: true
  93   )
  94   if _file == 'index'
  95     index_html = _tgt
  96   endif
  97 endforeach
  98
  99 # gi-docgen API reference
 100
 101 if build_gi_docgen
 102   subdir('reference')
 103 endif