configure.ac

   1 AC_INIT([barvinok], [0.35], [isl-development@googlegroups.com])
   2 AC_CONFIG_MACRO_DIR([m4])
   3 AM_INIT_AUTOMAKE([foreign])
   4 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   5 AC_PROG_CC
   6
   7 AC_PROG_CXX
   8 AM_PROG_LEX
   9 AC_PROG_YACC
  10 AC_SUBST(versioninfo)
  11 versioninfo=23:0:0
  12
  13 AC_CANONICAL_HOST
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_SUBST(BV_LDFLAGS)
  16 case $host in
  17         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  18         if test "$enable_shared" = yes; then
  19                 BV_LDFLAGS="-no-undefined"
  20         fi
  21         ;;
  22 esac
  23
  24 AC_PROG_LIBTOOL
  25
  26 PKG_PROG_PKG_CONFIG
  27
  28 AC_CHECK_HEADERS(getopt.h)
  29 AC_CHECK_HEADERS(sys/times.h)
  30 AC_CHECK_FUNCS(sigaction)
  31
  32 AC_MSG_CHECKING(whether to build shared libbarvinok)
  33 AC_ARG_ENABLE(shared_barvinok,
  34         AS_HELP_STRING([--enable-shared-barvinok],
  35                        [build shared barvinok library]),
  36         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  37 AC_MSG_RESULT($bv_cv_shared_barvinok)
  38 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  39         BV_LDFLAGS="$BV_LDFLAGS -static"
  40 fi
  41
  42 AC_CXX_GNUCXX_HASHMAP
  43
  44 AC_ARG_WITH(default-prefix,
  45         AS_HELP_STRING([--with-default-prefix=DIR],
  46             [Default installation prefix of optional packages]))
  47 if test "${with_default_prefix+set}" = set; then
  48         if test "${with_libgmp+set}" != set -a \
  49            -f "$with_default_prefix/include/gmp.h"; then
  50                 with_libgmp=$with_default_prefix
  51         fi
  52         if test "${with_ntl+set}" != set -a \
  53            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  54                 with_ntl=$with_default_prefix
  55         fi
  56         if test "${with_cddlib+set}" != set -a \
  57            -f "$with_default_prefix/include/cddmp.h"; then
  58                 with_cddlib=$with_default_prefix
  59         fi
  60         if test "${with_glpk+set}" != set -a \
  61            -f "$with_default_prefix/include/glpk.h"; then
  62                 with_glpk=$with_default_prefix
  63         fi
  64         if test "${with_topcom+set}" != set -a \
  65            -f "$with_default_prefix/bin/points2triangs"; then
  66                 with_topcom=$with_default_prefix
  67         fi
  68 fi
  69
  70 dnl Check for GMP library
  71 AC_MSG_CHECKING(whether to use GMP)
  72 AC_ARG_WITH(libgmp,
  73         [  --with-libgmp           DIR Location of the GMP Distribution],
  74         gmp_package=$withval, gmp_package=yes)
  75 if test "x$gmp_package" = "xno"; then
  76         AC_MSG_RESULT(no)
  77         AC_MSG_ERROR(Need gmp)
  78 else
  79         AC_MSG_RESULT(yes)
  80         if test "x$gmp_package" = "xyes"; then
  81                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  82         else
  83             bv_configure_args="$bv_configure_args --with-libgmp=$gmp_package"
  84             bv_configure_args="$bv_configure_args --with-gmp-prefix=$gmp_package"
  85             GMP_DIR=$gmp_package
  86             if test ! -d "$GMP_DIR"; then
  87                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  88             fi
  89             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  90             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  91         fi
  92         poly_cv_gmpfatal="no"
  93         AC_CHECK_HEADER(gmp.h,
  94                 [AC_CHECK_LIB(gmp,main,
  95                     [],
  96                     [poly_cv_gmpfatal="yes"])],
  97                 [poly_cv_gmpfatal="yes"])
  98         if test "$poly_cv_gmpfatal" = "yes"; then
  99                 AC_MSG_ERROR([GMP not found])
 100         fi
 101 fi
 102 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 103
 104 AX_SUBMODULE(polylib,build|bundled|system,bundled)
 105
 106 AC_SUBST(POLYLIB_CPPFLAGS)
 107 AC_SUBST(POLYLIB_LDFLAGS)
 108 AC_SUBST(POLYLIB_LIBS)
 109 case "$with_polylib" in
 110 bundled)
 111         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 112         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 113         ;;
 114 build)
 115         with_polylib_builddir=`echo @abs_builddir@ | $with_polylib_builddir/config.status --file=-`
 116         POLYLIB_CPPFLAGS="-I$polylib_srcdir/include -I$with_polylib_builddir/include"
 117         POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
 118         ;;
 119 system)
 120         POLYLIB_LIBS="-lpolylibgmp"
 121         if test "x$with_polylib_prefix" != "x"; then
 122                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 123                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 124         fi
 125         SAVE_CPPFLAGS="$CPPFLAGS"
 126         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 127         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 128                 AC_MSG_ERROR(Need PolyLib)
 129         ])
 130         CPPFLAGS="$SAVE_CPPFLAGS"
 131 esac
 132
 133 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 134
 135 AX_SUBMODULE(isl,build|bundled|system,bundled)
 136
 137 AC_SUBST(ISL_CFLAGS)
 138 AC_SUBST(ISL_LIBS)
 139 AC_SUBST(ISL_BUILDDIR)
 140 case "$with_isl" in
 141 bundled)
 142         ISL_BUILDDIR=isl
 143         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 144         bv_configure_args="$bv_configure_args --with-isl-builddir=../isl"
 145         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 146         ;;
 147 build)
 148         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 149         bv_configure_args="$bv_configure_args --with-isl-builddir=$ISL_BUILDDIR"
 150         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 151         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 152         ;;
 153 system)
 154         PKG_CHECK_MODULES([ISL], [isl])
 155         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 156 esac
 157 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 158 AM_CONDITIONAL(BUILD_ISL, test $with_isl = build)
 159
 160 AX_SUBMODULE(pet,bundled|build|system|no,no)
 161 AC_SUBST(PET_CFLAGS)
 162 AC_SUBST(PET_LIBS)
 163 AC_SUBST(PET_BUILDDIR)
 164 case "$with_pet" in
 165 bundled)
 166         PET_CFLAGS="-I\$(top_srcdir)/pet/include"
 167         AC_DEFINE(HAVE_PET,[],[use Pet])
 168         ;;
 169 build)
 170         PET_BUILDDIR=`echo @abs_builddir@ | $with_pet_builddir/config.status --file=-`
 171         PET_CFLAGS="-I$pet_srcdir/include"
 172         AC_DEFINE(HAVE_PET,[],[use Pet])
 173         ;;
 174 system)
 175         PKG_CHECK_MODULES([PET], [pet])
 176         AC_DEFINE(HAVE_PET,[],[use Pet])
 177 esac
 178 AM_CONDITIONAL(BUNDLED_PET, test $with_pet = bundled)
 179 AM_CONDITIONAL(BUILD_PET, test $with_pet = build)
 180
 181 AX_SUBMODULE(isl-polylib,build|bundled|system,bundled)
 182
 183 AC_SUBST(ISL_POLYLIB_CFLAGS)
 184 AC_SUBST(ISL_POLYLIB_LIBS)
 185 case "$with_isl_polylib" in
 186 bundled)
 187         ISL_POLYLIB_CFLAGS="-I\$(top_srcdir)/isl-polylib/include -I\$(top_builddir)/isl-polylib/include"
 188         ;;
 189 build)
 190         ISL_POLYLIB_CFLAGS="-I$isl_polylib_srcdir/include -I$with_isl_polylib_builddir/include"
 191         ISL_POLYLIB_LIBS="$with_isl_polylib_builddir/libisl-polylib.la"
 192         ;;
 193 system)
 194         PKG_CHECK_MODULES([ISL_POLYLIB], [isl-polylib])
 195 esac
 196 AM_CONDITIONAL(BUNDLED_ISL_POLYLIB, test $with_isl_polylib = bundled)
 197
 198 AC_MSG_CHECKING(if the fractional representation should be used)
 199 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 200                                           [Don't use fractional representation])],
 201             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 202 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 203                                       [Don't use fractional representation])],
 204             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 205 AC_MSG_RESULT($bv_cv_modulo)
 206 if test "x$bv_cv_modulo" != "xno" ; then
 207         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 208 fi
 209
 210 AC_MSG_CHECKING(whether to use incremental algorithm)
 211 AC_ARG_ENABLE(incremental,
 212         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 213                         [Enable incremental algorithm [bf]])],
 214         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 215 AC_MSG_RESULT($bv_cv_incremental)
 216 case $bv_cv_incremental in
 217         yes | bf)
 218                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 219                           [Use breadth-first incremental algorithm])
 220         ;;
 221         df)
 222                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 223                           [Use depth-first incremental algorithm])
 224         ;;
 225 esac
 226
 227 AC_ARG_WITH(ntl,
 228             [  --with-ntl=DIR          DIR Location of NTL],
 229             [ echo "Package ntl : $withval" && ntl_package=$withval],
 230             [ ntl_package=yes ])
 231
 232 if test "$ntl_package" = "no"; then
 233     AC_MSG_ERROR(Need ntl)
 234 fi
 235
 236 AC_SUBST(NTL_CPPFLAGS)
 237 AC_SUBST(NTL_LDFLAGS)
 238 if test "$ntl_package" != "yes"; then
 239     NTL_CPPFLAGS="-I$ntl_package/include"
 240     NTL_LDFLAGS="-L$ntl_package/lib"
 241 fi
 242
 243 bv_no_ntl=false
 244 SAVE_CPPFLAGS="$CPPFLAGS"
 245 SAVE_LDFLAGS="$LDFLAGS"
 246 CPPFLAGS="$NTL_CPPFLAGS $CPPFLAGS"
 247 LDFLAGS="$NTL_LDFLAGS $LDFLAGS"
 248 AC_LANG_PUSH(C++)
 249 AC_CHECK_HEADER([NTL/ZZ.h],[],[bv_no_ntl=true])
 250 AC_EGREP_CPP(yes, [
 251     #include <NTL/ZZ.h>
 252     #ifdef NTL_GMP_LIP
 253     yes
 254     #endif
 255     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 256 AC_LANG_POP
 257
 258 AC_CHECK_LIB(ntl, main,[],[bv_no_ntl=true])
 259 if test "$bv_no_ntl" = "true"; then
 260     AC_MSG_ERROR(Need ntl)
 261 fi
 262 CPPFLAGS="$SAVE_CPPFLAGS"
 263 LDFLAGS="$SAVE_LDFLAGS"
 264
 265 AC_SUBST(bv_cone_hilbert_basis)
 266 AC_MSG_CHECKING(whether to compile zsolve)
 267 AC_ARG_WITH(zsolve,
 268             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 269             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 270 AC_MSG_RESULT($with_zsolve)
 271
 272 use_zsolve=false
 273 if test "$with_zsolve" != "no"; then
 274         if test "$GCC" = "yes"; then
 275                 $CC --version |
 276                 sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 277                 (read major minor
 278                         if test $major -gt 3; then
 279                                 exit 0
 280                         fi
 281                         if test $major -eq 3 -a $minor -ge 4; then
 282                                 exit 0
 283                         fi
 284                         exit 1
 285                 ) && use_zsolve=true
 286         fi
 287         if test "$use_zsolve" = false; then
 288                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 289         else
 290                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 291                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 292         fi
 293 fi
 294 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 295
 296 AX_SUBMODULE(omega,no|system,no)
 297
 298 AC_SUBST(OMEGA_CPPFLAGS)
 299 AC_SUBST(OMEGA_LDFLAGS)
 300 AC_SUBST(OMEGA_LIBS)
 301 AC_SUBST(OMEGA_CODEGEN_LIBS)
 302 have_omega=false
 303 have_codegen=false
 304 case "$with_omega" in
 305 system)
 306     if test "x$with_omega_prefix" != "xyes"; then
 307         OMEGA_CPPFLAGS="-I$with_omega_prefix/include/omega"
 308         OMEGA_LDFLAGS="-L$with_omega_prefix/lib"
 309     else
 310         for i in /usr/include /usr/local/include; do
 311             if test -f $i/omega/omega.h; then
 312                 OMEGA_CPPFLAGS="-I$i/omega"
 313             fi
 314         done
 315     fi
 316
 317     AC_LANG_PUSH(C++)
 318     SAVE_CPPFLAGS="$CPPFLAGS"
 319     SAVE_LDFLAGS="$LDFLAGS"
 320     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 321     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 322     AC_CHECK_HEADERS([omega.h],[
 323         OMEGA_LIBS="-lomega"
 324         AC_CHECK_LIB(code_gen,main,[
 325                 OMEGA_CODEGEN_LIBS="-lcode_gen -lomega"
 326                 have_codegen=true
 327         ])
 328         have_omega=true
 329     ],[AC_MSG_WARN(Omega not found)])
 330     CPPFLAGS="$SAVE_CPPFLAGS"
 331     LDFLAGS="$SAVE_LDFLAGS"
 332     AC_LANG_POP
 333     ;;
 334 esac
 335 if test "$have_omega" = true; then
 336         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 337 fi
 338 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 339
 340 use_parker=false
 341 AC_MSG_CHECKING(whether to compile parker)
 342 AC_ARG_WITH(parker,
 343             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 344             [ with_parker=$withval],  [ with_parker=yes ])
 345 AC_MSG_RESULT($with_parker)
 346
 347 if test "$with_parker" != "no"; then
 348         AC_MSG_CHECKING(for mona)
 349         AC_ARG_WITH(mona,
 350                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 351                                 [], [AC_MSG_RESULT(not specified)])
 352
 353         if test "x$with_mona" != "x"; then
 354                 AC_SUBST(MONAPATH)
 355                 MONAPATH=$with_mona
 356                 AC_MSG_RESULT($MONAPATH)
 357                 use_parker=true
 358                 AC_DEFINE(USE_PARKER,[],[use parker])
 359         fi
 360
 361         if test "x$with_mona" = "x"; then
 362                 AC_MSG_WARN(mona source directory required to compile parker)
 363                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 364         fi
 365 fi
 366 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 367
 368 AC_MSG_CHECKING(whether to use cddlib)
 369 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 370             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 371 AC_MSG_RESULT($cddlib_package)
 372
 373 have_cddlib=false
 374 if test "$cddlib_package" != "no"; then
 375     if test "x$cddlib_package" != "xyes"; then
 376         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 377         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 378     fi
 379     AC_TRY_LINK([
 380 #define GMPRATIONAL
 381 #include <setoper.h>
 382 #include <cddmp.h>
 383 ], [
 384     mytype a;
 385     dd_init(a); ], [
 386         have_cddlib=true
 387         AC_CHECK_LIB(cddgmp, main,[
 388                 SAVE_LIBS="$LIBS"
 389                 LIBS="-lcddgmp $LIBS"
 390                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 391                 AC_LANG_PUSH(C++)
 392                 AC_RUN_IFELSE([AC_LANG_PROGRAM([[#define GMPRATIONAL
 393 #include <setoper.h>
 394 #include <cdd.h>]],
 395                 [[
 396         const char *filename = SRCDIR"/cdd94e-test";
 397         FILE *f;
 398         dd_MatrixPtr M;
 399         dd_LPType *lp;
 400         dd_ErrorType err = dd_NoError;
 401
 402         dd_set_global_constants();
 403
 404         f = fopen(filename, "r");
 405         M = dd_PolyFile2Matrix(f, &err);
 406         lp = dd_Matrix2LP(M, &err);
 407         dd_LPSolve(lp, dd_DualSimplex, &err);
 408         return lp->LPS == dd_Inconsistent;
 409                 ]])],[
 410                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 411                 ],[
 412                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 413                         LIBS="$SAVE_LIBS"
 414                         have_cddlib=false
 415                 ])
 416                 AC_LANG_POP
 417         ],[have_cddlib=false])
 418     ])
 419 fi
 420 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 421
 422
 423
 424 AC_MSG_CHECKING(whether to use GLPK)
 425 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 426             [ glpk_package=$withval],  [ glpk_package=yes ])
 427 AC_MSG_RESULT($glpk_package)
 428
 429 have_glpk=false
 430 if test "$glpk_package" != "no"; then
 431     if test "x$glpk_package" != "xyes"; then
 432         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 433         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 434     fi
 435     AC_CHECK_HEADERS([glpk.h],[
 436         have_glpk=true
 437         AC_CHECK_LIB(glpk, main,[],[have_glpk=false])
 438     ])
 439 fi
 440 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 441
 442 AC_MSG_CHECKING(location of TOPCOM)
 443 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 444             [topcom_package=$withval], [topcom_package=unspecified])
 445 AC_MSG_RESULT($topcom_package)
 446 have_topcom=false
 447 if test "$topcom_package" != no; then
 448         topcom_path="$PATH"
 449         if test "$topcom_package" != unspecified; then
 450                 topcom_path="$topcom_package/bin"
 451         fi
 452         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 453         if test -n "$POINTS2TRIANGS"; then
 454                 have_topcom=true
 455                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 456                                     [Path of points2triangs])
 457         fi
 458 fi
 459 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 460
 461 AX_SUBMODULE(cloog,no|build|bundled|system,bundled)
 462
 463 AC_SUBST(CLOOG_LDFLAGS)
 464 AC_SUBST(CLOOG_CFLAGS)
 465 AC_SUBST(CLOOG_LIBS)
 466 CLOOG_CFLAGS="-DCLOOG_INT_GMP=1"
 467 case "$with_cloog" in
 468 bundled)
 469         CLOOG_CFLAGS="$CLOOG_CFLAGS -I\$(top_srcdir)/cloog/include -I\$(top_builddir)/cloog/include"
 470         AC_DEFINE(HAVE_CLOOG,[],[use CLooG])
 471         ;;
 472 build)
 473         with_cloog_builddir=`echo @abs_builddir@ | $with_cloog_builddir/config.status --file=-`
 474         CLOOG_CFLAGS="$CLOOG_CFLAGS -I$cloog_srcdir/include -I$with_cloog_builddir/include"
 475         CLOOG_LIBS="$with_cloog_builddir/libcloog-isl.la"
 476         AC_DEFINE(HAVE_CLOOG,[],[use CLooG])
 477         ;;
 478 system)
 479         if test "x$with_cloog_prefix" != "x"; then
 480                 CLOOG_CFLAGS="$CLOOG_CFLAGS -I$with_cloog_prefix/include"
 481         fi
 482         if test "x$with_cloog_exec_prefix" != "x"; then
 483                 CLOOG_LDFLAGS="-L$with_cloog_exec_prefix/lib"
 484         fi
 485         CLOOG_LIBS="-lcloog-isl"
 486         AC_DEFINE(HAVE_CLOOG,[],[use CLooG])
 487 esac
 488 AM_CONDITIONAL(BUNDLED_CLOOG, test $with_cloog = bundled)
 489
 490 AC_SUBST(GIT_HEAD_ID)
 491 AC_SUBST(GIT_HEAD)
 492 AC_SUBST(GIT_HEAD_VERSION)
 493 if test -f $srcdir/.git/HEAD; then
 494     GIT_HEAD="$srcdir/.git/index"
 495     GIT_REPO="$srcdir/.git"
 496     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git describe`
 497 elif test -f $srcdir/GIT_HEAD_ID; then
 498     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 499 else
 500     mysrcdir=`(cd $srcdir; pwd)`
 501     head=`basename $mysrcdir | sed -e 's/.*-//'`
 502     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 503     head3=`echo $head2 | sed -e 's/........................................//'`
 504     base=`basename $mysrcdir | sed -e 's/-.*//'`
 505     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 506         GIT_HEAD_ID="barvinok-$VERSION-$head
 507     elif test "x$base" = "xbarvinok-$VERSION" -a "x$head" != "x"; then
 508         GIT_HEAD_ID="barvinok-$VERSION-$head
 509     else
 510         GIT_HEAD_ID="UNKNOWN"
 511     fi
 512 fi
 513 if test -z "$GIT_REPO" ; then
 514     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 515 else
 516     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git describe\`"
 517 fi
 518 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 519
 520 AC_LANG_PUSH(C++)
 521 AC_TRY_COMPILE([
 522                 #include <set>
 523                 void negate();
 524         ], [negate()],
 525         suffix="normal", suffix="broken")
 526 AC_CONFIG_COMMANDS([barvinok/set.h],
 527                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 528                    [suffix="$suffix"])
 529 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 530                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 531                    [suffix="$suffix"])
 532 use_fdstream=false
 533 SAVE_CPPFLAGS="$CPPFLAGS"
 534 CPPFLAGS="-I$srcdir $CPPFLAGS"
 535 AC_TRY_COMPILE([#include "fdstream.h"],[],
 536         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 537         use_fdstream=true])
 538 CPPFLAGS="$SAVE_CPPFLAGS"
 539 AC_LANG_POP
 540 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 541
 542 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 543 PACKAGE_LIBS="-lbarvinok $EXTRA_PACKAGE_LIBS -lisl-polylib -lpolylibgmp -lisl"
 544 AX_CREATE_PKGCONFIG_INFO
 545
 546 AC_CONFIG_HEADERS(config.h)
 547 AC_CONFIG_FILES(Makefile zsolve/Makefile doc/Makefile)
 548 AC_CONFIG_FILES(parker/Makefile)
 549 if test $with_polylib = bundled; then
 550         AC_CONFIG_SUBDIRS(polylib)
 551 fi
 552 if test $with_isl = bundled; then
 553         AC_CONFIG_SUBDIRS(isl)
 554 fi
 555 if test $with_pet = bundled; then
 556         AC_CONFIG_SUBDIRS(pet)
 557 fi
 558 if test $with_isl_polylib = bundled; then
 559         AC_CONFIG_SUBDIRS(isl-polylib)
 560 fi
 561 if test $with_cloog = bundled; then
 562         AC_CONFIG_SUBDIRS(cloog)
 563 fi
 564 AC_CONFIG_COMMANDS_POST([
 565         dnl pass on arguments to subdir configures, but don't
 566         dnl add them to config.status
 567         ac_configure_args="$ac_configure_args $bv_configure_args"
 568 ])
 569 AC_OUTPUT