configure.in

   1
   2 ###
   3 ### Welcome to Beagle's configure.in.  We hope you enjoy your stay.
   4 ###
   5
   6 AC_INIT(beagled/BeagleDaemon.cs)
   7 AC_CANONICAL_SYSTEM
   8 AM_INIT_AUTOMAKE(beagle, 0.2.1)
   9
  10 ########################################################################
  11
  12 ###
  13 ### Some dependencies
  14 ###
  15
  16 MONO_REQUIRED=1.1.10
  17 GTK_SHARP_REQUIRED=2.3.90
  18 GMIME_SHARP_REQUIRED=2.1.19
  19 EVOLUTION_SHARP_REQUIRED=0.10.2
  20 GSF_SHARP_REQUIRED=0.6
  21 GTK_REQUIRED=2.6.0
  22
  23 LIBBEAGLE_GOBJECT_REQUIRED=2.6
  24 LIBBEAGLE_LIBXML_REQUIRED=2.6.19
  25
  26 PYTHON_REQUIRED=2.3
  27 PYGTK_REQUIRED=2.6
  28
  29 ########################################################################
  30
  31 AM_MAINTAINER_MODE
  32 AM_CONFIG_HEADER(config.h)
  33
  34 AC_PROG_INSTALL
  35 AM_PROG_LIBTOOL
  36 AC_PROG_CXX
  37
  38 VERSION=${VERSION}
  39 AC_SUBST(VERSION)
  40
  41 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  42 if test "x$PKG_CONFIG" = "xno"; then
  43         AC_MSG_ERROR([You need to install pkg-config])
  44 fi
  45
  46 AC_PATH_PROG(BASH, bash)
  47 AC_SUBST(BASH)
  48
  49 # mozilla extension uses zip to create the jar/xpi files
  50 AC_PATH_PROG(ZIP, zip)
  51
  52 AC_PATH_PROG(MONO, mono)
  53 AC_PATH_PROG(MCS, mcs)
  54
  55 AC_MSG_CHECKING([for mono.pc])
  56 if test -z `$PKG_CONFIG --variable=prefix mono`; then
  57   AC_MSG_ERROR([missing the mono.pc file, usually found in the mono-devel package])
  58 else
  59   AC_MSG_RESULT([found])
  60 fi
  61
  62 # check that we have the require version of mono
  63 PKG_CHECK_MODULES(MONO, mono >= $MONO_REQUIRED)
  64
  65 # SharpZipLib broke API in 1.1.11.  Route around the damage.
  66 if `$PKG_CONFIG --atleast-version=1.1.11 mono`; then
  67   SHARPZIPLIB_LIBS="-r:`$PKG_CONFIG --variable=prefix mono`/lib/mono/compat-1.0/ICSharpCode.SharpZipLib.dll"
  68 else
  69   SHARPZIPLIB_LIBS="-r:ICSharpCode.SharpZipLib"
  70 fi
  71 AC_SUBST(SHARPZIPLIB_LIBS)
  72
  73 # check for various mono DLLs that we need.
  74 needed_dlls="Mono.Data.SqliteClient Mono.Posix System.Runtime.Remoting System.Web System.Web.Services"
  75 for i in $needed_dlls; do
  76   AC_MSG_CHECKING([for $i.dll])
  77   if test ! -e `$PKG_CONFIG --variable=prefix mono`/lib/mono/1.0/$i.dll; then
  78     AC_MSG_ERROR([missing required mono DLL: $i.dll])
  79   else
  80     AC_MSG_RESULT([found])
  81   fi
  82 done
  83
  84 # check for OS
  85 case "$target" in
  86   *-*-linux*)
  87     os=linux
  88         os_has_inotify=yes
  89     ;;
  90   *-*-freebsd*)
  91     os=freebsd
  92         os_has_inotify=no
  93     ;;
  94   *)
  95     AC_MSG_ERROR([Unrecognised target OS: $target])
  96     ;;
  97 esac
  98 AM_CONDITIONAL(OS_LINUX, test "x$os" = "xlinux")
  99 AM_CONDITIONAL(OS_FREEBSD, test "x$os" = "xfreebsd")
 100
 101 # check for desktop-launch
 102
 103 AC_PATH_PROG(DESKTOP_LAUNCH, desktop-launch, no)
 104 AM_CONDITIONAL(ENABLE_DESKTOP_LAUNCH, test "x$DESKTOP_LAUNCH" != "xno")
 105
 106 # check for wsdl
 107 AC_PATH_PROG(WSDL, wsdl)
 108
 109 #
 110 # I18N
 111 #
 112
 113 AC_PROG_INTLTOOL([0.23])
 114 GETTEXT_PACKAGE=beagle
 115 AC_SUBST(GETTEXT_PACKAGE)
 116 ALL_LINGUAS="bg ca cs da de el en_CA en_GB es fi fr gl he hu it ja ko lt mk nb nl no pl pt_BR sv tr uk vi zh_CN zh_HK zh_TW"
 117 AM_GLIB_GNU_GETTEXT
 118 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Name of the package for translations])
 119
 120 # Many distros don't have a dependency on sqlite for their
 121 # mono-data-sqlite packages, and the mono build process itself
 122 # doesn't require it.  But we do, so check for it here.
 123 SQLITE_MAJ_VER="0"
 124 PKG_CHECK_MODULES(SQLITE, sqlite, SQLITE_MAJ_VER="2", do_nothing="1")
 125 # Note we really need 3.3.1, but the pkgconfig file from upstream only
 126 # reports 3.3 for all releases in the 3.3 line.
 127 PKG_CHECK_MODULES(SQLITE3, sqlite3 >= 3.3, SQLITE_MAJ_VER="3", do_nothing="1")
 128
 129 if test "x$SQLITE_MAJ_VER" = "x0"; then
 130         # Note we really need 3.3.1, but the pkgconfig file from upstream only
 131         # reports 3.3 for all releases in the 3.3 line.  Make sure we error out
 132         # with the correct 3.3.1 version requirement, though.
 133         AC_MSG_ERROR([You need to install sqlite 2.x or >= 3.3.1])
 134 fi
 135
 136 AC_SUBST(SQLITE_MAJ_VER)
 137
 138 # Needed by glue/screensaver-glue.c
 139 # The OLD_CFLAGS/CFLAGS hack is needed to build on Ubuntu Breezy Badger
 140 OLD_CFLAGS="$CFLAGS"
 141 OLD_LDFLAGS="$LDFLAGS"
 142 OLD_LIBS="$LIBS"
 143 CFLAGS="$CFLAGS -I/usr/X11R6/include"
 144 LDFLAGS="$LDFLAGS -L/usr/X11R6/lib"
 145 AC_CHECK_HEADER(X11/extensions/scrnsaver.h,, [AC_MSG_ERROR([Unable to find scrnsaver.h.  You probably need to install X development packages])])
 146 AC_CHECK_LIB(Xss,XScreenSaverQueryExtension,, [AC_MSG_ERROR([Unable to find libXss.  You probably need to install X development packages])])
 147 CFLAGS="$OLD_CFLAGS"
 148 LDFLAGS="$OLD_LDFLAGS"
 149 LIBS="$OLD_LIBS"
 150
 151 dnl -------------------------------------------------------
 152
 153 AC_ARG_ENABLE([gui],
 154         AC_HELP_STRING([--disable-gui], [Disable beagle-search]),
 155         enable_gui=$enableval,
 156         enable_gui=yes)
 157
 158 AM_CONDITIONAL(ENABLE_GUI, test "x$enable_gui" = "xyes")
 159
 160 if test "x$enable_gui" = "xyes"; then
 161
 162         # We pinvoke into gnome-vfs directly from Util/GnomeFu.cs, and
 163         # we get the GNOME prefix from libgnome-2.0
 164         PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 libgnome-2.0)
 165
 166         dnl -------------------------------------------------------
 167         dnl Various version requirements
 168
 169         PKG_CHECK_MODULES(BEAGLE_UI,
 170 [
 171         gtk-sharp-2.0 >= $GTK_SHARP_REQUIRED
 172         gconf-sharp-2.0 >= $GTK_SHARP_REQUIRED
 173         glade-sharp-2.0 >= $GTK_SHARP_REQUIRED
 174         gnome-sharp-2.0 >= $GTK_SHARP_REQUIRED
 175         gnome-vfs-sharp-2.0 >= $GTK_SHARP_REQUIRED
 176         gmime-sharp >= $GMIME_SHARP_REQUIRED
 177 ])
 178         AC_SUBST(BEAGLE_UI_LIBS)
 179 fi
 180
 181 PKG_CHECK_MODULES(UIGLUE, gtk+-2.0 >= $GTK_REQUIRED librsvg-2.0)
 182 AC_SUBST(UIGLUE_CFLAGS)
 183 AC_SUBST(UIGLUE_LIBS)
 184
 185 dnl ----------------------------------------------
 186
 187 dnl Gdk and Atk are needed for trayicon glue
 188
 189 GDK20_MINIMUM_VERSION=2.2.3
 190 ATK_MINIMUM_VERSION=1.2.4
 191
 192 PKG_CHECK_MODULES(LIBTRAYICON, gdk-2.0 >= $GDK20_MINIMUM_VERSION atk >= $ATK_MINIMUM_VERSION)
 193 AC_SUBST(LIBTRAYICON_CFLAGS)
 194 AC_SUBST(LIBTRAYICON_LIBS)
 195
 196 dnl ----------------------------------------------
 197
 198 dnl evolution support
 199
 200 AC_ARG_ENABLE([evolution],
 201         AC_HELP_STRING([--disable-evolution], [Disable evolution support (default auto)]),
 202         enable_evo=$enableval,
 203         enable_evo_sharp=auto)
 204
 205
 206 EVO_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix evolution-sharp`
 207
 208 EVO_LIBDIR=`$PKG_CONFIG --variable=evolibdir evolution-sharp`
 209 AC_SUBST(EVO_LIBDIR)
 210
 211 PKG_CHECK_MODULES(EVO,
 212                   evolution-sharp >= $EVOLUTION_SHARP_REQUIRED  \
 213                   gconf-sharp-2.0 >= $GTK_SHARP_REQUIRED        \
 214                   gmime-sharp >= $GMIME_SHARP_REQUIRED,
 215                   have_evo_dependencies=yes, have_evo_dependencies=no)
 216 AC_SUBST(EVO_LIBS)
 217
 218 if test "x$have_evo_dependencies" = "xno"; then
 219
 220         dnl error out if user has explicitly requested evolution support
 221         if test "x$enable_evo" = "xyes"; then
 222                 AC_MSG_ERROR([Could not find Evolution dependencies])
 223         fi
 224
 225         enable_evo="no (missing dependencies)"
 226
 227 else
 228
 229         if test "x$enable_evo" != "xno"; then
 230                 enable_evo="yes"
 231         else
 232                 enable_evo="no (disabled)"
 233         fi
 234
 235 fi
 236
 237 AM_CONDITIONAL(ENABLE_EVOLUTION, test "x$enable_evo" = "xyes")
 238
 239 dnl ----------------------------------------------
 240
 241 dnl Should we use our own copy of the sqlite bindings or the version
 242 dnl that got installed along with mono?
 243
 244 use_local_sqlite="yes" # hard-wired for now
 245 AM_CONDITIONAL(USE_LOCAL_SQLITE, test "x$use_local_sqlite" = "xyes")
 246
 247 dnl ----------------------------------------------
 248
 249 dnl inotify
 250
 251 AC_ARG_ENABLE([inotify],
 252          AC_HELP_STRING([--disable-inotify], [Disable inotify filesystem monitoring support (default auto)]),
 253          enable_inotify=$enableval,
 254          enable_inotify=auto)
 255
 256 if test "x$os_has_inotify" = "xno"; then
 257
 258         dnl error out if user has explicitly requested inotify
 259         if test "x$enable_inotify" = "xyes"; then
 260                 AC_MSG_ERROR([inotify is unavailable on your system architecture])
 261         fi
 262
 263         enable_inotify="no (unavailable)"
 264
 265 else
 266
 267         if test "x$enable_inotify" != "xno"; then
 268                 enable_inotify="yes"
 269         else
 270                 enable_inotify="no (disabled)"
 271         fi
 272
 273 fi
 274
 275 AM_CONDITIONAL(ENABLE_INOTIFY, test "x$enable_inotify" = "xyes")
 276
 277 dnl ----------------------------------------------
 278
 279 dnl beagled
 280
 281 PKG_CHECK_MODULES(GSF_SHARP, gsf-sharp >= 0.5, enable_gsf_sharp=yes, enable_gsf_sharp=no)
 282 AM_CONDITIONAL(ENABLE_GSF_SHARP, test "x$enable_gsf_sharp" = "xyes")
 283
 284 dnl ----------------------------------------------
 285
 286 dnl libexif: Needed to index jpeg metadata
 287
 288 LIBEXIF_API_CHANGE=0.6.0
 289 LIBEXIF_REQUIRED_MIN=0.5.7
 290 LIBEXIF_REQUIRED_MAX=0.7.0
 291
 292 PKG_CHECK_MODULES(LIBEXIF, libexif >= $LIBEXIF_REQUIRED_MIN libexif < $LIBEXIF_REQUIRED_MAX)
 293 PKG_CHECK_MODULES(LIBEXIF_API_CHECK, libexif >= $LIBEXIF_API_CHANGE, have_old_libexif=no, have_old_libexif=yes)
 294
 295 if test "x$have_old_libexif" = "xyes"; then
 296         EXIF_SOVERSION=9
 297 else
 298         PKG_CHECK_MODULES(LIBEXIF_VERSION_CHECK, libexif >= 0.6.12, EXIF_SOVERSION=12, EXIF_SOVERSION=10)
 299 fi
 300 AC_SUBST(EXIF_SOVERSION)
 301
 302 PKG_CHECK_MODULES(BEAGLED,
 303 [
 304         shared-mime-info
 305         gmime-sharp >= $GMIME_SHARP_REQUIRED
 306         gtk-sharp-2.0 >= $GTK_SHARP_REQUIRED
 307 ])
 308         BEAGLED_LIBS="$BEAGLED_LIBS $GSF_SHARP_LIBS"
 309 AC_SUBST(BEAGLED_LIBS)
 310
 311 GSF_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gsf-sharp`
 312 GMIME_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gmime-sharp`
 313
 314 dnl ----------------------------------------------
 315
 316 dnl libbeagle
 317
 318 GTK_DOC_CHECK(1.0)
 319
 320 AC_ARG_ENABLE([libbeagle],
 321         AC_HELP_STRING([--disable-libbeagle], [Disable libbeagle (C API)]),
 322         enable_libbeagle=$enableval,
 323         enable_libbeagle=auto)
 324
 325 dnl library versioning
 326 dnl Increase when changing the API
 327 LIBBEAGLE_CURRENT=0
 328
 329 dnl Update when changing implementation of current API,
 330 dnl reset to 0 when changing CURRENT.  This is the revision of
 331 dnl current API version
 332 LIBBEAGLE_REVISION=0
 333
 334 dnl Increase of API change is ABI compatible, otherwise reset to 0
 335 LIBBEAGLE_AGE=0
 336
 337 LIBBEAGLE_VERSION_INFO="$LIBBEAGLE_CURRENT:$LIBBEAGLE_REVISION:$LIBBEAGLE_AGE"
 338 AC_SUBST(LIBBEAGLE_VERSION_INFO)
 339
 340 PKG_CHECK_MODULES(LIBBEAGLE, [
 341         gobject-2.0 >= $LIBBEAGLE_GOBJECT_REQUIRED
 342         libxml-2.0  >= $LIBBEAGLE_LIBXML_REQUIRED
 343 ], have_libbeagle_deps=yes, have_libbeagle_deps=no)
 344
 345 AC_SUBST(LIBBEAGLE_CFLAGS)
 346 AC_SUBST(LIBBEAGLE_LIBS)
 347
 348 if test "x$have_libbeagle_deps" = "xno"; then
 349
 350         if test "x$enable_libbeagle" = "xyes"; then
 351                 AC_MSG_ERROR([Missing libbeagle dependencies])
 352         fi
 353
 354         enable_libbeagle="no (missing dependencies)"
 355 else
 356         if test "x$enable_libbeagle" != "xno"; then
 357                 enable_libbeagle="yes"
 358         else
 359                 enable_libbeagle="no (disabled)"
 360         fi
 361 fi
 362
 363 AM_CONDITIONAL(ENABLE_LIBBEAGLE, test "x$enable_libbeagle" = "xyes")
 364
 365 dnl ----------------------------------------------
 366
 367 dnl Epiphany Extension
 368 dnl Much of this is cut&pasted from epiphany-extensions/configure.ac
 369
 370 AC_ARG_ENABLE([epiphany-extension],
 371         AC_HELP_STRING([--enable-epiphany-extension], [Enable Epiphany Extension (default auto)]),
 372         enable_epiphany_extension=$enableval,
 373         enable_epiphany_extension=auto)
 374
 375 if $PKG_CONFIG --exists epiphany-1.8; then
 376         EPIPHANY_MAJOR=1.8
 377         EPIPHANY_REQUIRED=1.7.0
 378 elif $PKG_CONFIG --exists epiphany-1.6; then
 379         EPIPHANY_MAJOR=1.6
 380         EPIPHANY_REQUIRED=1.6.0
 381 else
 382         enable_epiphany_extension="no (Epiphany not installed)"
 383 fi
 384
 385 if test "x$enable_epiphany_extension" = "xyes"; then
 386
 387 LIBXML_REQUIRED=2.6.0
 388 LIBGLIB_REQUIRED=2.4.0
 389 LIBGTK_REQUIRED=2.4.0
 390
 391 AC_SUBST(EPIPHANY_REQUIRED)
 392 AC_SUBST(LIBXML_REQUIRED)
 393 AC_SUBST(LIBGLIB_REQUIRED)
 394 AC_SUBST(LIBGTK_REQUIRED)
 395
 396 PKG_CHECK_MODULES(EPIPHANY_DEPENDENCY,
 397                   libxml-2.0 >= $LIBXML_REQUIRED \
 398                   libglade-2.0 \
 399                   glib-2.0 >= $LIBGLIB_REQUIRED \
 400                   gmodule-2.0 \
 401                   gtk+-2.0 >= $LIBGTK_REQUIRED \
 402                   epiphany-$EPIPHANY_MAJOR >= $EPIPHANY_REQUIRED,
 403                   have_epiphany_dependencies=yes,
 404                   have_epiphany_dependencies=no)
 405 AC_SUBST(EPIPHANY_DEPENDENCY_CFLAGS)
 406 AC_SUBST(EPIPHANY_DEPENDENCY_LIBS)
 407
 408 EPIPHANY_EXTENSIONS_DIR="`$PKG_CONFIG --variable=extensionsdir epiphany-$EPIPHANY_MAJOR`"
 409 AC_SUBST([EPIPHANY_EXTENSIONS_DIR])
 410 EPIPHANY_PREFIX="`$PKG_CONFIG --variable=prefix epiphany-$EPIPHANY_MAJOR`"
 411 AC_SUBST(EPIPHANY_PREFIX)
 412
 413 if test "x$have_epiphany_dependencies" = "xno"; then
 414         enable_epiphany_extension="no (missing dependencies)"
 415 elif test "x$enable_epiphany_extension" != "xyes"; then
 416         enable_epiphany_extension="disabled"
 417 fi
 418
 419 fi
 420
 421 AM_CONDITIONAL(ENABLE_EPIPHANY_EXTENSION, test "x$enable_epiphany_extension" = "xyes")
 422
 423 AC_ARG_ENABLE([epiphany-extension-install],
 424         AS_HELP_STRING([--enable-epiphany-extension-install],[Install Epiphany Extension]),
 425         [install_epiphany_extension=$enableval],
 426         [install_epiphany_extension=yes])
 427
 428 AM_CONDITIONAL([INSTALL_EPIPHANY_EXTENSION], [test "x$install_epiphany_extension" = "xyes"])
 429
 430 dnl ----------------------------------------------
 431
 432 dnl Galago
 433
 434 PKG_CHECK_MODULES(GALAGO, galago-sharp, enable_galago=yes, enable_galago=no)
 435 AM_CONDITIONAL(ENABLE_GALAGO, test "x$enable_galago" = "xyes")
 436 AC_SUBST(GALAGO_LIBS)
 437
 438
 439 dnl ----------------------------------------------
 440
 441 GTK_BINARY_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 442 AC_SUBST(GTK_BINARY_VERSION)
 443
 444 dnl For the systeminfo glue
 445
 446 PKG_CHECK_MODULES(SYSTEMINFO_GLUE, gdk-2.0)
 447 AC_PATH_XTRA
 448 SYSTEMINFO_GLUE_X_LIBS="$X_PRE_LIBS $X_LIBS -lX11 -lXss $X_EXTRA_LIBS"
 449 AC_SUBST(SYSTEMINFO_GLUE_X_LIBS)
 450
 451 dnl ----------------------------------------------
 452
 453 dnl For the wv1 glue
 454
 455 PKG_CHECK_MODULES(WV1, wv-1.0, enable_wv1=yes, enable_wv1=no)
 456 AM_CONDITIONAL(ENABLE_WV1, test "x$enable_wv1" = "xyes")
 457 AC_SUBST(WV1_LIBS)
 458
 459 dnl ----------------------------------------------
 460
 461 dnl KDE launcher/icon support
 462
 463 kde_prefix_print="unknown; will guess at runtime"
 464 AC_PATH_PROG(KDE_CONFIG, [kde-config], [no])
 465 if test ! "x$KDE_CONFIG" = "xno"; then
 466         KDE_PREFIX=`$KDE_CONFIG --prefix`
 467         kde_prefix_print="$KDE_PREFIX"
 468 fi
 469 AC_SUBST(KDE_PREFIX)
 470
 471 dnl ----------------------------------------------
 472
 473 dnl Beagle webservices
 474
 475 dnl AC_ARG_ENABLE([webservices],
 476 dnl        AC_HELP_STRING([--enable-webservices], [Enable WebServices (default disabled)]),
 477 dnl        enable_webservices=$enableval,
 478 dnl        enable_webservices=no)
 479
 480 enable_webservices=no
 481 AM_CONDITIONAL(ENABLE_WEBSERVICES, test "x$enable_webservices" = "xyes")
 482
 483 dnl ----------------------------------------------
 484
 485 dnl Prefixes for helper scripts
 486 GAC_PREFIX="$EVO_SHARP_PREFIX:$GSF_SHARP_PREFIX:$GMIME_SHARP_PREFIX"
 487 dnl Remove duplicate prefixes
 488 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|:|\n|g' | sort | uniq | tr '\n' ':'`"
 489 dnl Remove stray :s
 490 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|::\+|:|g' -e 's|^:\+||' -e 's|:\+$||'`"
 491 AC_SUBST(GAC_PREFIX)
 492
 493 GNOME_PREFIX="`$PKG_CONFIG --variable=prefix libgnome-2.0`"
 494 AC_SUBST(GNOME_PREFIX)
 495
 496 dnl ----------------------------------------------
 497
 498 dnl Check if the system has libchm, used by the CHMFilter
 499
 500 # FIXME: Disabled since its broken
 501 #AC_CHECK_LIB(chm,chm_open,has_libchm=yes,has_libchm=no)
 502 has_libchm=no
 503 AM_CONDITIONAL(HAS_LIBCHM, test "x$has_libchm" = "xyes")
 504
 505 dnl ----------------------------------------------
 506
 507 dnl Conditional for debugging XML messages.
 508
 509 BEAGLE_DEFINES=""
 510
 511 AC_ARG_ENABLE([xml-dump],
 512         AC_HELP_STRING([--enable-xml-dump], [Enables printing of the XML messages sent between components (default no)]),
 513         enable_xml_dump=$enableval,
 514         enable_xml_dump=no)
 515
 516 if test "x$enable_xml_dump" = "xyes"; then
 517         AC_DEFINE_UNQUOTED(ENABLE_XML_DUMP, 1, [Dump XML messages for debugging])
 518         BEAGLE_DEFINES="-define:ENABLE_XML_DUMP"
 519 fi
 520
 521 AC_SUBST(BEAGLE_DEFINES)
 522
 523 dnl ----------------------------------------------
 524
 525 dnl Python 2.3
 526
 527 AC_ARG_ENABLE(python,
 528         AC_HELP_STRING([--disable-python], [Disable python support (default auto)]),
 529         enable_python=$enableval,
 530         enable_python=auto)
 531
 532 have_python=no
 533 if test "x$enable_libbeagle" = "xyes" -a "x$enable_python" != "xno"; then
 534         have_python_version=no
 535         have_python_headers=no
 536         have_pygtk_deps=no
 537         have_pygtk_codegen=no
 538
 539         AM_PATH_PYTHON()
 540
 541         if test -z "$PYTHON"; then
 542                 AC_MSG_WARN([Python not found])
 543         else
 544                 AM_PYTHON_CHECK_VERSION($PYTHON, $PYTHON_REQUIRED,
 545                         have_python_version=yes,
 546                         have_python_version=no)
 547         fi
 548
 549         if test "x$have_python_version" != "xyes"; then
 550                 AC_MSG_WARN([Python version $PYTHON_REQUIRED not found])
 551         else
 552                 AM_CHECK_PYTHON_HEADERS(have_python_headers=yes, have_python_headers=no)
 553         fi
 554
 555         if test "x$have_python_headers" != "xyes"; then
 556                 AC_MSG_WARN([could not find Python headers])
 557         else
 558                 PKG_CHECK_MODULES(PYBEAGLE,
 559                         pygtk-2.0 >= $PYGTK_REQUIRED
 560                         pygobject-2.0 >= $PYGTK_REQUIRED,
 561                         have_pygtk_deps=yes,
 562                         have_pygtk_deps=no)
 563         fi
 564
 565         if test "x$have_pygtk_deps" != "xyes"; then
 566                 AC_MSG_WARN([could not find pygtk])
 567         else
 568                 AC_PATH_PROG(PYGTK_CODEGEN, pygtk-codegen-2.0, no)
 569         fi
 570
 571         if test -z "$PYGTK_CODEGEN"; then
 572                 AC_MSG_WARN([could not find pygtk-codegen in path])
 573         else
 574                 AC_MSG_CHECKING(for pygtk defs)
 575                 PYGTK_DEFSDIR=`$PKG_CONFIG --variable=defsdir pygtk-2.0`
 576                 AC_MSG_RESULT($PYGTK_DEFSDIR)
 577
 578                 have_python=yes
 579         fi
 580 fi
 581
 582 if test "x$enable_python" = "xyes"; then
 583         if test "x$enable_libbeagle" != "xyes"; then
 584                 AC_MSG_ERROR([Python bindings are requested, but libbeagle isn't to be built])
 585         elif test "x$have_python" = "xno"; then
 586                 AC_MSG_ERROR([Python bindings are requested, but cannot be built])
 587         fi
 588 fi
 589
 590 AM_CONDITIONAL(ENABLE_PYTHON, test "x$have_python" = "xyes")
 591 AC_SUBST(PYBEAGLE_LIBS)
 592 AC_SUBST(PYBEAGLE_CFLAGS)
 593 AC_SUBST(PYGTK_DEFSDIR)
 594
 595 dnl ----------------------------------------------
 596
 597 AC_OUTPUT([
 598 Makefile
 599 Util/Makefile
 600 Util/Util.dll.config
 601 images/Makefile
 602 glue/Makefile
 603 BeagleClient/Makefile
 604 beagled/Makefile
 605 Filters/Makefile
 606 tools/Makefile
 607 search/Makefile
 608 ImLogViewer/Makefile
 609 libbeagle/Makefile
 610 libbeagle/libbeagle-0.0.pc
 611 libbeagle/beagle/Makefile
 612 libbeagle/examples/Makefile
 613 libbeagle/docs/Makefile
 614 libbeagle/docs/reference/Makefile
 615 epiphany-extension/Makefile
 616 mozilla-extension/Makefile
 617 bludgeon/Makefile
 618 wrappers/Makefile
 619 wrappers/python/Makefile
 620 beagle-0.0.pc
 621 beagle-daemon.pc
 622 beagle.spec
 623 po/Makefile.in
 624 ])
 625
 626 echo "
 627         Beagle Version:           ${VERSION}
 628         Target OS:                ${os}
 629         inotify?                  ${enable_inotify}
 630
 631         Prefix:                   ${prefix}
 632         GNOME Prefix:             ${GNOME_PREFIX}
 633         KDE Prefix:               ${kde_prefix_print}
 634
 635         Evolution support?        ${enable_evo}
 636         gsf-sharp?                ${enable_gsf_sharp}
 637         wv1?                      ${enable_wv1}
 638         galago-sharp?             ${enable_galago}
 639         libchm?                   ${has_libchm} (Currently broken)
 640
 641         Mozilla Extension?        yes
 642         Epiphany Extension?       ${enable_epiphany_extension}
 643
 644         Local SqliteClient?       ${use_local_sqlite}
 645         Sqlite version:           ${SQLITE_MAJ_VER}.x
 646
 647         Enable WebServices        no (WebServices are deprecated)
 648         Enable libbeagle          ${enable_libbeagle}
 649         Enable python bindings    ${have_python}
 650
 651         Enable beagle-search GUI  ${enable_gui}
 652 "
 653 echo
 654
 655 if test "x$enable_epiphany_extension" = "xyes"; then
 656    echo "NOTE: The Beagle Epiphany Extension Is Totally Insecure!"
 657    echo "      Use it at your own risk!"
 658    echo
 659 fi