configure.in

   1 AC_INIT(beagled/BeagleDaemon.cs)
   2 AC_CANONICAL_SYSTEM
   3 AM_INIT_AUTOMAKE(beagle, 0.0.13.1)
   4 AM_MAINTAINER_MODE
   5 AM_CONFIG_HEADER(config.h)
   6
   7 AC_PROG_INSTALL
   8 AM_PROG_LIBTOOL
   9 AC_PROG_CXX
  10
  11 VERSION=${VERSION}
  12 AC_SUBST(VERSION)
  13
  14 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  15 if test "x$PKG_CONFIG" = "xno"; then
  16         AC_MSG_ERROR([You need to install pkg-config])
  17 fi
  18
  19 AC_PATH_PROG(BASH, bash)
  20 AC_SUBST(BASH)
  21
  22 # mozilla extension uses zip to create the jar/xpi files
  23 AC_PATH_PROG(ZIP, zip)
  24
  25 AC_PATH_PROG(MONO, mono)
  26 AC_PATH_PROG(MCS, mcs)
  27
  28 AC_MSG_CHECKING([for mono.pc])
  29 if test -z `$PKG_CONFIG --variable=prefix mono`; then
  30   AC_MSG_ERROR([missing the mono.pc file, usually found in the mono-devel package])
  31 else
  32   AC_MSG_RESULT([found])
  33 fi
  34
  35 # require mono 1.0.6 or newer
  36 PKG_CHECK_MODULES(MONO, mono >= 1.0.6)
  37
  38 # check for various mono DLLs that we need.
  39 needed_dlls="Mono.Data.SqliteClient Mono.Posix System.Runtime.Remoting System.Web System.Web.Services"
  40 for i in $needed_dlls; do
  41   AC_MSG_CHECKING([for $i.dll])
  42   if test ! -e `$PKG_CONFIG --variable=prefix mono`/lib/mono/1.0/$i.dll; then
  43     AC_MSG_ERROR([missing required mono DLL: $i.dll])
  44   else
  45     AC_MSG_RESULT([found])
  46   fi
  47 done
  48
  49 # check for OS
  50 case "$target" in
  51   *-*-linux*)
  52     os=linux
  53     AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="libattr",)
  54     AC_CHECK_FUNC(lsetxattr, XATTR_LIB="libc",)
  55     ;;
  56   *-*-freebsd*)
  57     os=freebsd
  58     AC_CHECK_FUNC(extattr_set_link, XATTR_LIB="libc")
  59     ;;
  60   *)
  61     AC_MSG_ERROR([Unrecognised target OS: $target])
  62     ;;
  63 esac
  64 AM_CONDITIONAL(OS_LINUX, test "x$os" = "xlinux")
  65 AM_CONDITIONAL(OS_FREEBSD, test "x$os" = "xfreebsd")
  66
  67 # check for xattr implementation
  68 if test "x$XATTR_LIB" = "x"; then
  69     AC_MSG_ERROR([Could not find a support extended attribute implementation (tried libc and libattr)])
  70 fi
  71 AC_SUBST(XATTR_LIB)
  72
  73 # check for desktop-launch
  74
  75 AC_PATH_PROG(DESKTOP_LAUNCH, desktop-launch, no)
  76 AM_CONDITIONAL(ENABLE_DESKTOP_LAUNCH, test "x$DESKTOP_LAUNCH" != "xno")
  77
  78 # check for wsdl
  79 AC_PATH_PROG(WSDL, wsdl)
  80
  81 #
  82 # I18N
  83 #
  84
  85 AC_PROG_INTLTOOL([0.23])
  86 GETTEXT_PACKAGE=beagle
  87 AC_SUBST(GETTEXT_PACKAGE)
  88 ALL_LINGUAS="bg ca cs da de el en_CA en_GB es fr hu ja mk nb nl no pl pt_BR sv tr uk zh_CN zh_TW"
  89 AM_GLIB_GNU_GETTEXT
  90
  91 # Many distros don't have a dependency on sqlite for their
  92 # mono-data-sqlite packages, and the mono build process itself
  93 # doesn't require it.  But we do, so check for it here.
  94 SQLITE_MAJ_VER="0"
  95 PKG_CHECK_MODULES(SQLITE, sqlite, SQLITE_MAJ_VER="2", do_nothing="1")
  96 #PKG_CHECK_MODULES(SQLITE, sqlite3, SQLITE_MAJ_VER="3", do_nothing="1")
  97
  98 if test "x$SQLITE_MAJ_VER" = "x0"; then
  99         AC_MSG_ERROR([You need to install either sqlite2 or sqlite3])
 100 fi
 101
 102 AC_SUBST(SQLITE_MAJ_VER)
 103
 104 # Needed by glue/screensaver-glue.c
 105 # The OLD_CFLAGS/CFLAGS hack is needed to build on Ubuntu Breezy Badger
 106 OLD_CFLAGS="$CFLAGS"
 107 CFLAGS="$CFLAGS -I/usr/X11R6/include"
 108 AC_CHECK_HEADER(X11/extensions/scrnsaver.h,, [AC_MSG_ERROR([Unable to find scrnsaver.h.  You probably need to install XFree86 development packages])])
 109 CFLAGS="$OLD_CFLAGS"
 110
 111 # We pinvoke into gnome-vfs directly from Util/gnome.cs and Util/Vfs.cs, and
 112 # we get the GNOME prefix from libgnome-2.0
 113 PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 libgnome-2.0)
 114
 115 dnl ******************
 116 dnl Mozilla name check
 117 dnl ******************
 118
 119 AC_MSG_CHECKING([which mozilla to use])
 120
 121 MOZILLA=
 122 AC_ARG_WITH([mozilla],
 123         AC_HELP_STRING([--with-mozilla@<:@=mozilla|firefox|thunderbird@:>@],
 124                        [Whether to use mozilla, firefox or thunderbird gtkmozembed (default: mozilla)]),
 125         [MOZILLA="$withval"])
 126
 127 dnl try to autodetect: if mozilla exists, use it, else try firefox, then thunderbird
 128 if test "x$MOZILLA" = "x"; then
 129   if pkg-config --exists mozilla-gtkmozembed; then
 130     MOZILLA=mozilla
 131   elif pkg-config --exists firefox-gtkmozembed; then
 132     MOZILLA=firefox
 133   elif pkg-config --exists thunderbird-gtkmozembed; then
 134     MOZILLA=thunderbird
 135   else
 136     AC_MSG_ERROR([unable to find gtkmozembed; this can be found in mozilla/firefox/thunderbird development packages])
 137   fi
 138 elif test "x$with_mozilla" != "xmozilla" -a "x$with_mozilla" != "xfirefox" -a "x$with_mozilla" != "xthunderbird"; then
 139   AC_MSG_ERROR([unknown mozilla name ($MOZILLA)])
 140 fi
 141
 142 AC_SUBST(MOZILLA)
 143
 144 AC_MSG_RESULT([$MOZILLA])
 145
 146 case "$MOZILLA" in
 147 mozilla) min_version=1.6 flavour=mozilla ;;
 148 firefox) min_version=0.10 flavour=toolkit ;;
 149 thunderbird) min_version=0.8 flavour=toolkit ;;
 150 esac
 151
 152 MOZILLA_FLAVOUR=$flavour
 153 AC_SUBST(MOZILLA_FLAVOUR)
 154 PKG_CHECK_MODULES(MOZILLA_COMPONENT, $MOZILLA-gtkmozembed >= $min_version $MOZILLA-xpcom >= $min_version)
 155 AC_SUBST(MOZILLA_COMPONENT_CFLAGS)
 156 AC_SUBST(MOZILLA_COMPONENT_LIBS)
 157
 158 MOZILLA_INCLUDE_ROOT="`$PKG_CONFIG --variable=includedir $MOZILLA-gtkmozembed`"
 159 AC_SUBST(MOZILLA_INCLUDE_ROOT)
 160
 161 MOZILLA_HOME="`$PKG_CONFIG --variable=libdir $MOZILLA-gtkmozembed`"
 162 AC_SUBST(MOZILLA_HOME)
 163
 164 MOZILLA_PREFIX="`$PKG_CONFIG --variable=prefix $MOZILLA-gtkmozembed`"
 165 AC_SUBST(MOZILLA_PREFIX)
 166
 167
 168
 169 dnl *************************************************************************
 170 dnl This is from Mozilla's configure.in. They set almost all the config stuff
 171 dnl they need in mozilla-config.h Except for this compiler flag, which can't
 172 dnl go in mozilla-config.h So we check the flag too and now we can include
 173 dnl mozilla-config.h without breaking epiphany.
 174 dnl This is really gcc-only
 175 dnl Do this test using CXX only since some versions of gcc
 176 dnl 2.95-2.97 have a signed wchar_t in c++ only and some versions
 177 dnl only have short-wchar support for c++.
 178 AC_LANG_PUSH(C++)
 179 _SAVE_CXXFLAGS=$CXXFLAGS
 180 _SAVE_AM_CXXFLAGS=$AM_CXXFLAGS
 181 AM_CXXFLAGS="$AM_CXXFLAGS -fshort-wchar"
 182 CXXFLAGS="$CXXFLAGS $AM_CXXFLAGS"
 183
 184
 185 AC_CACHE_CHECK(for compiler -fshort-wchar option,
 186     ac_cv_have_usable_wchar_option,
 187     [AC_TRY_RUN([#include <stddef.h>
 188                  int main () {
 189                    return (sizeof(wchar_t) != 2) ||
 190                           (wchar_t)-1 < (wchar_t) 0 ; } ],
 191                 ac_cv_have_usable_wchar_option="yes",
 192                 ac_cv_have_usable_wchar_option="no",
 193                 ac_cv_have_usable_wchar_option="maybe")])
 194
 195 if test "$ac_cv_have_usable_wchar_option" != "yes"; then
 196     AM_CXXFLAGS=$_SAVE_AM_CXXFLAGS
 197 fi
 198
 199 dnl **********************************
 200 dnl now tests for mozilla API variance
 201 dnl **********************************
 202
 203 dnl FIXME find a m4/autoconf guru who can distill this into a nice macro
 204
 205 CXXFLAGS="$_SAVE_CXXFLAGS $AM_CXXFLAGS -I$MOZILLA_INCLUDE_ROOT -I$MOZILLA_INCLUDE_ROOT/embedstring -I$MOZILLA_INCLUDE_ROOT/content -I$MOZILLA_INCLUDE_ROOT/necko `pkg-config --cflags $MOZILLA-xpcom`"
 206
 207 dnl Changed from PRUnichar* to nsAString& in 1.8a1 and on aviary branch
 208
 209 AC_MSG_CHECKING([whether nsIFilePicker methods expect nsAString&])
 210                                                                                 AC_COMPILE_IFELSE(
 211         [AC_LANG_PROGRAM(
 212                 [[#include <nsEmbedString.h>
 213                   #include <widget/nsIFilePicker.h>]],
 214                 [[nsIFilePicker *p;
 215                   p->SetDefaultString (nsEmbedString());]]
 216         )],
 217         [AC_DEFINE([MOZ_NSIFILEPICKER_NSASTRING_],[1],[Define if nsIFilePicker uses nsAString&]) result=yes],
 218         [result=no])
 219
 220 AC_MSG_RESULT([$result])
 221
 222 dnl Changed from char* to nsAString& in 1.8a1
 223
 224 AC_MSG_CHECKING([whether nsIMIMEInfo methods expect nsAString&])
 225
 226 AC_COMPILE_IFELSE(
 227         [AC_LANG_PROGRAM(
 228                 [[#include <nsEmbedString.h>
 229                   #include <mimetype/nsIMIMEInfo.h>]],
 230                 [[nsIMIMEInfo *p;
 231                   p->SetDescription (nsEmbedString());]]
 232         )],
 233         [AC_DEFINE([MOZ_NSIMIMEINFO_NSACSTRING_],[1],[Define if nsIMIMEInfo uses nsAString&]) result=yes],
 234         [result=no])
 235
 236 AC_MSG_RESULT([$result])
 237
 238 dnl Firefox doesn't have this API (?)
 239
 240 AC_MSG_CHECKING([for nsIXULChromeRegistry API])
 241
 242 AC_COMPILE_IFELSE(
 243         [AC_LANG_PROGRAM(
 244                 [[#include <nsEmbedString.h>
 245                   #include <nsIChromeRegistry.h>]],
 246                 [[nsIXULChromeRegistry *p;
 247                   p->SelectSkin (nsEmbedCString(), PR_FALSE);]]
 248         )],
 249         [AC_DEFINE([MOZ_NSIXULCHROMEREGISTRY_SELECTSKIN],[1],[dummy]) result=yes],
 250         [result=no])
 251 AC_MSG_RESULT([$result])
 252
 253 dnl changed from nsIXULChromeRegistry in 1.8a4
 254
 255 AC_CHECK_FILE([$MOZILLA_INCLUDE_ROOT/chrome/nsIChromeRegistrySea.h],
 256         [AC_DEFINE([HAVE_CHROME_NSICHROMEREGISTRYSEA_H], [1], [Define if nsIChromeRegistrySea.h exists])])
 257
 258 MOZILLA_WARN_CXXFLAGS="-Wall -Wconversion -Wpointer-arith -Wcast-align -Woverloaded-virtual -Wsynth -Wno-ctor-dtor-privacy -Wno-non-virtual-dtor"
 259 AC_SUBST(MOZILLA_WARN_CXXFLAGS)
 260
 261 dnl -------------------------------------------------------
 262
 263 PKG_CHECK_MODULES(LIBGECKOGLUE, gtk+-2.0 >= 2.2 $MOZILLA-gtkmozembed)
 264 AC_SUBST(LIBGECKOGLUE_CFLAGS)
 265 AC_SUBST(LIBGECKOGLUE_LIBS)
 266
 267 dnl -------------------------------------------------------
 268
 269 PKG_CHECK_MODULES(BEAGLE_UI, gtk-sharp-2.0 glade-sharp-2.0 gecko-sharp-2.0 gnome-sharp-2.0 gconf-sharp-2.0 gmime-sharp >= 2.1.16)
 270 AC_SUBST(BEAGLE_UI_LIBS)
 271
 272 dnl ----------------------------------------------
 273
 274 # Gdk and Atk are needed for libtrayiconglue
 275 GDK20_MINIMUM_VERSION=2.2.3
 276 ATK_MINIMUM_VERSION=1.2.4
 277
 278 PKG_CHECK_MODULES(LIBTRAYICON,
 279                   gdk-2.0 >= $GDK20_MINIMUM_VERSION
 280                   atk >= $ATK_MINIMUM_VERSION)
 281 AC_SUBST(LIBTRAYICON_CFLAGS)
 282 AC_SUBST(LIBTRAYICON_LIBS)
 283
 284 dnl ----------------------------------------------
 285
 286 AC_ARG_ENABLE([evolution-sharp],
 287          AC_HELP_STRING([--disable-evolution-sharp], [Disable evolution-sharp support (default auto)]),
 288          enable_evo_sharp=$enableval,
 289          enable_evo_sharp=auto)
 290
 291 EVOLUTION_SHARP_REQUIRED=0.9
 292 AC_SUBST(EVO_SHARP_LIBS)
 293 EVO_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix evolution-sharp`
 294
 295 PKG_CHECK_MODULES(EVO_SHARP,
 296          evolution-sharp >= $EVOLUTION_SHARP_REQUIRED, \
 297          have_evo_sharp_dependencies=yes,
 298          have_evo_sharp_dependencies=no)
 299
 300 if test "x$have_evo_sharp_dependencies" = "xno"; then
 301
 302         dnl error out if user has explicitly requested evo-sharp
 303         if test "x$enable_evo_sharp" = "xyes"; then
 304                 AC_MSG_ERROR([Could not find evolution-sharp])
 305         fi
 306
 307         enable_evo_sharp="no (missing dependencies)"
 308
 309 else
 310
 311         if test "x$enable_evo_sharp" != "xno"; then
 312                 enable_evo_sharp="yes"
 313         else
 314                 enable_evo_sharp="no (disabled)"
 315         fi
 316
 317 fi
 318
 319 AM_CONDITIONAL(ENABLE_EVO_SHARP, test "x$enable_evo_sharp" = "xyes")
 320
 321 dnl ----------------------------------------------
 322
 323 dnl Should we use our own copy of the sqlite bindings or the version
 324 dnl that got installed along with mono?
 325
 326 use_local_sqlite="yes" # hard-wired for now
 327 AM_CONDITIONAL(USE_LOCAL_SQLITE, test "x$use_local_sqlite" = "xyes")
 328
 329 dnl ----------------------------------------------
 330
 331 dnl beagled
 332
 333 PKG_CHECK_MODULES(GSF_SHARP, gsf-sharp >= 0.4, enable_gsf_sharp=yes, enable_gsf_sharp=no)
 334 AM_CONDITIONAL(ENABLE_GSF_SHARP, test "x$enable_gsf_sharp" = "xyes")
 335
 336 dnl ----------------------------------------------
 337 dnl GST# is not in a usable stage as of 9.3 release, disabling it.
 338
 339 PKG_CHECK_MODULES(GST_SHARP, gst-sharp >= __DISABLE_FOR_NOW__, enable_gst_sharp=yes, enable_gst_sharp=disabled)
 340 AM_CONDITIONAL(ENABLE_GST_SHARP, test "x$enable_gst_sharp" = "xyes")
 341
 342 dnl ----------------------------------------------
 343
 344 dnl Needed to index jpeg metadata
 345 LIBEXIF_API_CHANGE=0.6.0
 346 LIBEXIF_REQUIRED_MIN=0.5.7
 347 LIBEXIF_REQUIRED_MAX=0.7.0
 348
 349 PKG_CHECK_MODULES(LIBEXIF, libexif >= $LIBEXIF_REQUIRED_MIN libexif < $LIBEXIF_REQUIRED_MAX)
 350 PKG_CHECK_MODULES(LIBEXIF_API_CHECK, libexif >= $LIBEXIF_API_CHANGE, have_old_libexif=no, have_old_libexif=yes)
 351
 352 if test "x$have_old_libexif" = "xyes"; then
 353         EXIF_SOVERSION=9
 354 else
 355         PKG_CHECK_MODULES(LIBEXIF_VERSION_CHECK, libexif >= 0.6.12, EXIF_SOVERSION=12, EXIF_SOVERSION=10)
 356 fi
 357 AC_SUBST(EXIF_SOVERSION)
 358
 359 PKG_CHECK_MODULES(BEAGLED, gmime-sharp >= 2.1.16 gtk-sharp-2.0 gconf-sharp-2.0)
 360 BEAGLED_LIBS="$BEAGLED_LIBS $EVO_SHARP_LIBS $GSF_SHARP_LIBS"
 361 AC_SUBST(BEAGLED_LIBS)
 362
 363 GSF_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gsf-sharp`
 364 GMIME_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gmime-sharp`
 365
 366 BEAGLE_DEFINES=""
 367 AC_SUBST(BEAGLE_DEFINES)
 368
 369 dnl ----------------------------------------------
 370 dnl libbeagle
 371
 372 GTK_DOC_CHECK(1.0)
 373
 374 AC_ARG_ENABLE([libbeagle],
 375         AC_HELP_STRING([--disable-libbeagle], [Disable libbeagle (C API)]),
 376         enable_libbeagle=$enableval,
 377         enable_libbeagle=auto)
 378
 379 dnl library versioning
 380 dnl Increase when changing the API
 381 LIBBEAGLE_CURRENT=0
 382
 383 dnl Update when changing implementation of current API,
 384 dnl reset to 0 when changing CURRENT.  This is the revision of
 385 dnl current API version
 386 LIBBEAGLE_REVISION=0
 387
 388 dnl Increase of API change is ABI compatible, otherwise reset to 0
 389 LIBBEAGLE_AGE=0
 390
 391 LIBBEAGLE_VERSION_INFO="$LIBBEAGLE_CURRENT:$LIBBEAGLE_REVISION:$LIBBEAGLE_AGE"
 392 AC_SUBST(LIBBEAGLE_VERSION_INFO)
 393
 394 PKG_CHECK_MODULES(LIBBEAGLE, [
 395         gobject-2.0 >= 2.6
 396         libxml-2.0 >= 2.6.19
 397 ], have_libbeagle_deps=yes, have_libbeagle_deps=no)
 398
 399 AC_SUBST(LIBBEAGLE_CFLAGS)
 400 AC_SUBST(LIBBEAGLE_LIBS)
 401
 402 if test "x$have_libbeagle_deps" = "xno"; then
 403
 404         if test "x$enable_libbeagle" = "xyes"; then
 405                 AC_MSG_ERROR([Missing libbeagle dependencies])
 406         fi
 407
 408         enable_libbeagle="no (missing dependencies)"
 409 else
 410         if test "x$enable_libbeagle" != "xno"; then
 411                 enable_libbeagle="yes"
 412         else
 413                 enable_libbeagle="no (disabled)"
 414         fi
 415 fi
 416
 417 AM_CONDITIONAL(ENABLE_LIBBEAGLE, test "x$enable_libbeagle" = "xyes")
 418
 419 dnl ----------------------------------------------
 420
 421 dnl Epiphany Extension
 422 dnl Much of this is cut&pasted from epiphany-extensions/configure.ac
 423
 424 AC_ARG_ENABLE([epiphany-extension],
 425         AC_HELP_STRING([--enable-epiphany-extension], [Enable Epiphany Extension (default auto)]),
 426         enable_epiphany_extension=$enableval,
 427         enable_epiphany_extension=auto)
 428
 429 if $PKG_CONFIG --exists epiphany-1.8; then
 430         EPIPHANY_MAJOR=1.8
 431         EPIPHANY_REQUIRED=1.7.0
 432 elif $PKG_CONFIG --exists epiphany-1.6; then
 433         EPIPHANY_MAJOR=1.6
 434         EPIPHANY_REQUIRED=1.6.0
 435 else
 436         enable_epiphany_extension="no (Epiphany not installed)"
 437 fi
 438
 439 if test "x$enable_epiphany_extension" = "xyes"; then
 440
 441 LIBXML_REQUIRED=2.6.0
 442 LIBGLIB_REQUIRED=2.4.0
 443 LIBGTK_REQUIRED=2.4.0
 444
 445 AC_SUBST(EPIPHANY_REQUIRED)
 446 AC_SUBST(LIBXML_REQUIRED)
 447 AC_SUBST(LIBGLIB_REQUIRED)
 448 AC_SUBST(LIBGTK_REQUIRED)
 449
 450 PKG_CHECK_MODULES(EPIPHANY_DEPENDENCY, \
 451                   libxml-2.0 >= $LIBXML_REQUIRED \
 452                   libglade-2.0 \
 453                   glib-2.0 >= $LIBGLIB_REQUIRED \
 454                   gmodule-2.0 \
 455                   gtk+-2.0 >= $LIBGTK_REQUIRED \
 456                   epiphany-$EPIPHANY_MAJOR >= $EPIPHANY_REQUIRED,
 457                   have_epiphany_dependencies=yes,
 458                   have_epiphany_dependencies=no)
 459 AC_SUBST(EPIPHANY_DEPENDENCY_CFLAGS)
 460 AC_SUBST(EPIPHANY_DEPENDENCY_LIBS)
 461
 462 EPIPHANY_EXTENSIONS_DIR="`$PKG_CONFIG --variable=extensionsdir epiphany-$EPIPHANY_MAJOR`"
 463 AC_SUBST([EPIPHANY_EXTENSIONS_DIR])
 464 EPIPHANY_PREFIX="`$PKG_CONFIG --variable=prefix epiphany-$EPIPHANY_MAJOR`"
 465 AC_SUBST(EPIPHANY_PREFIX)
 466
 467 if test "x$have_epiphany_dependencies" = "xno"; then
 468         enable_epiphany_extension="no (missing dependencies)"
 469 elif test "x$enable_epiphany_extension" != "xyes"; then
 470         enable_epiphany_extension="disabled"
 471 fi
 472
 473 fi
 474
 475 AM_CONDITIONAL(ENABLE_EPIPHANY_EXTENSION, test "x$enable_epiphany_extension" = "xyes")
 476
 477 AC_ARG_ENABLE([epiphany-extension-install],
 478         AS_HELP_STRING([--enable-epiphany-extension-install],[Install Epiphany Extension]),
 479         [install_epiphany_extension=$enableval],
 480         [install_epiphany_extension=yes])
 481
 482 AM_CONDITIONAL([INSTALL_EPIPHANY_EXTENSION], [test "x$install_epiphany_extension" = "xyes"])
 483
 484 dnl ----------------------------------------------
 485
 486 dnl Galago
 487
 488 PKG_CHECK_MODULES(GALAGO, galago-sharp, enable_galago=yes, enable_galago=no)
 489 AM_CONDITIONAL(ENABLE_GALAGO, test "x$enable_galago" = "xyes")
 490 AC_SUBST(GALAGO_LIBS)
 491
 492
 493 dnl ----------------------------------------------
 494
 495 GTK_BINARY_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 496 AC_SUBST(GTK_BINARY_VERSION)
 497
 498 dnl For the systeminfo glue
 499
 500 PKG_CHECK_MODULES(SYSTEMINFO_GLUE, gdk-2.0)
 501 AC_PATH_XTRA
 502 SYSTEMINFO_GLUE_X_LIBS="$X_PRE_LIBS $X_LIBS -lX11 -lXss $X_EXTRA_LIBS"
 503 AC_SUBST(SYSTEMINFO_GLUE_X_LIBS)
 504
 505 dnl ----------------------------------------------
 506
 507 dnl For the wv1 glue
 508
 509 PKG_CHECK_MODULES(WV1, wv-1.0, enable_wv1=yes, enable_wv1=no)
 510 AM_CONDITIONAL(ENABLE_WV1, test "x$enable_wv1" = "xyes")
 511 AC_SUBST(WV1_LIBS)
 512
 513 dnl ----------------------------------------------
 514
 515 dnl Searchomatic
 516
 517 PKG_CHECK_MODULES(SEARCHOMATIC, gtk+-2.0)
 518 AC_SUBST(SEARCHOMATIC_CFLAGS)
 519 AC_SUBST(SEARCHOMATIC_LIBS)
 520
 521 dnl ----------------------------------------------
 522
 523 dnl Chooser-fu
 524
 525 PKG_CHECK_MODULES(CHOOSER_FU, gtk+-2.0)
 526 AC_SUBST(CHOOSER_FU_CFLAGS)
 527 AC_SUBST(CHOOSER_FU_LIBS)
 528
 529 dnl ----------------------------------------------
 530
 531 dnl KDE launcher/icon support
 532
 533 kde_prefix_print="unknown; will guess at runtime"
 534 AC_PATH_PROG(KDE_CONFIG, [kde-config], [no])
 535 if test ! "x$KDE_CONFIG" = "xno"; then
 536         KDE_PREFIX=`$KDE_CONFIG --prefix`
 537         kde_prefix_print="$KDE_PREFIX"
 538 fi
 539 AC_SUBST(KDE_PREFIX)
 540
 541 AC_ARG_ENABLE([webservices],
 542         AC_HELP_STRING([--enable-webservices], [Enable WebServices (default disabled)]),
 543         enable_webservices=$enableval,
 544         enable_webservices=no)
 545
 546 AM_CONDITIONAL(ENABLE_WEBSERVICES, test "x$enable_webservices" = "xyes")
 547
 548 dnl ----------------------------------------------
 549 dnl Prefixes for helper scripts
 550 GAC_PREFIX="$EVO_SHARP_PREFIX:$GSF_SHARP_PREFIX:$GMIME_SHARP_PREFIX"
 551 dnl Remove duplicate prefixes
 552 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|:|\n|g' | sort | uniq | tr '\n' ':'`"
 553 dnl Remove stray :s
 554 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|::\+|:|g' -e 's|^:\+||' -e 's|:\+$||'`"
 555 AC_SUBST(GAC_PREFIX)
 556
 557 GNOME_PREFIX="`$PKG_CONFIG --variable=prefix libgnome-2.0`"
 558 AC_SUBST(GNOME_PREFIX)
 559
 560 dnl ----------------------------------------------
 561
 562 dnl Check if the system has libchm, used by the CHMFilter
 563
 564 AC_CHECK_LIB(chm,chm_open,has_libchm=yes,has_libchm=no)
 565 AM_CONDITIONAL(HAS_LIBCHM, test "x$has_libchm" = "xyes")
 566
 567 dnl ----------------------------------------------
 568
 569 AC_OUTPUT([
 570 Makefile
 571 Util/Makefile
 572 Util/Util.dll.config
 573 images/Makefile
 574 glue/Makefile
 575 BeagleClient/Makefile
 576 beagled/Makefile
 577 Filters/Makefile
 578 Tiles/Makefile
 579 tools/Makefile
 580 Best/Makefile
 581 ImLogViewer/Makefile
 582 libbeagle/Makefile
 583 libbeagle/libbeagle-0.0.pc
 584 libbeagle/beagle/Makefile
 585 libbeagle/examples/Makefile
 586 libbeagle/docs/Makefile
 587 libbeagle/docs/reference/Makefile
 588 epiphany-extension/Makefile
 589 mozilla-extension/Makefile
 590 searchomatic/Makefile
 591 bludgeon/Makefile
 592 beagle-0.0.pc
 593 beagle-daemon.pc
 594 beagle.spec
 595 po/Makefile.in
 596 ])
 597
 598 echo "
 599         Target OS:              ${os}
 600         Extended Attributes:    ${XATTR_LIB}
 601
 602         Prefix:                 ${prefix}
 603         GNOME Prefix:           ${GNOME_PREFIX}
 604         KDE Prefix:             ${kde_prefix_print}
 605
 606         Evolution-Sharp?        ${enable_evo_sharp}
 607         gsf-sharp?              ${enable_gsf_sharp}
 608         gst-sharp?              ${enable_gst_sharp}
 609         Epiphany Extension?     ${enable_epiphany_extension}
 610         Mozilla Extension?      yes
 611         wv1?                    ${enable_wv1}
 612         galago-sharp?           ${enable_galago}
 613         libchm?                 ${has_libchm}
 614
 615         Local SqliteClient?     ${use_local_sqlite}
 616         Sqlite version:         ${SQLITE_MAJ_VER}.x
 617
 618         Enable WebServices      ${enable_webservices}
 619         Enable libbeagle        ${enable_libbeagle}"
 620 echo
 621
 622 if test "x$enable_epiphany_extension" = "xyes"; then
 623    echo "NOTE: The Beagle Epiphany Extension Is Totally Insecure!"
 624    echo "      Use it at your own risk!"
 625    echo
 626 fi