configure.in

   1 ###
   2 ### Welcome to Beagle's configure.in.  We hope you enjoy your stay.
   3 ###
   4
   5 AC_INIT(beagled/BeagleDaemon.cs)
   6 AC_CANONICAL_SYSTEM
   7 AM_INIT_AUTOMAKE(beagle, 0.2.9)
   8
   9 ########################################################################
  10
  11 ###
  12 ### Some dependencies
  13 ###
  14
  15 MONO_REQUIRED=1.1.13.5
  16 GTK_SHARP_REQUIRED=2.3.90
  17 GMIME_SHARP_REQUIRED=2.1.19
  18 EVOLUTION_SHARP_REQUIRED=0.10.2
  19 GSF_SHARP_REQUIRED=0.6
  20 GTK_REQUIRED=2.6.0
  21
  22 LIBBEAGLE_GOBJECT_REQUIRED=2.6
  23 LIBBEAGLE_LIBXML_REQUIRED=2.6.19
  24
  25 PYTHON_REQUIRED=2.3
  26 PYGTK_REQUIRED=2.6
  27
  28 ########################################################################
  29
  30 AM_MAINTAINER_MODE
  31 AM_CONFIG_HEADER(config.h)
  32
  33 AC_PROG_INSTALL
  34 AM_PROG_LIBTOOL
  35 AC_PROG_CXX
  36
  37 VERSION=${VERSION}
  38 AC_SUBST(VERSION)
  39
  40 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  41 if test "x$PKG_CONFIG" = "xno"; then
  42         AC_MSG_ERROR([You need to install pkg-config])
  43 fi
  44
  45 AC_PATH_PROG(BASH, bash)
  46 AC_SUBST(BASH)
  47
  48 # mozilla extension uses zip to create the jar/xpi files
  49 AC_PATH_PROG(ZIP, zip)
  50
  51 AC_PATH_PROG(MONO, mono)
  52 AC_PATH_PROG(MCS, mcs)
  53
  54 AC_MSG_CHECKING([for mono.pc])
  55 if test -z `$PKG_CONFIG --variable=prefix mono`; then
  56   AC_MSG_ERROR([missing the mono.pc file, usually found in the mono-devel package])
  57 else
  58   AC_MSG_RESULT([found])
  59 fi
  60
  61 # check that we have the require version of mono
  62 PKG_CHECK_MODULES(MONO, mono >= $MONO_REQUIRED)
  63
  64 # SharpZipLib broke API in 1.1.11.  Route around the damage.
  65 if `$PKG_CONFIG --atleast-version=1.1.11 mono`; then
  66   SHARPZIPLIB_LIBS="-r:`$PKG_CONFIG --variable=prefix mono`/lib/mono/compat-1.0/ICSharpCode.SharpZipLib.dll"
  67 else
  68   SHARPZIPLIB_LIBS="-r:ICSharpCode.SharpZipLib"
  69 fi
  70 AC_SUBST(SHARPZIPLIB_LIBS)
  71
  72 # check for various mono DLLs that we need.
  73 needed_dlls="Mono.Data.SqliteClient Mono.Posix System.Runtime.Remoting System.Web System.Web.Services"
  74 for i in $needed_dlls; do
  75   AC_MSG_CHECKING([for $i.dll])
  76   if test ! -e `$PKG_CONFIG --variable=prefix mono`/lib/mono/1.0/$i.dll; then
  77     AC_MSG_ERROR([missing required mono DLL: $i.dll])
  78   else
  79     AC_MSG_RESULT([found])
  80   fi
  81 done
  82
  83 # check for OS
  84 case "$target" in
  85   *-*-linux*)
  86     os=linux
  87         os_has_inotify=yes
  88     ;;
  89   *-*-freebsd*)
  90     os=freebsd
  91         os_has_inotify=no
  92     ;;
  93   *)
  94     AC_MSG_ERROR([Unrecognised target OS: $target])
  95     ;;
  96 esac
  97 AM_CONDITIONAL(OS_LINUX, test "x$os" = "xlinux")
  98 AM_CONDITIONAL(OS_FREEBSD, test "x$os" = "xfreebsd")
  99
 100 # xdgmime really wants to have HAVE_MMAP defined
 101 AC_FUNC_MMAP()
 102
 103 # check for desktop-launch
 104
 105 AC_PATH_PROG(DESKTOP_LAUNCH, desktop-launch, no)
 106 AM_CONDITIONAL(ENABLE_DESKTOP_LAUNCH, test "x$DESKTOP_LAUNCH" != "xno")
 107
 108 # Google QueryDriver
 109 # Disable GoogleDriver by default, enable if you want know what you are doing
 110 dnl -----------------------------------------------
 111 AC_ARG_ENABLE([googledriver],
 112         AC_HELP_STRING([--enable-googledriver], [Enable Google backend]),
 113         enable_googledriver=$enableval,
 114         enable_googledriver=no)
 115
 116 if test "x$enable_googledriver" = "xyes"; then
 117         # check for wsdl
 118         AC_PATH_PROG(WSDL, wsdl)
 119 fi
 120
 121 AM_CONDITIONAL(ENABLE_GOOGLEDRIVER, test "x$enable_googledriver" = "xyes")
 122
 123 #
 124 # I18N
 125 #
 126
 127 AC_PROG_INTLTOOL([0.23])
 128 GETTEXT_PACKAGE=beagle
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 ALL_LINGUAS="bg ca cs da de el en_CA en_GB es fi fr gl he hi hu it ja ka ko lt lv mk nb nl pa pl pt_BR ru sv tr uk vi zh_CN zh_HK zh_TW"
 131 AM_GLIB_GNU_GETTEXT
 132 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Name of the package for translations])
 133
 134 # Many distros don't have a dependency on sqlite for their
 135 # mono-data-sqlite packages, and the mono build process itself
 136 # doesn't require it.  But we do, so check for it here.
 137 SQLITE_MAJ_VER="0"
 138 PKG_CHECK_MODULES(SQLITE, sqlite, SQLITE_MAJ_VER="2", do_nothing="1")
 139 # Note we really need 3.3.1, but the pkgconfig file from upstream only
 140 # reports 3.3 for all releases in the 3.3 line.
 141 PKG_CHECK_MODULES(SQLITE3, sqlite3 >= 3.3, SQLITE_MAJ_VER="3", do_nothing="1")
 142
 143 if test "x$SQLITE_MAJ_VER" = "x0"; then
 144         # Note we really need 3.3.1, but the pkgconfig file from upstream only
 145         # reports 3.3 for all releases in the 3.3 line.  Make sure we error out
 146         # with the correct 3.3.1 version requirement, though.
 147         AC_MSG_ERROR([You need to install sqlite 2.x or >= 3.3.1])
 148 fi
 149
 150 AC_SUBST(SQLITE_MAJ_VER)
 151
 152 AC_ARG_ENABLE([xss],
 153               AC_HELP_STRING([--disable-xss], [Disable monitoring xscreensaver to speed up indexing when user is idle]),
 154               enable_xss=$enableval,
 155               enable_xss=yes)
 156
 157 AC_PATH_XTRA
 158
 159 # Needed by glue/screensaver-glue.c
 160 # The OLD_CFLAGS/CFLAGS hack is needed to build on Ubuntu Breezy Badger
 161 OLD_CFLAGS="$CFLAGS"
 162 OLD_LDFLAGS="$LDFLAGS"
 163 OLD_LIBS="$LIBS"
 164 CFLAGS="$CFLAGS $X_CFLAGS"
 165 LDFLAGS="$LDFLAGS $X_LIBS"
 166 AC_CHECK_HEADER(X11/extensions/scrnsaver.h, enable_scrnsaver=yes, enable_scrnsaver=no)
 167 AC_CHECK_LIB(Xss,XScreenSaverQueryExtension, enable_libxss=yes, enable_libxss=no)
 168 have_xss=no
 169 if test "x$enable_xss$enable_scrnsaver$enable_libxss" = "xyesyesyes"; then
 170         XSS_LIBS="-lXss"
 171         have_xss=yes
 172         AC_DEFINE(HAVE_LIBXSS,1,[Define to 1 if libXss is installed])
 173 fi
 174 AM_CONDITIONAL(ENABLE_LIBXSS, test "x$have_xss" = "xyes")
 175 CFLAGS="$OLD_CFLAGS"
 176 LDFLAGS="$OLD_LDFLAGS"
 177 LIBS="$OLD_LIBS"
 178
 179 dnl ----------------------------------------------
 180 AC_ARG_ENABLE([thunderbird],
 181         AC_HELP_STRING([--disable-thunderbird], [Disable Thunderbird Mail Backend]),
 182         enable_tbird=$enableval,
 183         enable_tbird=yes)
 184 AM_CONDITIONAL(ENABLE_THUNDERBIRD, test "x$enable_tbird" = "xyes")
 185
 186 dnl -------------------------------------------------------
 187
 188 AC_ARG_ENABLE([gui],
 189         AC_HELP_STRING([--disable-gui], [Disable beagle-search]),
 190         enable_gui=$enableval,
 191         enable_gui=yes)
 192
 193 AM_CONDITIONAL(ENABLE_GUI, test "x$enable_gui" = "xyes")
 194
 195 if test "x$enable_gui" = "xyes"; then
 196
 197         # We pinvoke into gnome-vfs directly from Util/GnomeFu.cs, and
 198         # we get the GNOME prefix from libgnome-2.0
 199         PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 libgnome-2.0)
 200
 201         dnl -------------------------------------------------------
 202         dnl Various version requirements
 203
 204         PKG_CHECK_MODULES(BEAGLE_UI,
 205 [
 206         gtk-sharp-2.0 >= $GTK_SHARP_REQUIRED
 207         gconf-sharp-2.0 >= $GTK_SHARP_REQUIRED
 208         glade-sharp-2.0 >= $GTK_SHARP_REQUIRED
 209         gnome-sharp-2.0 >= $GTK_SHARP_REQUIRED
 210         gnome-vfs-sharp-2.0 >= $GTK_SHARP_REQUIRED
 211         gmime-sharp >= $GMIME_SHARP_REQUIRED
 212 ])
 213         AC_SUBST(BEAGLE_UI_LIBS)
 214
 215         PKG_CHECK_MODULES(UIGLUE, gtk+-2.0 >= $GTK_REQUIRED librsvg-2.0)
 216         AC_SUBST(UIGLUE_CFLAGS)
 217         AC_SUBST(UIGLUE_LIBS)
 218
 219         dnl Gdk and Atk are needed for trayicon glue
 220
 221         GDK20_MINIMUM_VERSION=2.2.3
 222         ATK_MINIMUM_VERSION=1.2.4
 223
 224         PKG_CHECK_MODULES(LIBTRAYICON,
 225 [
 226         gdk-2.0 >= $GDK20_MINIMUM_VERSION
 227         atk >= $ATK_MINIMUM_VERSION
 228 ])
 229         AC_SUBST(LIBTRAYICON_CFLAGS)
 230         AC_SUBST(LIBTRAYICON_LIBS)
 231
 232 fi
 233
 234 dnl ----------------------------------------------
 235
 236 dnl "Open With" Menu (Requires GTK 2.8)
 237         PKG_CHECK_MODULES(OPEN_WITH,
 238 [
 239         gtk-sharp-2.0 >= 2.8
 240 ],OPEN_WITH=yes,OPEN_WITH=no)
 241 AM_CONDITIONAL(ENABLE_OPEN_WITH, test "x$OPEN_WITH" != "xno")
 242 dnl ----------------------------------------------
 243
 244 dnl evolution support
 245
 246 AC_ARG_ENABLE([evolution],
 247         AC_HELP_STRING([--disable-evolution], [Disable evolution support (default auto)]),
 248         enable_evo=$enableval,
 249         enable_evo_sharp=auto)
 250
 251
 252 EVO_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix evolution-sharp`
 253
 254 EVO_LIBDIR=`$PKG_CONFIG --variable=evolibdir evolution-sharp`
 255 AC_SUBST(EVO_LIBDIR)
 256
 257 PKG_CHECK_MODULES(EVO,
 258                   evolution-sharp >= $EVOLUTION_SHARP_REQUIRED  \
 259                   gconf-sharp-2.0 >= $GTK_SHARP_REQUIRED        \
 260                   gmime-sharp >= $GMIME_SHARP_REQUIRED,
 261                   have_evo_dependencies=yes, have_evo_dependencies=no)
 262 AC_SUBST(EVO_LIBS)
 263
 264 if test "x$have_evo_dependencies" = "xno"; then
 265
 266         dnl error out if user has explicitly requested evolution support
 267         if test "x$enable_evo" = "xyes"; then
 268                 AC_MSG_ERROR([Could not find Evolution dependencies])
 269         fi
 270
 271         enable_evo="no (missing dependencies)"
 272
 273 else
 274
 275         if test "x$enable_evo" != "xno"; then
 276                 enable_evo="yes"
 277         else
 278                 enable_evo="no (disabled)"
 279         fi
 280
 281 fi
 282
 283 AM_CONDITIONAL(ENABLE_EVOLUTION, test "x$enable_evo" = "xyes")
 284
 285 dnl ----------------------------------------------
 286
 287 dnl Should we use our own copy of the sqlite bindings or the version
 288 dnl that got installed along with mono?
 289
 290 use_local_sqlite="yes" # hard-wired for now
 291 AM_CONDITIONAL(USE_LOCAL_SQLITE, test "x$use_local_sqlite" = "xyes")
 292
 293 dnl ----------------------------------------------
 294
 295 dnl inotify
 296
 297 AC_ARG_ENABLE([inotify],
 298          AC_HELP_STRING([--disable-inotify], [Disable inotify filesystem monitoring support (default auto)]),
 299          enable_inotify=$enableval,
 300          enable_inotify=auto)
 301
 302 if test "x$os_has_inotify" = "xno"; then
 303
 304         dnl error out if user has explicitly requested inotify
 305         if test "x$enable_inotify" = "xyes"; then
 306                 AC_MSG_ERROR([inotify is unavailable on your system architecture])
 307         fi
 308
 309         enable_inotify="no (unavailable)"
 310
 311 else
 312
 313         if test "x$enable_inotify" != "xno"; then
 314                 enable_inotify="yes"
 315         else
 316                 enable_inotify="no (disabled)"
 317         fi
 318
 319 fi
 320
 321 AM_CONDITIONAL(ENABLE_INOTIFY, test "x$enable_inotify" = "xyes")
 322
 323 dnl ----------------------------------------------
 324
 325 dnl beagled
 326
 327 PKG_CHECK_MODULES(GSF_SHARP, gsf-sharp >= 0.5, enable_gsf_sharp=yes, enable_gsf_sharp=no)
 328 AM_CONDITIONAL(ENABLE_GSF_SHARP, test "x$enable_gsf_sharp" = "xyes")
 329
 330 dnl ----------------------------------------------
 331
 332 dnl libexif: Needed to index jpeg metadata
 333
 334 LIBEXIF_API_CHANGE=0.6.0
 335 LIBEXIF_REQUIRED_MIN=0.5.7
 336 LIBEXIF_REQUIRED_MAX=0.7.0
 337
 338 PKG_CHECK_MODULES(LIBEXIF, libexif >= $LIBEXIF_REQUIRED_MIN libexif < $LIBEXIF_REQUIRED_MAX)
 339 PKG_CHECK_MODULES(LIBEXIF_API_CHECK, libexif >= $LIBEXIF_API_CHANGE, have_old_libexif=no, have_old_libexif=yes)
 340
 341 if test "x$have_old_libexif" = "xyes"; then
 342         EXIF_SOVERSION=9
 343 else
 344         PKG_CHECK_MODULES(LIBEXIF_VERSION_CHECK, libexif >= 0.6.12, EXIF_SOVERSION=12, EXIF_SOVERSION=10)
 345 fi
 346 AC_SUBST(EXIF_SOVERSION)
 347
 348 PKG_CHECK_MODULES(BEAGLED,
 349 [
 350         shared-mime-info
 351         gmime-sharp >= $GMIME_SHARP_REQUIRED
 352         glib-sharp-2.0 >= $GTK_SHARP_REQUIRED
 353 ])
 354         BEAGLED_LIBS="$BEAGLED_LIBS $GSF_SHARP_LIBS"
 355 AC_SUBST(BEAGLED_LIBS)
 356
 357 GSF_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gsf-sharp`
 358 GMIME_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gmime-sharp`
 359
 360 dnl ----------------------------------------------
 361
 362 dnl libbeagle
 363
 364 GTK_DOC_CHECK(1.0)
 365
 366 AC_ARG_ENABLE([libbeagle],
 367         AC_HELP_STRING([--disable-libbeagle], [Disable libbeagle (C API)]),
 368         enable_libbeagle=$enableval,
 369         enable_libbeagle=auto)
 370
 371 dnl library versioning
 372 dnl Increase when changing the API
 373 LIBBEAGLE_CURRENT=0
 374
 375 dnl Update when changing implementation of current API,
 376 dnl reset to 0 when changing CURRENT.  This is the revision of
 377 dnl current API version
 378 LIBBEAGLE_REVISION=0
 379
 380 dnl Increase of API change is ABI compatible, otherwise reset to 0
 381 LIBBEAGLE_AGE=0
 382
 383 LIBBEAGLE_VERSION_INFO="$LIBBEAGLE_CURRENT:$LIBBEAGLE_REVISION:$LIBBEAGLE_AGE"
 384 AC_SUBST(LIBBEAGLE_VERSION_INFO)
 385
 386 PKG_CHECK_MODULES(LIBBEAGLE, [
 387         gobject-2.0 >= $LIBBEAGLE_GOBJECT_REQUIRED
 388         libxml-2.0  >= $LIBBEAGLE_LIBXML_REQUIRED
 389 ], have_libbeagle_deps=yes, have_libbeagle_deps=no)
 390
 391 AC_SUBST(LIBBEAGLE_CFLAGS)
 392 AC_SUBST(LIBBEAGLE_LIBS)
 393
 394 if test "x$have_libbeagle_deps" = "xno"; then
 395
 396         if test "x$enable_libbeagle" = "xyes"; then
 397                 AC_MSG_ERROR([Missing libbeagle dependencies])
 398         fi
 399
 400         enable_libbeagle="no (missing dependencies)"
 401 else
 402         if test "x$enable_libbeagle" != "xno"; then
 403                 enable_libbeagle="yes"
 404         else
 405                 enable_libbeagle="no (disabled)"
 406         fi
 407 fi
 408
 409 AM_CONDITIONAL(ENABLE_LIBBEAGLE, test "x$enable_libbeagle" = "xyes")
 410
 411 dnl ----------------------------------------------
 412 AC_ARG_ENABLE([bludgeon],
 413         AC_HELP_STRING([--disable-bludgeon], [Disable bludgeon testing tool]),
 414         enable_bludgeon=$enableval,
 415         enable_bludgeon=yes)
 416 AM_CONDITIONAL(ENABLE_BLUDGEON, test "x$enable_bludgeon" = "xyes")
 417
 418
 419 dnl ----------------------------------------------
 420 dnl Epiphany Extension
 421 dnl Much of this is cut&pasted from epiphany-extensions/configure.ac
 422
 423 AC_ARG_ENABLE([epiphany-extension],
 424         AC_HELP_STRING([--enable-epiphany-extension], [Enable Epiphany Extension (default auto)]),
 425         enable_epiphany_extension=$enableval,
 426         enable_epiphany_extension=auto)
 427
 428 if $PKG_CONFIG --exists epiphany-2.16; then
 429         EPIPHANY_MAJOR=2.16
 430         EPIPHANY_REQUIRED=2.16.0
 431 elif $PKG_CONFIG --exists epiphany-2.14; then
 432         EPIPHANY_MAJOR=2.14
 433         EPIPHANY_REQUIRED=2.14.0
 434 elif $PKG_CONFIG --exists epiphany-1.8; then
 435         EPIPHANY_MAJOR=1.8
 436         EPIPHANY_REQUIRED=1.7.0
 437 elif $PKG_CONFIG --exists epiphany-1.6; then
 438         EPIPHANY_MAJOR=1.6
 439         EPIPHANY_REQUIRED=1.6.0
 440 else
 441         enable_epiphany_extension="no (Epiphany not installed)"
 442 fi
 443
 444 if test "x$enable_epiphany_extension" = "xyes"; then
 445
 446 LIBXML_REQUIRED=2.6.0
 447 LIBGLIB_REQUIRED=2.4.0
 448 LIBGTK_REQUIRED=2.4.0
 449
 450 AC_SUBST(EPIPHANY_REQUIRED)
 451 AC_SUBST(LIBXML_REQUIRED)
 452 AC_SUBST(LIBGLIB_REQUIRED)
 453 AC_SUBST(LIBGTK_REQUIRED)
 454
 455 PKG_CHECK_MODULES(EPIPHANY_DEPENDENCY,
 456                   libxml-2.0 >= $LIBXML_REQUIRED \
 457                   libglade-2.0 \
 458                   glib-2.0 >= $LIBGLIB_REQUIRED \
 459                   gmodule-2.0 \
 460                   gtk+-2.0 >= $LIBGTK_REQUIRED \
 461                   epiphany-$EPIPHANY_MAJOR >= $EPIPHANY_REQUIRED,
 462                   have_epiphany_dependencies=yes,
 463                   have_epiphany_dependencies=no)
 464 AC_SUBST(EPIPHANY_DEPENDENCY_CFLAGS)
 465 AC_SUBST(EPIPHANY_DEPENDENCY_LIBS)
 466
 467 EPIPHANY_EXTENSIONS_DIR="`$PKG_CONFIG --variable=extensionsdir epiphany-$EPIPHANY_MAJOR`"
 468 AC_SUBST([EPIPHANY_EXTENSIONS_DIR])
 469 EPIPHANY_PREFIX="`$PKG_CONFIG --variable=prefix epiphany-$EPIPHANY_MAJOR`"
 470 AC_SUBST(EPIPHANY_PREFIX)
 471
 472 if test "x$have_epiphany_dependencies" = "xno"; then
 473         enable_epiphany_extension="no (missing dependencies)"
 474 elif test "x$enable_epiphany_extension" != "xyes"; then
 475         enable_epiphany_extension="disabled"
 476 fi
 477
 478 fi
 479
 480 AM_CONDITIONAL(ENABLE_EPIPHANY_EXTENSION, test "x$enable_epiphany_extension" = "xyes")
 481
 482 AC_ARG_ENABLE([epiphany-extension-install],
 483         AS_HELP_STRING([--enable-epiphany-extension-install],[Install Epiphany Extension]),
 484         [install_epiphany_extension=$enableval],
 485         [install_epiphany_extension=yes])
 486
 487 AM_CONDITIONAL([INSTALL_EPIPHANY_EXTENSION], [test "x$install_epiphany_extension" = "xyes"])
 488
 489 dnl ----------------------------------------------
 490
 491 dnl Galago
 492
 493 PKG_CHECK_MODULES(GALAGO, galago-sharp >= 0.5 , enable_galago=yes, enable_galago=no)
 494 AM_CONDITIONAL(ENABLE_GALAGO, test "x$enable_galago" = "xyes")
 495 AC_SUBST(GALAGO_LIBS)
 496
 497
 498 dnl ----------------------------------------------
 499
 500 GTK_BINARY_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 501 AC_SUBST(GTK_BINARY_VERSION)
 502
 503 dnl For the systeminfo glue
 504
 505 SYSTEMINFO_GLUE_X_LIBS="$X_PRE_LIBS $X_LIBS -lX11 $XSS_LIBS $X_EXTRA_LIBS"
 506 AC_SUBST(SYSTEMINFO_GLUE_X_LIBS)
 507
 508 dnl ----------------------------------------------
 509
 510 dnl For the wv1 glue
 511
 512 PKG_CHECK_MODULES(WV1, wv-1.0, enable_wv1=yes, enable_wv1=no)
 513 AM_CONDITIONAL(ENABLE_WV1, test "x$enable_wv1" = "xyes")
 514 AC_SUBST(WV1_LIBS)
 515
 516 dnl ----------------------------------------------
 517
 518 dnl KDE launcher/icon support
 519
 520 kde_prefix_print="unknown; will guess at runtime"
 521 AC_PATH_PROG(KDE_CONFIG, [kde-config], [no])
 522 if test ! "x$KDE_CONFIG" = "xno"; then
 523         KDE_PREFIX=`$KDE_CONFIG --prefix`
 524         kde_prefix_print="$KDE_PREFIX"
 525 fi
 526 AC_SUBST(KDE_PREFIX)
 527
 528 dnl ----------------------------------------------
 529
 530 dnl Beagle webservices
 531
 532 dnl AC_ARG_ENABLE([webservices],
 533 dnl        AC_HELP_STRING([--enable-webservices], [Enable WebServices (default disabled)]),
 534 dnl        enable_webservices=$enableval,
 535 dnl        enable_webservices=no)
 536
 537 enable_webservices=no
 538 AM_CONDITIONAL(ENABLE_WEBSERVICES, test "x$enable_webservices" = "xyes")
 539
 540 dnl ----------------------------------------------
 541
 542 dnl Prefixes for helper scripts
 543 GAC_PREFIX="$EVO_SHARP_PREFIX:$GSF_SHARP_PREFIX:$GMIME_SHARP_PREFIX"
 544 dnl Remove duplicate prefixes
 545 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|:|\n|g' | sort | uniq | tr '\n' ':'`"
 546 dnl Remove stray :s
 547 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|::\+|:|g' -e 's|^:\+||' -e 's|:\+$||'`"
 548 AC_SUBST(GAC_PREFIX)
 549
 550 GNOME_PREFIX="`$PKG_CONFIG --variable=prefix libgnome-2.0`"
 551 AC_SUBST(GNOME_PREFIX)
 552
 553 dnl ----------------------------------------------
 554
 555 dnl Check if the system has libchm, used by the CHMFilter
 556
 557 # Check for libchm for CHM filter
 558 AC_CHECK_LIB(chm,chm_open,has_libchm=yes,has_libchm=no)
 559 AM_CONDITIONAL(HAS_LIBCHM, test "x$has_libchm" = "xyes")
 560
 561 dnl ----------------------------------------------
 562
 563 dnl Conditional for debugging XML messages.
 564
 565 BEAGLE_DEFINES=""
 566
 567 AC_ARG_ENABLE([xml-dump],
 568         AC_HELP_STRING([--enable-xml-dump], [Enables printing of the XML messages sent between components (default no)]),
 569         enable_xml_dump=$enableval,
 570         enable_xml_dump=no)
 571
 572 if test "x$enable_xml_dump" = "xyes"; then
 573         AC_DEFINE_UNQUOTED(ENABLE_XML_DUMP, 1, [Dump XML messages for debugging])
 574         BEAGLE_DEFINES="-define:ENABLE_XML_DUMP"
 575 fi
 576
 577 AC_SUBST(BEAGLE_DEFINES)
 578
 579 dnl ----------------------------------------------
 580
 581 dnl Python 2.3
 582
 583 AC_ARG_ENABLE(python,
 584         AC_HELP_STRING([--disable-python], [Disable python support (default auto)]),
 585         enable_python=$enableval,
 586         enable_python=auto)
 587
 588 have_python=no
 589 if test "x$enable_libbeagle" = "xyes" -a "x$enable_python" != "xno"; then
 590         have_python_version=no
 591         have_python_headers=no
 592         have_pygtk_deps=no
 593         have_pygtk_codegen=no
 594
 595         AM_PATH_PYTHON()
 596
 597         if test -z "$PYTHON"; then
 598                 AC_MSG_WARN([Python not found])
 599         else
 600                 AM_PYTHON_CHECK_VERSION($PYTHON, $PYTHON_REQUIRED,
 601                         have_python_version=yes,
 602                         have_python_version=no)
 603         fi
 604
 605         if test "x$have_python_version" != "xyes"; then
 606                 AC_MSG_WARN([Python version $PYTHON_REQUIRED not found])
 607         else
 608                 AM_CHECK_PYTHON_HEADERS(have_python_headers=yes, have_python_headers=no)
 609         fi
 610
 611         if test "x$have_python_headers" != "xyes"; then
 612                 AC_MSG_WARN([could not find Python headers])
 613         else
 614                 PKG_CHECK_MODULES(PYBEAGLE,
 615                         pygtk-2.0 >= $PYGTK_REQUIRED
 616                         pygobject-2.0 >= $PYGTK_REQUIRED,
 617                         have_pygtk_deps=yes,
 618                         have_pygtk_deps=no)
 619         fi
 620
 621         if test "x$have_pygtk_deps" != "xyes"; then
 622                 AC_MSG_WARN([could not find pygtk])
 623         else
 624                 AC_PATH_PROG(PYGTK_CODEGEN, pygtk-codegen-2.0, no)
 625         fi
 626
 627         if test -z "$PYGTK_CODEGEN"; then
 628                 AC_MSG_WARN([could not find pygtk-codegen in path])
 629         else
 630                 AC_MSG_CHECKING(for pygtk defs)
 631                 PYGTK_DEFSDIR=`$PKG_CONFIG --variable=defsdir pygtk-2.0`
 632                 AC_MSG_RESULT($PYGTK_DEFSDIR)
 633
 634                 have_python=yes
 635         fi
 636 fi
 637
 638 if test "x$enable_python" = "xyes"; then
 639         if test "x$enable_libbeagle" != "xyes"; then
 640                 AC_MSG_ERROR([Python bindings are requested, but libbeagle isn't to be built])
 641         elif test "x$have_python" = "xno"; then
 642                 AC_MSG_ERROR([Python bindings are requested, but cannot be built])
 643         fi
 644 fi
 645
 646 AM_CONDITIONAL(ENABLE_PYTHON, test "x$have_python" = "xyes")
 647 AC_SUBST(PYBEAGLE_LIBS)
 648 AC_SUBST(PYBEAGLE_CFLAGS)
 649 AC_SUBST(PYGTK_DEFSDIR)
 650
 651 dnl ----------------------------------------------
 652
 653 AC_OUTPUT([
 654 Makefile
 655 Util/Makefile
 656 Util/Util.dll.config
 657 images/Makefile
 658 glue/Makefile
 659 BeagleClient/Makefile
 660 beagled/Makefile
 661 Filters/Makefile
 662 tools/Makefile
 663 search/Makefile
 664 ImLogViewer/Makefile
 665 ContactViewer/Makefile
 666 libbeagle/Makefile
 667 libbeagle/libbeagle-0.0.pc
 668 libbeagle/beagle/Makefile
 669 libbeagle/examples/Makefile
 670 libbeagle/docs/Makefile
 671 libbeagle/docs/reference/Makefile
 672 epiphany-extension/Makefile
 673 mozilla-extension/Makefile
 674 bludgeon/Makefile
 675 wrappers/Makefile
 676 wrappers/python/Makefile
 677 beagle-0.0.pc
 678 beagle-daemon.pc
 679 beagle-ui-0.0.pc
 680 beagle.spec
 681 po/Makefile.in
 682 ])
 683
 684 echo "
 685         Beagle Version:           ${VERSION}
 686         Target OS:                ${os}
 687         inotify?                  ${enable_inotify}
 688
 689         Prefix:                   ${prefix}
 690         GNOME Prefix:             ${GNOME_PREFIX}
 691         KDE Prefix:               ${kde_prefix_print}
 692
 693         Evolution support?        ${enable_evo}
 694         gsf-sharp?                ${enable_gsf_sharp}
 695         wv1?                      ${enable_wv1}
 696         galago-sharp?             ${enable_galago}
 697         libchm?                   ${has_libchm}
 698         google backend?           ${enable_googledriver} (Unsupported)
 699         Thunderbird backend?      ${enable_tbird}
 700
 701         Mozilla Extension?        yes
 702         Epiphany Extension?       ${enable_epiphany_extension}
 703
 704         Local SqliteClient?       ${use_local_sqlite}
 705         Sqlite version:           ${SQLITE_MAJ_VER}.x
 706
 707         Enable WebServices        no (WebServices are deprecated)
 708         Enable libbeagle          ${enable_libbeagle}
 709         Enable python bindings    ${have_python}
 710         Monitor screensaver       ${have_xss}
 711
 712         Enable beagle-search GUI  ${enable_gui}
 713         Enable \"Open With\" menu   ${OPEN_WITH}
 714 "
 715 echo
 716
 717 if test "x$enable_epiphany_extension" = "xyes"; then
 718    echo "NOTE: The Beagle Epiphany Extension Is Totally Insecure!"
 719    echo "      Use it at your own risk!"
 720    echo
 721 fi