configure.in

   1 AC_INIT(beagled/BeagleDaemon.cs)
   2 AC_CANONICAL_SYSTEM
   3 AM_INIT_AUTOMAKE(beagle, 0.0.13)
   4 AM_MAINTAINER_MODE
   5 AM_CONFIG_HEADER(config.h)
   6
   7 AC_PROG_INSTALL
   8 AM_PROG_LIBTOOL
   9 AC_PROG_CXX
  10
  11 VERSION=${VERSION}
  12 AC_SUBST(VERSION)
  13
  14 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  15 if test "x$PKG_CONFIG" = "xno"; then
  16         AC_MSG_ERROR([You need to install pkg-config])
  17 fi
  18
  19 AC_PATH_PROG(BASH, bash)
  20 AC_SUBST(BASH)
  21
  22 # mozilla extension uses zip to create the jar/xpi files
  23 AC_PATH_PROG(ZIP, zip)
  24
  25 AC_PATH_PROG(MONO, mono)
  26 AC_PATH_PROG(MCS, mcs)
  27
  28 AC_MSG_CHECKING([for mono.pc])
  29 if test -z `$PKG_CONFIG --variable=prefix mono`; then
  30   AC_MSG_ERROR([missing the mono.pc file, usually found in the mono-devel package])
  31 else
  32   AC_MSG_RESULT([found])
  33 fi
  34
  35 # require mono 1.0.6 or newer
  36 PKG_CHECK_MODULES(MONO, mono >= 1.0.6)
  37
  38 # check for various mono DLLs that we need.
  39 needed_dlls="Mono.Data.SqliteClient Mono.Posix System.Runtime.Remoting System.Web System.Web.Services"
  40 for i in $needed_dlls; do
  41   AC_MSG_CHECKING([for $i.dll])
  42   if test ! -e `$PKG_CONFIG --variable=prefix mono`/lib/mono/1.0/$i.dll; then
  43     AC_MSG_ERROR([missing required mono DLL: $i.dll])
  44   else
  45     AC_MSG_RESULT([found])
  46   fi
  47 done
  48
  49 # check for OS
  50 case "$target" in
  51   *-*-linux*)
  52     os=linux
  53     AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="libattr",)
  54     AC_CHECK_FUNC(lsetxattr, XATTR_LIB="libc",)
  55     ;;
  56   *-*-freebsd*)
  57     os=freebsd
  58     AC_CHECK_FUNC(extattr_set_link, XATTR_LIB="libc")
  59     ;;
  60   *)
  61     AC_MSG_ERROR([Unrecognised target OS: $target])
  62     ;;
  63 esac
  64 AM_CONDITIONAL(OS_LINUX, test "x$os" = "xlinux")
  65 AM_CONDITIONAL(OS_FREEBSD, test "x$os" = "xfreebsd")
  66
  67 # check for xattr implementation
  68 if test "x$XATTR_LIB" = "x"; then
  69     AC_MSG_ERROR([Could not find a support extended attribute implementation (tried libc and libattr)])
  70 fi
  71 AC_SUBST(XATTR_LIB)
  72
  73 # check for desktop-launch
  74
  75 AC_PATH_PROG(DESKTOP_LAUNCH, desktop-launch, no)
  76 AM_CONDITIONAL(ENABLE_DESKTOP_LAUNCH, test "x$DESKTOP_LAUNCH" != "xno")
  77
  78 # check for wsdl
  79 AC_PATH_PROG(WSDL, wsdl)
  80
  81 #
  82 # I18N
  83 #
  84
  85 AC_PROG_INTLTOOL([0.23])
  86 GETTEXT_PACKAGE=beagle
  87 AC_SUBST(GETTEXT_PACKAGE)
  88 ALL_LINGUAS="bg ca cs da de el en_CA en_GB es fr hu ja mk nb nl no pl pt_BR sv tr uk zh_CN zh_TW"
  89 AM_GLIB_GNU_GETTEXT
  90
  91 # Many distros don't have a dependency on sqlite for their
  92 # mono-data-sqlite packages, and the mono build process itself
  93 # doesn't require it.  But we do, so check for it here.
  94 PKG_CHECK_MODULES(SQLITE, sqlite, have_sqlite2="yes", have_sqlite2="no")
  95 PKG_CHECK_MODULES(SQLITE, sqlite3, have_sqlite3="yes", have_sqlite3="no")
  96
  97 if test "x$have_sqlite2" = "xno" -a "x$have_sqlite3" = "xno"; then
  98         AC_MSG_ERROR([You need to install either sqlite2 or sqlite3])
  99 fi
 100
 101 # Needed by glue/screensaver-glue.c
 102 # The OLD_CFLAGS/CFLAGS hack is needed to build on Ubuntu Breezy Badger
 103 OLD_CFLAGS="$CFLAGS"
 104 CFLAGS="$CFLAGS -I/usr/X11R6/include"
 105 AC_CHECK_HEADER(X11/extensions/scrnsaver.h,, [AC_MSG_ERROR([Unable to find scrnsaver.h.  You probably need to install XFree86 development packages])])
 106 CFLAGS="$OLD_CFLAGS"
 107
 108 # We pinvoke into gnome-vfs directly from Util/gnome.cs and Util/Vfs.cs, and
 109 # we get the GNOME prefix from libgnome-2.0
 110 PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 libgnome-2.0)
 111
 112 dnl ******************
 113 dnl Mozilla name check
 114 dnl ******************
 115
 116 AC_MSG_CHECKING([which mozilla to use])
 117
 118 MOZILLA=
 119 AC_ARG_WITH([mozilla],
 120         AC_HELP_STRING([--with-mozilla@<:@=mozilla|firefox|thunderbird@:>@],
 121                        [Whether to use mozilla, firefox or thunderbird gtkmozembed (default: mozilla)]),
 122         [MOZILLA="$withval"])
 123
 124 dnl try to autodetect: if mozilla exists, use it, else try firefox, then thunderbird
 125 if test "x$MOZILLA" = "x"; then
 126   if pkg-config --exists mozilla-gtkmozembed; then
 127     MOZILLA=mozilla
 128   elif pkg-config --exists firefox-gtkmozembed; then
 129     MOZILLA=firefox
 130   elif pkg-config --exists thunderbird-gtkmozembed; then
 131     MOZILLA=thunderbird
 132   else
 133     AC_MSG_ERROR([unable to find gtkmozembed; this can be found in mozilla/firefox/thunderbird development packages])
 134   fi
 135 elif test "x$with_mozilla" != "xmozilla" -a "x$with_mozilla" != "xfirefox" -a "x$with_mozilla" != "xthunderbird"; then
 136   AC_MSG_ERROR([unknown mozilla name ($MOZILLA)])
 137 fi
 138
 139 AC_SUBST(MOZILLA)
 140
 141 AC_MSG_RESULT([$MOZILLA])
 142
 143 case "$MOZILLA" in
 144 mozilla) min_version=1.6 flavour=mozilla ;;
 145 firefox) min_version=0.10 flavour=toolkit ;;
 146 thunderbird) min_version=0.8 flavour=toolkit ;;
 147 esac
 148
 149 MOZILLA_FLAVOUR=$flavour
 150 AC_SUBST(MOZILLA_FLAVOUR)
 151 PKG_CHECK_MODULES(MOZILLA_COMPONENT, $MOZILLA-gtkmozembed >= $min_version $MOZILLA-xpcom >= $min_version)
 152 AC_SUBST(MOZILLA_COMPONENT_CFLAGS)
 153 AC_SUBST(MOZILLA_COMPONENT_LIBS)
 154
 155 MOZILLA_INCLUDE_ROOT="`$PKG_CONFIG --variable=includedir $MOZILLA-gtkmozembed`"
 156 AC_SUBST(MOZILLA_INCLUDE_ROOT)
 157
 158 MOZILLA_HOME="`$PKG_CONFIG --variable=libdir $MOZILLA-gtkmozembed`"
 159 AC_SUBST(MOZILLA_HOME)
 160
 161 MOZILLA_PREFIX="`$PKG_CONFIG --variable=prefix $MOZILLA-gtkmozembed`"
 162 AC_SUBST(MOZILLA_PREFIX)
 163
 164
 165
 166 dnl *************************************************************************
 167 dnl This is from Mozilla's configure.in. They set almost all the config stuff
 168 dnl they need in mozilla-config.h Except for this compiler flag, which can't
 169 dnl go in mozilla-config.h So we check the flag too and now we can include
 170 dnl mozilla-config.h without breaking epiphany.
 171 dnl This is really gcc-only
 172 dnl Do this test using CXX only since some versions of gcc
 173 dnl 2.95-2.97 have a signed wchar_t in c++ only and some versions
 174 dnl only have short-wchar support for c++.
 175 AC_LANG_PUSH(C++)
 176 _SAVE_CXXFLAGS=$CXXFLAGS
 177 _SAVE_AM_CXXFLAGS=$AM_CXXFLAGS
 178 AM_CXXFLAGS="$AM_CXXFLAGS -fshort-wchar"
 179 CXXFLAGS="$CXXFLAGS $AM_CXXFLAGS"
 180
 181
 182 AC_CACHE_CHECK(for compiler -fshort-wchar option,
 183     ac_cv_have_usable_wchar_option,
 184     [AC_TRY_RUN([#include <stddef.h>
 185                  int main () {
 186                    return (sizeof(wchar_t) != 2) ||
 187                           (wchar_t)-1 < (wchar_t) 0 ; } ],
 188                 ac_cv_have_usable_wchar_option="yes",
 189                 ac_cv_have_usable_wchar_option="no",
 190                 ac_cv_have_usable_wchar_option="maybe")])
 191
 192 if test "$ac_cv_have_usable_wchar_option" != "yes"; then
 193     AM_CXXFLAGS=$_SAVE_AM_CXXFLAGS
 194 fi
 195
 196 dnl **********************************
 197 dnl now tests for mozilla API variance
 198 dnl **********************************
 199
 200 dnl FIXME find a m4/autoconf guru who can distill this into a nice macro
 201
 202 CXXFLAGS="$_SAVE_CXXFLAGS $AM_CXXFLAGS -I$MOZILLA_INCLUDE_ROOT -I$MOZILLA_INCLUDE_ROOT/embedstring -I$MOZILLA_INCLUDE_ROOT/content -I$MOZILLA_INCLUDE_ROOT/necko `pkg-config --cflags $MOZILLA-xpcom`"
 203
 204 dnl Changed from PRUnichar* to nsAString& in 1.8a1 and on aviary branch
 205
 206 AC_MSG_CHECKING([whether nsIFilePicker methods expect nsAString&])
 207                                                                                 AC_COMPILE_IFELSE(
 208         [AC_LANG_PROGRAM(
 209                 [[#include <nsEmbedString.h>
 210                   #include <widget/nsIFilePicker.h>]],
 211                 [[nsIFilePicker *p;
 212                   p->SetDefaultString (nsEmbedString());]]
 213         )],
 214         [AC_DEFINE([MOZ_NSIFILEPICKER_NSASTRING_],[1],[Define if nsIFilePicker uses nsAString&]) result=yes],
 215         [result=no])
 216
 217 AC_MSG_RESULT([$result])
 218
 219 dnl Changed from char* to nsAString& in 1.8a1
 220
 221 AC_MSG_CHECKING([whether nsIMIMEInfo methods expect nsAString&])
 222
 223 AC_COMPILE_IFELSE(
 224         [AC_LANG_PROGRAM(
 225                 [[#include <nsEmbedString.h>
 226                   #include <mimetype/nsIMIMEInfo.h>]],
 227                 [[nsIMIMEInfo *p;
 228                   p->SetDescription (nsEmbedString());]]
 229         )],
 230         [AC_DEFINE([MOZ_NSIMIMEINFO_NSACSTRING_],[1],[Define if nsIMIMEInfo uses nsAString&]) result=yes],
 231         [result=no])
 232
 233 AC_MSG_RESULT([$result])
 234
 235 dnl Firefox doesn't have this API (?)
 236
 237 AC_MSG_CHECKING([for nsIXULChromeRegistry API])
 238
 239 AC_COMPILE_IFELSE(
 240         [AC_LANG_PROGRAM(
 241                 [[#include <nsEmbedString.h>
 242                   #include <nsIChromeRegistry.h>]],
 243                 [[nsIXULChromeRegistry *p;
 244                   p->SelectSkin (nsEmbedCString(), PR_FALSE);]]
 245         )],
 246         [AC_DEFINE([MOZ_NSIXULCHROMEREGISTRY_SELECTSKIN],[1],[dummy]) result=yes],
 247         [result=no])
 248 AC_MSG_RESULT([$result])
 249
 250 dnl changed from nsIXULChromeRegistry in 1.8a4
 251
 252 AC_CHECK_FILE([$MOZILLA_INCLUDE_ROOT/chrome/nsIChromeRegistrySea.h],
 253         [AC_DEFINE([HAVE_CHROME_NSICHROMEREGISTRYSEA_H], [1], [Define if nsIChromeRegistrySea.h exists])])
 254
 255 MOZILLA_WARN_CXXFLAGS="-Wall -Wconversion -Wpointer-arith -Wcast-align -Woverloaded-virtual -Wsynth -Wno-ctor-dtor-privacy -Wno-non-virtual-dtor"
 256 AC_SUBST(MOZILLA_WARN_CXXFLAGS)
 257
 258 dnl -------------------------------------------------------
 259
 260 PKG_CHECK_MODULES(LIBGECKOGLUE, gtk+-2.0 >= 2.2 $MOZILLA-gtkmozembed)
 261 AC_SUBST(LIBGECKOGLUE_CFLAGS)
 262 AC_SUBST(LIBGECKOGLUE_LIBS)
 263
 264 dnl -------------------------------------------------------
 265
 266 PKG_CHECK_MODULES(BEAGLE_UI, gtk-sharp glade-sharp gecko-sharp = 0.6 gnome-sharp gconf-sharp gmime-sharp >= 2.1.15)
 267 AC_SUBST(BEAGLE_UI_LIBS)
 268
 269 dnl ----------------------------------------------
 270
 271 # Gdk and Atk are needed for libtrayiconglue
 272 GDK20_MINIMUM_VERSION=2.2.3
 273 ATK_MINIMUM_VERSION=1.2.4
 274
 275 PKG_CHECK_MODULES(LIBTRAYICON,
 276                   gdk-2.0 >= $GDK20_MINIMUM_VERSION
 277                   atk >= $ATK_MINIMUM_VERSION)
 278 AC_SUBST(LIBTRAYICON_CFLAGS)
 279 AC_SUBST(LIBTRAYICON_LIBS)
 280
 281 dnl ----------------------------------------------
 282
 283 AC_ARG_ENABLE([evolution-sharp],
 284          AC_HELP_STRING([--disable-evolution-sharp], [Disable evolution-sharp support (default auto)]),
 285          enable_evo_sharp=$enableval,
 286          enable_evo_sharp=auto)
 287
 288 EVOLUTION_SHARP_REQUIRED=0.8
 289 AC_SUBST(EVO_SHARP_LIBS)
 290 EVO_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix evolution-sharp`
 291
 292 PKG_CHECK_MODULES(EVO_SHARP,
 293          evolution-sharp >= $EVOLUTION_SHARP_REQUIRED, \
 294          have_evo_sharp_dependencies=yes,
 295          have_evo_sharp_dependencies=no)
 296
 297 if test "x$have_evo_sharp_dependencies" = "xno"; then
 298
 299         dnl error out if user has explicitly requested evo-sharp
 300         if test "x$enable_evo_sharp" = "xyes"; then
 301                 AC_MSG_ERROR([Could not find evolution-sharp])
 302         fi
 303
 304         enable_evo_sharp="no (missing dependencies)"
 305
 306 else
 307
 308         if test "x$enable_evo_sharp" != "xno"; then
 309                 enable_evo_sharp="yes"
 310         else
 311                 enable_evo_sharp="no (disabled)"
 312         fi
 313
 314 fi
 315
 316 AM_CONDITIONAL(ENABLE_EVO_SHARP, test "x$enable_evo_sharp" = "xyes")
 317
 318 dnl ----------------------------------------------
 319
 320 dnl Should we use our own copy of the sqlite bindings or the version
 321 dnl that got installed along with mono?
 322
 323 use_local_sqlite="yes" # hard-wired for now
 324 AM_CONDITIONAL(USE_LOCAL_SQLITE, test "x$use_local_sqlite" = "xyes")
 325
 326 dnl ----------------------------------------------
 327
 328 dnl beagled
 329
 330 PKG_CHECK_MODULES(GSF_SHARP, gsf-sharp >= 0.2, enable_gsf_sharp=yes, enable_gsf_sharp=no)
 331 AM_CONDITIONAL(ENABLE_GSF_SHARP, test "x$enable_gsf_sharp" = "xyes")
 332
 333 dnl ----------------------------------------------
 334 dnl GST# is not in a usable stage as of 9.3 release, disabling it.
 335
 336 PKG_CHECK_MODULES(GST_SHARP, gst-sharp >= __DISABLE_FOR_NOW__, enable_gst_sharp=yes, enable_gst_sharp=disabled)
 337 AM_CONDITIONAL(ENABLE_GST_SHARP, test "x$enable_gst_sharp" = "xyes")
 338
 339 dnl ----------------------------------------------
 340
 341 dnl Needed to index jpeg metadata
 342 LIBEXIF_API_CHANGE=0.6.0
 343 LIBEXIF_REQUIRED_MIN=0.5.7
 344 LIBEXIF_REQUIRED_MAX=0.7.0
 345
 346 PKG_CHECK_MODULES(LIBEXIF, libexif >= $LIBEXIF_REQUIRED_MIN libexif < $LIBEXIF_REQUIRED_MAX)
 347 PKG_CHECK_MODULES(LIBEXIF_API_CHECK, libexif >= $LIBEXIF_API_CHANGE, have_old_libexif=no, have_old_libexif=yes)
 348
 349 if test "x$have_old_libexif" = "xyes"; then
 350         EXIF_SOVERSION=9
 351 else
 352         PKG_CHECK_MODULES(LIBEXIF_VERSION_CHECK, libexif >= 0.6.12, EXIF_SOVERSION=12, EXIF_SOVERSION=10)
 353 fi
 354 AC_SUBST(EXIF_SOVERSION)
 355
 356 PKG_CHECK_MODULES(BEAGLED, gmime-sharp >= 2.1.15 gtk-sharp gconf-sharp)
 357 BEAGLED_LIBS="$BEAGLED_LIBS $EVO_SHARP_LIBS $GSF_SHARP_LIBS"
 358 AC_SUBST(BEAGLED_LIBS)
 359
 360 GSF_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gsf-sharp`
 361 GMIME_SHARP_PREFIX=`$PKG_CONFIG --variable=prefix gmime-sharp`
 362
 363 BEAGLE_DEFINES=""
 364 AC_SUBST(BEAGLE_DEFINES)
 365
 366 dnl ----------------------------------------------
 367 dnl libbeagle
 368
 369 GTK_DOC_CHECK(1.0)
 370
 371 AC_ARG_ENABLE([libbeagle],
 372         AC_HELP_STRING([--disable-libbeagle], [Disable libbeagle (C API)]),
 373         enable_libbeagle=$enableval,
 374         enable_libbeagle=auto)
 375
 376 dnl library versioning
 377 dnl Increase when changing the API
 378 LIBBEAGLE_CURRENT=0
 379
 380 dnl Update when changing implementation of current API,
 381 dnl reset to 0 when changing CURRENT.  This is the revision of
 382 dnl current API version
 383 LIBBEAGLE_REVISION=0
 384
 385 dnl Increase of API change is ABI compatible, otherwise reset to 0
 386 LIBBEAGLE_AGE=0
 387
 388 LIBBEAGLE_VERSION_INFO="$LIBBEAGLE_CURRENT:$LIBBEAGLE_REVISION:$LIBBEAGLE_AGE"
 389 AC_SUBST(LIBBEAGLE_VERSION_INFO)
 390
 391 PKG_CHECK_MODULES(LIBBEAGLE, [
 392         gobject-2.0 >= 2.6
 393         libxml-2.0 >= 2.6.19
 394 ], have_libbeagle_deps=yes, have_libbeagle_deps=no)
 395
 396 AC_SUBST(LIBBEAGLE_CFLAGS)
 397 AC_SUBST(LIBBEAGLE_LIBS)
 398
 399 if test "x$have_libbeagle_deps" = "xno"; then
 400
 401         if test "x$enable_libbeagle" = "xyes"; then
 402                 AC_MSG_ERROR([Missing libbeagle dependencies])
 403         fi
 404
 405         enable_libbeagle="no (missing dependencies)"
 406 else
 407         if test "x$enable_libbeagle" != "xno"; then
 408                 enable_libbeagle="yes"
 409         else
 410                 enable_libbeagle="no (disabled)"
 411         fi
 412 fi
 413
 414 AM_CONDITIONAL(ENABLE_LIBBEAGLE, test "x$enable_libbeagle" = "xyes")
 415
 416 dnl ----------------------------------------------
 417
 418 dnl Epiphany Extension
 419 dnl Much of this is cut&pasted from epiphany-extensions/configure.ac
 420
 421 AC_ARG_ENABLE([epiphany-extension],
 422         AC_HELP_STRING([--enable-epiphany-extension], [Enable Epiphany Extension (default auto)]),
 423         enable_epiphany_extension=$enableval,
 424         enable_epiphany_extension=auto)
 425
 426 if $PKG_CONFIG --exists epiphany-1.8; then
 427         EPIPHANY_MAJOR=1.8
 428         EPIPHANY_REQUIRED=1.7.0
 429 elif $PKG_CONFIG --exists epiphany-1.6; then
 430         EPIPHANY_MAJOR=1.6
 431         EPIPHANY_REQUIRED=1.6.0
 432 else
 433         enable_epiphany_extension="no (Epiphany not installed)"
 434 fi
 435
 436 if test "x$enable_epiphany_extension" = "xyes"; then
 437
 438 LIBXML_REQUIRED=2.6.0
 439 LIBGLIB_REQUIRED=2.4.0
 440 LIBGTK_REQUIRED=2.4.0
 441
 442 AC_SUBST(EPIPHANY_REQUIRED)
 443 AC_SUBST(LIBXML_REQUIRED)
 444 AC_SUBST(LIBGLIB_REQUIRED)
 445 AC_SUBST(LIBGTK_REQUIRED)
 446
 447 PKG_CHECK_MODULES(EPIPHANY_DEPENDENCY, \
 448                   libxml-2.0 >= $LIBXML_REQUIRED \
 449                   libglade-2.0 \
 450                   glib-2.0 >= $LIBGLIB_REQUIRED \
 451                   gmodule-2.0 \
 452                   gtk+-2.0 >= $LIBGTK_REQUIRED \
 453                   epiphany-$EPIPHANY_MAJOR >= $EPIPHANY_REQUIRED,
 454                   have_epiphany_dependencies=yes,
 455                   have_epiphany_dependencies=no)
 456 AC_SUBST(EPIPHANY_DEPENDENCY_CFLAGS)
 457 AC_SUBST(EPIPHANY_DEPENDENCY_LIBS)
 458
 459 EPIPHANY_EXTENSIONS_DIR="`$PKG_CONFIG --variable=extensionsdir epiphany-$EPIPHANY_MAJOR`"
 460 AC_SUBST([EPIPHANY_EXTENSIONS_DIR])
 461 EPIPHANY_PREFIX="`$PKG_CONFIG --variable=prefix epiphany-$EPIPHANY_MAJOR`"
 462 AC_SUBST(EPIPHANY_PREFIX)
 463
 464 if test "x$have_epiphany_dependencies" = "xno"; then
 465         enable_epiphany_extension="no (missing dependencies)"
 466 elif test "x$enable_epiphany_extension" != "xyes"; then
 467         enable_epiphany_extension="disabled"
 468 fi
 469
 470 fi
 471
 472 AM_CONDITIONAL(ENABLE_EPIPHANY_EXTENSION, test "x$enable_epiphany_extension" = "xyes")
 473
 474 AC_ARG_ENABLE([epiphany-extension-install],
 475         AS_HELP_STRING([--enable-epiphany-extension-install],[Install Epiphany Extension]),
 476         [install_epiphany_extension=$enableval],
 477         [install_epiphany_extension=yes])
 478
 479 AM_CONDITIONAL([INSTALL_EPIPHANY_EXTENSION], [test "x$install_epiphany_extension" = "xyes"])
 480
 481 dnl ----------------------------------------------
 482
 483 dnl Galago
 484
 485 PKG_CHECK_MODULES(GALAGO, galago-sharp, enable_galago=yes, enable_galago=no)
 486 AM_CONDITIONAL(ENABLE_GALAGO, test "x$enable_galago" = "xyes")
 487 AC_SUBST(GALAGO_LIBS)
 488
 489
 490 dnl ----------------------------------------------
 491
 492 GTK_BINARY_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 493 AC_SUBST(GTK_BINARY_VERSION)
 494
 495 dnl For the systeminfo glue
 496
 497 PKG_CHECK_MODULES(SYSTEMINFO_GLUE, gdk-2.0)
 498 AC_PATH_XTRA
 499 SYSTEMINFO_GLUE_X_LIBS="$X_PRE_LIBS $X_LIBS -lX11 -lXss $X_EXTRA_LIBS"
 500 AC_SUBST(SYSTEMINFO_GLUE_X_LIBS)
 501
 502 dnl ----------------------------------------------
 503
 504 dnl For the wv1 glue
 505
 506 PKG_CHECK_MODULES(WV1, wv-1.0, enable_wv1=yes, enable_wv1=no)
 507 AM_CONDITIONAL(ENABLE_WV1, test "x$enable_wv1" = "xyes")
 508 AC_SUBST(WV1_LIBS)
 509
 510 dnl ----------------------------------------------
 511
 512 dnl Searchomatic
 513
 514 PKG_CHECK_MODULES(SEARCHOMATIC, gtk+-2.0)
 515 AC_SUBST(SEARCHOMATIC_CFLAGS)
 516 AC_SUBST(SEARCHOMATIC_LIBS)
 517
 518 dnl ----------------------------------------------
 519
 520 dnl Chooser-fu
 521
 522 PKG_CHECK_MODULES(CHOOSER_FU, gtk+-2.0)
 523 AC_SUBST(CHOOSER_FU_CFLAGS)
 524 AC_SUBST(CHOOSER_FU_LIBS)
 525
 526 dnl ----------------------------------------------
 527
 528 dnl KDE launcher/icon support
 529
 530 kde_prefix_print="unknown; will guess at runtime"
 531 AC_PATH_PROG(KDE_CONFIG, [kde-config], [no])
 532 if test ! "x$KDE_CONFIG" = "xno"; then
 533         KDE_PREFIX=`$KDE_CONFIG --prefix`
 534         kde_prefix_print="$KDE_PREFIX"
 535 fi
 536 AC_SUBST(KDE_PREFIX)
 537
 538 AC_ARG_ENABLE([webservices],
 539         AC_HELP_STRING([--enable-webservices], [Enable WebServices (default disabled)]),
 540         enable_webservices=$enableval,
 541         enable_webservices=no)
 542
 543 AM_CONDITIONAL(ENABLE_WEBSERVICES, test "x$enable_webservices" = "xyes")
 544
 545 dnl ----------------------------------------------
 546 dnl Prefixes for helper scripts
 547 GAC_PREFIX="$EVO_SHARP_PREFIX:$GSF_SHARP_PREFIX:$GMIME_SHARP_PREFIX"
 548 dnl Remove duplicate prefixes
 549 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|:|\n|g' | sort | uniq | tr '\n' ':'`"
 550 dnl Remove stray :s
 551 GAC_PREFIX="`echo $GAC_PREFIX | sed -e 's|::\+|:|g' -e 's|^:\+||' -e 's|:\+$||'`"
 552 AC_SUBST(GAC_PREFIX)
 553
 554 GNOME_PREFIX="`$PKG_CONFIG --variable=prefix libgnome-2.0`"
 555 AC_SUBST(GNOME_PREFIX)
 556
 557 dnl ----------------------------------------------
 558
 559 dnl Check if the system has libchm, used by the CHMFilter
 560
 561 AC_CHECK_LIB(chm,chm_open,has_libchm=yes,has_libchm=no)
 562 AM_CONDITIONAL(HAS_LIBCHM, test "x$has_libchm" = "xyes")
 563
 564 dnl ----------------------------------------------
 565
 566 AC_OUTPUT([
 567 Makefile
 568 Util/Makefile
 569 Util/Util.dll.config
 570 images/Makefile
 571 templates/Makefile
 572 glue/Makefile
 573 BeagleClient/Makefile
 574 beagled/Makefile
 575 Filters/Makefile
 576 Tiles/Makefile
 577 tools/Makefile
 578 Best/Makefile
 579 ImLogViewer/Makefile
 580 libbeagle/Makefile
 581 libbeagle/libbeagle-0.0.pc
 582 libbeagle/beagle/Makefile
 583 libbeagle/examples/Makefile
 584 libbeagle/docs/Makefile
 585 libbeagle/docs/reference/Makefile
 586 epiphany-extension/Makefile
 587 mozilla-extension/Makefile
 588 searchomatic/Makefile
 589 bludgeon/Makefile
 590 beagle-0.0.pc
 591 beagle-daemon.pc
 592 beagle.spec
 593 po/Makefile.in
 594 ])
 595
 596 echo "
 597         Target OS:              ${os}
 598         Extended Attributes:    ${XATTR_LIB}
 599
 600         Prefix:                 ${prefix}
 601         GNOME Prefix:           ${GNOME_PREFIX}
 602         KDE Prefix:             ${kde_prefix_print}
 603
 604         Evolution-Sharp?        ${enable_evo_sharp}
 605         gsf-sharp?              ${enable_gsf_sharp}
 606         gst-sharp?              ${enable_gst_sharp}
 607         Epiphany Extension?     ${enable_epiphany_extension}
 608         Mozilla Extension?      yes
 609         wv1?                    ${enable_wv1}
 610         galago-sharp?           ${enable_galago}
 611         libchm?                 ${has_libchm}
 612
 613         Local SqliteClient?     ${use_local_sqlite}
 614
 615         Enable WebServices      ${enable_webservices}
 616         Enable libbeagle        ${enable_libbeagle}"
 617 echo
 618
 619 if test "x$enable_epiphany_extension" = "xyes"; then
 620    echo "NOTE: The Beagle Epiphany Extension Is Totally Insecure!"
 621    echo "      Use it at your own risk!"
 622    echo
 623 fi