src/link/stm32_flash_f4_split.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_f4_split.ld
   5 **
   6 **  Abstract    : Common linker script for STM32 devices.
   7 **
   8 *****************************************************************************
   9 */
  10
  11 /* Entry Point */
  12 ENTRY(Reset_Handler)
  13
  14 /* Highest address of the user mode stack */
  15 _Hot_Reboot_Flags_Size = 16;
  16 _estack = ORIGIN(STACKRAM) + LENGTH(STACKRAM) - _Hot_Reboot_Flags_Size;    /* end of RAM */
  17
  18 /* Base address where the config is stored. */
  19 __config_start = ORIGIN(FLASH_CONFIG);
  20 __config_end = ORIGIN(FLASH_CONFIG) + LENGTH(FLASH_CONFIG);
  21
  22 /* Generate a link error if heap and stack don't fit into RAM */
  23 _Min_Heap_Size = 0;      /* required amount of heap  */
  24 _Min_Stack_Size = 0x800; /* required amount of stack */
  25
  26 /* Define output sections */
  27 SECTIONS
  28 {
  29   /*
  30    * The ISR vector table is loaded at the beginning of the FLASH,
  31    * But it is linked (space reserved) at the beginning of the VECTAB region,
  32    * which is aliased either to FLASH or RAM.
  33    * When linked to RAM, the table can optionally be copied from FLASH to RAM
  34    * for table relocation.
  35    */
  36
  37   _isr_vector_table_flash_base = LOADADDR(.isr_vector);
  38   PROVIDE (isr_vector_table_flash_base = _isr_vector_table_flash_base);
  39
  40   .isr_vector :
  41   {
  42     . = ALIGN(4);
  43     PROVIDE (isr_vector_table_base = .);
  44     KEEP(*(.isr_vector)) /* Startup code */
  45     . = ALIGN(4);
  46     PROVIDE (isr_vector_table_end = .);
  47   } >VECTAB AT> FLASH
  48
  49   /* System memory (read-only bootloader) interrupt vector */
  50   .system_isr_vector (NOLOAD) :
  51   {
  52     . = ALIGN(4);
  53     PROVIDE (system_isr_vector_table_base = .);
  54     KEEP(*(.system_isr_vector)) /* Bootloader code */
  55     . = ALIGN(4);
  56   } >SYSTEM_MEMORY
  57
  58   /* The program code and other data goes into FLASH */
  59   .text :
  60   {
  61     . = ALIGN(4);
  62     *(.text)           /* .text sections (code) */
  63     *(.text*)          /* .text* sections (code) */
  64     *(.rodata)         /* .rodata sections (constants, strings, etc.) */
  65     *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
  66     *(.glue_7)         /* glue arm to thumb code */
  67     *(.glue_7t)        /* glue thumb to arm code */
  68     *(.eh_frame)
  69
  70     KEEP (*(.init))
  71     KEEP (*(.fini))
  72
  73     . = ALIGN(4);
  74     _etext = .;        /* define a global symbols at end of code */
  75   } >FLASH1
  76
  77
  78    .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  79     .ARM : {
  80     __exidx_start = .;
  81       *(.ARM.exidx*)
  82       __exidx_end = .;
  83     } >MOVABLE_FLASH
  84
  85   .preinit_array     :
  86   {
  87     PROVIDE_HIDDEN (__preinit_array_start = .);
  88     KEEP (*(.preinit_array*))
  89     PROVIDE_HIDDEN (__preinit_array_end = .);
  90   } >MOVABLE_FLASH
  91   .init_array :
  92   {
  93     PROVIDE_HIDDEN (__init_array_start = .);
  94     KEEP (*(SORT(.init_array.*)))
  95     KEEP (*(.init_array*))
  96     PROVIDE_HIDDEN (__init_array_end = .);
  97   } >MOVABLE_FLASH
  98   .fini_array :
  99   {
 100     PROVIDE_HIDDEN (__fini_array_start = .);
 101     KEEP (*(.fini_array*))
 102     KEEP (*(SORT(.fini_array.*)))
 103     PROVIDE_HIDDEN (__fini_array_end = .);
 104   } >MOVABLE_FLASH
 105   .pg_registry :
 106   {
 107     PROVIDE_HIDDEN (__pg_registry_start = .);
 108     KEEP (*(.pg_registry))
 109     KEEP (*(SORT(.pg_registry.*)))
 110     PROVIDE_HIDDEN (__pg_registry_end = .);
 111   } >MOVABLE_FLASH
 112   .pg_resetdata :
 113   {
 114     PROVIDE_HIDDEN (__pg_resetdata_start = .);
 115     KEEP (*(.pg_resetdata))
 116     PROVIDE_HIDDEN (__pg_resetdata_end = .);
 117   } >FLASH1
 118
 119   /* Storage for the address for the configuration section so we can grab it out of the hex file */
 120   .custom_defaults :
 121   {
 122     . = ALIGN(4);
 123     KEEP (*(.custom_defaults_start_address))
 124     . = ALIGN(4);
 125     KEEP (*(.custom_defaults_end_address))
 126     . = ALIGN(4);
 127     __custom_defaults_internal_start = .;
 128     KEEP (*(.custom_defaults))
 129     . = ALIGN(4);
 130   } >FLASH_CUSTOM_DEFAULTS
 131
 132     PROVIDE_HIDDEN (__custom_defaults_start = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? ORIGIN(FLASH_CUSTOM_DEFAULTS_EXTENDED) : __custom_defaults_internal_start);
 133     PROVIDE_HIDDEN (__custom_defaults_end = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? ORIGIN(FLASH_CUSTOM_DEFAULTS_EXTENDED) + LENGTH(FLASH_CUSTOM_DEFAULTS_EXTENDED) : ORIGIN(FLASH_CUSTOM_DEFAULTS) + LENGTH(FLASH_CUSTOM_DEFAULTS));
 134
 135   /* used by the startup to initialize data */
 136   _sidata = LOADADDR(.data);
 137
 138   /* Initialized data sections goes into RAM, load LMA copy after code */
 139   .data :
 140   {
 141     . = ALIGN(4);
 142     _sdata = .;        /* create a global symbol at data start */
 143     *(.data)           /* .data sections */
 144     *(.data*)          /* .data* sections */
 145
 146     . = ALIGN(4);
 147     _edata = .;        /* define a global symbol at data end */
 148   } >RAM AT> MOVABLE_FLASH
 149
 150   /* Uninitialized data section */
 151   . = ALIGN(4);
 152   .bss (NOLOAD) :
 153   {
 154     /* This is used by the startup in order to initialize the .bss secion */
 155     _sbss = .;         /* define a global symbol at bss start */
 156     __bss_start__ = _sbss;
 157     *(.bss)
 158     *(SORT_BY_ALIGNMENT(.bss*))
 159     *(COMMON)
 160
 161     . = ALIGN(4);
 162     _ebss = .;         /* define a global symbol at bss end */
 163     __bss_end__ = _ebss;
 164   } >RAM
 165
 166   /* used during startup to initialized fastram_data */
 167   _sfastram_idata = LOADADDR(.fastram_data);
 168
 169   /* Initialized FAST_DATA section for unsuspecting developers */
 170   .fastram_data :
 171   {
 172     . = ALIGN(4);
 173     _sfastram_data = .;        /* create a global symbol at data start */
 174     *(.fastram_data)           /* .data sections */
 175     *(.fastram_data*)          /* .data* sections */
 176
 177     . = ALIGN(4);
 178     _efastram_data = .;        /* define a global symbol at data end */
 179   } >FASTRAM AT> FLASH1
 180
 181   . = ALIGN(4);
 182   .fastram_bss (NOLOAD) :
 183   {
 184     __fastram_bss_start__ = .;
 185     *(.fastram_bss)
 186     *(SORT_BY_ALIGNMENT(.fastram_bss*))
 187     . = ALIGN(4);
 188     __fastram_bss_end__ = .;
 189   } >FASTRAM
 190
 191   .persistent_data (NOLOAD) :
 192   {
 193     __persistent_data_start__ = .;
 194     *(.persistent_data)
 195     . = ALIGN(4);
 196     __persistent_data_end__ = .;
 197   } >RAM
 198
 199   /* User_heap_stack section, used to check that there is enough RAM left */
 200   _heap_stack_end = ORIGIN(STACKRAM) + LENGTH(STACKRAM) - _Hot_Reboot_Flags_Size;
 201   _heap_stack_begin = _heap_stack_end - _Min_Stack_Size  - _Min_Heap_Size;
 202   . = _heap_stack_begin;
 203   ._user_heap_stack :
 204   {
 205     . = ALIGN(4);
 206     PROVIDE ( end = . );
 207     PROVIDE ( _end = . );
 208     . = . + _Min_Heap_Size;
 209     . = . + _Min_Stack_Size;
 210     . = ALIGN(4);
 211   } >STACKRAM = 0xa5
 212
 213   /* MEMORY_bank1 section, code must be located here explicitly            */
 214   /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
 215   .memory_b1_text :
 216   {
 217     *(.mb1text)        /* .mb1text sections (code) */
 218     *(.mb1text*)       /* .mb1text* sections (code)  */
 219     *(.mb1rodata)      /* read-only data (constants) */
 220     *(.mb1rodata*)
 221   } >MEMORY_B1
 222
 223   /* Remove information from the standard libraries */
 224   /DISCARD/ :
 225   {
 226     libc.a ( * )
 227     libm.a ( * )
 228     libgcc.a ( * )
 229   }
 230
 231   .ARM.attributes 0 : { *(.ARM.attributes) }
 232 }