src/link/stm32_flash_f405.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_f405.ld
   5 **
   6 **  Abstract    : Linker script for STM32F405RG Device with
   7 **                1024KByte FLASH, 128KByte RAM 64KByte CCM (RAM)
   8 **
   9 *****************************************************************************
  10 */
  11
  12 /*
  13 0x08000000 to 0x080FFFFF 1024K full flash,
  14 0x08000000 to 0x08003FFF   16K isr vector, startup code,
  15 0x08004000 to 0x08007FFF   16K config,                  // FLASH_Sector_1
  16 0x08008000 to 0x080FFFFF  992K firmware,
  17 */
  18
  19 /* Specify the memory areas */
  20 MEMORY
  21 {
  22     FLASH (rx)        : ORIGIN = 0x08000000, LENGTH = 10K
  23     FLASH_CUSTOM_DEFAULTS (r) : ORIGIN = 0x08002800, LENGTH = 6K
  24     FLASH_CONFIG (r)  : ORIGIN = 0x08004000, LENGTH = 16K
  25     FLASH1 (rx)       : ORIGIN = 0x08008000, LENGTH = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 976K : 992K
  26     FLASH_CUSTOM_DEFAULTS_EXTENDED (r): ORIGIN = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 0x080FC000 : 0x08100000, LENGTH = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 16K : 0K
  27
  28     SYSTEM_MEMORY (rx): ORIGIN = 0x1FFF0000, LENGTH = 29K
  29
  30     RAM (rwx)         : ORIGIN = 0x20000000, LENGTH = 128K
  31     CCM (rwx)         : ORIGIN = 0x10000000, LENGTH = 64K
  32     BACKUP_SRAM (rwx) : ORIGIN = 0x40024000, LENGTH = 4K
  33     MEMORY_B1 (rx)    : ORIGIN = 0x60000000, LENGTH = 0K
  34 }
  35
  36 REGION_ALIAS("STACKRAM", CCM)
  37 REGION_ALIAS("FASTRAM", CCM)
  38 REGION_ALIAS("VECTAB", RAM)
  39
  40 /* Put various bits and bobs of data into the main chunk of flash as we have enough of it */
  41
  42 REGION_ALIAS("MOVABLE_FLASH", FLASH1)
  43
  44 INCLUDE "stm32_flash_f4_split.ld"