src/link/stm32_flash_f411.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_f411.ld
   5 **
   6 **  Abstract    : Linker script for STM32F411 Device with
   7 **                512KByte FLASH, 128KByte RAM
   8 **
   9 *****************************************************************************
  10 */
  11
  12 /*
  13 0x08000000 to 0x0807FFFF  512K full flash,
  14 0x08000000 to 0x08003FFF   16K isr vector, startup code,
  15
  16 0x08004000 to 0x08007FFF   16K config,                  // FLASH_Sector_1
  17 0x08008000 to 0x0807FFFF  480K firmware,
  18 */
  19
  20 /* Specify the memory areas */
  21 MEMORY
  22 {
  23     FLASH (rx)        : ORIGIN = 0x08000000, LENGTH = 10K
  24     FLASH_CUSTOM_DEFAULTS (r) : ORIGIN = 0x08002800, LENGTH = 6K
  25     FLASH_CONFIG (r)  : ORIGIN = 0x08004000, LENGTH = 16K
  26     FLASH1 (rx)       : ORIGIN = 0x08008000, LENGTH = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 464K : 480K
  27     FLASH_CUSTOM_DEFAULTS_EXTENDED (r): ORIGIN = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 0x0807C000 : 0x08080000, LENGTH = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 16K : 0K
  28
  29     SYSTEM_MEMORY (rx): ORIGIN = 0x1FFF0000, LENGTH = 29K
  30
  31     RAM (rwx)         : ORIGIN = 0x20000000, LENGTH = 128K
  32     MEMORY_B1 (rx)    : ORIGIN = 0x60000000, LENGTH = 0K
  33 }
  34
  35 REGION_ALIAS("STACKRAM", RAM)
  36 REGION_ALIAS("FASTRAM", RAM)
  37 REGION_ALIAS("VECTAB", RAM)
  38
  39 /* Put various bits and bobs of data into the free space after the vector table in sector 0 to save flash space. */
  40
  41 REGION_ALIAS("MOVABLE_FLASH", FLASH)
  42
  43 INCLUDE "stm32_flash_f4_split.ld"