src/link/stm32_flash_f722.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_f722.ld
   5 **
   6 **  Abstract    : Linker script for STM32F722RETx Device with
   7 **                512KByte FLASH, 256KByte RAM
   8 **
   9 *****************************************************************************
  10 */
  11
  12 /*
  13 0x08000000 to 0x0807FFFF  512K full flash
  14 0x08000000 to 0x08003FFF   16K ISR vector
  15 0x08004000 to 0x08007FFF   16K config
  16 0x08008000 to 0x0807FFFF  480K firmware
  17 */
  18
  19 /* Specify the memory areas */
  20 MEMORY
  21 {
  22     ITCM_RAM (rx)           : ORIGIN = 0x00000000, LENGTH = 16K
  23
  24 /* Alternate access to the same flash storage as AXIM flash, but not writable by the boot loader. */
  25     ITCM_FLASH (rx)         : ORIGIN = 0x00200000, LENGTH = 16K
  26     ITCM_FLASH_CONFIG (r)   : ORIGIN = 0x00204000, LENGTH = 16K
  27     ITCM_FLASH1 (rx)        : ORIGIN = 0x00208000, LENGTH = 480K
  28
  29     AXIM_FLASH (rx)         : ORIGIN = 0x08000000, LENGTH = 10K
  30     AXIM_FLASH_CUSTOM_DEFAULTS (r) : ORIGIN = 0x08002800, LENGTH = 6K
  31     /* config occupies the entire flash sector 1 for the ease of erasure, 16K on F72x */
  32     AXIM_FLASH_CONFIG (r)   : ORIGIN = 0x08004000, LENGTH = 16K
  33     AXIM_FLASH1 (rx)        : ORIGIN = 0x08008000, LENGTH = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 464K : 480K
  34     AXIM_FLASH_CUSTOM_DEFAULTS_EXTENDED (r) : ORIGIN = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 0x0807C000 : 0x08080000, LENGTH = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? 16K : 0K
  35
  36     DTCM_RAM (rwx)          : ORIGIN = 0x20000000, LENGTH = 64K
  37     SRAM1 (rwx)             : ORIGIN = 0x20010000, LENGTH = 176K
  38     SRAM2 (rwx)             : ORIGIN = 0x2003C000, LENGTH = 16K
  39     MEMORY_B1 (rx)          : ORIGIN = 0x60000000, LENGTH = 0K
  40 }
  41
  42 REGION_ALIAS("FLASH", AXIM_FLASH)
  43 REGION_ALIAS("WRITABLE_FLASH", AXIM_FLASH)
  44 REGION_ALIAS("FLASH_CUSTOM_DEFAULTS", AXIM_FLASH_CUSTOM_DEFAULTS)
  45 REGION_ALIAS("FLASH_CONFIG", AXIM_FLASH_CONFIG)
  46 REGION_ALIAS("FLASH1", AXIM_FLASH1)
  47 REGION_ALIAS("WRITABLE_FLASH1", AXIM_FLASH1)
  48 REGION_ALIAS("FLASH_CUSTOM_DEFAULTS_EXTENDED", AXIM_FLASH_CUSTOM_DEFAULTS_EXTENDED)
  49
  50 REGION_ALIAS("STACKRAM", DTCM_RAM)
  51 REGION_ALIAS("FASTRAM", DTCM_RAM)
  52 REGION_ALIAS("RAM", SRAM1)
  53
  54 /* Put various bits and bobs of data into the free space after the vector table in sector 0 to save flash space. */
  55
  56 REGION_ALIAS("MOVABLE_FLASH", AXIM_FLASH)
  57
  58 INCLUDE "stm32_flash_f7_split.ld"