src/link/stm32_flash_f765.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_f765.ld
   5 **
   6 **  Abstract    : Linker script for STM32F765xITx Device with
   7 **                2048KByte FLASH, 512KByte RAM
   8 **
   9 *****************************************************************************
  10 */
  11
  12 /*
  13 0x00000000 to 0x00003FFF   16K TCM RAM,
  14
  15 0x08000000 to 0x081FFFFF 2048K full flash,
  16 0x08000000 to 0x08007FFF   32K isr vector, startup code,
  17 0x08008000 to 0x0800FFFF   32K config,
  18 0x08010000 to 0x081FFFFF  1984K firmware,
  19 */
  20
  21 /* Specify the memory areas */
  22 MEMORY
  23 {
  24     ITCM_RAM (rx)           : ORIGIN = 0x00000000, LENGTH = 16K
  25
  26 /* Alternate access to the same flash storage as AXIM flash, but not writable by the boot loader. */
  27     ITCM_FLASH (rx)         : ORIGIN = 0x00200000, LENGTH = 32K
  28     ITCM_FLASH_CONFIG (r)   : ORIGIN = 0x00208000, LENGTH = 32K
  29     ITCM_FLASH1 (rx)        : ORIGIN = 0x00210000, LENGTH = 1984K
  30
  31     AXIM_FLASH (rx)         : ORIGIN = 0x08000000, LENGTH = 10K
  32     AXIM_FLASH_CUSTOM_DEFAULTS (r) : ORIGIN = 0x08002800, LENGTH = 10K
  33     AXIM_FLASH_UNUSED (r)   : ORIGIN = 0x08005000, LENGTH = 12K
  34     AXIM_FLASH_CONFIG (r)   : ORIGIN = 0x08008000, LENGTH = 32K
  35     AXIM_FLASH1 (rx)        : ORIGIN = 0x08010000, LENGTH = 1984K
  36
  37     DTCM_RAM (rwx)          : ORIGIN = 0x20000000, LENGTH = 128K
  38     SRAM1 (rwx)             : ORIGIN = 0x20020000, LENGTH = 368K
  39     SRAM2 (rwx)             : ORIGIN = 0x2007C000, LENGTH = 16K
  40     MEMORY_B1 (rx)          : ORIGIN = 0x60000000, LENGTH = 0K
  41 }
  42
  43 REGION_ALIAS("FLASH", ITCM_FLASH)
  44 REGION_ALIAS("WRITABLE_FLASH", AXIM_FLASH)
  45 REGION_ALIAS("FLASH_CUSTOM_DEFAULTS", AXIM_FLASH_CUSTOM_DEFAULTS)
  46 REGION_ALIAS("FLASH_CONFIG", AXIM_FLASH_CONFIG)
  47 REGION_ALIAS("FLASH1", ITCM_FLASH1)
  48 REGION_ALIAS("WRITABLE_FLASH1", AXIM_FLASH1)
  49
  50 REGION_ALIAS("STACKRAM", DTCM_RAM)
  51 REGION_ALIAS("FASTRAM", DTCM_RAM)
  52 REGION_ALIAS("RAM", DTCM_RAM)
  53
  54 /* Put various bits and bobs of data into the main chunk of flash as we have enough of it */
  55
  56 REGION_ALIAS("MOVABLE_FLASH", AXIM_FLASH1)
  57
  58 INCLUDE "stm32_flash_f7_split.ld"