src/link/stm32_flash_f4_split.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_f4_split.ld
   5 **
   6 **  Abstract    : Common linker script for STM32 devices.
   7 **
   8 *****************************************************************************
   9 */
  10
  11 /* Entry Point */
  12 ENTRY(Reset_Handler)
  13
  14 /* Highest address of the user mode stack */
  15 _Hot_Reboot_Flags_Size = 16;
  16 _estack = ORIGIN(STACKRAM) + LENGTH(STACKRAM) - _Hot_Reboot_Flags_Size;    /* end of RAM */
  17
  18 /* Base address where the config is stored. */
  19 __config_start = ORIGIN(FLASH_CONFIG);
  20 __config_end = ORIGIN(FLASH_CONFIG) + LENGTH(FLASH_CONFIG);
  21
  22 /* Generate a link error if heap and stack don't fit into RAM */
  23 _Min_Heap_Size = 0;      /* required amount of heap  */
  24 _Min_Stack_Size = 0x800; /* required amount of stack */
  25
  26 /* Define output sections */
  27 SECTIONS
  28 {
  29   /*
  30    * The ISR vector table is loaded at the beginning of the FLASH,
  31    * But it is linked (space reserved) at the beginning of the VECTAB region,
  32    * which is aliased either to FLASH or RAM.
  33    * When linked to RAM, the table can optionally be copied from FLASH to RAM
  34    * for table relocation.
  35    */
  36
  37   _isr_vector_table_flash_base = LOADADDR(.isr_vector);
  38   PROVIDE (isr_vector_table_flash_base = _isr_vector_table_flash_base);
  39
  40   .isr_vector :
  41   {
  42     . = ALIGN(4);
  43     PROVIDE (isr_vector_table_base = .);
  44     KEEP(*(.isr_vector)) /* Startup code */
  45     . = ALIGN(4);
  46     PROVIDE (isr_vector_table_end = .);
  47   } >VECTAB AT> FLASH
  48
  49   /* System memory (read-only bootloader) interrupt vector */
  50   .system_isr_vector (NOLOAD) :
  51   {
  52     . = ALIGN(4);
  53     PROVIDE (system_isr_vector_table_base = .);
  54     KEEP(*(.system_isr_vector)) /* Bootloader code */
  55     . = ALIGN(4);
  56   } >SYSTEM_MEMORY
  57
  58   /* The program code and other data goes into FLASH */
  59   .text :
  60   {
  61     . = ALIGN(4);
  62     *(.text)           /* .text sections (code) */
  63     *(.text*)          /* .text* sections (code) */
  64     *(.rodata)         /* .rodata sections (constants, strings, etc.) */
  65     *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
  66     *(.glue_7)         /* glue arm to thumb code */
  67     *(.glue_7t)        /* glue thumb to arm code */
  68     *(.eh_frame)
  69
  70     KEEP (*(.init))
  71     KEEP (*(.fini))
  72
  73     . = ALIGN(4);
  74     _etext = .;        /* define a global symbols at end of code */
  75   } >FLASH1
  76
  77
  78    .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  79     .ARM : {
  80     __exidx_start = .;
  81       *(.ARM.exidx*)
  82       __exidx_end = .;
  83     } >MOVABLE_FLASH
  84
  85   .preinit_array     :
  86   {
  87     PROVIDE_HIDDEN (__preinit_array_start = .);
  88     KEEP (*(.preinit_array*))
  89     PROVIDE_HIDDEN (__preinit_array_end = .);
  90   } >MOVABLE_FLASH
  91   .init_array :
  92   {
  93     PROVIDE_HIDDEN (__init_array_start = .);
  94     KEEP (*(SORT(.init_array.*)))
  95     KEEP (*(.init_array*))
  96     PROVIDE_HIDDEN (__init_array_end = .);
  97   } >MOVABLE_FLASH
  98   .fini_array :
  99   {
 100     PROVIDE_HIDDEN (__fini_array_start = .);
 101     KEEP (*(.fini_array*))
 102     KEEP (*(SORT(.fini_array.*)))
 103     PROVIDE_HIDDEN (__fini_array_end = .);
 104   } >MOVABLE_FLASH
 105   .pg_registry :
 106   {
 107     PROVIDE_HIDDEN (__pg_registry_start = .);
 108     KEEP (*(.pg_registry))
 109     KEEP (*(SORT(.pg_registry.*)))
 110     PROVIDE_HIDDEN (__pg_registry_end = .);
 111   } >MOVABLE_FLASH
 112   .pg_resetdata :
 113   {
 114     PROVIDE_HIDDEN (__pg_resetdata_start = .);
 115     KEEP (*(.pg_resetdata))
 116     PROVIDE_HIDDEN (__pg_resetdata_end = .);
 117   } >FLASH1
 118
 119   /* used by the startup to initialize data */
 120   _sidata = LOADADDR(.data);
 121
 122   /* Initialized data sections goes into RAM, load LMA copy after code */
 123   .data :
 124   {
 125     . = ALIGN(4);
 126     _sdata = .;        /* create a global symbol at data start */
 127     *(.data)           /* .data sections */
 128     *(.data*)          /* .data* sections */
 129
 130     . = ALIGN(4);
 131     _edata = .;        /* define a global symbol at data end */
 132   } >RAM AT> MOVABLE_FLASH
 133
 134   /* Uninitialized data section */
 135   . = ALIGN(4);
 136   .bss (NOLOAD) :
 137   {
 138     /* This is used by the startup in order to initialize the .bss secion */
 139     _sbss = .;         /* define a global symbol at bss start */
 140     __bss_start__ = _sbss;
 141     *(.bss)
 142     *(SORT_BY_ALIGNMENT(.bss*))
 143     *(COMMON)
 144
 145     . = ALIGN(4);
 146     _ebss = .;         /* define a global symbol at bss end */
 147     __bss_end__ = _ebss;
 148   } >RAM
 149
 150   /* used during startup to initialized fastram_data */
 151   _sfastram_idata = LOADADDR(.fastram_data);
 152
 153   /* Initialized FAST_DATA section for unsuspecting developers */
 154   .fastram_data :
 155   {
 156     . = ALIGN(4);
 157     _sfastram_data = .;        /* create a global symbol at data start */
 158     *(.fastram_data)           /* .data sections */
 159     *(.fastram_data*)          /* .data* sections */
 160
 161     . = ALIGN(4);
 162     _efastram_data = .;        /* define a global symbol at data end */
 163   } >FASTRAM AT> FLASH1
 164
 165   . = ALIGN(4);
 166   .fastram_bss (NOLOAD) :
 167   {
 168     __fastram_bss_start__ = .;
 169     *(.fastram_bss)
 170     *(SORT_BY_ALIGNMENT(.fastram_bss*))
 171     . = ALIGN(4);
 172     __fastram_bss_end__ = .;
 173   } >FASTRAM
 174
 175   .persistent_data (NOLOAD) :
 176   {
 177     __persistent_data_start__ = .;
 178     *(.persistent_data)
 179     . = ALIGN(4);
 180     __persistent_data_end__ = .;
 181   } >RAM
 182
 183   /* User_heap_stack section, used to check that there is enough RAM left */
 184   _heap_stack_end = ORIGIN(STACKRAM) + LENGTH(STACKRAM) - _Hot_Reboot_Flags_Size;
 185   _heap_stack_begin = _heap_stack_end - _Min_Stack_Size  - _Min_Heap_Size;
 186   . = _heap_stack_begin;
 187   ._user_heap_stack :
 188   {
 189     . = ALIGN(4);
 190     PROVIDE ( end = . );
 191     PROVIDE ( _end = . );
 192     . = . + _Min_Heap_Size;
 193     . = . + _Min_Stack_Size;
 194     . = ALIGN(4);
 195   } >STACKRAM = 0xa5
 196
 197   /* MEMORY_bank1 section, code must be located here explicitly            */
 198   /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
 199   .memory_b1_text :
 200   {
 201     *(.mb1text)        /* .mb1text sections (code) */
 202     *(.mb1text*)       /* .mb1text* sections (code)  */
 203     *(.mb1rodata)      /* read-only data (constants) */
 204     *(.mb1rodata*)
 205   } >MEMORY_B1
 206
 207   /* Remove information from the standard libraries */
 208   /DISCARD/ :
 209   {
 210     libc.a ( * )
 211     libm.a ( * )
 212     libgcc.a ( * )
 213   }
 214
 215   .ARM.attributes 0 : { *(.ARM.attributes) }
 216 }