src/link/stm32_flash_g4_split.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_g4_split.ld
   5 **
   6 **  Abstract    : Common linker script for STM32 devices.
   7 **
   8 *****************************************************************************
   9 */
  10
  11 /* Entry Point */
  12 ENTRY(Reset_Handler)
  13
  14 /* Highest address of the user mode stack */
  15 _Hot_Reboot_Flags_Size = 16;
  16 _estack = ORIGIN(STACKRAM) + LENGTH(STACKRAM) - _Hot_Reboot_Flags_Size;    /* end of RAM */
  17
  18 /* Base address where the config is stored. */
  19 __config_start = ORIGIN(FLASH_CONFIG);
  20 __config_end = ORIGIN(FLASH_CONFIG) + LENGTH(FLASH_CONFIG);
  21
  22 /* Generate a link error if heap and stack don't fit into RAM */
  23 _Min_Heap_Size = 0;      /* required amount of heap  */
  24 _Min_Stack_Size = 0x800; /* required amount of stack */
  25
  26 /* Define output sections */
  27 SECTIONS
  28 {
  29   /*
  30    * The ISR vector table is loaded at the beginning of the FLASH,
  31    * But it is linked (space reserved) at the beginning of the VECTAB region,
  32    * which is aliased either to FLASH or RAM.
  33    * When linked to RAM, the table can optionally be copied from FLASH to RAM
  34    * for table relocation.
  35    */
  36
  37   _isr_vector_table_flash_base = LOADADDR(.isr_vector);
  38   PROVIDE (isr_vector_table_flash_base = _isr_vector_table_flash_base);
  39
  40   .isr_vector :
  41   {
  42     . = ALIGN(4);
  43     PROVIDE (isr_vector_table_base = .);
  44     KEEP(*(.isr_vector)) /* Startup code */
  45     . = ALIGN(4);
  46     PROVIDE (isr_vector_table_end = .);
  47   } >VECTAB AT> FLASH
  48
  49   /* System memory (read-only bootloader) interrupt vector */
  50   .system_isr_vector (NOLOAD) :
  51   {
  52     . = ALIGN(4);
  53     PROVIDE (system_isr_vector_table_base = .);
  54     KEEP(*(.system_isr_vector)) /* Bootloader code */
  55     . = ALIGN(4);
  56   } >SYSTEM_MEMORY
  57
  58   /* The program code and other data goes into FLASH */
  59   .text :
  60   {
  61     . = ALIGN(4);
  62     *(.text)           /* .text sections (code) */
  63     *(.text*)          /* .text* sections (code) */
  64     *(.rodata)         /* .rodata sections (constants, strings, etc.) */
  65     *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
  66     *(.glue_7)         /* glue arm to thumb code */
  67     *(.glue_7t)        /* glue thumb to arm code */
  68     *(.eh_frame)
  69
  70     KEEP (*(.init))
  71     KEEP (*(.fini))
  72
  73     . = ALIGN(4);
  74     _etext = .;        /* define a global symbols at end of code */
  75   } >FLASH1
  76
  77
  78    .ARM.extab   : {
  79        *(.ARM.extab* .gnu.linkonce.armextab.*)
  80    } >MOVABLE_FLASH
  81
  82     .ARM : {
  83     __exidx_start = .;
  84       *(.ARM.exidx*)
  85       __exidx_end = .;
  86     } >MOVABLE_FLASH
  87
  88   .preinit_array     :
  89   {
  90     PROVIDE_HIDDEN (__preinit_array_start = .);
  91     KEEP (*(.preinit_array*))
  92     PROVIDE_HIDDEN (__preinit_array_end = .);
  93   } >FLASH1
  94   .init_array :
  95   {
  96     PROVIDE_HIDDEN (__init_array_start = .);
  97     KEEP (*(SORT(.init_array.*)))
  98     KEEP (*(.init_array*))
  99     PROVIDE_HIDDEN (__init_array_end = .);
 100   } >FLASH1
 101   .fini_array :
 102   {
 103     PROVIDE_HIDDEN (__fini_array_start = .);
 104     KEEP (*(.fini_array*))
 105     KEEP (*(SORT(.fini_array.*)))
 106     PROVIDE_HIDDEN (__fini_array_end = .);
 107   } >FLASH1
 108   .pg_registry :
 109   {
 110     PROVIDE_HIDDEN (__pg_registry_start = .);
 111     KEEP (*(.pg_registry))
 112     KEEP (*(SORT(.pg_registry.*)))
 113     PROVIDE_HIDDEN (__pg_registry_end = .);
 114   } >FLASH1
 115   .pg_resetdata :
 116   {
 117     PROVIDE_HIDDEN (__pg_resetdata_start = .);
 118     KEEP (*(.pg_resetdata))
 119     PROVIDE_HIDDEN (__pg_resetdata_end = .);
 120   } >FLASH1
 121
 122   /* used by the startup to initialize data */
 123   _sidata = LOADADDR(.data);
 124
 125   /* Initialized data sections goes into RAM, load LMA copy after code */
 126   .data :
 127   {
 128     . = ALIGN(4);
 129     _sdata = .;        /* create a global symbol at data start */
 130     *(.data)           /* .data sections */
 131     *(.data*)          /* .data* sections */
 132
 133     . = ALIGN(4);
 134     _edata = .;        /* define a global symbol at data end */
 135   } >RAM AT> FLASH1
 136
 137   /* Uninitialized data section */
 138   . = ALIGN(4);
 139   .bss (NOLOAD) :
 140   {
 141     /* This is used by the startup in order to initialize the .bss secion */
 142     _sbss = .;         /* define a global symbol at bss start */
 143     __bss_start__ = _sbss;
 144     *(.bss)
 145     *(SORT_BY_ALIGNMENT(.bss*))
 146     *(COMMON)
 147
 148     . = ALIGN(4);
 149     _ebss = .;         /* define a global symbol at bss end */
 150     __bss_end__ = _ebss;
 151   } >RAM
 152
 153   /* used during startup to initialized fastram_data */
 154   _sfastram_idata = LOADADDR(.fastram_data);
 155
 156   /* Initialized FAST_RAM section for unsuspecting developers */
 157   .fastram_data :
 158   {
 159     . = ALIGN(4);
 160     _sfastram_data = .;        /* create a global symbol at data start */
 161     *(.fastram_data)           /* .data sections */
 162     *(.fastram_data*)          /* .data* sections */
 163
 164     . = ALIGN(4);
 165     _efastram_data = .;        /* define a global symbol at data end */
 166   } >FASTRAM AT> FLASH1
 167
 168   . = ALIGN(4);
 169   .fastram_bss (NOLOAD) :
 170   {
 171     _sfastram_bss = .;
 172     __fastram_bss_start__ = _sfastram_bss;
 173     *(.fastram_bss)
 174     *(SORT_BY_ALIGNMENT(.fastram_bss*))
 175     . = ALIGN(4);
 176     _efastram_bss = .;
 177     __fastram_bss_end__ = _efastram_bss;
 178   } >FASTRAM
 179
 180   .persistent_data (NOLOAD) :
 181   {
 182     __persistent_data_start__ = .;
 183     *(.persistent_data)
 184     . = ALIGN(4);
 185     __persistent_data_end__ = .;
 186   } >RAM
 187
 188   .DMA_RAM_R (NOLOAD) :
 189   {
 190     . = ALIGN(32);
 191     _sdma_ram_r = .;
 192     PROVIDE(dma_ram_r_start = .);
 193     _dma_ram_r_start__ = _sdma_ram_r;
 194     KEEP(*(.DMA_RAM_R))
 195     PROVIDE(dma_ram_r_end = .);
 196     _edma_ram_r = .;
 197     _dma_ram_r_end__ = _edma_ram_r;
 198   } >RAM
 199
 200   .DMA_RAM_W (NOLOAD) :
 201   {
 202     . = ALIGN(32);
 203     _sdma_ram_w = .;
 204     PROVIDE(dma_ram_w_start = .);
 205     _dma_ram_w_start__ = _sdma_ram_w;
 206     KEEP(*(.DMA_RAM_W))
 207     PROVIDE(dma_ram_w_end = .);
 208     _edma_ram_w = .;
 209     _dma_ram_w_end__ = _edma_ram_w;
 210   } >RAM
 211
 212   .DMA_RAM_RW (NOLOAD) :
 213   {
 214     . = ALIGN(32);
 215     _sdma_ram_rw = .;
 216     PROVIDE(dma_ram_rw_start = .);
 217     _dma_ram_rw_start__ = _sdma_ram_rw;
 218     KEEP(*(.DMA_RAM_RW))
 219     PROVIDE(dma_ram_rw_end = .);
 220     _edma_ram_rw = .;
 221     _dma_ram_rw_end__ = _edma_ram_rw;
 222   } >RAM
 223
 224   /* User_heap_stack section, used to check that there is enough RAM left */
 225   _heap_stack_end = ORIGIN(STACKRAM) + LENGTH(STACKRAM) - _Hot_Reboot_Flags_Size;
 226   _heap_stack_begin = _heap_stack_end - _Min_Stack_Size  - _Min_Heap_Size;
 227   . = _heap_stack_begin;
 228   ._user_heap_stack :
 229   {
 230     . = ALIGN(4);
 231     PROVIDE ( end = . );
 232     PROVIDE ( _end = . );
 233     . = . + _Min_Heap_Size;
 234     . = . + _Min_Stack_Size;
 235     . = ALIGN(4);
 236   } >STACKRAM = 0xa5
 237
 238   /* MEMORY_bank1 section, code must be located here explicitly            */
 239   /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
 240   .memory_b1_text :
 241   {
 242     *(.mb1text)        /* .mb1text sections (code) */
 243     *(.mb1text*)       /* .mb1text* sections (code)  */
 244     *(.mb1rodata)      /* read-only data (constants) */
 245     *(.mb1rodata*)
 246   } >MEMORY_B1
 247
 248   /* Remove information from the standard libraries */
 249   /DISCARD/ :
 250   {
 251     libc.a ( * )
 252     libm.a ( * )
 253     libgcc.a ( * )
 254   }
 255
 256   .ARM.attributes 0 : { *(.ARM.attributes) }
 257 }