src/link/stm32_flash_f4_split.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_f4_split.ld
   5 **
   6 **  Abstract    : Common linker script for STM32 devices.
   7 **
   8 *****************************************************************************
   9 */
  10
  11 /* Entry Point */
  12 ENTRY(Reset_Handler)
  13
  14 /* Highest address of the user mode stack */
  15 _Hot_Reboot_Flags_Size = 16;
  16 _estack = ORIGIN(STACKRAM) + LENGTH(STACKRAM) - _Hot_Reboot_Flags_Size;    /* end of RAM */
  17
  18 /* Base address where the config is stored. */
  19 __config_start = ORIGIN(FLASH_CONFIG);
  20 __config_end = ORIGIN(FLASH_CONFIG) + LENGTH(FLASH_CONFIG);
  21
  22 /* Generate a link error if heap and stack don't fit into RAM */
  23 _Min_Heap_Size = 0;      /* required amount of heap  */
  24 _Min_Stack_Size = 0x800; /* required amount of stack */
  25
  26 /* Define output sections */
  27 SECTIONS
  28 {
  29   /*
  30    * The ISR vector table is loaded at the beginning of the FLASH,
  31    * But it is linked (space reserved) at the beginning of the VECTAB region,
  32    * which is aliased either to FLASH or RAM.
  33    * When linked to RAM, the table can optionally be copied from FLASH to RAM
  34    * for table relocation.
  35    */
  36
  37   _isr_vector_table_flash_base = LOADADDR(.isr_vector);
  38   PROVIDE (isr_vector_table_flash_base = _isr_vector_table_flash_base);
  39
  40   .isr_vector :
  41   {
  42     . = ALIGN(4);
  43     PROVIDE (isr_vector_table_base = .);
  44     KEEP(*(.isr_vector)) /* Startup code */
  45     . = ALIGN(4);
  46     PROVIDE (isr_vector_table_end = .);
  47   } >VECTAB AT> FLASH
  48
  49   /* System memory (read-only bootloader) interrupt vector */
  50   .system_isr_vector (NOLOAD) :
  51   {
  52     . = ALIGN(4);
  53     PROVIDE (system_isr_vector_table_base = .);
  54     KEEP(*(.system_isr_vector)) /* Bootloader code */
  55     . = ALIGN(4);
  56   } >SYSTEM_MEMORY
  57
  58   /* The program code and other data goes into FLASH */
  59   .text :
  60   {
  61     . = ALIGN(4);
  62     *(.text)           /* .text sections (code) */
  63     *(.text*)          /* .text* sections (code) */
  64     *(.rodata)         /* .rodata sections (constants, strings, etc.) */
  65     *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
  66     *(.glue_7)         /* glue arm to thumb code */
  67     *(.glue_7t)        /* glue thumb to arm code */
  68     *(.eh_frame)
  69
  70     KEEP (*(.init))
  71     KEEP (*(.fini))
  72
  73     . = ALIGN(4);
  74     _etext = .;        /* define a global symbols at end of code */
  75   } >FLASH1
  76
  77
  78    .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  79     .ARM : {
  80     __exidx_start = .;
  81       *(.ARM.exidx*)
  82       __exidx_end = .;
  83     } >MOVABLE_FLASH
  84
  85   .preinit_array     :
  86   {
  87     PROVIDE_HIDDEN (__preinit_array_start = .);
  88     KEEP (*(.preinit_array*))
  89     PROVIDE_HIDDEN (__preinit_array_end = .);
  90   } >MOVABLE_FLASH
  91   .init_array :
  92   {
  93     PROVIDE_HIDDEN (__init_array_start = .);
  94     KEEP (*(SORT(.init_array.*)))
  95     KEEP (*(.init_array*))
  96     PROVIDE_HIDDEN (__init_array_end = .);
  97   } >MOVABLE_FLASH
  98   .fini_array :
  99   {
 100     PROVIDE_HIDDEN (__fini_array_start = .);
 101     KEEP (*(.fini_array*))
 102     KEEP (*(SORT(.fini_array.*)))
 103     PROVIDE_HIDDEN (__fini_array_end = .);
 104   } >MOVABLE_FLASH
 105   .pg_registry :
 106   {
 107     PROVIDE_HIDDEN (__pg_registry_start = .);
 108     KEEP (*(.pg_registry))
 109     KEEP (*(SORT(.pg_registry.*)))
 110     PROVIDE_HIDDEN (__pg_registry_end = .);
 111   } >MOVABLE_FLASH
 112   .pg_resetdata :
 113   {
 114     PROVIDE_HIDDEN (__pg_resetdata_start = .);
 115     KEEP (*(.pg_resetdata))
 116     PROVIDE_HIDDEN (__pg_resetdata_end = .);
 117   } >FLASH1
 118
 119   /* Storage for the address for the configuration section so we can grab it out of the hex file */
 120   .custom_defaults :
 121   {
 122     . = ALIGN(4);
 123     KEEP (*(.custom_defaults_start_address))
 124     . = ALIGN(4);
 125     KEEP (*(.custom_defaults_end_address))
 126     . = ALIGN(4);
 127     __custom_defaults_internal_start = .;
 128     *(.custom_defaults);
 129   } >FLASH_CUSTOM_DEFAULTS
 130
 131     PROVIDE_HIDDEN (__custom_defaults_start = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? ORIGIN(FLASH_CUSTOM_DEFAULTS_EXTENDED) : __custom_defaults_internal_start);
 132     PROVIDE_HIDDEN (__custom_defaults_end = DEFINED(USE_CUSTOM_DEFAULTS_EXTENDED) ? ORIGIN(FLASH_CUSTOM_DEFAULTS_EXTENDED) + LENGTH(FLASH_CUSTOM_DEFAULTS_EXTENDED) : ORIGIN(FLASH_CUSTOM_DEFAULTS) + LENGTH(FLASH_CUSTOM_DEFAULTS));
 133
 134   /* used by the startup to initialize data */
 135   _sidata = LOADADDR(.data);
 136
 137   /* Initialized data sections goes into RAM, load LMA copy after code */
 138   .data :
 139   {
 140     . = ALIGN(4);
 141     _sdata = .;        /* create a global symbol at data start */
 142     *(.data)           /* .data sections */
 143     *(.data*)          /* .data* sections */
 144
 145     . = ALIGN(4);
 146     _edata = .;        /* define a global symbol at data end */
 147   } >RAM AT> MOVABLE_FLASH
 148
 149   /* Uninitialized data section */
 150   . = ALIGN(4);
 151   .bss (NOLOAD) :
 152   {
 153     /* This is used by the startup in order to initialize the .bss secion */
 154     _sbss = .;         /* define a global symbol at bss start */
 155     __bss_start__ = _sbss;
 156     *(.bss)
 157     *(SORT_BY_ALIGNMENT(.bss*))
 158     *(COMMON)
 159
 160     . = ALIGN(4);
 161     _ebss = .;         /* define a global symbol at bss end */
 162     __bss_end__ = _ebss;
 163   } >RAM
 164
 165   /* used during startup to initialized fastram_data */
 166   _sfastram_idata = LOADADDR(.fastram_data);
 167
 168   /* Initialized FAST_DATA section for unsuspecting developers */
 169   .fastram_data :
 170   {
 171     . = ALIGN(4);
 172     _sfastram_data = .;        /* create a global symbol at data start */
 173     *(.fastram_data)           /* .data sections */
 174     *(.fastram_data*)          /* .data* sections */
 175
 176     . = ALIGN(4);
 177     _efastram_data = .;        /* define a global symbol at data end */
 178   } >FASTRAM AT> FLASH1
 179
 180   . = ALIGN(4);
 181   .fastram_bss (NOLOAD) :
 182   {
 183     __fastram_bss_start__ = .;
 184     *(.fastram_bss)
 185     *(SORT_BY_ALIGNMENT(.fastram_bss*))
 186     . = ALIGN(4);
 187     __fastram_bss_end__ = .;
 188   } >FASTRAM
 189
 190   .persistent_data (NOLOAD) :
 191   {
 192     __persistent_data_start__ = .;
 193     *(.persistent_data)
 194     . = ALIGN(4);
 195     __persistent_data_end__ = .;
 196   } >RAM
 197
 198   /* User_heap_stack section, used to check that there is enough RAM left */
 199   _heap_stack_end = ORIGIN(STACKRAM) + LENGTH(STACKRAM) - _Hot_Reboot_Flags_Size;
 200   _heap_stack_begin = _heap_stack_end - _Min_Stack_Size  - _Min_Heap_Size;
 201   . = _heap_stack_begin;
 202   ._user_heap_stack :
 203   {
 204     . = ALIGN(4);
 205     PROVIDE ( end = . );
 206     PROVIDE ( _end = . );
 207     . = . + _Min_Heap_Size;
 208     . = . + _Min_Stack_Size;
 209     . = ALIGN(4);
 210   } >STACKRAM = 0xa5
 211
 212   /* MEMORY_bank1 section, code must be located here explicitly            */
 213   /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
 214   .memory_b1_text :
 215   {
 216     *(.mb1text)        /* .mb1text sections (code) */
 217     *(.mb1text*)       /* .mb1text* sections (code)  */
 218     *(.mb1rodata)      /* read-only data (constants) */
 219     *(.mb1rodata*)
 220   } >MEMORY_B1
 221
 222   /* Remove information from the standard libraries */
 223   /DISCARD/ :
 224   {
 225     libc.a ( * )
 226     libm.a ( * )
 227     libgcc.a ( * )
 228   }
 229
 230   .ARM.attributes 0 : { *(.ARM.attributes) }
 231 }