configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include(config/gcc-plugin.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT
  36 AC_CONFIG_SRCDIR([move-if-change])
  37 AC_DISABLE_OPTION_CHECKING
  38
  39 progname=$0
  40 # if PWD already has a value, it is probably wrong.
  41 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  42
  43 # Export original configure arguments for use by sub-configures.
  44 # Quote arguments with shell meta charatcers.
  45 TOPLEVEL_CONFIGURE_ARGUMENTS=
  46 set -- "$progname" "$@"
  47 for ac_arg
  48 do
  49   case "$ac_arg" in
  50   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  51     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  52     # if the argument is of the form -foo=baz, quote the baz part only
  53     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  54   *) ;;
  55   esac
  56   # Add the quoted argument to the list.
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  58 done
  59 if test "$silent" = yes; then
  60   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  61 fi
  62 # Remove the initial space we just introduced and, as these will be
  63 # expanded by make, quote '$'.
  64 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  65 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  66
  67 # Find the build, host, and target systems.
  68 ACX_NONCANONICAL_BUILD
  69 ACX_NONCANONICAL_HOST
  70 ACX_NONCANONICAL_TARGET
  71
  72 dnl Autoconf 2.5x and later will set a default program prefix if
  73 dnl --target was used, even if it was the same as --host.  Disable
  74 dnl that behavior.  This must be done before AC_CANONICAL_TARGET
  75 dnl to take effect.
  76 test "$host_noncanonical" = "$target_noncanonical" &&
  77   test "$program_prefix$program_suffix$program_transform_name" = \
  78     NONENONEs,x,x, &&
  79   program_transform_name=s,y,y,
  80
  81 AC_CANONICAL_TARGET
  82 AC_ARG_PROGRAM
  83
  84 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  85 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  86
  87 # Get 'install' or 'install-sh' and its variants.
  88 AC_PROG_INSTALL
  89 ACX_PROG_LN
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_AWK
  93
  94 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  95
  96 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  97 # a relative path.
  98 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  99   INSTALL="${srcpwd}/install-sh -c"
 100 fi
 101
 102 # Set srcdir to "." if that's what it is.
 103 # This is important for multilib support.
 104 pwd=`${PWDCMD-pwd}`
 105 if test "${pwd}" = "${srcpwd}" ; then
 106   srcdir=.
 107 fi
 108
 109 topsrcdir=$srcpwd
 110
 111 extra_host_args=
 112
 113 ### To add a new directory to the tree, first choose whether it is a target
 114 ### or a host dependent tool.  Then put it into the appropriate list
 115 ### (library or tools, host or target), doing a dependency sort.
 116
 117 # Subdirs will be configured in the order listed in build_configdirs,
 118 # configdirs, or target_configdirs; see the serialization section below.
 119
 120 # Dependency sorting is only needed when *configuration* must be done in
 121 # a particular order.  In all cases a dependency should be specified in
 122 # the Makefile, whether or not it's implicitly specified here.
 123
 124 # Double entries in build_configdirs, configdirs, or target_configdirs may
 125 # cause circular dependencies and break everything horribly.
 126
 127 # these library is used by various programs built for the build
 128 # environment
 129 #
 130 build_libs="build-libiberty build-libcpp"
 131
 132 # these tools are built for the build environment
 133 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 134
 135 # these libraries are used by various programs built for the host environment
 136 #f
 137 host_libs="gettext libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe libgrust "
 138
 139 # these tools are built for the host environment
 140 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 141 # know that we are building the simulator.
 142 # binutils, gas and ld appear in that order because it makes sense to run
 143 # "make check" in that particular order.
 144 # If --enable-gold is used, "gold" may replace "ld".
 145 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gm2tools gotools c++tools"
 146
 147 # these libraries are built for the target environment, and are built after
 148 # the host libraries and the host tools (which may be a cross compiler)
 149 # Note that libiberty is not a target library.
 150 target_libraries="target-libgcc \
 151                 target-libbacktrace \
 152                 target-libgloss \
 153                 target-newlib \
 154                 target-libgomp \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgm2 \
 167                 target-libgo \
 168                 target-libgrust \
 169                 target-libphobos \
 170                 target-zlib"
 171
 172 # these tools are built using the target libraries, and are intended to
 173 # run only in the target environment
 174 #
 175 # note: any program that *uses* libraries that are in the "target_libraries"
 176 # list belongs in this list.
 177 #
 178 target_tools="target-rda"
 179
 180 ################################################################################
 181
 182 ## All tools belong in one of the four categories, and are assigned above
 183 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 184 ## is important because configure will choke if they ever get through.
 185 ## ${configdirs} is directories we build using the host tools.
 186 ## ${target_configdirs} is directories we build using the target tools.
 187 configdirs=`echo ${host_libs} ${host_tools}`
 188 target_configdirs=`echo ${target_libraries} ${target_tools}`
 189 build_configdirs=`echo ${build_libs} ${build_tools}`
 190
 191 m4_divert_text([PARSE_ARGS],
 192 [case $srcdir in
 193   *" "*)
 194 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 195     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 196 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 197     ;;
 198 esac
 199 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 200 ])
 201
 202 ################################################################################
 203
 204 srcname="gnu development package"
 205
 206 # This gets set non-empty for some net releases of packages.
 207 appdirs=""
 208
 209 # Define is_cross_compiler to save on calls to 'test'.
 210 is_cross_compiler=
 211 if test x"${host}" = x"${target}" ; then
 212   is_cross_compiler=no
 213 else
 214   is_cross_compiler=yes
 215 fi
 216
 217 # Find the build and target subdir names.
 218 GCC_TOPLEV_SUBDIRS
 219 # Be sure to cover against remnants of an in-tree build.
 220 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 221   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 222 Use a pristine source tree when building in a separate tree])
 223 fi
 224
 225 # Skipdirs are removed silently.
 226 skipdirs=
 227 # Noconfigdirs are removed loudly.
 228 noconfigdirs=""
 229
 230 use_gnu_ld=
 231 # Make sure we don't let GNU ld be added if we didn't want it.
 232 if test x$with_gnu_ld = xno ; then
 233   use_gnu_ld=no
 234   noconfigdirs="$noconfigdirs ld gold"
 235 fi
 236
 237 use_gnu_as=
 238 # Make sure we don't let GNU as be added if we didn't want it.
 239 if test x$with_gnu_as = xno ; then
 240   use_gnu_as=no
 241   noconfigdirs="$noconfigdirs gas"
 242 fi
 243
 244 use_included_zlib=
 245 AC_ARG_WITH(system-zlib,
 246 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 247 # Make sure we don't let ZLIB be added if we didn't want it.
 248 if test x$with_system_zlib = xyes ; then
 249   use_included_zlib=no
 250   noconfigdirs="$noconfigdirs zlib"
 251 fi
 252
 253 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 254 # is provided.
 255 if test x$with_system_readline = xyes ; then
 256   noconfigdirs="$noconfigdirs readline"
 257 fi
 258
 259 AC_ARG_WITH(zstd,
 260 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 261
 262 # some tools are so dependent upon X11 that if we're not building with X,
 263 # it's not even worth trying to configure, much less build, that tool.
 264
 265 case ${with_x} in
 266   yes | "") ;; # the default value for this tree is that X11 is available
 267   no)
 268     skipdirs="${skipdirs} tk itcl libgui"
 269     # We won't be able to build gdbtk without X.
 270     enable_gdbtk=no
 271     ;;
 272   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 273 esac
 274
 275 # Some are only suitable for cross toolchains.
 276 # Remove these if host=target.
 277 cross_only="target-libgloss target-newlib target-opcodes"
 278
 279 case $is_cross_compiler in
 280   no) skipdirs="${skipdirs} ${cross_only}" ;;
 281 esac
 282
 283 # If both --with-headers and --with-libs are specified, default to
 284 # --without-newlib.
 285 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 286    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 287   if test x"${with_newlib}" = x ; then
 288     with_newlib=no
 289   fi
 290 fi
 291
 292 # Recognize --with-newlib/--without-newlib.
 293 case ${with_newlib} in
 294   no) skipdirs="${skipdirs} target-newlib" ;;
 295   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 296 esac
 297
 298 AC_ARG_ENABLE(as-accelerator-for,
 299 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 300                 [build as offload target compiler.
 301                 Specify offload host triple by ARG])])
 302
 303 AC_ARG_ENABLE(offload-targets,
 304 [AS_HELP_STRING([--enable-offload-targets=LIST],
 305                 [enable offloading to devices from comma-separated LIST of
 306                 TARGET[=DIR]. Use optional path to find offload target compiler
 307                 during the build])],
 308 [
 309   if test x"$enable_offload_targets" = x; then
 310     AC_MSG_ERROR([no offload targets specified])
 311   fi
 312 ], [enable_offload_targets=])
 313
 314 AC_ARG_ENABLE(offload-defaulted,
 315 [AS_HELP_STRING([--enable-offload-defaulted]
 316                 [If enabled, configured but not installed offload compilers and
 317                 libgomp plugins are silently ignored.  Useful for distribution
 318                 compilers where those are in separate optional packages.])],
 319 [enable_offload_defaulted=$enableval],
 320 [enable_offload_defaulted=])
 321
 322 # Handle --enable-gold, --enable-ld.
 323 # --disable-gold [--enable-ld]
 324 #     Build only ld.  Default option.
 325 # --enable-gold [--enable-ld]
 326 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 327 #     as "ld.bfd" and "ld".
 328 # --enable-gold=default [--enable-ld]
 329 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 330 #     install ld as "ld.bfd".
 331 # --enable-gold[=default] --disable-ld
 332 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 333 # --enable-gold --enable-ld=default
 334 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 335 #     and ld.bfd).
 336 #     In other words, ld is default
 337 # --enable-gold=default --enable-ld=default
 338 #     Error.
 339
 340 default_ld=
 341 AC_ARG_ENABLE(gold,
 342 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 343                 [build gold @<:@ARG={default,yes,no}@:>@])],
 344 ENABLE_GOLD=$enableval,
 345 ENABLE_GOLD=no)
 346 case "${ENABLE_GOLD}" in
 347   yes|default)
 348     # Check for ELF target.
 349     is_elf=no
 350     case "${target}" in
 351       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 352       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 353       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 354       | *-*-solaris2* | *-*-nto* | *-*-nacl* | *-*-haiku*)
 355         case "${target}" in
 356           *-*-linux*aout* | *-*-linux*oldld*)
 357             ;;
 358           *)
 359             is_elf=yes
 360             ;;
 361         esac
 362     esac
 363
 364     if test "$is_elf" = "yes"; then
 365       # Check for target supported by gold.
 366       case "${target}" in
 367         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 368         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 369           configdirs="$configdirs gold"
 370           if test x${ENABLE_GOLD} = xdefault; then
 371             default_ld=gold
 372           fi
 373           ENABLE_GOLD=yes
 374           ;;
 375       esac
 376     fi
 377     ;;
 378   no)
 379     ;;
 380   *)
 381     AC_MSG_ERROR([invalid --enable-gold argument])
 382     ;;
 383 esac
 384
 385 AC_ARG_ENABLE(ld,
 386 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 387                 [build ld @<:@ARG={default,yes,no}@:>@])],
 388 ENABLE_LD=$enableval,
 389 ENABLE_LD=yes)
 390
 391 case "${ENABLE_LD}" in
 392   default)
 393     if test x${default_ld} != x; then
 394       AC_MSG_ERROR([either gold or ld can be the default ld])
 395     fi
 396     ;;
 397   yes)
 398     ;;
 399   no)
 400     if test x${ENABLE_GOLD} != xyes; then
 401       AC_MSG_WARN([neither ld nor gold are enabled])
 402     fi
 403     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 404     ;;
 405   *)
 406     AC_MSG_ERROR([invalid --enable-ld argument])
 407     ;;
 408 esac
 409
 410 AC_ARG_ENABLE(gprofng,
 411 [AS_HELP_STRING([[--disable-gprofng]], [do not build gprofng])],
 412 enable_gprofng=$enableval,
 413 enable_gprofng=yes)
 414 if test "$enable_gprofng" = "yes"; then
 415   case "${target}" in
 416     *-musl*)
 417       ;;
 418     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux* | riscv64-*-linux*)
 419     configdirs="$configdirs gprofng"
 420     ;;
 421   esac
 422 fi
 423
 424
 425 # PR gas/19109
 426 # Decide the default method for compressing debug sections.
 427 # Provide a configure time option to override our default.
 428 AC_ARG_ENABLE(compressed_debug_sections,
 429 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 430                 [Enable compressed debug sections for gas, gold or ld by
 431                  default])],
 432 [
 433   if test x"$enable_compressed_debug_sections" = xyes; then
 434     AC_MSG_ERROR([no program with compressed debug sections specified])
 435   fi
 436 ], [enable_compressed_debug_sections=])
 437
 438 # Select default compression algorithm.
 439 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 440 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 441                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 442 [], [default_compressed_debug_sections_algorithm=])
 443
 444 # Configure extra directories which are host specific
 445
 446 case "${host}" in
 447   *-cygwin*)
 448     configdirs="$configdirs libtermcap" ;;
 449 esac
 450
 451 # A target can indicate whether a language isn't supported for some reason.
 452 # Only spaces may be used in this macro; not newlines or tabs.
 453 unsupported_languages=
 454
 455 # Remove more programs from consideration, based on the host or
 456 # target this usually means that a port of the program doesn't
 457 # exist yet.
 458
 459 case "${host}" in
 460   i[[3456789]]86-*-msdosdjgpp*)
 461     noconfigdirs="$noconfigdirs tcl tk itcl"
 462     ;;
 463 esac
 464
 465 # Default to --disable-year2038 until we can handle differences between
 466 # projects that use gnulib (which understands year 2038) and projects that
 467 # do not (like BFD).
 468 AC_ARG_ENABLE(year2038,
 469 AS_HELP_STRING([--enable-year2038],
 470   [enable support for timestamps past the year 2038]),
 471 ENABLE_YEAR2038=$enableval,
 472 ENABLE_YEAR2038=no)
 473 enable_year2038=
 474 if test "${ENABLE_YEAR2038}" = "no" ; then
 475   enable_year2038=no
 476 fi
 477
 478 AC_ARG_ENABLE(libquadmath,
 479 AS_HELP_STRING([--disable-libquadmath],
 480   [do not build libquadmath directory]),
 481 ENABLE_LIBQUADMATH=$enableval,
 482 ENABLE_LIBQUADMATH=yes)
 483 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 484   noconfigdirs="$noconfigdirs target-libquadmath"
 485 fi
 486
 487
 488 AC_ARG_ENABLE(libquadmath-support,
 489 AS_HELP_STRING([--disable-libquadmath-support],
 490   [disable libquadmath support for Fortran]),
 491 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 492 ENABLE_LIBQUADMATH_SUPPORT=yes)
 493 enable_libquadmath_support=
 494 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 495   enable_libquadmath_support=no
 496 fi
 497
 498
 499 AC_ARG_ENABLE(libada,
 500 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 501 ENABLE_LIBADA=$enableval,
 502 ENABLE_LIBADA=yes)
 503 if test "${ENABLE_LIBADA}" != "yes" ; then
 504   noconfigdirs="$noconfigdirs gnattools"
 505 fi
 506
 507 AC_ARG_ENABLE(libgm2,
 508 [AS_HELP_STRING([--enable-libgm2], [build libgm2 directory])],
 509 ENABLE_LIBGM2=$enableval,
 510 ENABLE_LIBGM2=no)
 511 if test "${ENABLE_LIBGM2}" != "yes" ; then
 512   noconfigdirs="$noconfigdirs gm2tools"
 513 fi
 514
 515 AC_ARG_ENABLE(libssp,
 516 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 517 ENABLE_LIBSSP=$enableval,
 518 ENABLE_LIBSSP=yes)
 519
 520 AC_ARG_ENABLE(libstdcxx,
 521 AS_HELP_STRING([--disable-libstdcxx],
 522   [do not build libstdc++-v3 directory]),
 523 ENABLE_LIBSTDCXX=$enableval,
 524 ENABLE_LIBSTDCXX=default)
 525 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 526   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 527 fi]
 528
 529 # Enable libgomp by default on hosted POSIX systems, and a few others.
 530 if test x$enable_libgomp = x ; then
 531     case "${target}" in
 532     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 533         ;;
 534     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 535         ;;
 536     *-*-solaris2* | *-*-hpux11*)
 537         ;;
 538     *-*-darwin* | *-*-aix*)
 539         ;;
 540     nvptx*-*-* | amdgcn*-*-*)
 541         ;;
 542     *)
 543         noconfigdirs="$noconfigdirs target-libgomp"
 544         ;;
 545     esac
 546 fi
 547
 548 # Disable libatomic on unsupported systems.
 549 if test -d ${srcdir}/libatomic; then
 550     if test x$enable_libatomic = x; then
 551         AC_MSG_CHECKING([for libatomic support])
 552         if (srcdir=${srcdir}/libatomic; \
 553                 . ${srcdir}/configure.tgt; \
 554                 test -n "$UNSUPPORTED")
 555         then
 556             AC_MSG_RESULT([no])
 557             noconfigdirs="$noconfigdirs target-libatomic"
 558         else
 559             AC_MSG_RESULT([yes])
 560         fi
 561     fi
 562 fi
 563
 564 # Disable libitm on unsupported systems.
 565 if test -d ${srcdir}/libitm; then
 566     if test x$enable_libitm = x; then
 567         AC_MSG_CHECKING([for libitm support])
 568         if (srcdir=${srcdir}/libitm; \
 569                 . ${srcdir}/configure.tgt; \
 570                 test -n "$UNSUPPORTED")
 571         then
 572             AC_MSG_RESULT([no])
 573             noconfigdirs="$noconfigdirs target-libitm"
 574         else
 575             AC_MSG_RESULT([yes])
 576         fi
 577     fi
 578 fi
 579
 580 # Disable libsanitizer on unsupported systems.
 581 if test -d ${srcdir}/libsanitizer; then
 582     if test x$enable_libsanitizer = x; then
 583         AC_MSG_CHECKING([for libsanitizer support])
 584         if (srcdir=${srcdir}/libsanitizer; \
 585                 . ${srcdir}/configure.tgt; \
 586                 test -n "$UNSUPPORTED")
 587         then
 588             AC_MSG_RESULT([no])
 589             noconfigdirs="$noconfigdirs target-libsanitizer"
 590         else
 591             AC_MSG_RESULT([yes])
 592         fi
 593     fi
 594 fi
 595
 596 # Disable libvtv on unsupported systems.
 597 if test -d ${srcdir}/libvtv; then
 598     if test x$enable_libvtv = x; then
 599         AC_MSG_CHECKING([for libvtv support])
 600         if (srcdir=${srcdir}/libvtv; \
 601                 . ${srcdir}/configure.tgt; \
 602                 test "$VTV_SUPPORTED" != "yes")
 603         then
 604             AC_MSG_RESULT([no])
 605             noconfigdirs="$noconfigdirs target-libvtv"
 606         else
 607             AC_MSG_RESULT([yes])
 608         fi
 609     fi
 610 fi
 611
 612 # Disable libquadmath for some systems.
 613 case "${target}" in
 614   avr-*-*)
 615     noconfigdirs="$noconfigdirs target-libquadmath"
 616     ;;
 617   # libquadmath is unused on AIX and libquadmath build process use of
 618   # LD_LIBRARY_PATH can break AIX bootstrap.
 619   powerpc-*-aix* | rs6000-*-aix*)
 620     noconfigdirs="$noconfigdirs target-libquadmath"
 621     ;;
 622 esac
 623
 624 # Disable libssp for some systems.
 625 case "${target}" in
 626   avr-*-*)
 627     # No hosted I/O support.
 628     noconfigdirs="$noconfigdirs target-libssp"
 629     ;;
 630   bpf-*-*)
 631     noconfigdirs="$noconfigdirs target-libssp"
 632     ;;
 633   powerpc-*-aix* | rs6000-*-aix*)
 634     noconfigdirs="$noconfigdirs target-libssp"
 635     ;;
 636   pru-*-*)
 637     # No hosted I/O support.
 638     noconfigdirs="$noconfigdirs target-libssp"
 639     ;;
 640   rl78-*-*)
 641     # libssp uses a misaligned load to trigger a fault, but the RL78
 642     # doesn't fault for those - instead, it gives a build-time error
 643     # for explicit misaligned loads.
 644     noconfigdirs="$noconfigdirs target-libssp"
 645     ;;
 646   visium-*-*)
 647     # No hosted I/O support.
 648     noconfigdirs="$noconfigdirs target-libssp"
 649     ;;
 650 esac
 651
 652 # Disable libstdc++-v3 for some systems.
 653 # Allow user to override this if they pass --enable-libstdcxx
 654 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 655   case "${target}" in
 656     *-*-vxworks*)
 657       # VxWorks uses the Dinkumware C++ library.
 658       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 659       ;;
 660     amdgcn*-*-*)
 661       # Not ported/fails to build when using newlib.
 662       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 663       ;;
 664     arm*-wince-pe*)
 665       # the C++ libraries don't build on top of CE's C libraries
 666       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 667       ;;
 668     avr-*-*)
 669       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 670       ;;
 671     bpf-*-*)
 672       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 673       ;;
 674     ft32-*-*)
 675       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 676       ;;
 677   esac
 678 fi
 679
 680 # Disable C++ on systems where it is known to not work.
 681 # For testing, you can override this with --enable-languages=c++.
 682 case ,${enable_languages}, in
 683   *,c++,*)
 684     ;;
 685   *)
 686       case "${target}" in
 687         bpf-*-*)
 688           unsupported_languages="$unsupported_languages c++"
 689           ;;
 690       esac
 691       ;;
 692 esac
 693
 694 # Disable Objc on systems where it is known to not work.
 695 # For testing, you can override this with --enable-languages=objc.
 696 case ,${enable_languages}, in
 697   *,objc,*)
 698     ;;
 699   *)
 700       case "${target}" in
 701         bpf-*-*)
 702           unsupported_languages="$unsupported_languages objc"
 703           ;;
 704       esac
 705       ;;
 706 esac
 707
 708 # Disable D on systems where it is known to not work.
 709 # For testing, you can override this with --enable-languages=d.
 710 case ,${enable_languages}, in
 711   *,d,*)
 712     ;;
 713   *)
 714     case "${target}" in
 715       bpf-*-*)
 716         unsupported_languages="$unsupported_languages d"
 717         ;;
 718     esac
 719     ;;
 720 esac
 721
 722 # Disable libphobos on unsupported systems.
 723 # For testing, you can override this with --enable-libphobos.
 724 if test -d ${srcdir}/libphobos; then
 725     if test x$enable_libphobos = x; then
 726         AC_MSG_CHECKING([for libphobos support])
 727         if (srcdir=${srcdir}/libphobos; \
 728                 . ${srcdir}/configure.tgt; \
 729                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 730         then
 731             AC_MSG_RESULT([no])
 732             noconfigdirs="$noconfigdirs target-libphobos"
 733         else
 734             AC_MSG_RESULT([yes])
 735         fi
 736     fi
 737 fi
 738
 739 # Disable Fortran for some systems.
 740 case "${target}" in
 741   mmix-*-*)
 742     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 743     unsupported_languages="$unsupported_languages fortran"
 744     ;;
 745   bpf-*-*)
 746     unsupported_languages="$unsupported_languages fortran"
 747     ;;
 748 esac
 749
 750 # Disable libffi for some systems.
 751 case "${target}" in
 752   powerpc-*-darwin*)
 753     ;;
 754   i[[3456789]]86-*-darwin*)
 755     ;;
 756   x86_64-*-darwin[[912]]*)
 757     ;;
 758   *-*-darwin*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   *-*-netware*)
 762     noconfigdirs="$noconfigdirs target-libffi"
 763     ;;
 764   *-*-phoenix*)
 765     noconfigdirs="$noconfigdirs target-libffi"
 766     ;;
 767   *-*-rtems*)
 768     noconfigdirs="$noconfigdirs target-libffi"
 769     ;;
 770   *-*-tpf*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   *-*-uclinux*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   *-*-vxworks*)
 777     noconfigdirs="$noconfigdirs target-libffi"
 778     ;;
 779   aarch64*-*-freebsd*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   alpha*-*-*vms*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785   arm*-*-freebsd*)
 786     noconfigdirs="$noconfigdirs target-libffi"
 787     ;;
 788   arm-wince-pe)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   arm*-*-symbianelf*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794   bpf-*-*)
 795     noconfigdirs="$noconfigdirs target-libffi"
 796     ;;
 797   cris-*-* | crisv32-*-*)
 798     case "${target}" in
 799       *-*-linux*)
 800         ;;
 801       *) # See PR46792 regarding target-libffi.
 802         noconfigdirs="$noconfigdirs target-libffi";;
 803     esac
 804     ;;
 805   hppa*64*-*-hpux*)
 806     noconfigdirs="$noconfigdirs target-libffi"
 807     ;;
 808   hppa*-hp-hpux11*)
 809     ;;
 810   hppa*-*-hpux*)
 811     noconfigdirs="$noconfigdirs target-libffi"
 812     ;;
 813   ia64*-*-*vms*)
 814     noconfigdirs="$noconfigdirs target-libffi"
 815     ;;
 816   i[[3456789]]86-w64-mingw*)
 817     noconfigdirs="$noconfigdirs target-libffi"
 818     ;;
 819   i[[3456789]]86-*-mingw*)
 820     noconfigdirs="$noconfigdirs target-libffi"
 821     ;;
 822   x86_64-*-mingw*)
 823     noconfigdirs="$noconfigdirs target-libffi"
 824     ;;
 825   mmix-*-*)
 826     noconfigdirs="$noconfigdirs target-libffi"
 827     ;;
 828   powerpc-*-aix*)
 829     ;;
 830   rs6000-*-aix*)
 831     ;;
 832   ft32-*-*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835   *-*-lynxos*)
 836     noconfigdirs="$noconfigdirs target-libffi"
 837     ;;
 838 esac
 839
 840 # Disable the go frontend on systems where it is known to not work. Please keep
 841 # this in sync with contrib/config-list.mk.
 842 case "${target}" in
 843 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 844     unsupported_languages="$unsupported_languages go"
 845     ;;
 846 esac
 847
 848 # Only allow gdbserver on some systems.
 849 if test -d ${srcdir}/gdbserver; then
 850     if test x$enable_gdbserver = x; then
 851         AC_MSG_CHECKING([for gdbserver support])
 852         if (srcdir=${srcdir}/gdbserver; \
 853                 . ${srcdir}/configure.srv; \
 854                 test -n "$UNSUPPORTED")
 855         then
 856             AC_MSG_RESULT([no])
 857             noconfigdirs="$noconfigdirs gdbserver"
 858         else
 859             AC_MSG_RESULT([yes])
 860         fi
 861     fi
 862 fi
 863
 864 # Disable libgo for some systems where it is known to not work.
 865 # For testing, you can easily override this with --enable-libgo.
 866 if test x$enable_libgo = x; then
 867     case "${target}" in
 868     *-*-darwin*)
 869         # PR 46986
 870         noconfigdirs="$noconfigdirs target-libgo"
 871         ;;
 872     *-*-cygwin* | *-*-mingw*)
 873         noconfigdirs="$noconfigdirs target-libgo"
 874         ;;
 875     bpf-*-*)
 876         noconfigdirs="$noconfigdirs target-libgo"
 877         ;;
 878     esac
 879 fi
 880
 881 # Default libgloss CPU subdirectory.
 882 libgloss_dir="$target_cpu"
 883
 884 case "${target}" in
 885   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 886     libgloss_dir=wince
 887     ;;
 888   aarch64*-*-* )
 889     libgloss_dir=aarch64
 890     ;;
 891   arm*-*-*)
 892     libgloss_dir=arm
 893     ;;
 894   cris-*-* | crisv32-*-*)
 895     libgloss_dir=cris
 896     ;;
 897   kvx-*-elf)
 898     libgloss_dir=kvx-elf
 899     ;;
 900   kvx-*-mbr)
 901     libgloss_dir=kvx-mbr
 902     ;;
 903   kvx-*-cos)
 904     libgloss_dir=kvx-cos
 905     ;;
 906   hppa*-*-*)
 907     libgloss_dir=pa
 908     ;;
 909   i[[3456789]]86-*-*)
 910     libgloss_dir=i386
 911     ;;
 912   loongarch*-*-*)
 913     libgloss_dir=loongarch
 914     ;;
 915   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 916     libgloss_dir=m68hc11
 917     ;;
 918   m68*-*-* | fido-*-*)
 919     libgloss_dir=m68k
 920     ;;
 921   mips*-*-*)
 922     libgloss_dir=mips
 923     ;;
 924   powerpc*-*-*)
 925     libgloss_dir=rs6000
 926     ;;
 927   pru-*-*)
 928     libgloss_dir=pru
 929     ;;
 930   sparc*-*-*)
 931     libgloss_dir=sparc
 932     ;;
 933 esac
 934
 935 # Disable newlib and libgloss for various target OSes.
 936 case "${target}" in
 937   alpha*-dec-osf*)
 938     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 939     ;;
 940   i[[3456789]]86-*-linux*)
 941     # This section makes it possible to build newlib natively on linux.
 942     # If we are using a cross compiler then don't configure newlib.
 943     if test x${is_cross_compiler} != xno ; then
 944       noconfigdirs="$noconfigdirs target-newlib"
 945     fi
 946     noconfigdirs="$noconfigdirs target-libgloss"
 947     # If we are not using a cross compiler, do configure newlib.
 948     # Note however, that newlib will only be configured in this situation
 949     # if the --with-newlib option has been given, because otherwise
 950     # 'target-newlib' will appear in skipdirs.
 951     ;;
 952   i[[3456789]]86-*-rdos*)
 953     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 954     ;;
 955   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 956     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 957     ;;
 958   sparc-*-sunos4*)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   bpf-*-*)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 963     ;;
 964   *-*-aix*)
 965     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 966     ;;
 967   *-*-beos*)
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   *-*-chorusos)
 971     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 972     ;;
 973   *-*-dragonfly*)
 974     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 975     ;;
 976   *-*-freebsd*)
 977     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 978     ;;
 979   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982   *-*-lynxos*)
 983     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 984     ;;
 985   *-*-mingw*)
 986     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 987     ;;
 988   *-*-netbsd*)
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   *-*-netware*)
 992     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 993     ;;
 994   *-*-tpf*)
 995     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 996     ;;
 997   *-*-uclinux*)
 998     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 999     ;;
1000   *-*-vxworks*)
1001     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1002     ;;
1003 esac
1004
1005 # The ARM simulator has been deprecated for all ARM targets.
1006 case "${target}" in
1007   arm*-*-*)
1008     noconfigdirs="$noconfigdirs sim"
1009     ;;
1010 esac
1011
1012 case "${target}" in
1013   *-*-chorusos)
1014     ;;
1015   aarch64-*-darwin*)
1016     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1017     noconfigdirs="$noconfigdirs sim target-rda"
1018     ;;
1019   amdgcn*-*-*)
1020     ;;
1021   arm-*-darwin*)
1022     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1023     noconfigdirs="$noconfigdirs target-rda"
1024     ;;
1025   powerpc-*-darwin*)
1026     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1027     noconfigdirs="$noconfigdirs sim target-rda"
1028     ;;
1029   i[[3456789]]86-*-darwin*)
1030     noconfigdirs="$noconfigdirs ld gprof"
1031     noconfigdirs="$noconfigdirs sim target-rda"
1032     ;;
1033   x86_64-*-darwin[[912]]*)
1034     noconfigdirs="$noconfigdirs ld gas gprof"
1035     noconfigdirs="$noconfigdirs sim target-rda"
1036     ;;
1037   *-*-darwin*)
1038     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1039     noconfigdirs="$noconfigdirs sim target-rda"
1040     ;;
1041   *-*-dragonfly*)
1042     ;;
1043   *-*-freebsd*)
1044     if test "x$with_gmp" = x \
1045         && ! test -d ${srcdir}/gmp \
1046         && test -f /usr/local/include/gmp.h; then
1047       with_gmp=/usr/local
1048     fi
1049     ;;
1050   *-*-kaos*)
1051     # Remove unsupported stuff on all kaOS configurations.
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054   *-*-netbsd*)
1055     ;;
1056   *-*-netware*)
1057     ;;
1058   *-*-phoenix*)
1059     noconfigdirs="$noconfigdirs target-libgloss"
1060     ;;
1061   *-*-rtems*)
1062     noconfigdirs="$noconfigdirs target-libgloss"
1063     ;;
1064     # The tpf target doesn't support gdb yet.
1065   *-*-tpf*)
1066     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1067     ;;
1068   *-*-uclinux*)
1069     noconfigdirs="$noconfigdirs target-rda"
1070     ;;
1071   *-*-vxworks*)
1072     ;;
1073   alpha*-dec-osf*)
1074     # ld works, but does not support shared libraries.
1075     # gas doesn't generate exception information.
1076     noconfigdirs="$noconfigdirs gas ld"
1077     ;;
1078   alpha*-*-*vms*)
1079     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1080     ;;
1081   alpha*-*-*)
1082     # newlib is not 64 bit ready
1083     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1084     ;;
1085   bpf-*-*)
1086     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1087     ;;
1088   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1089     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1090     ;;
1091   arc*-*-*)
1092     noconfigdirs="$noconfigdirs sim"
1093     ;;
1094   arm-*-pe*)
1095     noconfigdirs="$noconfigdirs target-libgloss"
1096     ;;
1097   arm-*-riscix*)
1098     noconfigdirs="$noconfigdirs ld target-libgloss"
1099     ;;
1100   avr-*-*)
1101     if test x${with_avrlibc} != xno; then
1102       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1103     fi
1104     ;;
1105   c4x-*-* | tic4x-*-*)
1106     noconfigdirs="$noconfigdirs target-libgloss"
1107     ;;
1108   tic54x-*-*)
1109     noconfigdirs="$noconfigdirs target-libgloss gdb"
1110     ;;
1111   d10v-*-*)
1112     noconfigdirs="$noconfigdirs target-libgloss"
1113     ;;
1114   d30v-*-*)
1115     noconfigdirs="$noconfigdirs gdb"
1116     ;;
1117   fr30-*-elf*)
1118     noconfigdirs="$noconfigdirs gdb"
1119     ;;
1120   ft32-*-*)
1121     noconfigdirs="$noconfigdirs target-rda gprof"
1122     ;;
1123   moxie-*-*)
1124     noconfigdirs="$noconfigdirs"
1125     ;;
1126   h8300*-*-*)
1127     noconfigdirs="$noconfigdirs target-libgloss"
1128     ;;
1129   h8500-*-*)
1130     noconfigdirs="$noconfigdirs target-libgloss"
1131     ;;
1132   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1133     ;;
1134   hppa*64*-*-hpux*)
1135     noconfigdirs="$noconfigdirs gdb"
1136     ;;
1137   hppa*-*-hpux11*)
1138     noconfigdirs="$noconfigdirs gdb ld"
1139     ;;
1140   hppa*64*-*-linux*)
1141     ;;
1142   hppa*-*-linux*)
1143     ;;
1144   hppa*-*-*elf* | \
1145   hppa*-*-lites* | \
1146   hppa*-*-openbsd* | \
1147   hppa*64*-*-*)
1148     ;;
1149   hppa*-*-pro*)
1150     ;;
1151   hppa*-*-*)
1152     noconfigdirs="$noconfigdirs ld"
1153     ;;
1154   i960-*-*)
1155     noconfigdirs="$noconfigdirs gdb"
1156     ;;
1157   ia64*-*-elf*)
1158     # No gdb support yet.
1159     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1160     ;;
1161   ia64*-**-hpux*)
1162     # No ld support yet.
1163     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1164     ;;
1165   ia64*-*-*vms*)
1166     # No ld support yet.
1167     noconfigdirs="$noconfigdirs libgui itcl ld"
1168     ;;
1169   i[[3456789]]86-w64-mingw*)
1170     ;;
1171   i[[3456789]]86-*-mingw*)
1172     target_configdirs="$target_configdirs target-winsup"
1173     ;;
1174   *-*-cygwin*)
1175     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1176     noconfigdirs="$noconfigdirs target-libgloss"
1177     # always build newlib if winsup directory is present.
1178     if test -d "$srcdir/winsup/cygwin"; then
1179       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1180     elif test -d "$srcdir/newlib"; then
1181       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1182     fi
1183     ;;
1184   i[[3456789]]86-*-pe)
1185     noconfigdirs="$noconfigdirs target-libgloss"
1186     ;;
1187   i[[3456789]]86-*-sco3.2v5*)
1188     # The linker does not yet know about weak symbols in COFF,
1189     # and is not configured to handle mixed ELF and COFF.
1190     noconfigdirs="$noconfigdirs ld target-libgloss"
1191     ;;
1192   i[[3456789]]86-*-sco*)
1193     noconfigdirs="$noconfigdirs gprof target-libgloss"
1194     ;;
1195   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1196     noconfigdirs="$noconfigdirs target-libgloss"
1197     ;;
1198   i[[3456789]]86-*-sysv4*)
1199     noconfigdirs="$noconfigdirs target-libgloss"
1200     ;;
1201   i[[3456789]]86-*-beos*)
1202     noconfigdirs="$noconfigdirs gdb"
1203     ;;
1204   i[[3456789]]86-*-rdos*)
1205     noconfigdirs="$noconfigdirs gdb"
1206     ;;
1207   kvx-*-*)
1208     noconfigdirs="$noconfigdirs gdb gdbserver sim"
1209     ;;
1210   mmix-*-*)
1211     noconfigdirs="$noconfigdirs gdb"
1212     ;;
1213   mt-*-*)
1214     noconfigdirs="$noconfigdirs sim"
1215     ;;
1216   nfp-*-*)
1217     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1218     noconfigdirs="$noconfigdirs $target_libraries"
1219     ;;
1220   pdp11-*-*)
1221     noconfigdirs="$noconfigdirs gdb gprof"
1222     ;;
1223   powerpc-*-aix*)
1224     # copied from rs6000-*-* entry
1225     noconfigdirs="$noconfigdirs gprof"
1226     ;;
1227   powerpc*-*-winnt* | powerpc*-*-pe*)
1228     target_configdirs="$target_configdirs target-winsup"
1229     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1230     # always build newlib.
1231     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1232     ;;
1233     # This is temporary until we can link against shared libraries
1234   powerpcle-*-solaris*)
1235     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1236     ;;
1237   powerpc-*-beos*)
1238     noconfigdirs="$noconfigdirs gdb"
1239     ;;
1240   rs6000-*-lynxos*)
1241     noconfigdirs="$noconfigdirs gprof"
1242     ;;
1243   rs6000-*-aix*)
1244     noconfigdirs="$noconfigdirs gprof"
1245     ;;
1246   rs6000-*-*)
1247     noconfigdirs="$noconfigdirs gprof"
1248     ;;
1249   m68k-apollo-*)
1250     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1251     ;;
1252   microblaze*)
1253     noconfigdirs="$noconfigdirs gprof"
1254     ;;
1255   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1256     if test x$with_newlib = xyes; then
1257       noconfigdirs="$noconfigdirs gprof"
1258     fi
1259     ;;
1260   mips*-*-irix5*)
1261     noconfigdirs="$noconfigdirs gprof target-libgloss"
1262     ;;
1263   mips*-*-irix6*)
1264     noconfigdirs="$noconfigdirs gprof target-libgloss"
1265     ;;
1266   mips*-*-bsd*)
1267     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1268     ;;
1269   mips*-*-linux*)
1270     ;;
1271   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1272   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1273     noconfigdirs="$noconfigdirs ld gas gprof"
1274     ;;
1275   mips*-*-*)
1276     noconfigdirs="$noconfigdirs gprof"
1277     ;;
1278   nvptx*-*-*)
1279     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1280     ;;
1281   sh-*-*)
1282     case "${target}" in
1283       sh*-*-elf)
1284          ;;
1285       *)
1286          noconfigdirs="$noconfigdirs target-libgloss" ;;
1287     esac
1288     ;;
1289   sparc-*-sunos4*)
1290     if test x${is_cross_compiler} = xno ; then
1291            use_gnu_ld=no
1292     fi
1293     ;;
1294   tic6x-*-*)
1295     noconfigdirs="$noconfigdirs sim"
1296     ;;
1297   tilepro*-*-* | tilegx*-*-*)
1298     noconfigdirs="$noconfigdirs sim"
1299     ;;
1300   v810-*-*)
1301     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1302     ;;
1303   vax-*-*)
1304     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1305     ;;
1306   wasm32-*-*)
1307     noconfigdirs="$noconfigdirs ld"
1308     ;;
1309   loongarch*-*-linux*)
1310     ;;
1311   loongarch*-*-*)
1312     noconfigdirs="$noconfigdirs gprof"
1313     ;;
1314 esac
1315
1316 # If we aren't building newlib, then don't build libgloss, since libgloss
1317 # depends upon some newlib header files.
1318 case "${noconfigdirs}" in
1319   *target-libgloss*) ;;
1320   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1321 esac
1322
1323 # Work in distributions that contain no compiler tools, like Autoconf.
1324 host_makefile_frag=/dev/null
1325 if test -d ${srcdir}/config ; then
1326 case "${host}" in
1327   i[[3456789]]86-*-msdosdjgpp*)
1328     host_makefile_frag="config/mh-djgpp"
1329     ;;
1330   *-cygwin*)
1331     ACX_CHECK_CYGWIN_CAT_WORKS
1332     host_makefile_frag="config/mh-cygwin"
1333     ;;
1334   *-mingw*)
1335     host_makefile_frag="config/mh-mingw"
1336     ;;
1337   alpha*-linux*)
1338     host_makefile_frag="config/mh-alpha-linux"
1339     ;;
1340   hppa*-hp-hpux*)
1341     host_makefile_frag="config/mh-pa"
1342     ;;
1343   hppa*-*)
1344     host_makefile_frag="config/mh-pa"
1345     ;;
1346   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1347     host_makefile_frag="config/mh-darwin"
1348     ;;
1349   powerpc-*-aix*)
1350     host_makefile_frag="config/mh-ppc-aix"
1351     ;;
1352   rs6000-*-aix*)
1353     host_makefile_frag="config/mh-ppc-aix"
1354     ;;
1355 esac
1356 fi
1357
1358 if test "${build}" != "${host}" ; then
1359   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1360   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1361   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1362   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1363   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1364   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1365   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1366   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1367   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1368   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1369   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1370   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1371   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1372   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1373   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1374 else
1375   AR_FOR_BUILD="\$(AR)"
1376   AS_FOR_BUILD="\$(AS)"
1377   CC_FOR_BUILD="\$(CC)"
1378   CXX_FOR_BUILD="\$(CXX)"
1379   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1380   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1381   GOC_FOR_BUILD="\$(GOC)"
1382   GDC_FOR_BUILD="\$(GDC)"
1383   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1384   LD_FOR_BUILD="\$(LD)"
1385   NM_FOR_BUILD="\$(NM)"
1386   RANLIB_FOR_BUILD="\$(RANLIB)"
1387   WINDRES_FOR_BUILD="\$(WINDRES)"
1388   WINDMC_FOR_BUILD="\$(WINDMC)"
1389 fi
1390
1391 AC_PROG_CC_C99
1392 AC_PROG_CXX
1393
1394 # We must set the default linker to the linker used by gcc for the correct
1395 # operation of libtool.  If LD is not defined and we are using gcc, try to
1396 # set the LD default to the ld used by gcc.
1397 if test -z "$LD"; then
1398   if test "$GCC" = yes; then
1399     case $build in
1400     *-*-mingw*)
1401       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1402     *)
1403       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1404     esac
1405     case $gcc_prog_ld in
1406     # Accept absolute paths.
1407     [[\\/]* | [A-Za-z]:[\\/]*)]
1408       LD="$gcc_prog_ld" ;;
1409     esac
1410   fi
1411 fi
1412
1413 # Check whether -static-libstdc++ -static-libgcc is supported.
1414 have_static_libs=no
1415 if test "$GCC" = yes; then
1416   saved_LDFLAGS="$LDFLAGS"
1417
1418   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1419   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1420   AC_LANG_PUSH(C++)
1421   AC_LINK_IFELSE([AC_LANG_SOURCE([
1422 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1423 #error -static-libstdc++ not implemented
1424 #endif
1425 int main() {}])],
1426     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1427     [AC_MSG_RESULT([no])])
1428   AC_LANG_POP(C++)
1429
1430   LDFLAGS="$saved_LDFLAGS"
1431 fi
1432
1433 ACX_PROG_GNAT
1434 ACX_PROG_GDC
1435 ACX_PROG_CMP_IGNORE_INITIAL
1436
1437 AC_ARG_ENABLE([bootstrap],
1438 [AS_HELP_STRING([--enable-bootstrap],
1439                 [enable bootstrapping @<:@yes if native build@:>@])],,
1440 enable_bootstrap=default)
1441
1442 # Issue errors and warnings for invalid/strange bootstrap combinations.
1443 if test -r $srcdir/gcc/configure; then
1444   have_compiler=yes
1445 else
1446   have_compiler=no
1447 fi
1448
1449 case "$have_compiler:$host:$target:$enable_bootstrap" in
1450   *:*:*:no) ;;
1451
1452   # Default behavior.  Enable bootstrap if we have a compiler
1453   # and we are in a native configuration.
1454   yes:$build:$build:default)
1455     enable_bootstrap=yes ;;
1456
1457   *:*:*:default)
1458     enable_bootstrap=no ;;
1459
1460   # We have a compiler and we are in a native configuration, bootstrap is ok
1461   yes:$build:$build:yes)
1462     ;;
1463
1464   # Other configurations, but we have a compiler.  Assume the user knows
1465   # what he's doing.
1466   yes:*:*:yes)
1467     AC_MSG_WARN([trying to bootstrap a cross compiler])
1468     ;;
1469
1470   # No compiler: if they passed --enable-bootstrap explicitly, fail
1471   no:*:*:yes)
1472     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1473
1474   # Fail if wrong command line
1475   *)
1476     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1477     ;;
1478 esac
1479
1480 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1481 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1482 # require C++11 (or higher).
1483 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1484   CXX="$CXX -std=c++11"
1485 elif test "$have_compiler" = yes; then
1486   AX_CXX_COMPILE_STDCXX(11)
1487
1488   if test "${build}" != "${host}"; then
1489     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1490   fi
1491 fi
1492
1493 AC_ARG_ENABLE([pgo-build],
1494 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1495                 [enable the PGO build])],
1496 [enable_pgo_build=$enableval],
1497 [enable_pgo_build=no])
1498
1499 # Issue errors and warnings for invalid/strange PGO build combinations.
1500 case "$have_compiler:$host:$target:$enable_pgo_build" in
1501   *:*:*:no) ;;
1502
1503   # Allow the PGO build only if we aren't building a compiler and
1504   # we are in a native configuration.
1505   no:$build:$build:yes | no:$build:$build:lto) ;;
1506
1507   # Disallow the PGO bootstrap if we are building a compiler.
1508   yes:*:*:yes | yes:*:*:lto)
1509     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1510
1511   *)
1512     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1513     ;;
1514 esac
1515
1516 if test "$enable_pgo_build" != "no"; then
1517   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1518   old_CFLAGS="$CFLAGS"
1519   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1520   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1521   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1522                     [PGO_BUILD_GEN_CFLAGS=])
1523   CFLAGS="$old_CFLAGS"
1524   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1525     AC_MSG_RESULT([yes])
1526     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1527   else
1528     AC_MSG_RESULT([no])
1529     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1530   fi
1531
1532   if test "$enable_pgo_build" = "lto"; then
1533     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1534     old_CFLAGS="$CFLAGS"
1535     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1536     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1537     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1538                       [PGO_BUILD_LTO_CFLAGS=])
1539     CFLAGS="$old_CFLAGS"
1540     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1541       AC_MSG_RESULT([yes])
1542     else
1543       AC_MSG_RESULT([no])
1544       AC_MSG_WARN([LTO is disabled for the PGO build])
1545     fi
1546   fi
1547 fi
1548 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1549 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1550 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1551
1552 # Used for setting $lt_cv_objdir
1553 _LT_CHECK_OBJDIR
1554
1555 # Check for GMP, MPFR and MPC
1556 require_gmp=no
1557 require_mpc=no
1558 if test -d ${srcdir}/gcc ; then
1559   require_gmp=yes
1560   require_mpc=yes
1561 fi
1562 if test -d ${srcdir}/gdb ; then
1563   if test "x$enable_gdb" != xno; then
1564    require_gmp=yes
1565   fi
1566 fi
1567
1568 gmplibs="-lmpfr -lgmp"
1569 if test x"$require_mpc" = "xyes" ; then
1570   gmplibs="-lmpc $gmplibs"
1571 fi
1572 gmpinc=
1573 have_gmp=no
1574
1575 # Specify a location for mpc
1576 # check for this first so it ends up on the link line before mpfr.
1577 AC_ARG_WITH(mpc,
1578 [AS_HELP_STRING([--with-mpc=PATH],
1579                 [specify prefix directory for installed MPC package.
1580                  Equivalent to --with-mpc-include=PATH/include
1581                  plus --with-mpc-lib=PATH/lib])])
1582 AC_ARG_WITH(mpc-include,
1583 [AS_HELP_STRING([--with-mpc-include=PATH],
1584                 [specify directory for installed MPC include files])])
1585 AC_ARG_WITH(mpc-lib,
1586 [AS_HELP_STRING([--with-mpc-lib=PATH],
1587                 [specify directory for the installed MPC library])])
1588
1589 if test "x$with_mpc" != x; then
1590   gmplibs="-L$with_mpc/lib $gmplibs"
1591   gmpinc="-I$with_mpc/include $gmpinc"
1592 fi
1593 if test "x$with_mpc_include" != x; then
1594   gmpinc="-I$with_mpc_include $gmpinc"
1595 fi
1596 if test "x$with_mpc_lib" != x; then
1597   gmplibs="-L$with_mpc_lib $gmplibs"
1598 fi
1599 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1600   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1601   gmpinc='-I$$s/mpc/src '"$gmpinc"
1602   # Do not test the mpc version.  Assume that it is sufficient, since
1603   # it is in the source tree, and the library has not been built yet
1604   # but it would be included on the link line in the version check below
1605   # hence making the test fail.
1606   have_gmp=yes
1607 fi
1608
1609 # Specify a location for mpfr
1610 # check for this first so it ends up on the link line before gmp.
1611 AC_ARG_WITH(mpfr,
1612 [AS_HELP_STRING([--with-mpfr=PATH],
1613                 [specify prefix directory for installed MPFR package.
1614                  Equivalent to --with-mpfr-include=PATH/include
1615                  plus --with-mpfr-lib=PATH/lib])])
1616 AC_ARG_WITH(mpfr-include,
1617 [AS_HELP_STRING([--with-mpfr-include=PATH],
1618                 [specify directory for installed MPFR include files])])
1619 AC_ARG_WITH(mpfr-lib,
1620 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1621                 [specify directory for the installed MPFR library])])
1622
1623 if test "x$with_mpfr" != x; then
1624   gmplibs="-L$with_mpfr/lib $gmplibs"
1625   gmpinc="-I$with_mpfr/include $gmpinc"
1626 fi
1627 if test "x$with_mpfr_include" != x; then
1628   gmpinc="-I$with_mpfr_include $gmpinc"
1629 fi
1630 if test "x$with_mpfr_lib" != x; then
1631   gmplibs="-L$with_mpfr_lib $gmplibs"
1632 fi
1633 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1634   # MPFR v3.1.0 moved the sources into a src sub-directory.
1635   if ! test -d ${srcdir}/mpfr/src; then
1636     AC_MSG_ERROR([dnl
1637 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1638   fi
1639   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1640   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1641   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1642   # Do not test the mpfr version.  Assume that it is sufficient, since
1643   # it is in the source tree, and the library has not been built yet
1644   # but it would be included on the link line in the version check below
1645   # hence making the test fail.
1646   have_gmp=yes
1647 fi
1648
1649 # Specify a location for gmp
1650 AC_ARG_WITH(gmp,
1651 [AS_HELP_STRING([--with-gmp=PATH],
1652                 [specify prefix directory for the installed GMP package.
1653                  Equivalent to --with-gmp-include=PATH/include
1654                  plus --with-gmp-lib=PATH/lib])])
1655 AC_ARG_WITH(gmp-include,
1656 [AS_HELP_STRING([--with-gmp-include=PATH],
1657                 [specify directory for installed GMP include files])])
1658 AC_ARG_WITH(gmp-lib,
1659 [AS_HELP_STRING([--with-gmp-lib=PATH],
1660                 [specify directory for the installed GMP library])])
1661
1662
1663 if test "x$with_gmp" != x; then
1664   gmplibs="-L$with_gmp/lib $gmplibs"
1665   gmpinc="-I$with_gmp/include $gmpinc"
1666 fi
1667 if test "x$with_gmp_include" != x; then
1668   gmpinc="-I$with_gmp_include $gmpinc"
1669 fi
1670 if test "x$with_gmp_lib" != x; then
1671   gmplibs="-L$with_gmp_lib $gmplibs"
1672 fi
1673 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1674   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1675   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1676   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1677   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1678   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1679   # Do not test the gmp version.  Assume that it is sufficient, since
1680   # it is in the source tree, and the library has not been built yet
1681   # but it would be included on the link line in the version check below
1682   # hence making the test fail.
1683   have_gmp=yes
1684 fi
1685
1686 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1687   have_gmp=yes
1688   saved_CFLAGS="$CFLAGS"
1689   CFLAGS="$CFLAGS $gmpinc"
1690   # Check for the recommended and required versions of GMP.
1691   AC_MSG_CHECKING([for the correct version of gmp.h])
1692   AC_TRY_COMPILE([#include "gmp.h"],[
1693   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1694   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1695   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1696   choke me
1697   #endif
1698   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1699   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1700   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1701   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1702   choke me
1703   #endif
1704   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1705    [AC_MSG_RESULT([no]); have_gmp=no])
1706
1707   # If we have GMP, check the MPFR version.
1708   if test x"$have_gmp" = xyes; then
1709     # Check for the recommended and required versions of MPFR.
1710     AC_MSG_CHECKING([for the correct version of mpfr.h])
1711     AC_TRY_COMPILE([#include <gmp.h>
1712     #include <mpfr.h>],[
1713     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1714     choke me
1715     #endif
1716     ], [AC_TRY_COMPILE([#include <gmp.h>
1717     #include <mpfr.h>],[
1718     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1719     choke me
1720     #endif
1721     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1722      [AC_MSG_RESULT([no]); have_gmp=no])
1723   fi
1724
1725   # Check for the MPC header version.
1726   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1727     # Check for the recommended and required versions of MPC.
1728     AC_MSG_CHECKING([for the correct version of mpc.h])
1729     AC_TRY_COMPILE([#include <mpc.h>],[
1730     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1731     choke me
1732     #endif
1733     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1734     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1735     choke me
1736     #endif
1737     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1738      [AC_MSG_RESULT([no]); have_gmp=no])
1739   fi
1740
1741   # Now check the MPFR library.
1742   if test x"$have_gmp" = xyes; then
1743     saved_LIBS="$LIBS"
1744     LIBS="$LIBS $gmplibs"
1745     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1746     AC_TRY_LINK([#include <mpfr.h>],[
1747     mpfr_t n;
1748     mpfr_t x;
1749     int t;
1750     mpfr_init (n);
1751     mpfr_init (x);
1752     mpfr_atan2 (n, n, x, MPFR_RNDN);
1753     mpfr_erfc (n, x, MPFR_RNDN);
1754     mpfr_subnormalize (x, t, MPFR_RNDN);
1755     mpfr_clear(n);
1756     mpfr_clear(x);
1757     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1758     LIBS="$saved_LIBS"
1759   fi
1760
1761   # Now check the MPC library
1762   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1763     saved_LIBS="$LIBS"
1764     LIBS="$LIBS $gmplibs"
1765     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1766     AC_TRY_LINK([#include <mpc.h>],[
1767     mpc_t c;
1768     mpc_init2 (c, 53);
1769     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1770     mpc_cosh (c, c, MPC_RNDNN);
1771     mpc_pow (c, c, c, MPC_RNDNN);
1772     mpc_acosh (c, c, MPC_RNDNN);
1773     mpc_clear (c);
1774     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1775     LIBS="$saved_LIBS"
1776   fi
1777
1778   CFLAGS="$saved_CFLAGS"
1779
1780 # The library versions listed in the error message below should match
1781 # the HARD-minimums enforced above.
1782   if test x$have_gmp != xyes; then
1783     if test -d ${srcdir}/gcc ; then
1784       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1785 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1786 their locations.  Source code for these libraries can be found at
1787 their respective hosting sites as well as at
1788 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1789 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1790 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1791 make sure that you have installed both the libraries and the header
1792 files.  They may be located in separate packages.])
1793     else
1794       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1795 Try the --with-gmp and/or --with-mpfr options to specify
1796 their locations.  If you obtained GMP and/or MPFR from a vendor
1797 distribution package, make sure that you have installed both the libraries
1798 and the header files.  They may be located in separate packages.])
1799     fi
1800   fi
1801 fi
1802
1803 # Flags needed for both GMP, MPFR and/or MPC.
1804 AC_SUBST(gmplibs)
1805 AC_SUBST(gmpinc)
1806 AC_SUBST(extra_mpfr_configure_flags)
1807 AC_SUBST(extra_mpc_gmp_configure_flags)
1808 AC_SUBST(extra_mpc_mpfr_configure_flags)
1809 AC_SUBST(extra_isl_gmp_configure_flags)
1810
1811 # Libraries to use for stage1 or when not bootstrapping.
1812 AC_ARG_WITH(stage1-libs,
1813 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1814 [if test "$withval" = "no" -o "$withval" = "yes"; then
1815    stage1_libs=
1816  else
1817    stage1_libs=$withval
1818  fi],
1819 [stage1_libs=])
1820 AC_SUBST(stage1_libs)
1821
1822 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1823 # default is yes if gcc is being built; no otherwise.  The reason for
1824 # this default is that gdb is sometimes linked against GNU Source
1825 # Highlight, which is a shared library that uses C++ exceptions.  In
1826 # this case, -static-libstdc++ will cause crashes.
1827 AC_ARG_WITH(static-standard-libraries,
1828 [AS_HELP_STRING([--with-static-standard-libraries],
1829                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1830 [], [with_static_standard_libraries=auto])
1831 if test "$with_static_standard_libraries" = auto; then
1832   with_static_standard_libraries=$have_compiler
1833 fi
1834
1835 # Linker flags to use for stage1 or when not bootstrapping.
1836 AC_ARG_WITH(stage1-ldflags,
1837 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1838 [if test "$withval" = "no" -o "$withval" = "yes"; then
1839    stage1_ldflags=
1840  else
1841    stage1_ldflags=$withval
1842  fi],
1843 [stage1_ldflags=
1844  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1845  # if supported.  But if the user explicitly specified the libraries to use,
1846  # trust that they are doing what they want.
1847  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1848      -a "$have_static_libs" = yes; then
1849    stage1_ldflags="-static-libstdc++ -static-libgcc"
1850  fi])
1851 AC_SUBST(stage1_ldflags)
1852
1853 # Libraries to use for stage2 and later builds.
1854 AC_ARG_WITH(boot-libs,
1855 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1856 [if test "$withval" = "no" -o "$withval" = "yes"; then
1857    poststage1_libs=
1858  else
1859    poststage1_libs=$withval
1860  fi],
1861 [poststage1_libs=])
1862 AC_SUBST(poststage1_libs)
1863
1864 # Linker flags to use for stage2 and later builds.
1865 AC_ARG_WITH(boot-ldflags,
1866 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1867                 [linker flags for stage2 and later])],
1868 [if test "$withval" = "no" -o "$withval" = "yes"; then
1869    poststage1_ldflags=
1870  else
1871    poststage1_ldflags=$withval
1872  fi],
1873 [poststage1_ldflags=
1874  # In stages 2 and 3, default to linking libstdc++ and libgcc
1875  # statically.  But if the user explicitly specified the libraries to
1876  # use, trust that they are doing what they want.
1877  if test "$poststage1_libs" = ""; then
1878    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1879  fi])
1880 case $target in
1881   *-darwin2* | *-darwin1[[56789]]*)
1882     # For these versions, we default to using embedded rpaths.
1883     if test "x$enable_darwin_at_rpath" != "xno"; then
1884       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1885     fi
1886   ;;
1887   *-darwin*)
1888     # For these versions, we only use embedded rpaths on demand.
1889     if test "x$enable_darwin_at_rpath" = "xyes"; then
1890       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1891     fi
1892   ;;
1893 esac
1894 AC_SUBST(poststage1_ldflags)
1895
1896 # GCC GRAPHITE dependency isl.
1897 # Basic setup is inlined here, actual checks are in config/isl.m4
1898
1899 AC_ARG_WITH(isl,
1900   [AS_HELP_STRING(
1901    [--with-isl=PATH],
1902    [Specify prefix directory for the installed isl package.
1903     Equivalent to --with-isl-include=PATH/include
1904     plus --with-isl-lib=PATH/lib])])
1905
1906 # Treat --without-isl as a request to disable
1907 # GRAPHITE support and skip all following checks.
1908 if test "x$with_isl" != "xno"; then
1909   # Check for isl
1910   dnl Provide configure switches and initialize islinc & isllibs
1911   dnl with user input.
1912   ISL_INIT_FLAGS
1913   dnl The versions of isl that work for Graphite
1914   ISL_CHECK_VERSION()
1915   dnl Only execute fail-action, if isl has been requested.
1916   ISL_IF_FAILED([
1917     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1918 fi
1919
1920 # If the isl check failed, disable builds of in-tree variant of isl
1921 if test "x$with_isl" = xno ||
1922    test "x$gcc_cv_isl" = xno; then
1923   noconfigdirs="$noconfigdirs isl"
1924   islinc=
1925 fi
1926
1927 AC_SUBST(isllibs)
1928 AC_SUBST(islinc)
1929
1930 # Check for LTO support.
1931 AC_ARG_ENABLE(lto,
1932 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1933 enable_lto=$enableval,
1934 enable_lto=yes; default_enable_lto=yes)
1935
1936 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1937   build_lto_plugin=yes
1938 ],[if test x"$default_enable_lto" = x"yes" ; then
1939     case $target in
1940       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1941       # On other non-ELF platforms, LTO has yet to be validated.
1942       *) enable_lto=no ;;
1943     esac
1944   else
1945   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1946   # It would also be nice to check the binutils support, but we don't
1947   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1948   # warn during gcc/ subconfigure; unless you're bootstrapping with
1949   # -flto it won't be needed until after installation anyway.
1950     case $target in
1951       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1952       *) if test x"$enable_lto" = x"yes"; then
1953         AC_MSG_ERROR([LTO support is not enabled for this target.])
1954         fi
1955       ;;
1956     esac
1957   fi
1958   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1959   # Build it unless LTO was explicitly disabled.
1960   case $target in
1961     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1962     *) ;;
1963   esac
1964 ])
1965
1966 AC_ARG_ENABLE(linker-plugin-configure-flags,
1967   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1968     [additional flags for configuring linker plugins @<:@none@:>@])],
1969   extra_linker_plugin_configure_flags=$enableval,
1970   extra_linker_plugin_configure_flags=)
1971 AC_SUBST(extra_linker_plugin_configure_flags)
1972 AC_ARG_ENABLE(linker-plugin-flags,
1973   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1974     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1975   extra_linker_plugin_flags=$enableval,
1976   extra_linker_plugin_flags=)
1977 AC_SUBST(extra_linker_plugin_flags)
1978
1979 # Handle --enable-host-pie
1980 # If host PIE executables are the default (or must be forced on) for some host,
1981 # we must pass that configuration to the gcc directory.
1982 gcc_host_pie=
1983 AC_ARG_ENABLE(host-pie,
1984 [AS_HELP_STRING([--enable-host-pie],
1985                 [build position independent host executables])],
1986 [host_pie=$enableval
1987  case $host in
1988    *-*-darwin2*)
1989      if test x$host_pie != xyes ; then
1990        # for Darwin20+ this is required.
1991        AC_MSG_WARN([PIE executables are required for the configured host, host-pie setting ignored.])
1992        host_pie=yes
1993        gcc_host_pie=--enable-host-pie
1994      fi ;;
1995   *) ;;
1996  esac],
1997 [case $host in
1998   *-*-darwin2*)
1999     # Default to PIE (mandatory for aarch64).
2000     host_pie=yes
2001     gcc_host_pie=--enable-host-pie
2002     ;;
2003   *) host_pie=no ;;
2004  esac])
2005
2006 AC_SUBST(host_pie)
2007 AC_SUBST(gcc_host_pie)
2008
2009 # Enable --enable-host-shared.
2010 # Checked early to determine whether jit is an 'all' language
2011 AC_ARG_ENABLE(host-shared,
2012 [AS_HELP_STRING([--enable-host-shared],
2013                 [build host code as shared libraries])],
2014 [host_shared=$enableval
2015  case $host in
2016    x86_64-*-darwin* | aarch64-*-darwin*)
2017      if test x$host_shared != xyes ; then
2018        # PIC is the default, and actually cannot be switched off.
2019        AC_MSG_WARN([PIC code is required for the configured host; host-shared setting ignored.])
2020        host_shared=yes
2021      fi ;;
2022    *-*-darwin*)
2023      if test x$host_pie = xyes -a x$host_shared != xyes ; then
2024        AC_MSG_WARN([PIC code is required for PIE host executables host-shared setting ignored.])
2025        host_shared=yes
2026      fi ;;
2027   *) ;;
2028  esac],
2029 [case $host in
2030   # 64B x86_64 and Aarch64 Darwin default to PIC.
2031   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
2032   # 32B and powerpc64 Darwin must use PIC to link PIE exes.
2033   *-*-darwin*) host_shared=$host_pie ;;
2034   *) host_shared=no;;
2035  esac])
2036
2037 AC_SUBST(host_shared)
2038
2039 if test x$host_shared = xyes; then
2040   case $host in
2041     *-*-darwin*)
2042       # Since host shared is the default for 64b Darwin, and also enabled for
2043       # host_pie, ensure that we present the PIE flag when host_pie is active.
2044       if test x$host_pie = xyes; then
2045         PICFLAG=-fPIE
2046       fi
2047       ;;
2048     *)
2049       PICFLAG=-fPIC
2050       ;;
2051   esac
2052 elif test x$host_pie = xyes; then
2053   PICFLAG=-fPIE
2054 else
2055   PICFLAG=
2056 fi
2057
2058 AC_SUBST(PICFLAG)
2059
2060 # If we are building PIC/PIE host executables, and we are building dependent
2061 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
2062 # code.
2063 host_libs_picflag=
2064 if test "$host_shared" = "yes" -o "$host_pie" = "yes"; then
2065 host_libs_picflag='--with-pic'
2066 fi
2067 AC_SUBST(host_libs_picflag)
2068
2069 # By default, C and C++ are the only stage 1 languages.
2070 stage1_languages=,c,
2071
2072 # Target libraries that we bootstrap.
2073 bootstrap_target_libs=,target-libgcc,
2074
2075 # Figure out what language subdirectories are present.
2076 # Look if the user specified --enable-languages="..."; if not, use
2077 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2078 # go away some day.
2079 # NB:  embedded tabs in this IF block -- do not untabify
2080 if test -d ${srcdir}/gcc; then
2081   if test x"${enable_languages+set}" != xset; then
2082     if test x"${LANGUAGES+set}" = xset; then
2083       enable_languages="${LANGUAGES}"
2084         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
2085     else
2086       enable_languages=default
2087     fi
2088   else
2089     if test x"${enable_languages}" = x ||
2090        test x"${enable_languages}" = xyes;
2091        then
2092       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2093       exit 1
2094     fi
2095   fi
2096   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2097
2098   # 'f95' is the old name for the 'fortran' language. We issue a warning
2099   # and make the substitution.
2100   case ,${enable_languages}, in
2101     *,f95,*)
2102       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2103       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2104       ;;
2105   esac
2106
2107   # If bootstrapping, C++ must be enabled.
2108   case ",$enable_languages,:$enable_bootstrap" in
2109     *,c++,*:*) ;;
2110     *:yes)
2111       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2112         enable_languages="${enable_languages},c++"
2113       else
2114         AC_MSG_ERROR([bootstrapping requires c++ sources])
2115       fi
2116       ;;
2117   esac
2118
2119   # First scan to see if an enabled language requires some other language.
2120   # We assume that a given config-lang.in will list all the language
2121   # front ends it requires, even if some are required indirectly.
2122   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2123     case ${lang_frag} in
2124       ..) ;;
2125       # The odd quoting in the next line works around
2126       # an apparent bug in bash 1.12 on linux.
2127       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2128       *)
2129         # From the config-lang.in, get $language, $lang_requires, and
2130         # $lang_requires_boot_languages.
2131         language=
2132         lang_requires=
2133         lang_requires_boot_languages=
2134         # set srcdir during sourcing lang_frag to the gcc dir.
2135         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2136         # polutes this shell
2137         saved_srcdir=${srcdir}
2138         srcdir=${srcdir}/gcc . ${lang_frag}
2139         srcdir=${saved_srcdir}
2140         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2141           case ,${enable_languages}, in
2142             *,$other,*) ;;
2143             *,default,*) ;;
2144             *,all,*) ;;
2145             *,$language,*)
2146               echo " \`$other' language required by \`$language'; enabling" 1>&2
2147               enable_languages="${enable_languages},${other}"
2148               ;;
2149           esac
2150         done
2151         for other in ${lang_requires_boot_languages} ; do
2152           if test "$other" != "c"; then
2153             case ,${enable_stage1_languages}, in
2154               *,$other,*) ;;
2155               *,default,*) ;;
2156               *,all,*) ;;
2157               *)
2158                 case ,${enable_languages}, in
2159                   *,$language,*)
2160                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2161                     enable_stage1_languages="$enable_stage1_languages,${other}"
2162                     ;;
2163                 esac
2164                 ;;
2165             esac
2166           fi
2167         done
2168         ;;
2169     esac
2170   done
2171
2172   new_enable_languages=,c,
2173
2174   # If LTO is enabled, add the LTO front end.
2175   if test "$enable_lto" = "yes" ; then
2176     case ,${enable_languages}, in
2177       *,lto,*) ;;
2178       *) enable_languages="${enable_languages},lto" ;;
2179     esac
2180     if test "${build_lto_plugin}" = "yes" ; then
2181       configdirs="$configdirs lto-plugin"
2182     fi
2183   fi
2184
2185   # If we're building an offloading compiler, add the LTO front end.
2186   if test x"$enable_as_accelerator_for" != x ; then
2187     case ,${enable_languages}, in
2188       *,lto,*) ;;
2189       *) enable_languages="${enable_languages},lto" ;;
2190     esac
2191   fi
2192
2193   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2194   potential_languages=,c,
2195
2196   enabled_target_libs=
2197   disabled_target_libs=
2198
2199   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2200     case ${lang_frag} in
2201       ..) ;;
2202       # The odd quoting in the next line works around
2203       # an apparent bug in bash 1.12 on linux.
2204       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2205       *)
2206         # From the config-lang.in, get $language, $target_libs,
2207         # $lang_dirs, $boot_language, and $build_by_default
2208         language=
2209         target_libs=
2210         lang_dirs=
2211         subdir_requires=
2212         boot_language=no
2213         build_by_default=yes
2214         # set srcdir during sourcing.  See above about save & restore
2215         saved_srcdir=${srcdir}
2216         srcdir=${srcdir}/gcc . ${lang_frag}
2217         srcdir=${saved_srcdir}
2218         if test x${language} = x; then
2219           echo "${lang_frag} doesn't set \$language." 1>&2
2220           exit 1
2221         fi
2222
2223         if test "$language" = "c++"; then
2224           boot_language=yes
2225         fi
2226
2227         add_this_lang=no
2228         # C is always enabled, so no need to add it again
2229         if test "$language" != "c"; then
2230           case ,${enable_languages}, in
2231             *,${language},*)
2232               # Language was explicitly selected; include it
2233               add_this_lang=yes
2234               ;;
2235             *,all,*)
2236               # All languages are enabled
2237               add_this_lang=all
2238               ;;
2239             *,default,*)
2240               # 'default' was selected, select it if it is a default language
2241               add_this_lang=${build_by_default}
2242               ;;
2243           esac
2244         fi
2245
2246         # Disable languages that need other directories if these aren't available.
2247         for i in $subdir_requires; do
2248           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2249           case ${add_this_lang} in
2250             yes)
2251               # Specifically requested language; tell them.
2252               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2253               ;;
2254             all)
2255               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2256               add_this_lang=unsupported
2257               ;;
2258             *)
2259               # Silently disable.
2260               add_this_lang=unsupported
2261               ;;
2262           esac
2263         done
2264
2265         # Disable Ada if no preexisting GNAT is available.
2266         case ${add_this_lang}:${language}:${have_gnat} in
2267           yes:ada:no)
2268             # Specifically requested language; tell them.
2269             AC_MSG_ERROR([GNAT is required to build $language])
2270             ;;
2271           all:ada:no)
2272             AC_MSG_WARN([GNAT is required to build $language])
2273             add_this_lang=unsupported
2274             ;;
2275           *:ada:no)
2276             # Silently disable.
2277             add_this_lang=unsupported
2278             ;;
2279         esac
2280
2281         # Disable D if no preexisting GDC is available.
2282         case ${add_this_lang}:${language}:${have_gdc} in
2283           yes:d:no)
2284             # Specifically requested language; tell them.
2285             AC_MSG_ERROR([GDC is required to build $language])
2286            ;;
2287           all:d:no)
2288             AC_MSG_WARN([GDC is required to build $language])
2289             add_this_lang=unsupported
2290             ;;
2291           *:d:no)
2292             # Silently disable.
2293             add_this_lang=unsupported
2294             ;;
2295         esac
2296
2297         # Disable jit if -enable-host-shared not specified
2298         # but not if building for Mingw. All code in Windows
2299         # is position independent code (PIC).
2300         case $target in
2301           *mingw*) ;;
2302           *)
2303           case ${add_this_lang}:${language}:${host_shared} in
2304             yes:jit:no)
2305                    # PR jit/64780: explicitly specify --enable-host-shared
2306             AC_MSG_ERROR([
2307 Enabling language "jit" requires --enable-host-shared.
2308
2309 --enable-host-shared typically slows the rest of the compiler down by
2310 a few %, so you must explicitly enable it.
2311
2312 If you want to build both the jit and the regular compiler, it is often
2313 best to do this via two separate configure/builds, in separate
2314 directories, to avoid imposing the performance cost of
2315 --enable-host-shared on the regular compiler.])
2316                     ;;
2317             all:jit:no)
2318               AC_MSG_WARN([--enable-host-shared required to build $language])
2319               add_this_lang=unsupported
2320               ;;
2321             *:jit:no)
2322               # Silently disable.
2323               add_this_lang=unsupported
2324               ;;
2325                 esac
2326           ;;
2327         esac
2328
2329         # Disable a language that is unsupported by the target.
2330         case "${add_this_lang}: $unsupported_languages " in
2331           no:*) ;;
2332           unsupported:*) ;;
2333           *:*" $language "*)
2334             AC_MSG_WARN([${language} not supported for this target])
2335             add_this_lang=unsupported
2336             ;;
2337         esac
2338
2339         case $add_this_lang in
2340           unsupported)
2341             # Remove language-dependent dirs.
2342             disabled_target_libs="$disabled_target_libs $target_libs"
2343             noconfigdirs="$noconfigdirs $lang_dirs"
2344             ;;
2345           no)
2346             # Remove language-dependent dirs; still show language as supported.
2347             disabled_target_libs="$disabled_target_libs $target_libs"
2348             noconfigdirs="$noconfigdirs $lang_dirs"
2349             potential_languages="${potential_languages}${language},"
2350             ;;
2351           all|yes)
2352             new_enable_languages="${new_enable_languages}${language},"
2353             potential_languages="${potential_languages}${language},"
2354             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2355             enabled_target_libs="$enabled_target_libs $target_libs"
2356             case "${boot_language}:,$enable_stage1_languages," in
2357               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2358                 # Add to (comma-separated) list of stage 1 languages.
2359                 case ",$stage1_languages," in
2360                   *,$language,* | ,yes, | ,all,) ;;
2361                   *) stage1_languages="${stage1_languages}${language}," ;;
2362                 esac
2363                 # We need to bootstrap any supporting libraries.
2364                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2365                 ;;
2366             esac
2367             ;;
2368         esac
2369         ;;
2370     esac
2371   done
2372
2373   # Add target libraries which are only needed for disabled languages
2374   # to noconfigdirs.
2375   if test -n "$disabled_target_libs"; then
2376     for dir in $disabled_target_libs; do
2377       case " $enabled_target_libs " in
2378       *" ${dir} "*) ;;
2379       *) noconfigdirs="$noconfigdirs $dir" ;;
2380       esac
2381     done
2382   fi
2383
2384   AC_ARG_ENABLE(stage1-languages,
2385   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2386                   [choose additional languages to build during
2387                   stage1.  Mostly useful for compiler development])],
2388   [case ,${enable_stage1_languages}, in
2389     ,no,|,,)
2390       # Set it to something that will have no effect in the loop below
2391       enable_stage1_languages=c ;;
2392     ,yes,)
2393       enable_stage1_languages=`echo $new_enable_languages | \
2394         sed -e "s/^,//" -e "s/,$//" ` ;;
2395     *,all,*)
2396       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2397         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2398   esac
2399
2400   # Add "good" languages from enable_stage1_languages to stage1_languages,
2401   # while "bad" languages go in missing_languages.  Leave no duplicates.
2402   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2403     case $potential_languages in
2404       *,$i,*)
2405         case $stage1_languages in
2406           *,$i,*) ;;
2407           *) stage1_languages="$stage1_languages$i," ;;
2408         esac ;;
2409       *)
2410         case $missing_languages in
2411           *,$i,*) ;;
2412           *) missing_languages="$missing_languages$i," ;;
2413         esac ;;
2414      esac
2415   done])
2416
2417   # Remove leading/trailing commas that were added for simplicity
2418   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2419   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2420   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2421   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2422
2423   if test "x$missing_languages" != x; then
2424     AC_MSG_ERROR([
2425 The following requested languages could not be built: ${missing_languages}
2426 Supported languages are: ${potential_languages}])
2427   fi
2428   if test "x$new_enable_languages" != "x$enable_languages"; then
2429     echo The following languages will be built: ${new_enable_languages}
2430     enable_languages="$new_enable_languages"
2431   fi
2432
2433   AC_SUBST(stage1_languages)
2434   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2435 fi
2436
2437 # Handle --disable-<component> generically.
2438 for dir in $configdirs $build_configdirs $target_configdirs ; do
2439   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2440   varname=`echo $dirname | sed -e s/+/_/g`
2441   if eval test x\${enable_${varname}} "=" xno ; then
2442     noconfigdirs="$noconfigdirs $dir"
2443   fi
2444 done
2445
2446 # Check for Boehm's garbage collector
2447 AC_ARG_ENABLE(objc-gc,
2448 [AS_HELP_STRING([--enable-objc-gc],
2449                 [enable use of Boehm's garbage collector with the
2450                  GNU Objective-C runtime])])
2451 AC_ARG_WITH([target-bdw-gc],
2452 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2453                 [specify prefix directory for installed bdw-gc package.
2454                  Equivalent to --with-target-bdw-gc-include=PATH/include
2455                  plus --with-target-bdw-gc-lib=PATH/lib])])
2456 AC_ARG_WITH([target-bdw-gc-include],
2457 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2458                 [specify directories for installed bdw-gc include files])])
2459 AC_ARG_WITH([target-bdw-gc-lib],
2460 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2461                 [specify directories for installed bdw-gc library])])
2462
2463 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2464   AC_MSG_CHECKING([for bdw garbage collector])
2465   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2466     dnl no bdw-gw options, assume default locations
2467     AC_MSG_RESULT([using bdw-gc in default locations])
2468   else
2469     dnl bdw-gw options, first error checking, complete checking in libobjc
2470     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2471       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2472     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2473       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2474     else
2475       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2476     fi
2477   fi
2478 esac
2479
2480 # Disable libitm, libsanitizer, libvtv if we're not building C++
2481 case ,${enable_languages}, in
2482   *,c++,*)
2483     # Disable libitm, libsanitizer if we're not building libstdc++
2484     case "${noconfigdirs}" in
2485       *target-libstdc++-v3*)
2486         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2487         ;;
2488       *) ;;
2489     esac
2490     ;;
2491   *)
2492     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2493     ;;
2494 esac
2495
2496 case ,${enable_languages}, in
2497   *,rust,*)
2498     case " ${noconfigdirs} " in
2499       *\ target-libstdc++-v3\ *)
2500         # Disable target libgrust if we're not building target libstdc++.
2501         noconfigdirs="$noconfigdirs target-libgrust"
2502         ;;
2503     esac
2504     ;;
2505 esac
2506
2507 # If gcc/ is not in the source tree then we'll not be building a
2508 # target compiler, assume in that case we don't want to build any
2509 # target libraries or tools.
2510 #
2511 # This was added primarily for the benefit for binutils-gdb who reuse
2512 # this configure script, but don't always have target tools available.
2513 if test ! -d ${srcdir}/gcc; then
2514    skipdirs="${skipdirs} ${target_configdirs}"
2515 fi
2516
2517 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2518 # $build_configdirs and $target_configdirs.
2519 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2520
2521 notsupp=""
2522 for dir in . $skipdirs $noconfigdirs ; do
2523   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2524   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2525     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2526     if test -r $srcdir/$dirname/configure ; then
2527       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2528         true
2529       else
2530         notsupp="$notsupp $dir"
2531       fi
2532     fi
2533   fi
2534   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2535     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2536     if test -r $srcdir/$dirname/configure ; then
2537       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2538         true
2539       else
2540         notsupp="$notsupp $dir"
2541       fi
2542     fi
2543   fi
2544   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2545     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2546     if test -r $srcdir/$dirname/configure ; then
2547       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2548         true
2549       else
2550         notsupp="$notsupp $dir"
2551       fi
2552     fi
2553   fi
2554 done
2555
2556 # Quietly strip out all directories which aren't configurable in this tree.
2557 # This relies on all configurable subdirectories being autoconfiscated, which
2558 # is now the case.
2559 build_configdirs_all="$build_configdirs"
2560 build_configdirs=
2561 for i in ${build_configdirs_all} ; do
2562   j=`echo $i | sed -e s/build-//g`
2563   if test -f ${srcdir}/$j/configure ; then
2564     build_configdirs="${build_configdirs} $i"
2565   fi
2566 done
2567
2568 configdirs_all="$configdirs"
2569 configdirs=
2570 for i in ${configdirs_all} ; do
2571   if test -f ${srcdir}/$i/configure ; then
2572     configdirs="${configdirs} $i"
2573   fi
2574 done
2575
2576 target_configdirs_all="$target_configdirs"
2577 target_configdirs=
2578 for i in ${target_configdirs_all} ; do
2579   j=`echo $i | sed -e s/target-//g`
2580   if test -f ${srcdir}/$j/configure ; then
2581     target_configdirs="${target_configdirs} $i"
2582   fi
2583 done
2584
2585 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2586 # so we have to add it after the preceding checks.
2587 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2588 then
2589   case " $configdirs " in
2590     *" libiberty "*)
2591       # If we can build libiberty, we can also build libiberty-linker-plugin.
2592       configdirs="$configdirs libiberty-linker-plugin"
2593       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2594         --with-libiberty=../libiberty-linker-plugin";;
2595     *)
2596       AC_MSG_ERROR([libiberty missing]);;
2597   esac
2598 fi
2599
2600 # Sometimes we have special requirements for the host libiberty.
2601 extra_host_libiberty_configure_flags=
2602 case " $configdirs " in
2603   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2604     # When these are to be built as shared libraries, the same applies to
2605     # libiberty.
2606     extra_host_libiberty_configure_flags=--enable-shared
2607     ;;
2608 esac
2609 AC_SUBST(extra_host_libiberty_configure_flags)
2610
2611 # Sometimes we have special requirements for the host zlib.
2612 extra_host_zlib_configure_flags=
2613 case " $configdirs " in
2614   *" bfd "*)
2615     # When bfd is to be built as a shared library, the same applies to
2616     # zlib.
2617     if test "$enable_shared" = "yes"; then
2618       extra_host_zlib_configure_flags=--enable-host-shared
2619     fi
2620     ;;
2621 esac
2622 AC_SUBST(extra_host_zlib_configure_flags)
2623
2624 # Produce a warning message for the subdirs we can't configure.
2625 # This isn't especially interesting in the Cygnus tree, but in the individual
2626 # FSF releases, it's important to let people know when their machine isn't
2627 # supported by the one or two programs in a package.
2628
2629 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2630   # If $appdirs is non-empty, at least one of those directories must still
2631   # be configured, or we error out.  (E.g., if the gas release supports a
2632   # specified target in some subdirs but not the gas subdir, we shouldn't
2633   # pretend that all is well.)
2634   if test -n "$appdirs" ; then
2635     for dir in $appdirs ; do
2636       if test -r $dir/Makefile.in ; then
2637         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2638           appdirs=""
2639           break
2640         fi
2641         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2642           appdirs=""
2643           break
2644         fi
2645       fi
2646     done
2647     if test -n "$appdirs" ; then
2648       echo "*** This configuration is not supported by this package." 1>&2
2649       exit 1
2650     fi
2651   fi
2652   # Okay, some application will build, or we don't care to check.  Still
2653   # notify of subdirs not getting built.
2654   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2655   echo "    ${notsupp}" 1>&2
2656   echo "    (Any other directories should still work fine.)" 1>&2
2657 fi
2658
2659 case "$host" in
2660   *msdosdjgpp*)
2661     enable_gdbtk=no ;;
2662 esac
2663
2664 # To find our prefix, in gcc_cv_tool_prefix.
2665 ACX_TOOL_DIRS
2666
2667 copy_dirs=
2668
2669 AC_ARG_WITH([build-sysroot],
2670   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2671                   [use sysroot as the system root during the build])],
2672   [if test x"$withval" != x ; then
2673      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2674    fi],
2675   [SYSROOT_CFLAGS_FOR_TARGET=])
2676 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2677
2678 AC_ARG_WITH([debug-prefix-map],
2679   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2680                   [map A to B, C to D ... in debug information])],
2681   [if test x"$withval" != x; then
2682      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2683      for debug_map in $withval; do
2684        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2685      done
2686    fi],
2687   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2688 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2689
2690 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2691 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2692 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2693 # We want to ensure that TARGET libraries (which we know are built with
2694 # gcc) are built with "-O2 -g", so include those options when setting
2695 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2696 if test "x$CFLAGS_FOR_TARGET" = x; then
2697   if test "x${is_cross_compiler}" = xyes; then
2698     CFLAGS_FOR_TARGET="-g -O2"
2699   else
2700     CFLAGS_FOR_TARGET=$CFLAGS
2701     case " $CFLAGS " in
2702       *" -O2 "*) ;;
2703       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2704     esac
2705     case " $CFLAGS " in
2706       *" -g "* | *" -g3 "*) ;;
2707       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2708     esac
2709   fi
2710 fi
2711 AC_SUBST(CFLAGS_FOR_TARGET)
2712
2713 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2714   if test "x${is_cross_compiler}" = xyes; then
2715     CXXFLAGS_FOR_TARGET="-g -O2"
2716   else
2717     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2718     case " $CXXFLAGS " in
2719       *" -O2 "*) ;;
2720       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2721     esac
2722     case " $CXXFLAGS " in
2723       *" -g "* | *" -g3 "*) ;;
2724       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2725     esac
2726   fi
2727 fi
2728 AC_SUBST(CXXFLAGS_FOR_TARGET)
2729
2730 AC_SUBST(LDFLAGS_FOR_TARGET)
2731
2732 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2733 # the named directory are copied to $(tooldir)/sys-include.
2734 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2735   if test x${is_cross_compiler} = xno ; then
2736     echo 1>&2 '***' --with-headers is only supported when cross compiling
2737     exit 1
2738   fi
2739   if test x"${with_headers}" != xyes ; then
2740     x=${gcc_cv_tool_prefix}
2741     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2742   fi
2743 fi
2744
2745 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2746 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2747 # are permitted.
2748 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2749   if test x${is_cross_compiler} = xno ; then
2750     echo 1>&2 '***' --with-libs is only supported when cross compiling
2751     exit 1
2752   fi
2753   if test x"${with_libs}" != xyes ; then
2754     # Copy the libraries in reverse order, so that files in the first named
2755     # library override files in subsequent libraries.
2756     x=${gcc_cv_tool_prefix}
2757     for l in ${with_libs}; do
2758       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2759     done
2760   fi
2761 fi
2762
2763 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2764 #
2765 # This is done by determining whether or not the appropriate directory
2766 # is available, and by checking whether or not specific configurations
2767 # have requested that this magic not happen.
2768 #
2769 # The command line options always override the explicit settings in
2770 # configure.ac, and the settings in configure.ac override this magic.
2771 #
2772 # If the default for a toolchain is to use GNU as and ld, and you don't
2773 # want to do that, then you should use the --without-gnu-as and
2774 # --without-gnu-ld options for the configure script.  Similarly, if
2775 # the default is to use the included zlib and you don't want to do that,
2776 # you should use the --with-system-zlib option for the configure script.
2777
2778 if test x${use_gnu_as} = x &&
2779    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2780   with_gnu_as=yes
2781   extra_host_args="$extra_host_args --with-gnu-as"
2782 fi
2783
2784 if test x${use_gnu_ld} = x &&
2785    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2786   with_gnu_ld=yes
2787   extra_host_args="$extra_host_args --with-gnu-ld"
2788 fi
2789
2790 if test x${use_included_zlib} = x &&
2791    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2792   :
2793 else
2794   with_system_zlib=yes
2795   extra_host_args="$extra_host_args --with-system-zlib"
2796 fi
2797
2798 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2799 # can detect this case.
2800
2801 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2802   with_newlib=yes
2803   extra_host_args="$extra_host_args --with-newlib"
2804 fi
2805
2806 # Handle ${copy_dirs}
2807 set fnord ${copy_dirs}
2808 shift
2809 while test $# != 0 ; do
2810   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2811     :
2812   else
2813     echo Copying $1 to $2
2814
2815     # Use the install script to create the directory and all required
2816     # parent directories.
2817     if test -d $2 ; then
2818       :
2819     else
2820       echo >config.temp
2821       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2822     fi
2823
2824     # Copy the directory, assuming we have tar.
2825     # FIXME: Should we use B in the second tar?  Not all systems support it.
2826     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2827
2828     # It is the responsibility of the user to correctly adjust all
2829     # symlinks.  If somebody can figure out how to handle them correctly
2830     # here, feel free to add the code.
2831
2832     echo $1 > $2/COPIED
2833   fi
2834   shift; shift
2835 done
2836
2837 # Determine a target-dependent exec_prefix that the installed
2838 # gcc will search in.  Keep this list sorted by triplet, with
2839 # the *-*-osname triplets last.
2840 md_exec_prefix=
2841 case "${target}" in
2842   i[[34567]]86-pc-msdosdjgpp*)
2843     md_exec_prefix=/dev/env/DJDIR/bin
2844     ;;
2845   *-*-hpux* | \
2846   *-*-nto-qnx* | \
2847   *-*-solaris2*)
2848     md_exec_prefix=/usr/ccs/bin
2849     ;;
2850 esac
2851
2852 extra_arflags_for_target=
2853 extra_nmflags_for_target=
2854 extra_ranlibflags_for_target=
2855 target_makefile_frag=/dev/null
2856 case "${target}" in
2857   spu-*-*)
2858     target_makefile_frag="config/mt-spu"
2859     ;;
2860   loongarch*-*linux* | loongarch*-*gnu*)
2861     target_makefile_frag="config/mt-loongarch-gnu"
2862     ;;
2863   loongarch*-*elf*)
2864     target_makefile_frag="config/mt-loongarch-elf"
2865     ;;
2866   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2867     target_makefile_frag="config/mt-sde"
2868     ;;
2869   mipsisa*-*-elfoabi*)
2870     target_makefile_frag="config/mt-mips-elfoabi"
2871     ;;
2872   mips*-*-*linux* | mips*-*-gnu*)
2873     target_makefile_frag="config/mt-mips-gnu"
2874     ;;
2875   nios2-*-elf*)
2876     target_makefile_frag="config/mt-nios2-elf"
2877     ;;
2878   *-*-linux-android*)
2879     target_makefile_frag="config/mt-android"
2880     ;;
2881   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2882     target_makefile_frag="config/mt-gnu"
2883     ;;
2884   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2885     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2886     # commands to handle both 32-bit and 64-bit objects.  These flags are
2887     # harmless if we're using GNU nm or ar.
2888     extra_arflags_for_target=" -X32_64"
2889     extra_nmflags_for_target=" -B -X32_64"
2890     ;;
2891 esac
2892
2893 alphaieee_frag=/dev/null
2894 case $target in
2895   alpha*-*-*)
2896     # This just makes sure to use the -mieee option to build target libs.
2897     # This should probably be set individually by each library.
2898     alphaieee_frag="config/mt-alphaieee"
2899     ;;
2900 esac
2901
2902 # If --enable-target-optspace always use -Os instead of -O2 to build
2903 # the target libraries, similarly if it is not specified, use -Os
2904 # on selected platforms.
2905 ospace_frag=/dev/null
2906 case "${enable_target_optspace}:${target}" in
2907   yes:*)
2908     ospace_frag="config/mt-ospace"
2909     ;;
2910   :d30v-*)
2911     ospace_frag="config/mt-d30v"
2912     ;;
2913   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2914     ospace_frag="config/mt-ospace"
2915     ;;
2916   no:* | :*)
2917     ;;
2918   *)
2919     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2920     ;;
2921 esac
2922
2923 # Some systems (e.g., one of the i386-aix systems the gas testers are
2924 # using) don't handle "\$" correctly, so don't use it here.
2925 tooldir='${exec_prefix}'/${target_noncanonical}
2926 build_tooldir=${tooldir}
2927
2928 # Create a .gdbinit file which runs the one in srcdir
2929 # and tells GDB to look there for source files.
2930
2931 if test -r ${srcdir}/.gdbinit ; then
2932   case ${srcdir} in
2933     .) ;;
2934     *) cat > ./.gdbinit <<EOF
2935 # ${NO_EDIT}
2936 dir ${srcdir}
2937 dir .
2938 source ${srcdir}/.gdbinit
2939 EOF
2940     ;;
2941   esac
2942 fi
2943
2944 # Make sure that the compiler is able to generate an executable.  If it
2945 # can't, we are probably in trouble.  We don't care whether we can run the
2946 # executable--we might be using a cross compiler--we only care whether it
2947 # can be created.  At this point the main configure script has set CC.
2948 we_are_ok=no
2949 echo "int main () { return 0; }" > conftest.c
2950 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2951 if test $? = 0 ; then
2952   if test -s conftest || test -s conftest.exe ; then
2953     we_are_ok=yes
2954   fi
2955 fi
2956 case $we_are_ok in
2957   no)
2958     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2959     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2960     rm -f conftest*
2961     exit 1
2962     ;;
2963 esac
2964 rm -f conftest*
2965
2966 # Decide which environment variable is used to find dynamic libraries.
2967 case "${host}" in
2968   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2969   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2970   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2971   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2972 esac
2973
2974 # On systems where the dynamic library environment variable is PATH,
2975 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2976 # built executables to PATH.
2977 if test "$RPATH_ENVVAR" = PATH; then
2978   GCC_SHLIB_SUBDIR=/shlib
2979 else
2980   GCC_SHLIB_SUBDIR=
2981 fi
2982
2983 # Adjust the toplevel makefile according to whether bootstrap was selected.
2984 case $enable_bootstrap in
2985   yes)
2986     bootstrap_suffix=bootstrap
2987     BUILD_CONFIG=bootstrap-debug
2988     ;;
2989   no)
2990     bootstrap_suffix=no-bootstrap
2991     BUILD_CONFIG=
2992     ;;
2993 esac
2994
2995 AC_MSG_CHECKING(for default BUILD_CONFIG)
2996
2997 AC_ARG_WITH([build-config],
2998   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2999                   [use config/NAME.mk build configuration])],
3000   [case $with_build_config in
3001    yes) with_build_config= ;;
3002    no) with_build_config= BUILD_CONFIG= ;;
3003    esac])
3004
3005 if test "x${with_build_config}" != x; then
3006   BUILD_CONFIG=$with_build_config
3007 else
3008   case $BUILD_CONFIG in
3009   bootstrap-debug)
3010     if echo "int f (void) { return 0; }" > conftest.c &&
3011        ${CC} -c conftest.c &&
3012        mv conftest.o conftest.o.g0 &&
3013        ${CC} -c -g conftest.c &&
3014        mv conftest.o conftest.o.g &&
3015        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
3016       :
3017     else
3018       BUILD_CONFIG=
3019     fi
3020     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
3021     ;;
3022   esac
3023 fi
3024 AC_MSG_RESULT($BUILD_CONFIG)
3025 AC_SUBST(BUILD_CONFIG)
3026
3027 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
3028 AC_MSG_CHECKING([for --enable-vtable-verify])
3029 AC_ARG_ENABLE(vtable-verify,
3030 [AS_HELP_STRING([--enable-vtable-verify],
3031                 [Enable vtable verification feature])],
3032 [case "$enableval" in
3033  yes) enable_vtable_verify=yes ;;
3034  no)  enable_vtable_verify=no ;;
3035  *)   enable_vtable_verify=no;;
3036  esac],
3037 [enable_vtable_verify=no])
3038 AC_MSG_RESULT($enable_vtable_verify)
3039
3040 # Record target_configdirs and the configure arguments for target and
3041 # build configuration in Makefile.
3042 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
3043 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
3044 bootstrap_fixincludes=no
3045
3046 # If we are building libgomp, bootstrap it.
3047 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
3048   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
3049 fi
3050
3051 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
3052 # or bootstrap-ubsan, bootstrap it.
3053 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
3054   case "$BUILD_CONFIG" in
3055     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
3056       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
3057       bootstrap_fixincludes=yes
3058       ;;
3059   esac
3060 fi
3061
3062 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
3063 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
3064    test "$enable_vtable_verify" != no; then
3065   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
3066 fi
3067
3068 # If we are building libatomic and the list of enabled languages includes the
3069 # D frontend, bootstrap it.
3070 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
3071   case ,${enable_languages}, in
3072     *,d,*)
3073       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
3074       ;;
3075   esac
3076 fi
3077
3078 # Determine whether gdb needs tk/tcl or not.
3079 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
3080 # and in that case we want gdb to be built without tk.  Ugh!
3081 # In fact I believe gdb is the *only* package directly dependent on tk,
3082 # so we should be able to put the 'maybe's in unconditionally and
3083 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
3084 # 100% sure that that's safe though.
3085
3086 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
3087 case "$enable_gdbtk" in
3088   no)
3089     GDB_TK="" ;;
3090   yes)
3091     GDB_TK="${gdb_tk}" ;;
3092   *)
3093     # Only add the dependency on gdbtk when GDBtk is part of the gdb
3094     # distro.  Eventually someone will fix this and move Insight, nee
3095     # gdbtk to a separate directory.
3096     if test -d ${srcdir}/gdb/gdbtk ; then
3097       GDB_TK="${gdb_tk}"
3098     else
3099       GDB_TK=""
3100     fi
3101     ;;
3102 esac
3103 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
3104 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
3105
3106 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
3107 # else does, only include them if one of these is built.  The Makefile
3108 # provides the ordering, so it's enough here to add to the list.
3109 case " ${configdirs} " in
3110   *\ gdb\ *)
3111     configdirs="${configdirs} gnulib gdbsupport"
3112     ;;
3113   *\ gdbserver\ *)
3114     configdirs="${configdirs} gnulib gdbsupport"
3115     ;;
3116   *\ sim\ *)
3117     configdirs="${configdirs} gnulib"
3118     ;;
3119 esac
3120
3121 # Strip out unwanted targets.
3122
3123 # While at that, we remove Makefiles if we were started for recursive
3124 # configuration, so that the top-level Makefile reconfigures them,
3125 # like we used to do when configure itself was recursive.
3126
3127 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3128 # but now we're fixing up the Makefile ourselves with the additional
3129 # commands passed to AC_CONFIG_FILES.  Use separate variables
3130 # extrasub-{build,host,target} not because there is any reason to split
3131 # the substitutions up that way, but only to remain below the limit of
3132 # 99 commands in a script, for HP-UX sed.
3133
3134 # Do not nest @if/@endif or @unless/@endunless pairs, because
3135 # configure will not warn you at all.
3136
3137 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3138   yes:yes:*\ gold\ *:*,c++,*) ;;
3139   yes:yes:*\ gold\ *:*)
3140     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3141     ;;
3142 esac
3143
3144 extrasub_build=
3145 for module in ${build_configdirs} ; do
3146   if test -z "${no_recursion}" \
3147      && test -f ${build_subdir}/${module}/Makefile; then
3148     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3149     rm -f ${build_subdir}/${module}/Makefile
3150   fi
3151   extrasub_build="$extrasub_build
3152 /^@if build-$module\$/d
3153 /^@endif build-$module\$/d
3154 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3155 /^@if build-$module-$bootstrap_suffix\$/d
3156 /^@endif build-$module-$bootstrap_suffix\$/d
3157 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3158 done
3159 extrasub_host=
3160 for module in ${configdirs} ; do
3161   if test -z "${no_recursion}"; then
3162     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3163       if test -f ${file}; then
3164         echo 1>&2 "*** removing ${file} to force reconfigure"
3165         rm -f ${file}
3166       fi
3167     done
3168   fi
3169   case ${module},${bootstrap_fixincludes} in
3170     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3171     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3172   esac
3173   extrasub_host="$extrasub_host
3174 /^@if $module\$/d
3175 /^@endif $module\$/d
3176 /^@unless $module\$/,/^@endunless $module\$/d
3177 /^@if $module-$host_bootstrap_suffix\$/d
3178 /^@endif $module-$host_bootstrap_suffix\$/d
3179 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3180 done
3181 extrasub_target=
3182 for module in ${target_configdirs} ; do
3183   if test -z "${no_recursion}" \
3184      && test -f ${target_subdir}/${module}/Makefile; then
3185     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3186     rm -f ${target_subdir}/${module}/Makefile
3187   fi
3188
3189   # We only bootstrap target libraries listed in bootstrap_target_libs.
3190   case $bootstrap_target_libs in
3191     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3192     *) target_bootstrap_suffix=no-bootstrap ;;
3193   esac
3194
3195   extrasub_target="$extrasub_target
3196 /^@if target-$module\$/d
3197 /^@endif target-$module\$/d
3198 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3199 /^@if target-$module-$target_bootstrap_suffix\$/d
3200 /^@endif target-$module-$target_bootstrap_suffix\$/d
3201 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3202 done
3203
3204 # Do the final fixup along with target modules.
3205 extrasub_target="$extrasub_target
3206 /^@if /,/^@endif /d
3207 /^@unless /d
3208 /^@endunless /d"
3209
3210 if test "$enable_pgo_build" != "no"; then
3211   extrasub_build="$extrasub_build
3212 /^@if pgo-build\$/d
3213 /^@endif pgo-build\$/d"
3214 fi
3215
3216 # Create the serialization dependencies.  This uses a temporary file.
3217
3218 AC_ARG_ENABLE([serial-configure],
3219 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3220                 [force sequential configuration of
3221                  sub-packages for the host, target or build
3222                  machine, or all sub-packages])])
3223
3224 case ${enable_serial_configure} in
3225   yes)
3226     enable_serial_build_configure=yes
3227     enable_serial_host_configure=yes
3228     enable_serial_target_configure=yes
3229     ;;
3230 esac
3231
3232 # These force 'configure's to be done one at a time, to avoid problems
3233 # with contention over a shared config.cache.
3234 rm -f serdep.tmp
3235 if test "x${enable_serial_build_configure}" = xyes || test "x${enable_serial_host_configure}" = xyes || test "x${enable_serial_target_configure}" = xyes; then
3236 echo '# serdep.tmp' > serdep.tmp
3237 fi
3238 olditem=
3239 test "x${enable_serial_build_configure}" = xyes &&
3240 for item in ${build_configdirs} ; do
3241   case ${olditem} in
3242     "") ;;
3243     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3244   esac
3245   olditem=${item}
3246 done
3247 olditem=
3248 test "x${enable_serial_host_configure}" = xyes &&
3249 for item in ${configdirs} ; do
3250   case ${olditem} in
3251     "") ;;
3252     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3253   esac
3254   olditem=${item}
3255 done
3256 olditem=
3257 test "x${enable_serial_target_configure}" = xyes &&
3258 for item in ${target_configdirs} ; do
3259   case ${olditem} in
3260     "") ;;
3261     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3262   esac
3263   olditem=${item}
3264 done
3265 serialization_dependencies=serdep.tmp
3266 AC_SUBST_FILE(serialization_dependencies)
3267
3268 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3269 # target, nonopt, and variable assignments.  These are the ones we
3270 # might not want to pass down to subconfigures.  The exception being
3271 # --cache-file=/dev/null, which is used to turn off the use of cache
3272 # files altogether, and which should be passed on to subconfigures.
3273 # Also strip program-prefix, program-suffix, and program-transform-name,
3274 # so that we can pass down a consistent program-transform-name.
3275 hbaseargs=
3276 bbaseargs=
3277 tbaseargs=
3278 keep_next=no
3279 skip_next=no
3280 eval "set -- $ac_configure_args"
3281 for ac_arg
3282 do
3283   if test X"$skip_next" = X"yes"; then
3284     skip_next=no
3285     continue
3286   fi
3287   if test X"$keep_next" = X"yes"; then
3288     case $ac_arg in
3289       *\'*)
3290         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3291     esac
3292     hbaseargs="$hbaseargs '$ac_arg'"
3293     bbaseargs="$bbaseargs '$ac_arg'"
3294     tbaseargs="$tbaseargs '$ac_arg'"
3295     keep_next=no
3296     continue
3297   fi
3298
3299   # Handle separated arguments.  Based on the logic generated by
3300   # autoconf 2.59.
3301   case $ac_arg in
3302     *=* | --config-cache | -C | -disable-* | --disable-* \
3303       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3304       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3305       | -with-* | --with-* | -without-* | --without-* | --x)
3306       separate_arg=no
3307       ;;
3308     -*)
3309       separate_arg=yes
3310       ;;
3311     *)
3312       separate_arg=no
3313       ;;
3314   esac
3315
3316   skip_targ=no
3317   skip_barg=no
3318   case $ac_arg in
3319 changequote(,)
3320   --with-* | --without-*)
3321     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3322
3323     case $libopt in
3324     *[-_]include)
3325       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3326       ;;
3327     *[-_]lib)
3328       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3329       ;;
3330     *[-_]prefix)
3331       lib=`echo "$libopt" | sed 's,[-_]prefix$,,'`
3332       ;;
3333     *[-_]type)
3334       lib=`echo "$libopt" | sed 's,[-_]type$,,'`
3335       ;;
3336     *)
3337       lib=$libopt
3338       ;;
3339     esac
3340 changequote([,])
3341
3342     case $lib in
3343     mpc | mpfr | gmp | isl)
3344       # If we're processing --with-$lib, --with-$lib-include or
3345       # --with-$lib-lib, for one of the libs above, and target is
3346       # different from host, don't pass the current argument to any
3347       # target library's configure.
3348       if test x$is_cross_compiler = xyes; then
3349         skip_targ=yes
3350       fi
3351       ;;
3352     libintl | libiconv)
3353       # We don't want libintl (and co.) in anything but the host arguments.
3354       skip_targ=yes
3355       skip_barg=yes
3356       ;;
3357     esac
3358     ;;
3359   esac
3360
3361   case "$ac_arg" in
3362     --cache-file=/dev/null | \
3363     -cache-file=/dev/null )
3364       # Handled here to avoid the test to skip args below.
3365       hbaseargs="$hbaseargs '$ac_arg'"
3366       bbaseargs="$bbaseargs '$ac_arg'"
3367       tbaseargs="$tbaseargs '$ac_arg'"
3368       # Assert: $separate_arg should always be no.
3369       keep_next=$separate_arg
3370       ;;
3371     --no*)
3372       continue
3373       ;;
3374     --c* | \
3375     --sr* | \
3376     --ho* | \
3377     --bu* | \
3378     --t* | \
3379     --program-* | \
3380     -cache_file* | \
3381     -srcdir* | \
3382     -host* | \
3383     -build* | \
3384     -target* | \
3385     -program-prefix* | \
3386     -program-suffix* | \
3387     -program-transform-name* )
3388       skip_next=$separate_arg
3389       continue
3390       ;;
3391     -*)
3392       # An option.  Add it.
3393       case $ac_arg in
3394         *\'*)
3395           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3396       esac
3397       hbaseargs="$hbaseargs '$ac_arg'"
3398       if test X"$skip_barg" = Xno; then
3399         bbaseargs="$bbaseargs '$ac_arg'"
3400       fi
3401       if test X"$skip_targ" = Xno; then
3402         tbaseargs="$tbaseargs '$ac_arg'"
3403       fi
3404       keep_next=$separate_arg
3405       ;;
3406     *)
3407       # Either a variable assignment, or a nonopt (triplet).  Don't
3408       # pass it down; let the Makefile handle this.
3409       continue
3410       ;;
3411   esac
3412 done
3413 # Remove the initial space we just introduced and, as these will be
3414 # expanded by make, quote '$'.
3415 hbaseargs=`echo "x$hbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3416 bbaseargs=`echo "x$bbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3417
3418 # Add in --program-transform-name, after --program-prefix and
3419 # --program-suffix have been applied to it.  Autoconf has already
3420 # doubled dollar signs and backslashes in program_transform_name; we want
3421 # the backslashes un-doubled, and then the entire thing wrapped in single
3422 # quotes, because this will be expanded first by make and then by the shell.
3423 # Also, because we want to override the logic in subdir configure scripts to
3424 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3425 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3426 ${program_transform_name}
3427 EOF_SED
3428 gcc_transform_name=`cat conftestsed.out`
3429 rm -f conftestsed.out
3430 hbaseargs="$hbaseargs --program-transform-name='${gcc_transform_name}'"
3431 bbaseargs="$bbaseargs --program-transform-name='${gcc_transform_name}'"
3432 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3433 if test "$silent" = yes; then
3434   bbaseargs="$bbaseargs --silent"
3435   hbaseargs="$hbaseargs --silent"
3436   tbaseargs="$tbaseargs --silent"
3437 fi
3438
3439 bbaseargs="$bbaseargs --disable-option-checking"
3440 hbaseargs="$hbaseargs --disable-option-checking"
3441 tbaseargs="$tbaseargs --disable-option-checking"
3442
3443 if test "$enable_year2038" = no; then
3444   bbaseargs="$bbaseargs --disable-year2038"
3445   hbaseargs="$hbaseargs --disable-year2038"
3446   tbaseargs="$tbaseargs --disable-year2038"
3447 fi
3448
3449 # Record and document user additions to sub configure arguments.
3450 AC_ARG_VAR([build_configargs],
3451            [additional configure arguments for build directories])
3452 AC_ARG_VAR([host_configargs],
3453            [additional configure arguments for host directories])
3454 AC_ARG_VAR([target_configargs],
3455            [additional configure arguments for target directories])
3456
3457 # For the build-side libraries, we just need to pretend we're native,
3458 # and not use the same cache file.  Multilibs are neither needed nor
3459 # desired.  We can't even use the same cache file for all build-side
3460 # libraries, as they're compiled differently; some with C, some with
3461 # C++ or with different feature-enabling options.
3462 build_configargs="$build_configargs --cache-file=./config.cache ${bbaseargs}"
3463
3464 # For host modules, accept cache file option, or specification as blank.
3465 case "${cache_file}" in
3466 "") # empty
3467   cache_file_option="" ;;
3468 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3469   cache_file_option="--cache-file=${cache_file}" ;;
3470 *) # relative path
3471   cache_file_option="--cache-file=../${cache_file}" ;;
3472 esac
3473
3474 # Host dirs don't like to share a cache file either, horribly enough.
3475 # This seems to be due to autoconf 2.5x stupidity.
3476 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${hbaseargs}"
3477
3478 target_configargs="$target_configargs ${tbaseargs}"
3479
3480 # Passing a --with-cross-host argument lets the target libraries know
3481 # whether they are being built with a cross-compiler or being built
3482 # native.  However, it would be better to use other mechanisms to make the
3483 # sorts of decisions they want to make on this basis.  Please consider
3484 # this option to be deprecated.  FIXME.
3485 if test x${is_cross_compiler} = xyes ; then
3486   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3487 fi
3488
3489 # Special user-friendly check for native x86_64-linux build, if
3490 # multilib is not explicitly enabled.
3491 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3492   x86_64-*linux*:yes:$build:$build:)
3493     # Make sure we have a development environment that handles 32-bit
3494     dev64=no
3495     echo "int main () { return 0; }" > conftest.c
3496     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3497     if test $? = 0 ; then
3498       if test -s conftest || test -s conftest.exe ; then
3499         dev64=yes
3500       fi
3501     fi
3502     rm -f conftest*
3503     if test x${dev64} != xyes ; then
3504       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3505     fi
3506     ;;
3507 esac
3508
3509 # Default to --enable-multilib.
3510 if test x${enable_multilib} = x ; then
3511   target_configargs="--enable-multilib ${target_configargs}"
3512 fi
3513
3514 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3515 # changed from the earlier setting of with_newlib.
3516 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3517   target_configargs="--with-newlib ${target_configargs}"
3518 fi
3519
3520 # Different target subdirs use different values of certain variables
3521 # (notably CXX).  Worse, multilibs use *lots* of different values.
3522 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3523 # it doesn't automatically accept command-line overrides of them.
3524 # This means it's not safe for target subdirs to share a cache file,
3525 # which is disgusting, but there you have it.  Hopefully this can be
3526 # fixed in future.  It's still worthwhile to use a cache file for each
3527 # directory.  I think.
3528
3529 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3530 # We need to pass --target, as newer autoconf's requires consistency
3531 # for target_alias and gcc doesn't manage it consistently.
3532 target_configargs="--cache-file=./config.cache ${target_configargs}"
3533
3534 FLAGS_FOR_TARGET=
3535 case " $target_configdirs " in
3536  *" newlib "*)
3537   case " $target_configargs " in
3538   *" --with-newlib "*)
3539    case "$target" in
3540     *-cygwin*)
3541       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3542       ;;
3543    esac
3544
3545    # If we're not building GCC, don't discard standard headers.
3546    if test -d ${srcdir}/gcc; then
3547      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3548
3549      if test "${build}" != "${host}"; then
3550        # On Canadian crosses, CC_FOR_TARGET will have already been set
3551        # by `configure', so we won't have an opportunity to add -Bgcc/
3552        # to it.  This is right: we don't want to search that directory
3553        # for binaries, but we want the header files in there, so add
3554        # them explicitly.
3555        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3556
3557        # Someone might think of using the pre-installed headers on
3558        # Canadian crosses, in case the installed compiler is not fully
3559        # compatible with the compiler being built.  In this case, it
3560        # would be better to flag an error than risking having
3561        # incompatible object files being constructed.  We can't
3562        # guarantee that an error will be flagged, but let's hope the
3563        # compiler will do it, when presented with incompatible header
3564        # files.
3565      fi
3566    fi
3567
3568    case "${target}-${is_cross_compiler}" in
3569    i[[3456789]]86-*-linux*-no)
3570       # Here host == target, so we don't need to build gcc,
3571       # so we don't want to discard standard headers.
3572       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3573       ;;
3574    *)
3575       # If we're building newlib, use its generic headers last, but search
3576       # for any libc-related directories first (so make it the last -B
3577       # switch).
3578       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3579
3580       # If we're building libgloss, find the startup file, simulator library
3581       # and linker script.
3582       case " $target_configdirs " in
3583         *" libgloss "*)
3584         # Look for startup file, simulator library and maybe linker script.
3585         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3586         # Look for libnosys.a in case the target needs it.
3587         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3588         # Most targets have the linker script in the source directory.
3589         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3590         ;;
3591       esac
3592       ;;
3593    esac
3594    ;;
3595   esac
3596   ;;
3597 esac
3598
3599 case "$target" in
3600   x86_64-*mingw* | *-w64-mingw*)
3601   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3602   # however, use a symlink named 'mingw' in ${prefix} .
3603     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3604     ;;
3605   *-mingw*)
3606   # MinGW can't be handled as Cygwin above since it does not use newlib.
3607     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3608     ;;
3609 esac
3610
3611 # Allow the user to override the flags for
3612 # our build compiler if desired.
3613 if test x"${build}" = x"${host}" ; then
3614   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3615   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3616   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3617   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3618 fi
3619
3620 # On Canadian crosses, we'll be searching the right directories for
3621 # the previously-installed cross compiler, so don't bother to add
3622 # flags for directories within the install tree of the compiler
3623 # being built; programs in there won't even run.
3624 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3625   # Search for pre-installed headers if nothing else fits.
3626   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3627 fi
3628
3629 if test "x${use_gnu_ld}" = x &&
3630    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3631   # Arrange for us to find uninstalled linker scripts.
3632   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3633 fi
3634
3635 # Search for other target-specific linker scripts and such.
3636 case "${target}" in
3637   mep*)
3638     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3639     ;;
3640   # The VxWorks support for shared libraries is getting in
3641   # incrementally.  Make sure it doesn't get activated implicitly:
3642   *vxworks*)
3643     if test "${enable_shared-unset}" = unset ; then
3644       enable_shared=no
3645       # So the build of libraries knows ...
3646       target_configargs="${target_configargs} --disable-shared"
3647       # So gcc knows ...
3648       host_configargs="${host_configargs} --disable-shared"
3649     fi
3650     ;;
3651 esac
3652
3653 # Makefile fragments.
3654 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3655 do
3656   eval fragval=\$$frag
3657   if test $fragval != /dev/null; then
3658     eval $frag=${srcdir}/$fragval
3659   fi
3660 done
3661 AC_SUBST_FILE(host_makefile_frag)
3662 AC_SUBST_FILE(target_makefile_frag)
3663 AC_SUBST_FILE(alphaieee_frag)
3664 AC_SUBST_FILE(ospace_frag)
3665
3666 # Miscellanea: directories, flags, etc.
3667 AC_SUBST(RPATH_ENVVAR)
3668 AC_SUBST(GCC_SHLIB_SUBDIR)
3669 AC_SUBST(tooldir)
3670 AC_SUBST(build_tooldir)
3671 AC_SUBST(CONFIGURE_GDB_TK)
3672 AC_SUBST(GDB_TK)
3673 AC_SUBST(INSTALL_GDB_TK)
3674
3675 # Build module lists & subconfigure args.
3676 AC_SUBST(build_configargs)
3677 AC_SUBST(build_configdirs)
3678
3679 # Host module lists & subconfigure args.
3680 AC_SUBST(host_configargs)
3681 AC_SUBST(configdirs)
3682 AC_SUBST(target_configdirs)
3683
3684 # Target module lists & subconfigure args.
3685 AC_SUBST(target_configargs)
3686
3687
3688 # Build tools.
3689 AC_SUBST(AR_FOR_BUILD)
3690 AC_SUBST(AS_FOR_BUILD)
3691 AC_SUBST(CC_FOR_BUILD)
3692 AC_SUBST(CFLAGS_FOR_BUILD)
3693 AC_SUBST(CPP_FOR_BUILD)
3694 AC_SUBST(CPPFLAGS_FOR_BUILD)
3695 AC_SUBST(CXXFLAGS_FOR_BUILD)
3696 AC_SUBST(CXX_FOR_BUILD)
3697 AC_SUBST(DLLTOOL_FOR_BUILD)
3698 AC_SUBST(DSYMUTIL_FOR_BUILD)
3699 AC_SUBST(GFORTRAN_FOR_BUILD)
3700 AC_SUBST(GOC_FOR_BUILD)
3701 AC_SUBST(GDC_FOR_BUILD)
3702 AC_SUBST(LDFLAGS_FOR_BUILD)
3703 AC_SUBST(LD_FOR_BUILD)
3704 AC_SUBST(NM_FOR_BUILD)
3705 AC_SUBST(RANLIB_FOR_BUILD)
3706 AC_SUBST(WINDMC_FOR_BUILD)
3707 AC_SUBST(WINDRES_FOR_BUILD)
3708
3709 # Generate default definitions for YACC, M4, LEX and other programs that run
3710 # on the build machine.  These are used if the Makefile can't locate these
3711 # programs in objdir.
3712 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3713
3714 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3715 case " $build_configdirs " in
3716   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3717 esac
3718
3719 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3720 case " $build_configdirs " in
3721   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3722 esac
3723
3724 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3725 case " $build_configdirs " in
3726   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3727 esac
3728
3729 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3730 case " $build_configdirs " in
3731   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3732   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3733 esac
3734
3735 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3736 case " $build_configdirs " in
3737   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3738 esac
3739
3740 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3741 case " $build_configdirs " in
3742   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3743   *)
3744 changequote(,)
3745     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3746     # higher, else we use the "missing" dummy.
3747     if ${MAKEINFO} --version \
3748        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3749       :
3750     else
3751       MAKEINFO="$MISSING makeinfo"
3752     fi
3753     ;;
3754 changequote([,])
3755 esac
3756
3757 # FIXME: expect and dejagnu may become build tools?
3758
3759 AC_CHECK_PROGS(EXPECT, expect, expect)
3760 case " $configdirs " in
3761   *" expect "*)
3762     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3763     ;;
3764 esac
3765
3766 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3767 case " $configdirs " in
3768   *" dejagnu "*)
3769     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3770     ;;
3771 esac
3772
3773
3774 # Host tools.
3775 NCN_STRICT_CHECK_TOOLS(AR, ar)
3776 NCN_STRICT_CHECK_TOOLS(AS, as)
3777 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3778 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3779 NCN_STRICT_CHECK_TOOLS(LD, ld)
3780 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3781 NCN_STRICT_CHECK_TOOLS(NM, nm)
3782 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3783 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3784 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3785 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3786 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3787 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3788 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3789 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3790 AC_SUBST(CC)
3791 AC_SUBST(CXX)
3792 AC_SUBST(CFLAGS)
3793 AC_SUBST(CXXFLAGS)
3794 AC_SUBST(GDC)
3795 AC_SUBST(GDCFLAGS)
3796 GDCFLAGS=${GDCFLAGS-${CFLAGS}}
3797 AC_SUBST(PKG_CONFIG_PATH)
3798
3799 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3800 AR_PLUGIN_OPTION=
3801 RANLIB_PLUGIN_OPTION=
3802 if test -n "$PLUGIN_OPTION"; then
3803   if $AR --help 2>&1 | grep -q "\--plugin"; then
3804     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3805   fi
3806   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3807     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3808   fi
3809 fi
3810 AC_SUBST(AR_PLUGIN_OPTION)
3811 AC_SUBST(RANLIB_PLUGIN_OPTION)
3812
3813 # Target tools.
3814 AC_ARG_WITH([build-time-tools],
3815   [AS_HELP_STRING([--with-build-time-tools=PATH],
3816                   [use given path to find target tools during the build])],
3817   [case x"$withval" in
3818      x/*) ;;
3819      *)
3820        with_build_time_tools=
3821        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3822        ;;
3823    esac],
3824   [with_build_time_tools=])
3825
3826 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3827 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3828 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3829 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3830 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3831 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3832 NCN_STRICT_CHECK_TARGET_TOOLS(GM2_FOR_TARGET, gm2)
3833
3834 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3835 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3836 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3837 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3838 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3839 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3840 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3841 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3842 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3843 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3844 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3845 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3846 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3847 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3848 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3849
3850 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3851
3852 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3853 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3854 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3855 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3856 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3857                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3858                 c++)
3859 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3860                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3861                 c++)
3862 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3863 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3864 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3865 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3866                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3867 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3868                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3869 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3870                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3871 GCC_TARGET_TOOL(gm2, GM2_FOR_TARGET, GM2,
3872                 [gcc/gm2 -B$$r/$(HOST_SUBDIR)/gcc/], m2)
3873 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3874 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3875 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3876 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3877 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3878 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3879 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3880 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3881 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3882 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3883 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3884
3885 AC_SUBST(FLAGS_FOR_TARGET)
3886 AC_SUBST(RAW_CXX_FOR_TARGET)
3887
3888 # Certain tools may need extra flags.
3889 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3890 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3891 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3892
3893 # When building target libraries, except in a Canadian cross, we use
3894 # the same toolchain as the compiler we just built.
3895 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3896 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3897 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3898 if test $host = $build; then
3899   case " $configdirs " in
3900     *" gcc "*)
3901       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3902       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3903       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3904       ;;
3905   esac
3906 fi
3907
3908 AC_SUBST(COMPILER_AS_FOR_TARGET)
3909 AC_SUBST(COMPILER_LD_FOR_TARGET)
3910 AC_SUBST(COMPILER_NM_FOR_TARGET)
3911
3912 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3913 AC_ARG_ENABLE(maintainer-mode,
3914 [AS_HELP_STRING([--enable-maintainer-mode],
3915                 [enable make rules and dependencies not useful
3916                  (and sometimes confusing) to the casual installer])],
3917       USE_MAINTAINER_MODE=$enableval,
3918       USE_MAINTAINER_MODE=no)
3919 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3920 AC_SUBST(MAINTAINER_MODE_TRUE)
3921 AC_SUBST(MAINTAINER_MODE_FALSE)
3922 if test "$USE_MAINTAINER_MODE" = yes; then
3923   MAINTAINER_MODE_TRUE=
3924   MAINTAINER_MODE_FALSE='#'
3925 else
3926   MAINTAINER_MODE_TRUE='#'
3927   MAINTAINER_MODE_FALSE=
3928 fi
3929 MAINT=$MAINTAINER_MODE_TRUE
3930 AC_SUBST(MAINT)dnl
3931
3932 # ---------------------
3933 # GCC bootstrap support
3934 # ---------------------
3935
3936 # Stage specific cflags for build.
3937 stage1_cflags="-g"
3938 case $build in
3939   vax-*-*)
3940     case ${GCC} in
3941       yes) stage1_cflags="-g -Wa,-J" ;;
3942       *) stage1_cflags="-g -J" ;;
3943     esac ;;
3944 esac
3945
3946 AC_SUBST(stage1_cflags)
3947
3948 # Enable --enable-checking in stage1 of the compiler.
3949 AC_ARG_ENABLE(stage1-checking,
3950 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3951                 [choose additional checking for stage1 of the compiler])],
3952 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3953 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3954   # For --disable-checking or implicit --enable-checking=release, avoid
3955   # setting --enable-checking=gc in the default stage1 checking for LTO
3956   # bootstraps.  See PR62077.
3957   case $BUILD_CONFIG in
3958     *lto*)
3959       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3960     *)
3961       stage1_checking=--enable-checking=yes,types;;
3962   esac
3963   if test "x$enable_checking" = x && \
3964      test -d ${srcdir}/gcc && \
3965      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3966     stage1_checking=--enable-checking=yes,types,extra
3967   fi
3968 else
3969   stage1_checking=--enable-checking=$enable_checking,types
3970 fi])
3971 AC_SUBST(stage1_checking)
3972
3973 # Enable -Werror in bootstrap stage2 and later.
3974 AC_ARG_ENABLE(werror,
3975 [AS_HELP_STRING([--enable-werror],
3976                 [enable -Werror in bootstrap stage2 and later])],
3977 [
3978 case ${enable_werror} in
3979   yes) stage2_werror_flag="--enable-werror-always" ;;
3980   *) stage2_werror_flag="" ;;
3981 esac
3982 ],
3983 [
3984 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3985   case $BUILD_CONFIG in
3986   bootstrap-debug)
3987       stage2_werror_flag="--enable-werror-always" ;;
3988   "")
3989       stage2_werror_flag="--enable-werror-always" ;;
3990   esac
3991 fi
3992 ])
3993
3994 AC_SUBST(stage2_werror_flag)
3995
3996 # Specify what files to not compare during bootstrap.
3997
3998 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3999 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/M2Version*"
4000 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/SYSTEM*"
4001 compare_exclusions="$compare_exclusions | gcc/m2/gm2version*"
4002 case "$target" in
4003   hppa*64*-*-hpux*) ;;
4004   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
4005 esac
4006 AC_SUBST(compare_exclusions)
4007
4008 AC_CONFIG_FILES([Makefile],
4009   [sed "$extrasub_build" Makefile |
4010    sed "$extrasub_host" |
4011    sed "$extrasub_target" > mf$$
4012    mv -f mf$$ Makefile],
4013   [extrasub_build="$extrasub_build"
4014    extrasub_host="$extrasub_host"
4015    extrasub_target="$extrasub_target"])
4016 AC_OUTPUT