sim/m4/sim_ac_option_profile.m4

   1 dnl Copyright (C) 1997-2024 Free Software Foundation, Inc.
   2 dnl
   3 dnl This program is free software; you can redistribute it and/or modify
   4 dnl it under the terms of the GNU General Public License as published by
   5 dnl the Free Software Foundation; either version 3 of the License, or
   6 dnl (at your option) any later version.
   7 dnl
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 dnl GNU General Public License for more details.
  12 dnl
  13 dnl You should have received a copy of the GNU General Public License
  14 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15 dnl
  16 dnl --enable-sim-profile
  17 dnl The argument is either a bitmask of things to enable [exactly what is
  18 dnl up to the simulator], or is a comma separated list of names of profiling
  19 dnl elements to enable.  The latter is only supported on simulators that
  20 dnl use WITH_PROFILE.
  21 AC_DEFUN([SIM_AC_OPTION_PROFILE],
  22 [dnl
  23 AC_MSG_CHECKING([for sim profile settings])
  24 profile="1"
  25 sim_profile="-1"
  26 AC_ARG_ENABLE(sim-profile,
  27 [AS_HELP_STRING([--enable-sim-profile=opts], [Enable profiling flags])],
  28 [case "${enableval}" in
  29   yes)  profile="1" sim_profile="-1";;
  30   no)   profile="0" sim_profile="0";;
  31   [[-0-9]]*)
  32         profile="(${enableval})" sim_profile="(${enableval})";;
  33   [[a-z]]*)
  34     profile="1"
  35         sim_profile=""
  36         for x in `echo "$enableval" | sed -e "s/,/ /g"`; do
  37           if test x"$sim_profile" = x; then
  38             sim_profile="(PROFILE_$x"
  39           else
  40             sim_profile="${sim_profile}|PROFILE_$x"
  41           fi
  42         done
  43         sim_profile="$sim_profile)" ;;
  44 esac])dnl
  45 AC_DEFINE_UNQUOTED([PROFILE], [$profile], [Sim profile settings])
  46 AC_DEFINE_UNQUOTED([WITH_PROFILE], [$sim_profile], [Sim profile settings])
  47 AC_MSG_RESULT($sim_profile)
  48 ])