gdb/testsuite/gdb.base/print-file-var.exp

   1 # Copyright 2012-2023 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  15
  16 if {[skip_shlib_tests]} {
  17     return -1
  18 }
  19
  20 proc test {hidden dlopen version_id_main lang} {
  21     global srcdir subdir
  22
  23     set main "print-file-var-main"
  24
  25     set suffix "-hidden$hidden-dlopen$dlopen-version_id_main$version_id_main"
  26
  27     # Normally we place different builds (C/C++) of a test into
  28     # subdirectories within the test build directory, however, using
  29     # gdb_load_shlib doesn't work well with this approach, so instead
  30     # add a language specific suffix to the binary and library names.
  31     if { $lang == "c" } {
  32         set suffix "${suffix}_c"
  33     } else {
  34         set suffix "${suffix}_cpp"
  35     }
  36
  37     set executable $main$suffix
  38
  39     set lib1 "print-file-var-lib1"
  40     set lib2 "print-file-var-lib2"
  41
  42     set libobj1 [standard_output_file ${lib1}$suffix.so]
  43     set libobj2 [standard_output_file ${lib2}$suffix.so]
  44
  45     set lib_opts { debug $lang }
  46     lappend lib_opts "additional_flags=-DHIDDEN=$hidden"
  47
  48     if { [gdb_compile_shlib ${srcdir}/${subdir}/${lib1}.c \
  49               ${libobj1} \
  50               ${lib_opts} ] != "" } {
  51         return -1
  52     }
  53     if { [gdb_compile_shlib ${srcdir}/${subdir}/${lib2}.c \
  54               ${libobj2} \
  55               ${lib_opts} ] != "" } {
  56         return -1
  57     }
  58
  59     set main_opts [list debug $lang]
  60     set link_opts [list debug shlib=${libobj1}]
  61
  62     set target_libobj2 [gdb_download_shlib $libobj2]
  63
  64     if {$dlopen} {
  65         lappend main_opts "additional_flags=-DSHLIB_NAME=\"$target_libobj2\""
  66         lappend link_opts "shlib_load"
  67     } else {
  68         lappend link_opts "shlib=${libobj2}"
  69     }
  70
  71     lappend main_opts "additional_flags=-DVERSION_ID_MAIN=$version_id_main"
  72
  73     if { [build_executable_from_specs ${main} \
  74               $executable \
  75               $link_opts \
  76               ${main}.c \
  77               $main_opts]
  78          != 0 } {
  79         return -1
  80     }
  81
  82     clean_restart $executable
  83     gdb_load_shlib $libobj1
  84     gdb_locate_shlib $libobj2
  85
  86     if ![runto_main] {
  87         return -1
  88     }
  89
  90     # Try printing "this_version_num" qualified with the name of the file
  91     # where the variables are defined.  There are three global variables
  92     # with that name, and some systems such as GNU/Linux merge them
  93     # into one single entity, while some other systems such as Windows
  94     # keep them separate.  In the first situation, we have to verify
  95     # that GDB does not randomly select the wrong instance, even when
  96     # a specific filename is used to qualified the lookup.  And in the
  97     # second case, we have to verify that GDB does select the instance
  98     # defined in the given filename.
  99     #
 100     # To avoid adding target-specific code in this testcase, the program
 101     # sets three local variables named 'vm', 'v1' and 'v2' with the value of
 102     # our global variables.  This allows us to compare the value that
 103     # GDB returns for each query against the actual value seen by
 104     # the program itself.
 105
 106     # Get past the initialization of the v* variables.
 107
 108     set bp_location \
 109         [gdb_get_line_number "STOP" "${main}.c"]
 110     gdb_test "break $main.c:$bp_location" \
 111         "Breakpoint \[0-9\]+ at 0x\[0-9a-fA-F\]+: .*" \
 112         "breakpoint at STOP marker"
 113
 114     gdb_test "continue" \
 115         "Breakpoint \[0-9\]+, main \\(\\) at.*STOP.*" \
 116         "continue to STOP marker"
 117
 118     # Now check the value of this_version_id in all of
 119     # print-file-var-main.c, print-file-var-lib1.c and
 120     # print-file-var-lib2.c.
 121
 122     # Compare the values of $sym1 and $sym2.
 123     proc compare {sym1 sym2} {
 124         with_test_prefix "sym1=$sym1,sym2=$sym2" {
 125             # Done this way instead of comparing the symbols with "print $sym1
 126             # == sym2" in GDB directly so that the values of the symbols end
 127             # up visible in the logs, for debug purposes.
 128             set vsym1 [get_integer_valueof $sym1 -1]
 129             set vsym2 [get_integer_valueof $sym2 -1]
 130             gdb_assert {$vsym1 == $vsym2} "$sym1 == $sym2"
 131         }
 132     }
 133
 134     if $version_id_main {
 135         compare "'print-file-var-main.c'::this_version_id" "vm"
 136         compare "this_version_id" "vm"
 137     }
 138
 139     compare "'print-file-var-lib1.c'::this_version_id" "v1"
 140     compare "'print-file-var-lib2.c'::this_version_id" "v2"
 141 }
 142
 143 # Only test C++ if we are able.  Always use C.
 144 if { [skip_cplus_tests] } {
 145     set lang_list {c}
 146 } else {
 147     set lang_list {c c++}
 148 }
 149
 150 foreach_with_prefix lang $lang_list {
 151     foreach_with_prefix hidden {0 1} {
 152         foreach_with_prefix dlopen {0 1} {
 153             foreach_with_prefix version_id_main {0 1} {
 154                 test $hidden $dlopen $version_id_main $lang
 155             }
 156         }
 157     }
 158 }