gdb/testsuite/gdb.base/print-symbol-loading.exp

   1 # Copyright 2012-2023 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Test the "print symbol-loading" option.
  17
  18 if {[skip_shlib_tests]} {
  19     return 0
  20 }
  21
  22 standard_testfile print-symbol-loading-main.c
  23 set libfile print-symbol-loading-lib
  24 set srcfile_lib ${libfile}.c
  25 set binfile_lib [standard_output_file ${libfile}.so]
  26 set gcorefile ${binfile}.gcore
  27 set objfile [standard_output_file ${testfile}.o]
  28
  29 if { [gdb_compile_shlib ${srcdir}/${subdir}/${srcfile_lib} ${binfile_lib} {debug}] != ""
  30      || [gdb_compile ${srcdir}/${subdir}/${srcfile} ${objfile} object {debug}] != "" } {
  31     untested "failed to compile"
  32     return -1
  33 }
  34 set opts [list debug shlib=${binfile_lib}]
  35 if { [gdb_compile ${objfile} ${binfile} executable $opts] != "" } {
  36     untested "failed to compile"
  37     return -1
  38 }
  39
  40 clean_restart ${binfile}
  41 gdb_load_shlib ${binfile_lib}
  42
  43 if ![runto lib] {
  44     return -1
  45 }
  46
  47 if {![gdb_gcore_cmd $gcorefile "save a corefile"]} {
  48     return -1
  49 }
  50
  51 proc test_load_core { print_symbol_loading } {
  52     global binfile binfile_lib gcorefile srcdir subdir
  53     with_test_prefix "core ${print_symbol_loading}" {
  54         gdb_exit
  55         gdb_start
  56         gdb_reinitialize_dir $srcdir/$subdir
  57         gdb_test_no_output "set print symbol-loading $print_symbol_loading"
  58         if { ${print_symbol_loading} != "off" } {
  59             gdb_test "file $binfile" "Reading symbols from.*" "file"
  60         } else {
  61             gdb_test_no_output "file $binfile" "file"
  62         }
  63         # Rename the shared lib so gdb can't find it.
  64         remote_exec host "mv -f ${binfile_lib} ${binfile_lib}.save"
  65         gdb_test "core ${gcorefile}" "Core was generated by .*" \
  66             "re-load generated corefile"
  67         # Now put it back and use "set solib-search-path" to trigger
  68         # loading of symbols.
  69         remote_exec host "mv -f ${binfile_lib}.save ${binfile_lib}"
  70         set test_name "load shared-lib"
  71         switch "${print_symbol_loading}" {
  72             "off" {
  73                 gdb_test_no_output "set solib-search-path [file dirname ${binfile_lib}]" \
  74                     ${test_name}
  75             }
  76             "brief" {
  77                 gdb_test "set solib-search-path [file dirname ${binfile_lib}]" \
  78                     "Loading symbols for shared libraries\\." \
  79                     ${test_name}
  80             }
  81             "full" {
  82                 gdb_test "set solib-search-path [file dirname ${binfile_lib}]" \
  83                     "Reading symbols from.*" \
  84                     ${test_name}
  85             }
  86         }
  87         gdb_test "frame" "#0 \[^\r\n\]* lib .*" "library got loaded"
  88     }
  89 }
  90
  91 test_load_core off
  92 test_load_core brief
  93 test_load_core full
  94
  95 # Now test the sharedlibrary command.
  96
  97 proc test_load_shlib { print_symbol_loading } {
  98     global binfile
  99     global gdb_prompt
 100     with_test_prefix "shlib ${print_symbol_loading}" {
 101         clean_restart ${binfile}
 102         gdb_test_no_output "set auto-solib-add off"
 103         if ![runto_main] {
 104             return -1
 105         }
 106         gdb_test_no_output "set print symbol-loading $print_symbol_loading"
 107         set test_name "load shared-lib"
 108         set libc_re \
 109             [multi_line \
 110                  "Symbols already loaded for\[^\r\n\]*\\/libc\\.\[^\r\n\]*(" \
 111                  "Symbols already loaded for\[^\r\n\]*\\/libpthread\\.\[^\r\n\]*)?"]
 112         switch ${print_symbol_loading} {
 113             "off" {
 114                 set cmd "sharedlibrary .*"
 115                 set cmd_regex [string_to_regexp $cmd]
 116                 gdb_test_multiple $cmd $test_name {
 117                     -re "^$cmd_regex\r\n$gdb_prompt $" {
 118                         pass $test_name
 119                     }
 120                     -re "^$cmd_regex\r\n$libc_re\r\n$gdb_prompt $" {
 121                         pass $test_name
 122                     }
 123                 }
 124             }
 125             "brief" {
 126                 gdb_test "sharedlibrary .*" \
 127                     "Loading symbols for shared libraries: \\.\\*.*?(?:Symbols already loaded for .*?libc)?" \
 128                     ${test_name}
 129             }
 130             "full" {
 131                 gdb_test "sharedlibrary .*" \
 132                     "Reading symbols from.*" \
 133                     ${test_name}
 134             }
 135         }
 136         gdb_breakpoint "lib"
 137         gdb_continue_to_breakpoint "lib"
 138         gdb_test "frame" "#0 \[^\r\n\]* lib .*" "library got loaded"
 139     }
 140 }
 141
 142 test_load_shlib off
 143 test_load_shlib brief
 144 test_load_shlib full