gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2023 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 m4_include([../bfd/version.m4])
  24 AC_INIT([gas], BFD_VERSION)
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32
  33 AM_INIT_AUTOMAKE
  34 AM_SILENT_RULES([yes])
  35
  36 AC_PROG_CC
  37 AC_GNU_SOURCE
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 LT_INIT
  41 ACX_LARGEFILE
  42 ACX_PROG_CMP_IGNORE_INITIAL
  43
  44 AC_ARG_ENABLE(targets,
  45 [  --enable-targets        alternative target configurations besides the primary],
  46 [case "${enableval}" in
  47   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  48             ;;
  49   no)       enable_targets= ;;
  50   *)        enable_targets=$enableval ;;
  51 esac])dnl
  52
  53 ac_checking=
  54 . ${srcdir}/../bfd/development.sh
  55 test "$development" = true && ac_checking=yes
  56 AC_ARG_ENABLE(checking,
  57 [  --enable-checking       enable run-time checks],
  58 [case "${enableval}" in
  59   no|none)  ac_checking= ;;
  60   *)        ac_checking=yes ;;
  61 esac])dnl
  62 if test x$ac_checking != x ; then
  63   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  64 fi
  65
  66 # PR gas/19109
  67 # Decide the default method for compressing debug sections.
  68 ac_default_compressed_debug_sections=unset
  69 # Provide a configure time option to override our default.
  70 AC_ARG_ENABLE(compressed_debug_sections,
  71               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  72               [compress debug sections by default]),
  73 [case ,"${enableval}", in
  74   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  75   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  76   *)   ac_default_compressed_debug_sections=unset ;;
  77 esac])dnl
  78
  79 # Select default compression algorithm.
  80 ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_GABI_ZLIB
  81 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
  82               AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
  83               [Default compression algorithm for --enable-compressed-debug-sections.]),
  84 [case "${enableval}" in
  85    zstd) ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_ZSTD ;;
  86 esac])dnl
  87
  88 # PR gas/19520
  89 # Decide if x86 assembler should generate relax relocations.
  90 ac_default_x86_relax_relocations=unset
  91 # Provide a configure time option to override our default.
  92 AC_ARG_ENABLE(x86_relax_relocations,
  93               AS_HELP_STRING([--enable-x86-relax-relocations],
  94               [generate x86 relax relocations by default]),
  95 [case "${enableval}" in
  96   no)  ac_default_x86_relax_relocations=0 ;;
  97 esac])dnl
  98
  99 # Decide if ELF assembler should generate common symbols with the
 100 # STT_COMMON type.
 101 ac_default_elf_stt_common=unset
 102 # Provide a configure time option to override our default.
 103 AC_ARG_ENABLE(elf_stt_common,
 104               AS_HELP_STRING([--enable-elf-stt-common],
 105               [generate ELF common symbols with STT_COMMON type by default]),
 106 [case "${enableval}" in
 107   yes)  ac_default_elf_stt_common=1 ;;
 108 esac])dnl
 109
 110
 111 # Decide if the ELF assembler should default to generating
 112 # GNU Build notes if none are provided by the input.
 113 ac_default_generate_build_notes=0
 114 # Provide a configuration option to override the default.
 115 AC_ARG_ENABLE(generate_build_notes,
 116               AS_HELP_STRING([--enable-generate-build-notes],
 117               [generate GNU Build notes if none are provided by the input]),
 118 [case "${enableval}" in
 119   yes)  ac_default_generate_build_notes=1 ;;
 120   no)   ac_default_generate_build_notes=0 ;;
 121 esac])dnl
 122
 123 # Decide if the MIPS assembler should default to enable MIPS fix Loongson3
 124 # LLSC errata.
 125 ac_default_mips_fix_loongson3_llsc=unset
 126 # Provide a configuration option to override the default.
 127 AC_ARG_ENABLE(mips-fix-loongson3-llsc,
 128              AS_HELP_STRING([--enable-mips-fix-loongson3-llsc],
 129              [enable MIPS fix Loongson3 LLSC errata]),
 130 [case "${enableval}" in
 131   yes)  ac_default_mips_fix_loongson3_llsc=1 ;;
 132   no)   ac_default_mips_fix_loongson3_llsc=0 ;;
 133 esac])dnl
 134
 135 # Decide if the x86 ELF assembler should default to generating GNU x86
 136 # used ISA and feature properties.
 137 ac_default_generate_x86_used_note=unset
 138 # Provide a configuration option to override the default.
 139 AC_ARG_ENABLE(x86-used-note,
 140               AS_HELP_STRING([--enable-x86-used-note],
 141               [generate GNU x86 used ISA and feature properties]),
 142 [case "${enableval}" in
 143   yes)  ac_default_generate_x86_used_note=1 ;;
 144   no)   ac_default_generate_x86_used_note=0 ;;
 145 esac])dnl
 146
 147 # Decide if the RISC-V ELF assembler should default to generating attribute.
 148 ac_default_generate_riscv_attr=unset
 149 # Provide a configuration option to override the default.
 150 AC_ARG_ENABLE(default-riscv-attribute,
 151               AS_HELP_STRING([--enable-default-riscv-attribute],
 152               [generate RISC-V arch attribute by default]),
 153 [case "${enableval}" in
 154   yes)  ac_default_generate_riscv_attr=1 ;;
 155   no)   ac_default_generate_riscv_attr=0 ;;
 156 esac])dnl
 157
 158 using_cgen=no
 159
 160 AM_BINUTILS_WARNINGS
 161
 162 # Generate a header file
 163 AC_CONFIG_HEADERS(config.h:config.in)
 164
 165 dnl Option --with-cpu=TYPE allows configure type control of the default
 166 dnl cpu type within the assembler.  Currently only the ARC target
 167 dnl supports this feature, but others may be added in the future.
 168 AC_ARG_WITH(cpu,
 169             AS_HELP_STRING([--with-cpu=CPU],
 170             [default cpu variant is CPU (currently only supported on ARC)]),
 171             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 172                                 "${with_cpu}",
 173                                 [Target specific CPU.])],
 174             [])
 175
 176 # PR 14072
 177 AH_VERBATIM([00_CONFIG_H_CHECK],
 178 [/* Check that config.h is #included before system headers
 179    (this works only for glibc, but that should be enough).  */
 180 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 181 #  error config.h must be #included before system headers
 182 #endif
 183 #define __CONFIG_H__ 1])
 184
 185 # If we are on a DOS filesystem, we must use gdb.ini rather than
 186 # .gdbinit.
 187 case "${host}" in
 188   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 189     GDBINIT="gdb.ini"
 190     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 191     ;;
 192   *)
 193     GDBINIT=".gdbinit"
 194     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 195     ;;
 196 esac
 197 AC_SUBST(GDBINIT)
 198
 199 #We need this for the host.
 200 AC_C_BIGENDIAN
 201
 202 te_file=generic
 203
 204 # Makefile target for installing gas in $(tooldir)/bin.
 205 install_tooldir=install-exec-tooldir
 206
 207 canon_targets=""
 208 all_targets=no
 209 if test -n "$enable_targets" ; then
 210   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 211     if test $t = "all"; then
 212       all_targets=yes
 213       continue
 214     fi
 215     result=`$ac_config_sub $t 2>/dev/null`
 216     if test -n "$result" ; then
 217       canon_targets="$canon_targets $result"
 218 #    else
 219 #      # Permit "all", etc.  We don't support it yet though.
 220 #      canon_targets="$canon_targets $t"
 221     fi
 222   done
 223   GAS_UNIQ(canon_targets)
 224 fi
 225
 226 emulations=""
 227
 228 for this_target in $target $canon_targets ; do
 229
 230     targ=${this_target}
 231     . ${srcdir}/configure.tgt
 232
 233     case ${target_cpu} in
 234       crisv32)
 235         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 236                            [Default CRIS architecture.])
 237         ;;
 238     esac
 239
 240     if test ${this_target} = $target ; then
 241       target_cpu_type=${cpu_type}
 242     elif test ${target_cpu_type} != ${cpu_type} ; then
 243       continue
 244     fi
 245
 246     generic_target=${cpu_type}-${target_vendor}-${target_os}
 247     case ${generic_target} in
 248       i386-*-msdosdjgpp* \
 249       | i386-*-go32*)
 250         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 251         ;;
 252
 253       i386-*-linux-* | x86_64-*-linux-*)
 254         if test ${this_target} = $target \
 255            && test ${ac_default_generate_x86_used_note} = unset; then
 256           ac_default_generate_x86_used_note=1
 257         fi
 258         ;;
 259
 260       i386-*-solaris2 \
 261       | x86_64-*-solaris2 \
 262       | i386-*-solaris2.[[0-9]] \
 263       | i386-*-solaris2.1[[01]] \
 264       | x86_64-*-solaris2.1[[01]])
 265         if test ${this_target} = $target \
 266            && test ${ac_default_x86_relax_relocations} = unset; then
 267           ac_default_x86_relax_relocations=0
 268         fi
 269         ;;
 270
 271       microblaze*)
 272         ;;
 273
 274 changequote(,)dnl
 275       ppc-*-aix[5-9].*)
 276 changequote([,])dnl
 277         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 278                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 279         ;;
 280       ppc-*-solaris*)
 281         if test ${this_target} = $target; then
 282           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 283                     [Define if default target is PowerPC Solaris.])
 284         fi
 285         if test x${endian} = xbig; then
 286           AC_MSG_ERROR(Solaris must be configured little endian)
 287         fi
 288         ;;
 289     esac
 290
 291     if test ${this_target} = $target ; then
 292       endian_def=
 293       if test x${endian} = xbig; then
 294         endian_def=1
 295       elif test x${endian} = xlittle; then
 296         endian_def=0
 297       fi
 298       if test x${endian_def} != x; then
 299         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 300                            [Define as 1 if big endian.])
 301       fi
 302     fi
 303
 304 # Other random stuff.
 305
 306     case ${cpu_type} in
 307       mips)
 308         # Set mips_cpu to the name of the default CPU.
 309         case ${target_cpu} in
 310           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 311             mips_cpu=from-abi
 312             ;;
 313           mipsisa32 | mipsisa32el)
 314             mips_cpu=mips32
 315             ;;
 316           mipsisa32r2 | mipsisa32r2el)
 317             mips_cpu=mips32r2
 318             ;;
 319           mipsisa32r3 | mipsisa32r3el)
 320             mips_cpu=mips32r3
 321             ;;
 322           mipsisa32r5 | mipsisa32r5el)
 323             mips_cpu=mips32r5
 324             ;;
 325           mipsisa32r6 | mipsisa32r6el)
 326             mips_cpu=mips32r6
 327             ;;
 328           mipsisa64 | mipsisa64el)
 329             mips_cpu=mips64
 330             ;;
 331           mipsisa64r2 | mipsisa64r2el)
 332             mips_cpu=mips64r2
 333             ;;
 334           mipsisa64r3 | mipsisa64r3el)
 335             mips_cpu=mips64r3
 336             ;;
 337           mipsisa64r5 | mipsisa64r5el)
 338             mips_cpu=mips64r5
 339             ;;
 340           mipsisa64r6 | mipsisa64r6el)
 341             mips_cpu=mips64r6
 342             ;;
 343           mipstx39 | mipstx39el)
 344             mips_cpu=r3900
 345             ;;
 346           mips64vr | mips64vrel)
 347             mips_cpu=vr4100
 348             ;;
 349           mipsisa32r2* | mipsisa64r2*)
 350 changequote(,)dnl
 351             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 352 changequote([,])dnl
 353             ;;
 354           mipsisa32r6* | mipsisa64r6*)
 355 changequote(,)dnl
 356             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 357 changequote([,])dnl
 358             ;;
 359           mips64* | mipsisa64* | mipsisa32*)
 360 changequote(,)dnl
 361             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 362 changequote([,])dnl
 363             ;;
 364           mips*)
 365 changequote(,)dnl
 366             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 367 changequote([,])dnl
 368             ;;
 369           *)
 370             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 371             ;;
 372         esac
 373         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 374         # binaries.  It's a GNU extension that some OSes don't understand.
 375         case ${target} in
 376           *-*-irix*)
 377             use_e_mips_abi_o32=0
 378             ;;
 379           *)
 380             use_e_mips_abi_o32=1
 381             ;;
 382         esac
 383         # Decide whether to generate 32-bit or 64-bit code by default.
 384         # Used to resolve -march=from-abi when an embedded ABI is selected.
 385         case ${target} in
 386           mips64*-*-* | mipsisa64*-*-*)
 387             mips_default_64bit=1
 388             ;;
 389           *)
 390             mips_default_64bit=0
 391             ;;
 392         esac
 393         # Decide which ABI to target by default.
 394         case ${target} in
 395           mips64*-openbsd* | mips64*-linux-gnuabi64)
 396             mips_default_abi=N64_ABI
 397             ;;
 398           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 399           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 400             mips_default_abi=N32_ABI
 401             ;;
 402           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 403             mips_default_abi=O32_ABI
 404             ;;
 405           *)
 406             mips_default_abi=NO_ABI
 407             ;;
 408         esac
 409         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 410                            [Default CPU for MIPS targets. ])
 411         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 412                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 413         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 414                            [Generate 64-bit code by default on MIPS targets. ])
 415         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 416                            [Choose a default ABI for MIPS targets. ])
 417         ;;
 418     esac
 419
 420     # Do we need the opcodes library?
 421     case ${cpu_type} in
 422       vax | tic30 | i386 | arm)
 423         ;;
 424
 425       *)
 426         need_opcodes=yes
 427
 428         case "${enable_shared}" in
 429         yes) shared_opcodes=true ;;
 430         *opcodes*) shared_opcodes=true ;;
 431         *) shared_opcodes=false ;;
 432         esac
 433         ;;
 434     esac
 435
 436     # Any other special object files needed ?
 437     case ${cpu_type} in
 438
 439       bfin)
 440         for f in config/bfin-parse.o config/bfin-lex-wrapper.o; do
 441           case " $extra_objects " in
 442             *" $f "*) ;;
 443             *) extra_objects="$extra_objects $f" ;;
 444           esac
 445         done
 446         ;;
 447
 448       bpf)
 449         if test $this_target = $target ; then
 450           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 451         fi
 452         using_cgen=yes
 453         ;;
 454       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 455         using_cgen=yes
 456         ;;
 457
 458       loongarch)
 459         for f in config/loongarch-parse.o config/loongarch-lex-wrapper.o; do
 460           case " $extra_objects " in
 461             *" $f "*) ;;
 462             *) extra_objects="$extra_objects $f" ;;
 463           esac
 464         done
 465         # --target=loongarch[32|64]-*-*.  */
 466         if test $this_target = $target ; then
 467           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 468         fi
 469         ;;
 470
 471       m32c)
 472         using_cgen=yes
 473         ;;
 474       frv)
 475         using_cgen=yes
 476         ;;
 477       m68k)
 478         f=config/m68k-parse.o
 479         case " $extra_objects " in
 480           *" $f "*) ;;
 481           *) extra_objects="$extra_objects $f" ;;
 482         esac
 483         ;;
 484
 485       mep)
 486         using_cgen=yes
 487         ;;
 488
 489       mips)
 490         for f in itbl-parse.o itbl-lex-wrapper.o itbl-ops.o; do
 491           case " $extra_objects " in
 492             *" $f "*) ;;
 493             *) extra_objects="$extra_objects $f" ;;
 494           esac
 495         done
 496         ;;
 497
 498       mt)
 499         using_cgen=yes
 500         ;;
 501
 502       nds32)
 503         # setup NDS32_LINUX_TOOLCHAIN definition
 504         if test "linux" = $em; then
 505           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 1,
 506             [Define value for nds32_linux_toolchain])
 507         else
 508           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 0,
 509             [Define default value for nds32_linux_toolchain])
 510         fi
 511
 512         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 513         # based on arch_name.
 514         AC_MSG_CHECKING(for default configuration of --with-arch)
 515         if test "x${with_arch}" != x; then
 516           case ${with_arch} in
 517             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 518               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 519                                  [Define value for nds32_arch_name])
 520               ;;
 521             *)
 522               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 523               ;;
 524           esac
 525         fi
 526         AC_MSG_RESULT($with_arch)
 527
 528         # Decide features one by one.
 529         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 530         if test "x${enable_dx_regs}" = xyes; then
 531           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 532                     [Define value for nds32_dx_regs])
 533         else
 534           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 535                     [Define default value for nds32_dx_regs])
 536         fi
 537         AC_MSG_RESULT($enable_dx_regs)
 538
 539         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 540         if test "x${enable_perf_ext}" = xno; then
 541           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 542                     [Define value for nds32_perf_ext])
 543         else
 544           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 545                     [Define default value for nds32_perf_ext])
 546         fi
 547         AC_MSG_RESULT($enable_perf_ext)
 548
 549         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 550         if test "x${enable_perf_ext2}" = xno; then
 551           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 552                     [Define value for nds32_perf_ext2])
 553         else
 554           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 555                     [Define default value for nds32_perf_ext2])
 556         fi
 557         AC_MSG_RESULT($enable_perf_ext2)
 558
 559         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 560         if test "x${enable_string_ext}" = xno; then
 561           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 562                     [Define value for nds32_string_ext])
 563         else
 564           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 565                     [Define default value for nds32_string_ext])
 566         fi
 567         AC_MSG_RESULT($enable_string_ext)
 568
 569         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 570         if test "x${enable_audio_ext}" = xno; then
 571           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 572                     [Define value for nds32_audio_ext])
 573         else
 574           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 575                     [Define default value for nds32_audio_ext])
 576         fi
 577         AC_MSG_RESULT($enable_audio_ext)
 578
 579         AC_MSG_CHECKING(for default configuration of --enable-dsp-ext)
 580         if test "x${enable_dsp_ext}" = xno; then
 581           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 0,
 582                     [Define value for nds32_dsp_ext])
 583         else
 584           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 1,
 585                     [Define default value for nds32_dsp_ext])
 586         fi
 587         AC_MSG_RESULT($enable_dsp_ext)
 588
 589         AC_MSG_CHECKING(for default configuration of --enable-zol-ext)
 590         if test "x${enable_zol_ext}" = xno; then
 591           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 0,
 592                     [Define value for nds32_zol_ext])
 593         else
 594           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 1,
 595                     [Define default value for nds32_zol_ext])
 596         fi
 597         AC_MSG_RESULT($enable_zol_ext)
 598         ;;
 599
 600       aarch64 | i386 | s390 | sparc)
 601         if test $this_target = $target ; then
 602           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 603         fi
 604         ;;
 605
 606       riscv)
 607         # --target=riscv[32|64]-*-*.  */
 608         if test $this_target = $target ; then
 609           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 610         fi
 611
 612         # --with-arch=<value>.  The syntax of <value> is same as Gas option -march.
 613         AC_MSG_CHECKING(for default configuration of --with-arch)
 614         if test "x${with_arch}" != x; then
 615         AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ARCH_WITH_EXT, "$with_arch",
 616                            [Define default value for RISC-V -march.])
 617         fi
 618         AC_MSG_RESULT($with_arch)
 619
 620         # --with-isa-spec=[2.2|20190608|20191213].
 621         AC_MSG_CHECKING(for default configuration of --with-isa-spec)
 622         if test "x${with_isa_spec}" != x; then
 623           AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ISA_SPEC, "$with_isa_spec",
 624                              [Define default value for RISC-V -misa-spec.])
 625         fi
 626         AC_MSG_RESULT($with_isa_spec)
 627
 628         # --with-priv-spec=[1.9.1|1.10|1.11|1.12].
 629         AC_MSG_CHECKING(for default configuration of --with-priv-spec)
 630         if test "x${with_priv_spec}" != x; then
 631           AC_DEFINE_UNQUOTED(DEFAULT_RISCV_PRIV_SPEC, "$with_priv_spec",
 632                              [Define default value for RISC-V -mpriv-spec])
 633         fi
 634         AC_MSG_RESULT($with_priv_spec)
 635         ;;
 636
 637       rl78)
 638         f=config/rl78-parse.o
 639         case " $extra_objects " in
 640           *" $f "*) ;;
 641           *) extra_objects="$extra_objects $f" ;;
 642         esac
 643         ;;
 644
 645       rx)
 646         f=config/rx-parse.o
 647         case " $extra_objects " in
 648           *" $f "*) ;;
 649           *) extra_objects="$extra_objects $f" ;;
 650         esac
 651         ;;
 652
 653       xstormy16)
 654         using_cgen=yes
 655         ;;
 656
 657       xtensa)
 658         f=config/xtensa-relax.o
 659         case " $extra_objects " in
 660           *" $f "*) ;;
 661           *) extra_objects="$extra_objects $f" ;;
 662         esac
 663         ;;
 664
 665       *)
 666         ;;
 667     esac
 668
 669     if test $using_cgen = yes ; then
 670         f=cgen.o
 671         case " $extra_objects " in
 672           *" $f "*) ;;
 673           *) extra_objects="$extra_objects $f" ;;
 674         esac
 675     fi
 676
 677 # See if we really can support this configuration with the emulation code.
 678
 679     if test $this_target = $target ; then
 680       obj_format=$fmt
 681       te_file=$em
 682     fi
 683
 684     case ${te_file} in
 685       vms)
 686         f=config/te-vms.o
 687         case " $extra_objects " in
 688           *" $f "*) ;;
 689           *) extra_objects="$extra_objects $f" ;;
 690         esac ;;
 691     esac
 692
 693 # From target name and format, produce a list of supported emulations.
 694
 695     case ${generic_target}-${fmt} in
 696       mips-*-*-*)       case "$endian" in
 697                         big)    emulation="mipsbelf mipslelf mipself" ;;
 698                         *)      emulation="mipslelf mipsbelf mipself" ;;
 699                         esac ;;
 700       # i386-pc-pe-coff != i386-pc-coff.
 701       i386-*-pe-coff)   ;;
 702       # Uncommenting the next line will turn on support for i386 AOUT
 703       # for the default linux configuration
 704       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 705       #
 706       i386-*-aout)      emulation="i386aout" ;;
 707       i386-*-coff)      emulation="i386coff" ;;
 708       i386-*-elf)       emulation="i386elf" ;;
 709
 710       # Always all formats.  The first stated emulation becomes the default.
 711       cris-*-*aout*)    emulation="crisaout criself" ;;
 712       cris-*-*)         emulation="criself crisaout" ;;
 713     esac
 714
 715     emulations="$emulations $emulation"
 716
 717 done
 718
 719 if test ${ac_default_x86_relax_relocations} = unset; then
 720   ac_default_x86_relax_relocations=1
 721 fi
 722 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 723   $ac_default_x86_relax_relocations,
 724   [Define to 1 if you want to generate x86 relax relocations by default.])
 725
 726 if test ${ac_default_elf_stt_common} = unset; then
 727   ac_default_elf_stt_common=0
 728 fi
 729 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 730   $ac_default_elf_stt_common,
 731   [Define to 1 if you want to generate ELF common symbols with the
 732    STT_COMMON type by default.])
 733
 734 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_BUILD_NOTES,
 735   $ac_default_generate_build_notes,
 736   [Define to 1 if you want to generate GNU Build attribute notes
 737    by default, if none are contained in the input.])
 738
 739 if test ${ac_default_generate_x86_used_note} = unset; then
 740   ac_default_generate_x86_used_note=0
 741 fi
 742 AC_DEFINE_UNQUOTED(DEFAULT_X86_USED_NOTE,
 743   $ac_default_generate_x86_used_note,
 744   [Define to 1 if you want to generate GNU x86 used ISA and feature
 745    properties by default.])
 746
 747 if test ${ac_default_generate_riscv_attr} = unset; then
 748   ac_default_generate_riscv_attr=1
 749 fi
 750
 751 AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ATTR,
 752   $ac_default_generate_riscv_attr,
 753   [Define to 1 if you want to generate RISC-V arch attribute by default.])
 754
 755 if test ${ac_default_mips_fix_loongson3_llsc} = unset; then
 756   ac_default_mips_fix_loongson3_llsc=0
 757 fi
 758 AC_DEFINE_UNQUOTED(DEFAULT_MIPS_FIX_LOONGSON3_LLSC,
 759   $ac_default_mips_fix_loongson3_llsc,
 760   [Define to 1 if you want to fix Loongson3 LLSC Errata by default.])
 761
 762 if test x$ac_default_compressed_debug_sections = xyes ; then
 763   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 764 fi
 765
 766 AC_DEFINE_UNQUOTED(DEFAULT_COMPRESSED_DEBUG_ALGORITHM, $ac_default_compressed_debug_sections_algorithm,
 767                    [Default compression algorithm for --enable-compressed-debug-sections.])
 768
 769 # Turn on all targets if possible
 770 if test ${all_targets} = "yes"; then
 771   case ${target_cpu_type} in
 772   i386)
 773     case ${obj_format} in
 774     aout)
 775       emulations="$emulations i386coff i386elf"
 776       ;;
 777     coff)
 778       emulations="$emulations i386aout i386elf"
 779     ;;
 780     elf)
 781       emulations="$emulations i386aout i386coff"
 782       ;;
 783     esac
 784   ;;
 785   x86_64)
 786     case ${obj_format} in
 787     aout)
 788       emulations="$emulations i386coff i386elf"
 789       ;;
 790     coff)
 791       emulations="$emulations i386aout i386elf"
 792     ;;
 793     elf)
 794       emulations="$emulations i386aout i386coff"
 795       ;;
 796     esac
 797   ;;
 798   esac
 799 fi
 800
 801 # PE code has way too many macros tweaking behaviour
 802 case ${te_file} in
 803   pe*) emulations="" ;;
 804 esac
 805
 806 # Assign floating point type.  Most processors with FP support
 807 # IEEE FP.  On those that don't support FP at all, usually IEEE
 808 # is emulated.
 809 case ${target_cpu} in
 810   vax | pdp11 ) atof=vax ;;
 811   *)            atof=ieee ;;
 812 esac
 813
 814 case "${obj_format}" in
 815   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 816 esac
 817
 818 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 819 cgen_cpu_prefix=""
 820 if test $using_cgen = yes ; then
 821   case ${target_cpu} in
 822     or1knd)
 823        cgen_cpu_prefix=or1k ;;
 824     *) cgen_cpu_prefix=${target_cpu} ;;
 825   esac
 826   AC_SUBST(cgen_cpu_prefix)
 827   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 828 fi
 829
 830 dnl
 831 dnl Make sure the desired support files exist.
 832 dnl
 833
 834 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 835   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 836 fi
 837
 838 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 839   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 840 fi
 841
 842 # Some COFF configurations want these random other flags set.
 843 case ${obj_format} in
 844   coff)
 845     case ${target_cpu_type} in
 846       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 847       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 848     esac
 849     ;;
 850 esac
 851
 852 # Getting this done right is going to be a bitch.  Each configuration specified
 853 # with --enable-targets=... should be checked for environment, format, cpu
 854 # setting.
 855 #
 856 # For each configuration, the necessary object file support code must be linked
 857 # in.  This might be only one, it might be up to four.  The necessary emulation
 858 # code needs to be provided, too.
 859 #
 860 # And then there's "--enable-targets=all"....
 861 #
 862 # For now, just always do it for MIPS ELF configurations.  Sigh.
 863
 864 formats="${obj_format}"
 865 emfiles=""
 866 EMULATIONS=""
 867 GAS_UNIQ(emulations)
 868 for em in . $emulations ; do
 869   case $em in
 870     .)  continue ;;
 871     mipsbelf | mipslelf | mipself)
 872         fmt=elf   file=mipself ;;
 873     *coff)
 874         fmt=coff  file=$em ;;
 875     *aout)
 876         fmt=aout file=$em ;;
 877     *elf)
 878         fmt=elf file=$em ;;
 879   esac
 880   formats="$formats $fmt"
 881   emfiles="$emfiles config/e-$file.o"
 882   EMULATIONS="$EMULATIONS &$em,"
 883 done
 884 GAS_UNIQ(formats)
 885 GAS_UNIQ(emfiles)
 886 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 887   for fmt in $formats ; do
 888     case $fmt in
 889       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 890       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 891       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 892       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 893       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 894       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 895     esac
 896     extra_objects="$extra_objects config/obj-$fmt.o"
 897   done
 898   obj_format=multi
 899 fi
 900 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 901   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 902   # e-mipself has more than one emulation per file, e-i386* has just one at the
 903   # moment.  If only one emulation is specified, then don't define
 904   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 905   case "${obj_format}${emfiles}" in
 906     multi* | *mipself*)
 907       extra_objects="$extra_objects $emfiles"
 908       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 909   esac
 910 fi
 911 AC_SUBST(extra_objects)
 912 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 913 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 914                    [Default emulation.])
 915
 916 reject_dev_configs=yes
 917
 918 case ${reject_dev_configs}-${dev} in
 919   yes-yes) # Oops.
 920     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 921     ;;
 922 esac
 923
 924 AC_SUBST(target_cpu_type)
 925 AC_SUBST(obj_format)
 926 AC_SUBST(te_file)
 927 AC_SUBST(install_tooldir)
 928 AC_SUBST(atof)
 929 dnl AC_SUBST(emulation)
 930
 931 # do we need the opcodes library?
 932 case "${need_opcodes}" in
 933 yes)
 934   OPCODES_LIB=../opcodes/libopcodes.la
 935   ;;
 936 esac
 937
 938 AC_SUBST(OPCODES_LIB)
 939
 940 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 941 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 942 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 943 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 944 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 945
 946 AC_PROG_YACC
 947 AM_PROG_LEX
 948
 949 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 950 ZW_GNU_GETTEXT_SISTER_DIR
 951 AM_PO_SUBDIRS
 952
 953 AM_MAINTAINER_MODE
 954 AM_CONDITIONAL(GENINSRC_NEVER, false)
 955 AC_EXEEXT
 956
 957 AC_CHECK_HEADERS(memory.h sys/stat.h sys/types.h unistd.h)
 958
 959 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 960 # people who are not cross-compiling but are compiling cross-assemblers.
 961 AC_MSG_CHECKING(whether compiling a cross-assembler)
 962 if test "${host}" = "${target}"; then
 963   cross_gas=no
 964 else
 965   cross_gas=yes
 966   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 967 fi
 968 AC_MSG_RESULT($cross_gas)
 969
 970 AC_CHECK_FUNCS(strsignal)
 971
 972 AM_LC_MESSAGES
 973
 974 # do we need the math library?
 975 case "${need_libm}" in
 976 yes)
 977   LT_LIB_M
 978   AC_SUBST(LIBM)
 979   ;;
 980 esac
 981
 982 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 983 # enough, but on some of those systems, the assert macro relies on requoting
 984 # working properly!
 985 GAS_WORKING_ASSERT
 986
 987 # On some systems, the system header files may not declare malloc, realloc,
 988 # and free.  There are places where gas needs these functions to have been
 989 # declared -- such as when taking their addresses.
 990 gas_test_headers="
 991 #ifdef HAVE_MEMORY_H
 992 #include <memory.h>
 993 #endif
 994 #include <string.h>
 995 #include <stdlib.h>
 996 #ifdef HAVE_UNISTD_H
 997 #include <unistd.h>
 998 #endif
 999 "
1000
1001 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
1002 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
1003 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
1004 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
1005 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
1006 if test $gas_cv_decl_getopt_unistd_h = yes; then
1007   AC_DEFINE([HAVE_DECL_GETOPT], 1,
1008             [Is the prototype for getopt in <unistd.h> in the expected format?])
1009 fi
1010
1011 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1012 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
1013
1014 AC_CHECK_DECLS([asprintf, mempcpy, stpcpy])
1015
1016 BFD_BINARY_FOPEN
1017
1018 # Link in zlib/zstd if we can.  This allows us to write compressed debug sections.
1019 AM_ZLIB
1020 AC_ZSTD
1021
1022 # Support for VMS timestamps via cross compile
1023
1024 if test "$ac_cv_header_time_h" = yes; then
1025   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
1026 fi
1027
1028 if test "$ac_cv_header_sys_stat_h" = yes; then
1029     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
1030     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
1031 fi
1032
1033
1034 dnl Required for html, pdf, install-pdf and install-html targets.
1035 AC_SUBST(datarootdir)
1036 AC_SUBST(docdir)
1037 AC_SUBST(htmldir)
1038 AC_SUBST(pdfdir)
1039
1040 dnl This must come last.
1041
1042 dnl We used to make symlinks to files in the source directory, but now
1043 dnl we just use the right name for .c files, and create .h files in
1044 dnl the build directory which include the right .h file.  Make sure
1045 dnl the old symlinks don't exist, so that a reconfigure in an existing
1046 dnl directory behaves reasonably.
1047
1048 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
1049 AC_CONFIG_COMMANDS([default],
1050 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1051  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1052  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1053  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1054  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1055  if test "x$cgen_cpu_prefix" != x ; then
1056    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1057  fi],
1058 [target_cpu_type=${target_cpu_type}
1059  cgen_cpu_prefix=${cgen_cpu_prefix}
1060  obj_format=${obj_format}
1061  te_file=${te_file}])
1062
1063 AC_OUTPUT
1064
1065 GNU_MAKE_JOBSERVER