gdb/testsuite/gdb.dwarf2/implptr.exp

   1 # Copyright 2010-2021 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15 load_lib dwarf.exp
  16
  17 # Test DW_OP_GNU_implicit_pointer.
  18
  19 # This test can only be run on targets which support DWARF-2 and use gas.
  20 if {![dwarf2_support]} {
  21     return 0
  22 }
  23
  24 standard_testfile .S
  25 set csrcfile ${testfile}.c
  26 set opts {}
  27
  28 if [info exists COMPILE] {
  29     # make check RUNTESTFLAGS='gdb.dwarf2/implptr.exp COMPILE=1 CC_FOR_TARGET=gcc\ -m32'
  30     set srcfile ${csrcfile}
  31     lappend opts debug optimize=-O2
  32 } elseif {![is_x86_like_target]} {
  33     # This test can only be run on x86 targets.
  34     return 0
  35 }
  36
  37 if {[prepare_for_testing "failed to prepare" ${testfile} $srcfile $opts]} {
  38     return -1
  39 }
  40
  41 # Additional test to verify the referenced CU is not aged out.
  42 gdb_test_no_output "maintenance set dwarf max-cache-age 0"
  43
  44 if ![runto_main] {
  45     return -1
  46 }
  47
  48 # Test various pointer depths in bar.
  49 proc implptr_test_bar {} {
  50     global csrcfile
  51     set line [gdb_get_line_number "bar breakpoint" $csrcfile]
  52     gdb_test "break implptr.c:$line" "Breakpoint 2.*" \
  53        "set bar breakpoint for implptr"
  54     gdb_continue_to_breakpoint "continue to bar breakpoint for implptr"
  55     gdb_test "print j" " = \\(intp\\) <synthetic pointer>" "print j in implptr:bar"
  56     gdb_test {print sizeof (j[0])} " = 4" {print sizeof (j[0]) in implptr:bar}
  57     gdb_test "print *j" " = 5" "print *j in implptr:bar"
  58     gdb_test "print **k" " = 5" "print **k in implptr:bar"
  59     gdb_test "print ***l" " = 5" "print ***l in implptr:bar"
  60 }
  61
  62 # Test implicit pointer offset.
  63 proc implptr_test_baz {} {
  64     global csrcfile
  65     set line [gdb_get_line_number "baz breakpoint" $csrcfile]
  66     gdb_test "break implptr.c:$line" "Breakpoint 3.*" \
  67         "set baz breakpoint for implptr"
  68     gdb_continue_to_breakpoint "continue to baz breakpoint for implptr"
  69
  70     # We are breaking in an inlined function.  GDB should appear to
  71     # have stopped "in" the inlined function.
  72     gdb_test "up" "#1  foo .*"
  73     gdb_test {p p[0].y} " = 92" "sanity check element 0"
  74     gdb_test {p p[1].y} " = 46" "sanity check element 1"
  75     gdb_test "down" "#0  add .*"
  76     gdb_test "p a->y" " = 92" "check element 0 for the offset"
  77     gdb_test "p b->y" " = 46" "check element 1 for the offset"
  78     gdb_continue_to_breakpoint "ignore the second baz breakpoint"
  79 }
  80
  81 # Test some values in foo.
  82 proc implptr_test_foo {} {
  83     global csrcfile
  84     set line [gdb_get_line_number "foo breakpoint" $csrcfile]
  85     gdb_test "break implptr.c:$line" "Breakpoint 4.*" \
  86         "set foo breakpoint for implptr"
  87     gdb_continue_to_breakpoint "continue to foo breakpoint for implptr"
  88     gdb_test "print p\[0].x" " = \\(int \\*\\) <synthetic pointer>" \
  89         "print p\[0].x in implptr:foo"
  90     gdb_test "print *p\[0].x" " = 69" \
  91         "print *p\[0].x in implptr:foo"
  92     gdb_test "print/d *(((char *) p\[0].x) + 1)" " = 0" \
  93         "print byte inside *p\[0].x in implptr:foo"
  94     gdb_test "print *(p\[0].x + 10)" \
  95         "access outside bounds of object referenced via synthetic pointer" \
  96         "print invalid offset from *p\[0].x in implptr:foo"
  97     gdb_test "print j" " = 69" \
  98         "print j in implptr:foo"
  99 }
 100
 101 implptr_test_bar
 102 implptr_test_baz
 103 implptr_test_foo