gdb/common/common.m4

   1 dnl Autoconf configure snippets for common.
   2 dnl Copyright (C) 1995-2015 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Invoke configury needed by the files in 'common'.
  20 AC_DEFUN([GDB_AC_COMMON], [
  21   AC_HEADER_STDC
  22   AC_FUNC_ALLOCA
  23
  24   dnl Note that this requires codeset.m4, which is included
  25   dnl by the users of common.m4.
  26   AM_LANGINFO_CODESET
  27
  28   AC_CHECK_HEADERS(linux/perf_event.h locale.h memory.h signal.h dnl
  29                    sys/resource.h sys/socket.h sys/syscall.h dnl
  30                    sys/un.h sys/wait.h dnl
  31                    thread_db.h wait.h)
  32
  33   AC_CHECK_FUNCS([fdwalk getrlimit pipe pipe2 socketpair])
  34
  35   AC_CHECK_DECLS([strerror, strstr])
  36
  37   dnl Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't
  38   dnl do since sigsetjmp might only be defined as a macro.
  39 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
  40 [AC_TRY_COMPILE([
  41 #include <setjmp.h>
  42 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
  43 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
  44 if test $gdb_cv_func_sigsetjmp = yes; then
  45   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
  46 fi
  47 ])