configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include(config/gcc-plugin.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT
  36 AC_CONFIG_SRCDIR([move-if-change])
  37 AC_DISABLE_OPTION_CHECKING
  38
  39 progname=$0
  40 # if PWD already has a value, it is probably wrong.
  41 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  42
  43 # Export original configure arguments for use by sub-configures.
  44 # Quote arguments with shell meta charatcers.
  45 TOPLEVEL_CONFIGURE_ARGUMENTS=
  46 set -- "$progname" "$@"
  47 for ac_arg
  48 do
  49   case "$ac_arg" in
  50   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  51     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  52     # if the argument is of the form -foo=baz, quote the baz part only
  53     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  54   *) ;;
  55   esac
  56   # Add the quoted argument to the list.
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  58 done
  59 if test "$silent" = yes; then
  60   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  61 fi
  62 # Remove the initial space we just introduced and, as these will be
  63 # expanded by make, quote '$'.
  64 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  65 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  66
  67 # Find the build, host, and target systems.
  68 ACX_NONCANONICAL_BUILD
  69 ACX_NONCANONICAL_HOST
  70 ACX_NONCANONICAL_TARGET
  71
  72 dnl Autoconf 2.5x and later will set a default program prefix if
  73 dnl --target was used, even if it was the same as --host.  Disable
  74 dnl that behavior.  This must be done before AC_CANONICAL_TARGET
  75 dnl to take effect.
  76 test "$host_noncanonical" = "$target_noncanonical" &&
  77   test "$program_prefix$program_suffix$program_transform_name" = \
  78     NONENONEs,x,x, &&
  79   program_transform_name=s,y,y,
  80
  81 AC_CANONICAL_TARGET
  82 AC_ARG_PROGRAM
  83
  84 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  85 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  86
  87 # Get 'install' or 'install-sh' and its variants.
  88 AC_PROG_INSTALL
  89 ACX_PROG_LN
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_AWK
  93
  94 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  95
  96 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  97 # a relative path.
  98 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  99   INSTALL="${srcpwd}/install-sh -c"
 100 fi
 101
 102 # Set srcdir to "." if that's what it is.
 103 # This is important for multilib support.
 104 pwd=`${PWDCMD-pwd}`
 105 if test "${pwd}" = "${srcpwd}" ; then
 106   srcdir=.
 107 fi
 108
 109 topsrcdir=$srcpwd
 110
 111 extra_host_args=
 112
 113 ### To add a new directory to the tree, first choose whether it is a target
 114 ### or a host dependent tool.  Then put it into the appropriate list
 115 ### (library or tools, host or target), doing a dependency sort.
 116
 117 # Subdirs will be configured in the order listed in build_configdirs,
 118 # configdirs, or target_configdirs; see the serialization section below.
 119
 120 # Dependency sorting is only needed when *configuration* must be done in
 121 # a particular order.  In all cases a dependency should be specified in
 122 # the Makefile, whether or not it's implicitly specified here.
 123
 124 # Double entries in build_configdirs, configdirs, or target_configdirs may
 125 # cause circular dependencies and break everything horribly.
 126
 127 # these library is used by various programs built for the build
 128 # environment
 129 #
 130 build_libs="build-libiberty build-libcpp"
 131
 132 # these tools are built for the build environment
 133 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 134
 135 # these libraries are used by various programs built for the host environment
 136 #f
 137 host_libs="gettext libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe libgrust "
 138
 139 # these tools are built for the host environment
 140 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 141 # know that we are building the simulator.
 142 # binutils, gas and ld appear in that order because it makes sense to run
 143 # "make check" in that particular order.
 144 # If --enable-gold is used, "gold" may replace "ld".
 145 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gm2tools gotools c++tools"
 146
 147 # these libraries are built for the target environment, and are built after
 148 # the host libraries and the host tools (which may be a cross compiler)
 149 # Note that libiberty is not a target library.
 150 target_libraries="target-libgcc \
 151                 target-libbacktrace \
 152                 target-libgloss \
 153                 target-newlib \
 154                 target-libgomp \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgm2 \
 167                 target-libgo \
 168                 target-libgrust \
 169                 target-libphobos \
 170                 target-zlib"
 171
 172 # these tools are built using the target libraries, and are intended to
 173 # run only in the target environment
 174 #
 175 # note: any program that *uses* libraries that are in the "target_libraries"
 176 # list belongs in this list.
 177 #
 178 target_tools="target-rda"
 179
 180 ################################################################################
 181
 182 ## All tools belong in one of the four categories, and are assigned above
 183 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 184 ## is important because configure will choke if they ever get through.
 185 ## ${configdirs} is directories we build using the host tools.
 186 ## ${target_configdirs} is directories we build using the target tools.
 187 configdirs=`echo ${host_libs} ${host_tools}`
 188 target_configdirs=`echo ${target_libraries} ${target_tools}`
 189 build_configdirs=`echo ${build_libs} ${build_tools}`
 190
 191 m4_divert_text([PARSE_ARGS],
 192 [case $srcdir in
 193   *" "*)
 194 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 195     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 196 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 197     ;;
 198 esac
 199 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 200 ])
 201
 202 ################################################################################
 203
 204 srcname="gnu development package"
 205
 206 # This gets set non-empty for some net releases of packages.
 207 appdirs=""
 208
 209 # Define is_cross_compiler to save on calls to 'test'.
 210 is_cross_compiler=
 211 if test x"${host}" = x"${target}" ; then
 212   is_cross_compiler=no
 213 else
 214   is_cross_compiler=yes
 215 fi
 216
 217 # Find the build and target subdir names.
 218 GCC_TOPLEV_SUBDIRS
 219 # Be sure to cover against remnants of an in-tree build.
 220 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 221   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 222 Use a pristine source tree when building in a separate tree])
 223 fi
 224
 225 # Skipdirs are removed silently.
 226 skipdirs=
 227 # Noconfigdirs are removed loudly.
 228 noconfigdirs=""
 229
 230 use_gnu_ld=
 231 # Make sure we don't let GNU ld be added if we didn't want it.
 232 if test x$with_gnu_ld = xno ; then
 233   use_gnu_ld=no
 234   noconfigdirs="$noconfigdirs ld gold"
 235 fi
 236
 237 use_gnu_as=
 238 # Make sure we don't let GNU as be added if we didn't want it.
 239 if test x$with_gnu_as = xno ; then
 240   use_gnu_as=no
 241   noconfigdirs="$noconfigdirs gas"
 242 fi
 243
 244 use_included_zlib=
 245 AC_ARG_WITH(system-zlib,
 246 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 247 # Make sure we don't let ZLIB be added if we didn't want it.
 248 if test x$with_system_zlib = xyes ; then
 249   use_included_zlib=no
 250   noconfigdirs="$noconfigdirs zlib"
 251 fi
 252
 253 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 254 # is provided.
 255 if test x$with_system_readline = xyes ; then
 256   noconfigdirs="$noconfigdirs readline"
 257 fi
 258
 259 AC_ARG_WITH(zstd,
 260 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 261
 262 # some tools are so dependent upon X11 that if we're not building with X,
 263 # it's not even worth trying to configure, much less build, that tool.
 264
 265 case ${with_x} in
 266   yes | "") ;; # the default value for this tree is that X11 is available
 267   no)
 268     skipdirs="${skipdirs} tk itcl libgui"
 269     # We won't be able to build gdbtk without X.
 270     enable_gdbtk=no
 271     ;;
 272   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 273 esac
 274
 275 # Some are only suitable for cross toolchains.
 276 # Remove these if host=target.
 277 cross_only="target-libgloss target-newlib target-opcodes"
 278
 279 case $is_cross_compiler in
 280   no) skipdirs="${skipdirs} ${cross_only}" ;;
 281 esac
 282
 283 # If both --with-headers and --with-libs are specified, default to
 284 # --without-newlib.
 285 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 286    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 287   if test x"${with_newlib}" = x ; then
 288     with_newlib=no
 289   fi
 290 fi
 291
 292 # Recognize --with-newlib/--without-newlib.
 293 case ${with_newlib} in
 294   no) skipdirs="${skipdirs} target-newlib" ;;
 295   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 296 esac
 297
 298 AC_ARG_ENABLE(as-accelerator-for,
 299 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 300                 [build as offload target compiler.
 301                 Specify offload host triple by ARG])])
 302
 303 AC_ARG_ENABLE(offload-targets,
 304 [AS_HELP_STRING([--enable-offload-targets=LIST],
 305                 [enable offloading to devices from comma-separated LIST of
 306                 TARGET[=DIR]. Use optional path to find offload target compiler
 307                 during the build])],
 308 [
 309   if test x"$enable_offload_targets" = x; then
 310     AC_MSG_ERROR([no offload targets specified])
 311   fi
 312 ], [enable_offload_targets=])
 313
 314 AC_ARG_ENABLE(offload-defaulted,
 315 [AS_HELP_STRING([--enable-offload-defaulted]
 316                 [If enabled, configured but not installed offload compilers and
 317                 libgomp plugins are silently ignored.  Useful for distribution
 318                 compilers where those are in separate optional packages.])],
 319 [enable_offload_defaulted=$enableval],
 320 [enable_offload_defaulted=])
 321
 322 # Handle --enable-gold, --enable-ld.
 323 # --disable-gold [--enable-ld]
 324 #     Build only ld.  Default option.
 325 # --enable-gold [--enable-ld]
 326 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 327 #     as "ld.bfd" and "ld".
 328 # --enable-gold=default [--enable-ld]
 329 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 330 #     install ld as "ld.bfd".
 331 # --enable-gold[=default] --disable-ld
 332 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 333 # --enable-gold --enable-ld=default
 334 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 335 #     and ld.bfd).
 336 #     In other words, ld is default
 337 # --enable-gold=default --enable-ld=default
 338 #     Error.
 339
 340 default_ld=
 341 AC_ARG_ENABLE(gold,
 342 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 343                 [build gold @<:@ARG={default,yes,no}@:>@])],
 344 ENABLE_GOLD=$enableval,
 345 ENABLE_GOLD=no)
 346 case "${ENABLE_GOLD}" in
 347   yes|default)
 348     # Check for ELF target.
 349     is_elf=no
 350     case "${target}" in
 351       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 352       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 353       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 354       | *-*-solaris2* | *-*-nto* | *-*-nacl* | *-*-haiku*)
 355         case "${target}" in
 356           *-*-linux*aout* | *-*-linux*oldld*)
 357             ;;
 358           *)
 359             is_elf=yes
 360             ;;
 361         esac
 362     esac
 363
 364     if test "$is_elf" = "yes"; then
 365       # Check for target supported by gold.
 366       case "${target}" in
 367         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 368         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 369           configdirs="$configdirs gold"
 370           if test x${ENABLE_GOLD} = xdefault; then
 371             default_ld=gold
 372           fi
 373           ENABLE_GOLD=yes
 374           ;;
 375       esac
 376     fi
 377     ;;
 378   no)
 379     ;;
 380   *)
 381     AC_MSG_ERROR([invalid --enable-gold argument])
 382     ;;
 383 esac
 384
 385 AC_ARG_ENABLE(ld,
 386 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 387                 [build ld @<:@ARG={default,yes,no}@:>@])],
 388 ENABLE_LD=$enableval,
 389 ENABLE_LD=yes)
 390
 391 case "${ENABLE_LD}" in
 392   default)
 393     if test x${default_ld} != x; then
 394       AC_MSG_ERROR([either gold or ld can be the default ld])
 395     fi
 396     ;;
 397   yes)
 398     ;;
 399   no)
 400     if test x${ENABLE_GOLD} != xyes; then
 401       AC_MSG_WARN([neither ld nor gold are enabled])
 402     fi
 403     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 404     ;;
 405   *)
 406     AC_MSG_ERROR([invalid --enable-ld argument])
 407     ;;
 408 esac
 409
 410 AC_ARG_ENABLE(gprofng,
 411 [AS_HELP_STRING([[--disable-gprofng]], [do not build gprofng])],
 412 enable_gprofng=$enableval,
 413 enable_gprofng=yes)
 414 if test "$enable_gprofng" = "yes"; then
 415   case "${target}" in
 416     *-musl*)
 417       ;;
 418     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux* | riscv64-*-linux*)
 419     configdirs="$configdirs gprofng"
 420     ;;
 421   esac
 422 fi
 423
 424
 425 # PR gas/19109
 426 # Decide the default method for compressing debug sections.
 427 # Provide a configure time option to override our default.
 428 AC_ARG_ENABLE(compressed_debug_sections,
 429 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 430                 [Enable compressed debug sections for gas, gold or ld by
 431                  default])],
 432 [
 433   if test x"$enable_compressed_debug_sections" = xyes; then
 434     AC_MSG_ERROR([no program with compressed debug sections specified])
 435   fi
 436 ], [enable_compressed_debug_sections=])
 437
 438 # Select default compression algorithm.
 439 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 440 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 441                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 442 [], [default_compressed_debug_sections_algorithm=])
 443
 444 # Configure extra directories which are host specific
 445
 446 case "${host}" in
 447   *-cygwin*)
 448     configdirs="$configdirs libtermcap" ;;
 449 esac
 450
 451 # A target can indicate whether a language isn't supported for some reason.
 452 # Only spaces may be used in this macro; not newlines or tabs.
 453 unsupported_languages=
 454
 455 # Remove more programs from consideration, based on the host or
 456 # target this usually means that a port of the program doesn't
 457 # exist yet.
 458
 459 case "${host}" in
 460   i[[3456789]]86-*-msdosdjgpp*)
 461     noconfigdirs="$noconfigdirs tcl tk itcl"
 462     ;;
 463 esac
 464
 465 # Default to --disable-year2038 until we can handle differences between
 466 # projects that use gnulib (which understands year 2038) and projects that
 467 # do not (like BFD).
 468 AC_ARG_ENABLE(year2038,
 469 AS_HELP_STRING([--enable-year2038],
 470   [enable support for timestamps past the year 2038]),
 471 ENABLE_YEAR2038=$enableval,
 472 ENABLE_YEAR2038=no)
 473 enable_year2038=
 474 if test "${ENABLE_YEAR2038}" = "no" ; then
 475   enable_year2038=no
 476 fi
 477
 478 AC_ARG_ENABLE(libquadmath,
 479 AS_HELP_STRING([--disable-libquadmath],
 480   [do not build libquadmath directory]),
 481 ENABLE_LIBQUADMATH=$enableval,
 482 ENABLE_LIBQUADMATH=yes)
 483 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 484   noconfigdirs="$noconfigdirs target-libquadmath"
 485 fi
 486
 487
 488 AC_ARG_ENABLE(libquadmath-support,
 489 AS_HELP_STRING([--disable-libquadmath-support],
 490   [disable libquadmath support for Fortran]),
 491 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 492 ENABLE_LIBQUADMATH_SUPPORT=yes)
 493 enable_libquadmath_support=
 494 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 495   enable_libquadmath_support=no
 496 fi
 497
 498
 499 AC_ARG_ENABLE(libada,
 500 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 501 ENABLE_LIBADA=$enableval,
 502 ENABLE_LIBADA=yes)
 503 if test "${ENABLE_LIBADA}" != "yes" ; then
 504   noconfigdirs="$noconfigdirs gnattools"
 505 fi
 506
 507 AC_ARG_ENABLE(libgm2,
 508 [AS_HELP_STRING([--enable-libgm2], [build libgm2 directory])],
 509 ENABLE_LIBGM2=$enableval,
 510 ENABLE_LIBGM2=no)
 511 if test "${ENABLE_LIBGM2}" != "yes" ; then
 512   noconfigdirs="$noconfigdirs gm2tools"
 513 fi
 514
 515 AC_ARG_ENABLE(libssp,
 516 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 517 ENABLE_LIBSSP=$enableval,
 518 ENABLE_LIBSSP=yes)
 519
 520 AC_ARG_ENABLE(libstdcxx,
 521 AS_HELP_STRING([--disable-libstdcxx],
 522   [do not build libstdc++-v3 directory]),
 523 ENABLE_LIBSTDCXX=$enableval,
 524 ENABLE_LIBSTDCXX=default)
 525 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 526   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 527 fi]
 528
 529 # Enable libgomp by default on hosted POSIX systems, and a few others.
 530 if test x$enable_libgomp = x ; then
 531     case "${target}" in
 532     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 533         ;;
 534     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 535         ;;
 536     *-*-solaris2* | *-*-hpux11*)
 537         ;;
 538     *-*-darwin* | *-*-aix*)
 539         ;;
 540     nvptx*-*-* | amdgcn*-*-*)
 541         ;;
 542     *)
 543         noconfigdirs="$noconfigdirs target-libgomp"
 544         ;;
 545     esac
 546 fi
 547
 548 # Disable libatomic on unsupported systems.
 549 if test -d ${srcdir}/libatomic; then
 550     if test x$enable_libatomic = x; then
 551         AC_MSG_CHECKING([for libatomic support])
 552         if (srcdir=${srcdir}/libatomic; \
 553                 . ${srcdir}/configure.tgt; \
 554                 test -n "$UNSUPPORTED")
 555         then
 556             AC_MSG_RESULT([no])
 557             noconfigdirs="$noconfigdirs target-libatomic"
 558         else
 559             AC_MSG_RESULT([yes])
 560         fi
 561     fi
 562 fi
 563
 564 # Disable libitm on unsupported systems.
 565 if test -d ${srcdir}/libitm; then
 566     if test x$enable_libitm = x; then
 567         AC_MSG_CHECKING([for libitm support])
 568         if (srcdir=${srcdir}/libitm; \
 569                 . ${srcdir}/configure.tgt; \
 570                 test -n "$UNSUPPORTED")
 571         then
 572             AC_MSG_RESULT([no])
 573             noconfigdirs="$noconfigdirs target-libitm"
 574         else
 575             AC_MSG_RESULT([yes])
 576         fi
 577     fi
 578 fi
 579
 580 # Disable libsanitizer on unsupported systems.
 581 if test -d ${srcdir}/libsanitizer; then
 582     if test x$enable_libsanitizer = x; then
 583         AC_MSG_CHECKING([for libsanitizer support])
 584         if (srcdir=${srcdir}/libsanitizer; \
 585                 . ${srcdir}/configure.tgt; \
 586                 test -n "$UNSUPPORTED")
 587         then
 588             AC_MSG_RESULT([no])
 589             noconfigdirs="$noconfigdirs target-libsanitizer"
 590         else
 591             AC_MSG_RESULT([yes])
 592         fi
 593     fi
 594 fi
 595
 596 # Disable libvtv on unsupported systems.
 597 if test -d ${srcdir}/libvtv; then
 598     if test x$enable_libvtv = x; then
 599         AC_MSG_CHECKING([for libvtv support])
 600         if (srcdir=${srcdir}/libvtv; \
 601                 . ${srcdir}/configure.tgt; \
 602                 test "$VTV_SUPPORTED" != "yes")
 603         then
 604             AC_MSG_RESULT([no])
 605             noconfigdirs="$noconfigdirs target-libvtv"
 606         else
 607             AC_MSG_RESULT([yes])
 608         fi
 609     fi
 610 fi
 611
 612 # Disable libquadmath for some systems.
 613 case "${target}" in
 614   avr-*-*)
 615     noconfigdirs="$noconfigdirs target-libquadmath"
 616     ;;
 617   # libquadmath is unused on AIX and libquadmath build process use of
 618   # LD_LIBRARY_PATH can break AIX bootstrap.
 619   powerpc-*-aix* | rs6000-*-aix*)
 620     noconfigdirs="$noconfigdirs target-libquadmath"
 621     ;;
 622 esac
 623
 624 # Disable libssp for some systems.
 625 case "${target}" in
 626   avr-*-*)
 627     # No hosted I/O support.
 628     noconfigdirs="$noconfigdirs target-libssp"
 629     ;;
 630   bpf-*-*)
 631     noconfigdirs="$noconfigdirs target-libssp"
 632     ;;
 633   powerpc-*-aix* | rs6000-*-aix*)
 634     noconfigdirs="$noconfigdirs target-libssp"
 635     ;;
 636   pru-*-*)
 637     # No hosted I/O support.
 638     noconfigdirs="$noconfigdirs target-libssp"
 639     ;;
 640   rl78-*-*)
 641     # libssp uses a misaligned load to trigger a fault, but the RL78
 642     # doesn't fault for those - instead, it gives a build-time error
 643     # for explicit misaligned loads.
 644     noconfigdirs="$noconfigdirs target-libssp"
 645     ;;
 646   visium-*-*)
 647     # No hosted I/O support.
 648     noconfigdirs="$noconfigdirs target-libssp"
 649     ;;
 650 esac
 651
 652 # Disable libstdc++-v3 for some systems.
 653 # Allow user to override this if they pass --enable-libstdcxx
 654 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 655   case "${target}" in
 656     *-*-vxworks*)
 657       # VxWorks uses the Dinkumware C++ library.
 658       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 659       ;;
 660     amdgcn*-*-*)
 661       # Not ported/fails to build when using newlib.
 662       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 663       ;;
 664     arm*-wince-pe*)
 665       # the C++ libraries don't build on top of CE's C libraries
 666       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 667       ;;
 668     avr-*-*)
 669       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 670       ;;
 671     bpf-*-*)
 672       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 673       ;;
 674     ft32-*-*)
 675       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 676       ;;
 677   esac
 678 fi
 679
 680 # Disable C++ on systems where it is known to not work.
 681 # For testing, you can override this with --enable-languages=c++.
 682 case ,${enable_languages}, in
 683   *,c++,*)
 684     ;;
 685   *)
 686       case "${target}" in
 687         bpf-*-*)
 688           unsupported_languages="$unsupported_languages c++"
 689           ;;
 690       esac
 691       ;;
 692 esac
 693
 694 # Disable Objc on systems where it is known to not work.
 695 # For testing, you can override this with --enable-languages=objc.
 696 case ,${enable_languages}, in
 697   *,objc,*)
 698     ;;
 699   *)
 700       case "${target}" in
 701         bpf-*-*)
 702           unsupported_languages="$unsupported_languages objc"
 703           ;;
 704       esac
 705       ;;
 706 esac
 707
 708 # Disable D on systems where it is known to not work.
 709 # For testing, you can override this with --enable-languages=d.
 710 case ,${enable_languages}, in
 711   *,d,*)
 712     ;;
 713   *)
 714     case "${target}" in
 715       bpf-*-*)
 716         unsupported_languages="$unsupported_languages d"
 717         ;;
 718     esac
 719     ;;
 720 esac
 721
 722 # Disable libphobos on unsupported systems.
 723 # For testing, you can override this with --enable-libphobos.
 724 if test -d ${srcdir}/libphobos; then
 725     if test x$enable_libphobos = x; then
 726         AC_MSG_CHECKING([for libphobos support])
 727         if (srcdir=${srcdir}/libphobos; \
 728                 . ${srcdir}/configure.tgt; \
 729                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 730         then
 731             AC_MSG_RESULT([no])
 732             noconfigdirs="$noconfigdirs target-libphobos"
 733         else
 734             AC_MSG_RESULT([yes])
 735         fi
 736     fi
 737 fi
 738
 739 # Disable Fortran for some systems.
 740 case "${target}" in
 741   mmix-*-*)
 742     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 743     unsupported_languages="$unsupported_languages fortran"
 744     ;;
 745   bpf-*-*)
 746     unsupported_languages="$unsupported_languages fortran"
 747     ;;
 748 esac
 749
 750 # Disable libffi for some systems.
 751 case "${target}" in
 752   powerpc-*-darwin*)
 753     ;;
 754   i[[3456789]]86-*-darwin*)
 755     ;;
 756   x86_64-*-darwin[[912]]*)
 757     ;;
 758   *-*-darwin*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   *-*-netware*)
 762     noconfigdirs="$noconfigdirs target-libffi"
 763     ;;
 764   *-*-phoenix*)
 765     noconfigdirs="$noconfigdirs target-libffi"
 766     ;;
 767   *-*-rtems*)
 768     noconfigdirs="$noconfigdirs target-libffi"
 769     ;;
 770   *-*-tpf*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   *-*-uclinux*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   *-*-vxworks*)
 777     noconfigdirs="$noconfigdirs target-libffi"
 778     ;;
 779   aarch64*-*-freebsd*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   alpha*-*-*vms*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785   arm*-*-freebsd*)
 786     noconfigdirs="$noconfigdirs target-libffi"
 787     ;;
 788   arm-wince-pe)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   arm*-*-symbianelf*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794   bpf-*-*)
 795     noconfigdirs="$noconfigdirs target-libffi"
 796     ;;
 797   cris-*-* | crisv32-*-*)
 798     case "${target}" in
 799       *-*-linux*)
 800         ;;
 801       *) # See PR46792 regarding target-libffi.
 802         noconfigdirs="$noconfigdirs target-libffi";;
 803     esac
 804     ;;
 805   hppa*64*-*-hpux*)
 806     noconfigdirs="$noconfigdirs target-libffi"
 807     ;;
 808   hppa*-hp-hpux11*)
 809     ;;
 810   hppa*-*-hpux*)
 811     noconfigdirs="$noconfigdirs target-libffi"
 812     ;;
 813   ia64*-*-*vms*)
 814     noconfigdirs="$noconfigdirs target-libffi"
 815     ;;
 816   i[[3456789]]86-w64-mingw*)
 817     noconfigdirs="$noconfigdirs target-libffi"
 818     ;;
 819   i[[3456789]]86-*-mingw*)
 820     noconfigdirs="$noconfigdirs target-libffi"
 821     ;;
 822   x86_64-*-mingw*)
 823     noconfigdirs="$noconfigdirs target-libffi"
 824     ;;
 825   mmix-*-*)
 826     noconfigdirs="$noconfigdirs target-libffi"
 827     ;;
 828   powerpc-*-aix*)
 829     ;;
 830   rs6000-*-aix*)
 831     ;;
 832   ft32-*-*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835   *-*-lynxos*)
 836     noconfigdirs="$noconfigdirs target-libffi"
 837     ;;
 838 esac
 839
 840 # Disable the go frontend on systems where it is known to not work. Please keep
 841 # this in sync with contrib/config-list.mk.
 842 case "${target}" in
 843 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 844     unsupported_languages="$unsupported_languages go"
 845     ;;
 846 esac
 847
 848 # Only allow gdbserver on some systems.
 849 if test -d ${srcdir}/gdbserver; then
 850     if test x$enable_gdbserver = x; then
 851         AC_MSG_CHECKING([for gdbserver support])
 852         if (srcdir=${srcdir}/gdbserver; \
 853                 . ${srcdir}/configure.srv; \
 854                 test -n "$UNSUPPORTED")
 855         then
 856             AC_MSG_RESULT([no])
 857             noconfigdirs="$noconfigdirs gdbserver"
 858         else
 859             AC_MSG_RESULT([yes])
 860         fi
 861     fi
 862 fi
 863
 864 # Disable libgo for some systems where it is known to not work.
 865 # For testing, you can easily override this with --enable-libgo.
 866 if test x$enable_libgo = x; then
 867     case "${target}" in
 868     *-*-darwin*)
 869         # PR 46986
 870         noconfigdirs="$noconfigdirs target-libgo"
 871         ;;
 872     *-*-cygwin* | *-*-mingw*)
 873         noconfigdirs="$noconfigdirs target-libgo"
 874         ;;
 875     bpf-*-*)
 876         noconfigdirs="$noconfigdirs target-libgo"
 877         ;;
 878     esac
 879 fi
 880
 881 # Default libgloss CPU subdirectory.
 882 libgloss_dir="$target_cpu"
 883
 884 case "${target}" in
 885   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 886     libgloss_dir=wince
 887     ;;
 888   aarch64*-*-* )
 889     libgloss_dir=aarch64
 890     ;;
 891   arm*-*-*)
 892     libgloss_dir=arm
 893     ;;
 894   cris-*-* | crisv32-*-*)
 895     libgloss_dir=cris
 896     ;;
 897   kvx-*-elf)
 898     libgloss_dir=kvx-elf
 899     ;;
 900   kvx-*-mbr)
 901     libgloss_dir=kvx-mbr
 902     ;;
 903   kvx-*-cos)
 904     libgloss_dir=kvx-cos
 905     ;;
 906   hppa*-*-*)
 907     libgloss_dir=pa
 908     ;;
 909   i[[3456789]]86-*-*)
 910     libgloss_dir=i386
 911     ;;
 912   loongarch*-*-*)
 913     libgloss_dir=loongarch
 914     ;;
 915   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 916     libgloss_dir=m68hc11
 917     ;;
 918   m68*-*-* | fido-*-*)
 919     libgloss_dir=m68k
 920     ;;
 921   mips*-*-*)
 922     libgloss_dir=mips
 923     ;;
 924   powerpc*-*-*)
 925     libgloss_dir=rs6000
 926     ;;
 927   pru-*-*)
 928     libgloss_dir=pru
 929     ;;
 930   sparc*-*-*)
 931     libgloss_dir=sparc
 932     ;;
 933 esac
 934
 935 # Disable newlib and libgloss for various target OSes.
 936 case "${target}" in
 937   alpha*-dec-osf*)
 938     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 939     ;;
 940   i[[3456789]]86-*-linux*)
 941     # This section makes it possible to build newlib natively on linux.
 942     # If we are using a cross compiler then don't configure newlib.
 943     if test x${is_cross_compiler} != xno ; then
 944       noconfigdirs="$noconfigdirs target-newlib"
 945     fi
 946     noconfigdirs="$noconfigdirs target-libgloss"
 947     # If we are not using a cross compiler, do configure newlib.
 948     # Note however, that newlib will only be configured in this situation
 949     # if the --with-newlib option has been given, because otherwise
 950     # 'target-newlib' will appear in skipdirs.
 951     ;;
 952   i[[3456789]]86-*-rdos*)
 953     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 954     ;;
 955   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 956     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 957     ;;
 958   sparc-*-sunos4*)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   bpf-*-*)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 963     ;;
 964   *-*-aix*)
 965     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 966     ;;
 967   *-*-beos*)
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   *-*-chorusos)
 971     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 972     ;;
 973   *-*-dragonfly*)
 974     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 975     ;;
 976   *-*-freebsd*)
 977     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 978     ;;
 979   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982   *-*-lynxos*)
 983     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 984     ;;
 985   *-*-mingw*)
 986     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 987     ;;
 988   *-*-netbsd*)
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   *-*-netware*)
 992     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 993     ;;
 994   *-*-tpf*)
 995     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 996     ;;
 997   *-*-uclinux*)
 998     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 999     ;;
1000   *-*-vxworks*)
1001     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1002     ;;
1003 esac
1004
1005 # The ARM simulator has been deprecated for all ARM targets.
1006 case "${target}" in
1007   arm*-*-*)
1008     noconfigdirs="$noconfigdirs sim"
1009     ;;
1010 esac
1011
1012 case "${target}" in
1013   *-*-chorusos)
1014     ;;
1015   aarch64-*-darwin*)
1016     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1017     noconfigdirs="$noconfigdirs sim target-rda"
1018     ;;
1019   amdgcn*-*-*)
1020     ;;
1021   arm-*-darwin*)
1022     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1023     noconfigdirs="$noconfigdirs target-rda"
1024     ;;
1025   powerpc-*-darwin*)
1026     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1027     noconfigdirs="$noconfigdirs sim target-rda"
1028     ;;
1029   i[[3456789]]86-*-darwin*)
1030     noconfigdirs="$noconfigdirs ld gprof"
1031     noconfigdirs="$noconfigdirs sim target-rda"
1032     ;;
1033   x86_64-*-darwin[[912]]*)
1034     noconfigdirs="$noconfigdirs ld gas gprof"
1035     noconfigdirs="$noconfigdirs sim target-rda"
1036     ;;
1037   *-*-darwin*)
1038     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1039     noconfigdirs="$noconfigdirs sim target-rda"
1040     ;;
1041   *-*-dragonfly*)
1042     ;;
1043   *-*-freebsd*)
1044     if test "x$with_gmp" = x \
1045         && ! test -d ${srcdir}/gmp \
1046         && test -f /usr/local/include/gmp.h; then
1047       with_gmp=/usr/local
1048     fi
1049     ;;
1050   *-*-kaos*)
1051     # Remove unsupported stuff on all kaOS configurations.
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054   *-*-netbsd*)
1055     ;;
1056   *-*-netware*)
1057     ;;
1058   *-*-phoenix*)
1059     noconfigdirs="$noconfigdirs target-libgloss"
1060     ;;
1061   *-*-rtems*)
1062     noconfigdirs="$noconfigdirs target-libgloss"
1063     ;;
1064     # The tpf target doesn't support gdb yet.
1065   *-*-tpf*)
1066     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1067     ;;
1068   *-*-uclinux*)
1069     noconfigdirs="$noconfigdirs target-rda"
1070     ;;
1071   *-*-vxworks*)
1072     ;;
1073   alpha*-dec-osf*)
1074     # ld works, but does not support shared libraries.
1075     # gas doesn't generate exception information.
1076     noconfigdirs="$noconfigdirs gas ld"
1077     ;;
1078   alpha*-*-*vms*)
1079     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1080     ;;
1081   alpha*-*-*)
1082     # newlib is not 64 bit ready
1083     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1084     ;;
1085   bpf-*-*)
1086     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1087     ;;
1088   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1089     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1090     ;;
1091   arc*-*-*)
1092     noconfigdirs="$noconfigdirs sim"
1093     ;;
1094   arm-*-pe*)
1095     noconfigdirs="$noconfigdirs target-libgloss"
1096     ;;
1097   arm-*-riscix*)
1098     noconfigdirs="$noconfigdirs ld target-libgloss"
1099     ;;
1100   avr-*-*)
1101     if test x${with_avrlibc} != xno; then
1102       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1103     fi
1104     ;;
1105   c4x-*-* | tic4x-*-*)
1106     noconfigdirs="$noconfigdirs target-libgloss"
1107     ;;
1108   tic54x-*-*)
1109     noconfigdirs="$noconfigdirs target-libgloss gdb"
1110     ;;
1111   d10v-*-*)
1112     noconfigdirs="$noconfigdirs target-libgloss"
1113     ;;
1114   d30v-*-*)
1115     noconfigdirs="$noconfigdirs gdb"
1116     ;;
1117   fr30-*-elf*)
1118     noconfigdirs="$noconfigdirs gdb"
1119     ;;
1120   ft32-*-*)
1121     noconfigdirs="$noconfigdirs target-rda gprof"
1122     ;;
1123   moxie-*-*)
1124     noconfigdirs="$noconfigdirs"
1125     ;;
1126   h8300*-*-*)
1127     noconfigdirs="$noconfigdirs target-libgloss"
1128     ;;
1129   h8500-*-*)
1130     noconfigdirs="$noconfigdirs target-libgloss"
1131     ;;
1132   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1133     ;;
1134   hppa*64*-*-hpux*)
1135     noconfigdirs="$noconfigdirs gdb"
1136     ;;
1137   hppa*-*-hpux11*)
1138     noconfigdirs="$noconfigdirs gdb ld"
1139     ;;
1140   hppa*64*-*-linux*)
1141     ;;
1142   hppa*-*-linux*)
1143     ;;
1144   hppa*-*-*elf* | \
1145   hppa*-*-lites* | \
1146   hppa*-*-openbsd* | \
1147   hppa*64*-*-*)
1148     ;;
1149   hppa*-*-pro*)
1150     ;;
1151   hppa*-*-*)
1152     noconfigdirs="$noconfigdirs ld"
1153     ;;
1154   i960-*-*)
1155     noconfigdirs="$noconfigdirs gdb"
1156     ;;
1157   ia64*-*-elf*)
1158     # No gdb support yet.
1159     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1160     ;;
1161   ia64*-**-hpux*)
1162     # No ld support yet.
1163     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1164     ;;
1165   ia64*-*-*vms*)
1166     # No ld support yet.
1167     noconfigdirs="$noconfigdirs libgui itcl ld"
1168     ;;
1169   i[[3456789]]86-w64-mingw*)
1170     ;;
1171   i[[3456789]]86-*-mingw*)
1172     target_configdirs="$target_configdirs target-winsup"
1173     ;;
1174   *-*-cygwin*)
1175     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1176     noconfigdirs="$noconfigdirs target-libgloss"
1177     # always build newlib if winsup directory is present.
1178     if test -d "$srcdir/winsup/cygwin"; then
1179       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1180     elif test -d "$srcdir/newlib"; then
1181       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1182     fi
1183     ;;
1184   i[[3456789]]86-*-pe)
1185     noconfigdirs="$noconfigdirs target-libgloss"
1186     ;;
1187   i[[3456789]]86-*-sco3.2v5*)
1188     # The linker does not yet know about weak symbols in COFF,
1189     # and is not configured to handle mixed ELF and COFF.
1190     noconfigdirs="$noconfigdirs ld target-libgloss"
1191     ;;
1192   i[[3456789]]86-*-sco*)
1193     noconfigdirs="$noconfigdirs gprof target-libgloss"
1194     ;;
1195   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1196     noconfigdirs="$noconfigdirs target-libgloss"
1197     ;;
1198   i[[3456789]]86-*-sysv4*)
1199     noconfigdirs="$noconfigdirs target-libgloss"
1200     ;;
1201   i[[3456789]]86-*-beos*)
1202     noconfigdirs="$noconfigdirs gdb"
1203     ;;
1204   i[[3456789]]86-*-rdos*)
1205     noconfigdirs="$noconfigdirs gdb"
1206     ;;
1207   kvx-*-*)
1208     noconfigdirs="$noconfigdirs gdb gdbserver sim"
1209     ;;
1210   mmix-*-*)
1211     noconfigdirs="$noconfigdirs gdb"
1212     ;;
1213   mt-*-*)
1214     noconfigdirs="$noconfigdirs sim"
1215     ;;
1216   nfp-*-*)
1217     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1218     noconfigdirs="$noconfigdirs $target_libraries"
1219     ;;
1220   pdp11-*-*)
1221     noconfigdirs="$noconfigdirs gdb gprof"
1222     ;;
1223   powerpc-*-aix*)
1224     # copied from rs6000-*-* entry
1225     noconfigdirs="$noconfigdirs gprof"
1226     ;;
1227   powerpc*-*-winnt* | powerpc*-*-pe*)
1228     target_configdirs="$target_configdirs target-winsup"
1229     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1230     # always build newlib.
1231     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1232     ;;
1233     # This is temporary until we can link against shared libraries
1234   powerpcle-*-solaris*)
1235     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1236     ;;
1237   powerpc-*-beos*)
1238     noconfigdirs="$noconfigdirs gdb"
1239     ;;
1240   rs6000-*-lynxos*)
1241     noconfigdirs="$noconfigdirs gprof"
1242     ;;
1243   rs6000-*-aix*)
1244     noconfigdirs="$noconfigdirs gprof"
1245     ;;
1246   rs6000-*-*)
1247     noconfigdirs="$noconfigdirs gprof"
1248     ;;
1249   m68k-apollo-*)
1250     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1251     ;;
1252   microblaze*)
1253     noconfigdirs="$noconfigdirs gprof"
1254     ;;
1255   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1256     if test x$with_newlib = xyes; then
1257       noconfigdirs="$noconfigdirs gprof"
1258     fi
1259     ;;
1260   mips*-*-irix5*)
1261     noconfigdirs="$noconfigdirs gprof target-libgloss"
1262     ;;
1263   mips*-*-irix6*)
1264     noconfigdirs="$noconfigdirs gprof target-libgloss"
1265     ;;
1266   mips*-*-bsd*)
1267     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1268     ;;
1269   mips*-*-linux*)
1270     ;;
1271   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1272   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1273     noconfigdirs="$noconfigdirs ld gas gprof"
1274     ;;
1275   mips*-*-*)
1276     noconfigdirs="$noconfigdirs gprof"
1277     ;;
1278   nvptx*-*-*)
1279     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1280     ;;
1281   sh-*-*)
1282     case "${target}" in
1283       sh*-*-elf)
1284          ;;
1285       *)
1286          noconfigdirs="$noconfigdirs target-libgloss" ;;
1287     esac
1288     ;;
1289   sparc-*-sunos4*)
1290     if test x${is_cross_compiler} = xno ; then
1291            use_gnu_ld=no
1292     fi
1293     ;;
1294   tic6x-*-*)
1295     noconfigdirs="$noconfigdirs sim"
1296     ;;
1297   tilepro*-*-* | tilegx*-*-*)
1298     noconfigdirs="$noconfigdirs sim"
1299     ;;
1300   v810-*-*)
1301     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1302     ;;
1303   vax-*-*)
1304     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1305     ;;
1306   wasm32-*-*)
1307     noconfigdirs="$noconfigdirs ld"
1308     ;;
1309   loongarch*-*-linux*)
1310     ;;
1311   loongarch*-*-*)
1312     noconfigdirs="$noconfigdirs gprof"
1313     ;;
1314 esac
1315
1316 # If we aren't building newlib, then don't build libgloss, since libgloss
1317 # depends upon some newlib header files.
1318 case "${noconfigdirs}" in
1319   *target-libgloss*) ;;
1320   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1321 esac
1322
1323 # Work in distributions that contain no compiler tools, like Autoconf.
1324 host_makefile_frag=/dev/null
1325 if test -d ${srcdir}/config ; then
1326 case "${host}" in
1327   i[[3456789]]86-*-msdosdjgpp*)
1328     host_makefile_frag="config/mh-djgpp"
1329     ;;
1330   *-cygwin*)
1331     ACX_CHECK_CYGWIN_CAT_WORKS
1332     host_makefile_frag="config/mh-cygwin"
1333     ;;
1334   *-mingw*)
1335     host_makefile_frag="config/mh-mingw"
1336     ;;
1337   alpha*-linux*)
1338     host_makefile_frag="config/mh-alpha-linux"
1339     ;;
1340   hppa*-hp-hpux*)
1341     host_makefile_frag="config/mh-pa"
1342     ;;
1343   hppa*-*)
1344     host_makefile_frag="config/mh-pa"
1345     ;;
1346   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1347     host_makefile_frag="config/mh-darwin"
1348     ;;
1349   powerpc-*-aix*)
1350     host_makefile_frag="config/mh-ppc-aix"
1351     ;;
1352   rs6000-*-aix*)
1353     host_makefile_frag="config/mh-ppc-aix"
1354     ;;
1355 esac
1356 fi
1357
1358 if test "${build}" != "${host}" ; then
1359   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1360   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1361   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1362   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1363   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1364   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1365   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1366   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1367   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1368   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1369   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1370   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1371   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1372   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1373   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1374 else
1375   AR_FOR_BUILD="\$(AR)"
1376   AS_FOR_BUILD="\$(AS)"
1377   CC_FOR_BUILD="\$(CC)"
1378   CXX_FOR_BUILD="\$(CXX)"
1379   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1380   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1381   GOC_FOR_BUILD="\$(GOC)"
1382   GDC_FOR_BUILD="\$(GDC)"
1383   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1384   LD_FOR_BUILD="\$(LD)"
1385   NM_FOR_BUILD="\$(NM)"
1386   RANLIB_FOR_BUILD="\$(RANLIB)"
1387   WINDRES_FOR_BUILD="\$(WINDRES)"
1388   WINDMC_FOR_BUILD="\$(WINDMC)"
1389 fi
1390
1391 AC_PROG_CC_C99
1392 AC_PROG_CXX
1393
1394 # We must set the default linker to the linker used by gcc for the correct
1395 # operation of libtool.  If LD is not defined and we are using gcc, try to
1396 # set the LD default to the ld used by gcc.
1397 if test -z "$LD"; then
1398   if test "$GCC" = yes; then
1399     case $build in
1400     *-*-mingw*)
1401       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1402     *)
1403       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1404     esac
1405     case $gcc_prog_ld in
1406     # Accept absolute paths.
1407     [[\\/]* | [A-Za-z]:[\\/]*)]
1408       LD="$gcc_prog_ld" ;;
1409     esac
1410   fi
1411 fi
1412
1413 # Check whether -static-libstdc++ -static-libgcc is supported.
1414 have_static_libs=no
1415 if test "$GCC" = yes; then
1416   saved_LDFLAGS="$LDFLAGS"
1417
1418   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1419   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1420   AC_LANG_PUSH(C++)
1421   AC_LINK_IFELSE([AC_LANG_SOURCE([
1422 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1423 #error -static-libstdc++ not implemented
1424 #endif
1425 int main() {}])],
1426     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1427     [AC_MSG_RESULT([no])])
1428   AC_LANG_POP(C++)
1429
1430   LDFLAGS="$saved_LDFLAGS"
1431 fi
1432
1433 ACX_PROG_GNAT
1434 ACX_PROG_GDC
1435 ACX_PROG_CARGO
1436 ACX_PROG_CMP_IGNORE_INITIAL
1437
1438 AC_ARG_ENABLE([bootstrap],
1439 [AS_HELP_STRING([--enable-bootstrap],
1440                 [enable bootstrapping @<:@yes if native build@:>@])],,
1441 enable_bootstrap=default)
1442
1443 # Issue errors and warnings for invalid/strange bootstrap combinations.
1444 if test -r $srcdir/gcc/configure; then
1445   have_compiler=yes
1446 else
1447   have_compiler=no
1448 fi
1449
1450 case "$have_compiler:$host:$target:$enable_bootstrap" in
1451   *:*:*:no) ;;
1452
1453   # Default behavior.  Enable bootstrap if we have a compiler
1454   # and we are in a native configuration.
1455   yes:$build:$build:default)
1456     enable_bootstrap=yes ;;
1457
1458   *:*:*:default)
1459     enable_bootstrap=no ;;
1460
1461   # We have a compiler and we are in a native configuration, bootstrap is ok
1462   yes:$build:$build:yes)
1463     ;;
1464
1465   # Other configurations, but we have a compiler.  Assume the user knows
1466   # what he's doing.
1467   yes:*:*:yes)
1468     AC_MSG_WARN([trying to bootstrap a cross compiler])
1469     ;;
1470
1471   # No compiler: if they passed --enable-bootstrap explicitly, fail
1472   no:*:*:yes)
1473     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1474
1475   # Fail if wrong command line
1476   *)
1477     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1478     ;;
1479 esac
1480
1481 # When bootstrapping with GCC, build stage 1 in C++14 mode to ensure that a
1482 # C++14 compiler can still start the bootstrap.  Otherwise, if building GCC,
1483 # require C++14 (or higher).
1484 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1485   CXX="$CXX -std=c++14"
1486 elif test "$have_compiler" = yes; then
1487   AX_CXX_COMPILE_STDCXX(14)
1488
1489   if test "${build}" != "${host}"; then
1490     AX_CXX_COMPILE_STDCXX(14, [], [], [_FOR_BUILD])
1491   fi
1492 fi
1493
1494 AC_ARG_ENABLE([pgo-build],
1495 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1496                 [enable the PGO build])],
1497 [enable_pgo_build=$enableval],
1498 [enable_pgo_build=no])
1499
1500 # Issue errors and warnings for invalid/strange PGO build combinations.
1501 case "$have_compiler:$host:$target:$enable_pgo_build" in
1502   *:*:*:no) ;;
1503
1504   # Allow the PGO build only if we aren't building a compiler and
1505   # we are in a native configuration.
1506   no:$build:$build:yes | no:$build:$build:lto) ;;
1507
1508   # Disallow the PGO bootstrap if we are building a compiler.
1509   yes:*:*:yes | yes:*:*:lto)
1510     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1511
1512   *)
1513     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1514     ;;
1515 esac
1516
1517 if test "$enable_pgo_build" != "no"; then
1518   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1519   old_CFLAGS="$CFLAGS"
1520   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1521   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1522   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1523                     [PGO_BUILD_GEN_CFLAGS=])
1524   CFLAGS="$old_CFLAGS"
1525   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1526     AC_MSG_RESULT([yes])
1527     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1528   else
1529     AC_MSG_RESULT([no])
1530     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1531   fi
1532
1533   if test "$enable_pgo_build" = "lto"; then
1534     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1535     old_CFLAGS="$CFLAGS"
1536     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1537     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1538     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1539                       [PGO_BUILD_LTO_CFLAGS=])
1540     CFLAGS="$old_CFLAGS"
1541     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1542       AC_MSG_RESULT([yes])
1543     else
1544       AC_MSG_RESULT([no])
1545       AC_MSG_WARN([LTO is disabled for the PGO build])
1546     fi
1547   fi
1548 fi
1549 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1550 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1551 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1552
1553 # Used for setting $lt_cv_objdir
1554 _LT_CHECK_OBJDIR
1555
1556 # Check for GMP, MPFR and MPC
1557 require_gmp=no
1558 require_mpc=no
1559 if test -d ${srcdir}/gcc ; then
1560   require_gmp=yes
1561   require_mpc=yes
1562 fi
1563 if test -d ${srcdir}/gdb ; then
1564   if test "x$enable_gdb" != xno; then
1565    require_gmp=yes
1566   fi
1567 fi
1568
1569 gmplibs="-lmpfr -lgmp"
1570 if test x"$require_mpc" = "xyes" ; then
1571   gmplibs="-lmpc $gmplibs"
1572 fi
1573 gmpinc=
1574 have_gmp=no
1575
1576 # Specify a location for mpc
1577 # check for this first so it ends up on the link line before mpfr.
1578 AC_ARG_WITH(mpc,
1579 [AS_HELP_STRING([--with-mpc=PATH],
1580                 [specify prefix directory for installed MPC package.
1581                  Equivalent to --with-mpc-include=PATH/include
1582                  plus --with-mpc-lib=PATH/lib])])
1583 AC_ARG_WITH(mpc-include,
1584 [AS_HELP_STRING([--with-mpc-include=PATH],
1585                 [specify directory for installed MPC include files])])
1586 AC_ARG_WITH(mpc-lib,
1587 [AS_HELP_STRING([--with-mpc-lib=PATH],
1588                 [specify directory for the installed MPC library])])
1589
1590 if test "x$with_mpc" != x; then
1591   gmplibs="-L$with_mpc/lib $gmplibs"
1592   gmpinc="-I$with_mpc/include $gmpinc"
1593 fi
1594 if test "x$with_mpc_include" != x; then
1595   gmpinc="-I$with_mpc_include $gmpinc"
1596 fi
1597 if test "x$with_mpc_lib" != x; then
1598   gmplibs="-L$with_mpc_lib $gmplibs"
1599 fi
1600 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1601   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1602   gmpinc='-I$$s/mpc/src '"$gmpinc"
1603   # Do not test the mpc version.  Assume that it is sufficient, since
1604   # it is in the source tree, and the library has not been built yet
1605   # but it would be included on the link line in the version check below
1606   # hence making the test fail.
1607   have_gmp=yes
1608 fi
1609
1610 # Specify a location for mpfr
1611 # check for this first so it ends up on the link line before gmp.
1612 AC_ARG_WITH(mpfr,
1613 [AS_HELP_STRING([--with-mpfr=PATH],
1614                 [specify prefix directory for installed MPFR package.
1615                  Equivalent to --with-mpfr-include=PATH/include
1616                  plus --with-mpfr-lib=PATH/lib])])
1617 AC_ARG_WITH(mpfr-include,
1618 [AS_HELP_STRING([--with-mpfr-include=PATH],
1619                 [specify directory for installed MPFR include files])])
1620 AC_ARG_WITH(mpfr-lib,
1621 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1622                 [specify directory for the installed MPFR library])])
1623
1624 if test "x$with_mpfr" != x; then
1625   gmplibs="-L$with_mpfr/lib $gmplibs"
1626   gmpinc="-I$with_mpfr/include $gmpinc"
1627 fi
1628 if test "x$with_mpfr_include" != x; then
1629   gmpinc="-I$with_mpfr_include $gmpinc"
1630 fi
1631 if test "x$with_mpfr_lib" != x; then
1632   gmplibs="-L$with_mpfr_lib $gmplibs"
1633 fi
1634 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1635   # MPFR v3.1.0 moved the sources into a src sub-directory.
1636   if ! test -d ${srcdir}/mpfr/src; then
1637     AC_MSG_ERROR([dnl
1638 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1639   fi
1640   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1641   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1642   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1643   # Do not test the mpfr version.  Assume that it is sufficient, since
1644   # it is in the source tree, and the library has not been built yet
1645   # but it would be included on the link line in the version check below
1646   # hence making the test fail.
1647   have_gmp=yes
1648 fi
1649
1650 # Specify a location for gmp
1651 AC_ARG_WITH(gmp,
1652 [AS_HELP_STRING([--with-gmp=PATH],
1653                 [specify prefix directory for the installed GMP package.
1654                  Equivalent to --with-gmp-include=PATH/include
1655                  plus --with-gmp-lib=PATH/lib])])
1656 AC_ARG_WITH(gmp-include,
1657 [AS_HELP_STRING([--with-gmp-include=PATH],
1658                 [specify directory for installed GMP include files])])
1659 AC_ARG_WITH(gmp-lib,
1660 [AS_HELP_STRING([--with-gmp-lib=PATH],
1661                 [specify directory for the installed GMP library])])
1662
1663
1664 if test "x$with_gmp" != x; then
1665   gmplibs="-L$with_gmp/lib $gmplibs"
1666   gmpinc="-I$with_gmp/include $gmpinc"
1667 fi
1668 if test "x$with_gmp_include" != x; then
1669   gmpinc="-I$with_gmp_include $gmpinc"
1670 fi
1671 if test "x$with_gmp_lib" != x; then
1672   gmplibs="-L$with_gmp_lib $gmplibs"
1673 fi
1674 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1675   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1676   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1677   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1678   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1679   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1680   # Do not test the gmp version.  Assume that it is sufficient, since
1681   # it is in the source tree, and the library has not been built yet
1682   # but it would be included on the link line in the version check below
1683   # hence making the test fail.
1684   have_gmp=yes
1685 fi
1686
1687 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1688   have_gmp=yes
1689   saved_CFLAGS="$CFLAGS"
1690   CFLAGS="$CFLAGS $gmpinc"
1691   # Check for the recommended and required versions of GMP.
1692   AC_MSG_CHECKING([for the correct version of gmp.h])
1693   AC_TRY_COMPILE([#include "gmp.h"],[
1694   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1695   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1696   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1697   choke me
1698   #endif
1699   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1700   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1701   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1702   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1703   choke me
1704   #endif
1705   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1706    [AC_MSG_RESULT([no]); have_gmp=no])
1707
1708   # If we have GMP, check the MPFR version.
1709   if test x"$have_gmp" = xyes; then
1710     # Check for the recommended and required versions of MPFR.
1711     AC_MSG_CHECKING([for the correct version of mpfr.h])
1712     AC_TRY_COMPILE([#include <gmp.h>
1713     #include <mpfr.h>],[
1714     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1715     choke me
1716     #endif
1717     ], [AC_TRY_COMPILE([#include <gmp.h>
1718     #include <mpfr.h>],[
1719     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1720     choke me
1721     #endif
1722     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1723      [AC_MSG_RESULT([no]); have_gmp=no])
1724   fi
1725
1726   # Check for the MPC header version.
1727   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1728     # Check for the recommended and required versions of MPC.
1729     AC_MSG_CHECKING([for the correct version of mpc.h])
1730     AC_TRY_COMPILE([#include <mpc.h>],[
1731     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1732     choke me
1733     #endif
1734     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1735     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1736     choke me
1737     #endif
1738     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1739      [AC_MSG_RESULT([no]); have_gmp=no])
1740   fi
1741
1742   # Now check the MPFR library.
1743   if test x"$have_gmp" = xyes; then
1744     saved_LIBS="$LIBS"
1745     LIBS="$LIBS $gmplibs"
1746     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1747     AC_TRY_LINK([#include <mpfr.h>],[
1748     mpfr_t n;
1749     mpfr_t x;
1750     int t;
1751     mpfr_init (n);
1752     mpfr_init (x);
1753     mpfr_atan2 (n, n, x, MPFR_RNDN);
1754     mpfr_erfc (n, x, MPFR_RNDN);
1755     mpfr_subnormalize (x, t, MPFR_RNDN);
1756     mpfr_clear(n);
1757     mpfr_clear(x);
1758     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1759     LIBS="$saved_LIBS"
1760   fi
1761
1762   # Now check the MPC library
1763   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1764     saved_LIBS="$LIBS"
1765     LIBS="$LIBS $gmplibs"
1766     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1767     AC_TRY_LINK([#include <mpc.h>],[
1768     mpc_t c;
1769     mpc_init2 (c, 53);
1770     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1771     mpc_cosh (c, c, MPC_RNDNN);
1772     mpc_pow (c, c, c, MPC_RNDNN);
1773     mpc_acosh (c, c, MPC_RNDNN);
1774     mpc_clear (c);
1775     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1776     LIBS="$saved_LIBS"
1777   fi
1778
1779   CFLAGS="$saved_CFLAGS"
1780
1781 # The library versions listed in the error message below should match
1782 # the HARD-minimums enforced above.
1783   if test x$have_gmp != xyes; then
1784     if test -d ${srcdir}/gcc ; then
1785       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1786 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1787 their locations.  Source code for these libraries can be found at
1788 their respective hosting sites as well as at
1789 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1790 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1791 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1792 make sure that you have installed both the libraries and the header
1793 files.  They may be located in separate packages.])
1794     else
1795       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1796 Try the --with-gmp and/or --with-mpfr options to specify
1797 their locations.  If you obtained GMP and/or MPFR from a vendor
1798 distribution package, make sure that you have installed both the libraries
1799 and the header files.  They may be located in separate packages.])
1800     fi
1801   fi
1802 fi
1803
1804 # Flags needed for both GMP, MPFR and/or MPC.
1805 AC_SUBST(gmplibs)
1806 AC_SUBST(gmpinc)
1807 AC_SUBST(extra_mpfr_configure_flags)
1808 AC_SUBST(extra_mpc_gmp_configure_flags)
1809 AC_SUBST(extra_mpc_mpfr_configure_flags)
1810 AC_SUBST(extra_isl_gmp_configure_flags)
1811
1812 # Libraries to use for stage1 or when not bootstrapping.
1813 AC_ARG_WITH(stage1-libs,
1814 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1815 [if test "$withval" = "no" -o "$withval" = "yes"; then
1816    stage1_libs=
1817  else
1818    stage1_libs=$withval
1819  fi],
1820 [stage1_libs=])
1821 AC_SUBST(stage1_libs)
1822
1823 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1824 # default is yes if gcc is being built; no otherwise.  The reason for
1825 # this default is that gdb is sometimes linked against GNU Source
1826 # Highlight, which is a shared library that uses C++ exceptions.  In
1827 # this case, -static-libstdc++ will cause crashes.
1828 AC_ARG_WITH(static-standard-libraries,
1829 [AS_HELP_STRING([--with-static-standard-libraries],
1830                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1831 [], [with_static_standard_libraries=auto])
1832 if test "$with_static_standard_libraries" = auto; then
1833   with_static_standard_libraries=$have_compiler
1834 fi
1835
1836 # Linker flags to use for stage1 or when not bootstrapping.
1837 AC_ARG_WITH(stage1-ldflags,
1838 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1839 [if test "$withval" = "no" -o "$withval" = "yes"; then
1840    stage1_ldflags=
1841  else
1842    stage1_ldflags=$withval
1843  fi],
1844 [stage1_ldflags=
1845  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1846  # if supported.  But if the user explicitly specified the libraries to use,
1847  # trust that they are doing what they want.
1848  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1849      -a "$have_static_libs" = yes; then
1850    stage1_ldflags="-static-libstdc++ -static-libgcc"
1851  fi])
1852 AC_SUBST(stage1_ldflags)
1853
1854 # Libraries to use for stage2 and later builds.
1855 AC_ARG_WITH(boot-libs,
1856 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1857 [if test "$withval" = "no" -o "$withval" = "yes"; then
1858    poststage1_libs=
1859  else
1860    poststage1_libs=$withval
1861  fi],
1862 [poststage1_libs=])
1863 AC_SUBST(poststage1_libs)
1864
1865 # Linker flags to use for stage2 and later builds.
1866 AC_ARG_WITH(boot-ldflags,
1867 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1868                 [linker flags for stage2 and later])],
1869 [if test "$withval" = "no" -o "$withval" = "yes"; then
1870    poststage1_ldflags=
1871  else
1872    poststage1_ldflags=$withval
1873  fi],
1874 [poststage1_ldflags=
1875  # In stages 2 and 3, default to linking libstdc++ and libgcc
1876  # statically.  But if the user explicitly specified the libraries to
1877  # use, trust that they are doing what they want.
1878  if test "$poststage1_libs" = ""; then
1879    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1880  fi])
1881 case $target in
1882   *-darwin2* | *-darwin1[[56789]]*)
1883     # For these versions, we default to using embedded rpaths.
1884     if test "x$enable_darwin_at_rpath" != "xno"; then
1885       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1886     fi
1887   ;;
1888   *-darwin*)
1889     # For these versions, we only use embedded rpaths on demand.
1890     if test "x$enable_darwin_at_rpath" = "xyes"; then
1891       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1892     fi
1893   ;;
1894 esac
1895 AC_SUBST(poststage1_ldflags)
1896
1897 # GCC GRAPHITE dependency isl.
1898 # Basic setup is inlined here, actual checks are in config/isl.m4
1899
1900 AC_ARG_WITH(isl,
1901   [AS_HELP_STRING(
1902    [--with-isl=PATH],
1903    [Specify prefix directory for the installed isl package.
1904     Equivalent to --with-isl-include=PATH/include
1905     plus --with-isl-lib=PATH/lib])])
1906
1907 # Treat --without-isl as a request to disable
1908 # GRAPHITE support and skip all following checks.
1909 if test "x$with_isl" != "xno"; then
1910   # Check for isl
1911   dnl Provide configure switches and initialize islinc & isllibs
1912   dnl with user input.
1913   ISL_INIT_FLAGS
1914   dnl The versions of isl that work for Graphite
1915   ISL_CHECK_VERSION()
1916   dnl Only execute fail-action, if isl has been requested.
1917   ISL_IF_FAILED([
1918     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1919 fi
1920
1921 # If the isl check failed, disable builds of in-tree variant of isl
1922 if test "x$with_isl" = xno ||
1923    test "x$gcc_cv_isl" = xno; then
1924   noconfigdirs="$noconfigdirs isl"
1925   islinc=
1926 fi
1927
1928 AC_SUBST(isllibs)
1929 AC_SUBST(islinc)
1930
1931 # Check for LTO support.
1932 AC_ARG_ENABLE(lto,
1933 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1934 enable_lto=$enableval,
1935 enable_lto=yes; default_enable_lto=yes)
1936
1937 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1938   build_lto_plugin=yes
1939 ],[if test x"$default_enable_lto" = x"yes" ; then
1940     case $target in
1941       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1942       # On other non-ELF platforms, LTO has yet to be validated.
1943       *) enable_lto=no ;;
1944     esac
1945   else
1946   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1947   # It would also be nice to check the binutils support, but we don't
1948   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1949   # warn during gcc/ subconfigure; unless you're bootstrapping with
1950   # -flto it won't be needed until after installation anyway.
1951     case $target in
1952       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1953       *) if test x"$enable_lto" = x"yes"; then
1954         AC_MSG_ERROR([LTO support is not enabled for this target.])
1955         fi
1956       ;;
1957     esac
1958   fi
1959   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1960   # Build it unless LTO was explicitly disabled.
1961   case $target in
1962     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1963     *) ;;
1964   esac
1965 ])
1966
1967 AC_ARG_ENABLE(linker-plugin-configure-flags,
1968   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1969     [additional flags for configuring linker plugins @<:@none@:>@])],
1970   extra_linker_plugin_configure_flags=$enableval,
1971   extra_linker_plugin_configure_flags=)
1972 AC_SUBST(extra_linker_plugin_configure_flags)
1973 AC_ARG_ENABLE(linker-plugin-flags,
1974   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1975     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1976   extra_linker_plugin_flags=$enableval,
1977   extra_linker_plugin_flags=)
1978 AC_SUBST(extra_linker_plugin_flags)
1979
1980 # Handle --enable-host-pie
1981 # If host PIE executables are the default (or must be forced on) for some host,
1982 # we must pass that configuration to the gcc directory.
1983 gcc_host_pie=
1984 AC_ARG_ENABLE(host-pie,
1985 [AS_HELP_STRING([--enable-host-pie],
1986                 [build position independent host executables])],
1987 [host_pie=$enableval
1988  case $host in
1989    *-*-darwin2*)
1990      if test x$host_pie != xyes ; then
1991        # for Darwin20+ this is required.
1992        AC_MSG_WARN([PIE executables are required for the configured host, host-pie setting ignored.])
1993        host_pie=yes
1994        gcc_host_pie=--enable-host-pie
1995      fi ;;
1996   *) ;;
1997  esac],
1998 [case $host in
1999   *-*-darwin2*)
2000     # Default to PIE (mandatory for aarch64).
2001     host_pie=yes
2002     gcc_host_pie=--enable-host-pie
2003     ;;
2004   *) host_pie=no ;;
2005  esac])
2006
2007 AC_SUBST(host_pie)
2008 AC_SUBST(gcc_host_pie)
2009
2010 # Enable --enable-host-shared.
2011 # Checked early to determine whether jit is an 'all' language
2012 AC_ARG_ENABLE(host-shared,
2013 [AS_HELP_STRING([--enable-host-shared],
2014                 [build host code as shared libraries])],
2015 [host_shared=$enableval
2016  case $host in
2017    x86_64-*-darwin* | aarch64-*-darwin*)
2018      if test x$host_shared != xyes ; then
2019        # PIC is the default, and actually cannot be switched off.
2020        AC_MSG_WARN([PIC code is required for the configured host; host-shared setting ignored.])
2021        host_shared=yes
2022      fi ;;
2023    *-*-darwin*)
2024      if test x$host_pie = xyes -a x$host_shared != xyes ; then
2025        AC_MSG_WARN([PIC code is required for PIE host executables host-shared setting ignored.])
2026        host_shared=yes
2027      fi ;;
2028   *) ;;
2029  esac],
2030 [case $host in
2031   # 64B x86_64 and Aarch64 Darwin default to PIC.
2032   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
2033   # 32B and powerpc64 Darwin must use PIC to link PIE exes.
2034   *-*-darwin*) host_shared=$host_pie ;;
2035   *) host_shared=no;;
2036  esac])
2037
2038 AC_SUBST(host_shared)
2039
2040 if test x$host_shared = xyes; then
2041   case $host in
2042     *-*-darwin*)
2043       # Since host shared is the default for 64b Darwin, and also enabled for
2044       # host_pie, ensure that we present the PIE flag when host_pie is active.
2045       if test x$host_pie = xyes; then
2046         PICFLAG=-fPIE
2047       fi
2048       ;;
2049     *)
2050       PICFLAG=-fPIC
2051       ;;
2052   esac
2053 elif test x$host_pie = xyes; then
2054   PICFLAG=-fPIE
2055 else
2056   PICFLAG=
2057 fi
2058
2059 AC_SUBST(PICFLAG)
2060
2061
2062 # Check for libdiagnostics support.
2063 AC_MSG_CHECKING([whether to enable libdiagnostics])
2064 AC_ARG_ENABLE(libdiagnostics,
2065 [AS_HELP_STRING([--enable-libdiagnostics],
2066                 [build libdiagnostics shared library])],
2067 enable_libdiagnostics=$enableval,
2068 enable_libdiagnostics=no)
2069
2070 if test x$enable_libdiagnostics = xyes; then
2071   # Disable libdiagnostics if -enable-host-shared not specified
2072   # but not if building for Mingw. All code in Windows
2073   # is position independent code (PIC).
2074   case $target in
2075      *mingw*) ;;
2076      *)
2077        if test x$host_shared != xyes; then
2078          AC_MSG_ERROR([
2079 Enabling libdiagnostics requires --enable-host-shared.
2080
2081 --enable-host-shared typically slows the rest of the compiler down by
2082 a few %, so you must explicitly enable it.
2083
2084 If you want to build both libdiagnostics and the regular compiler, it is often
2085 best to do this via two separate configure/builds, in separate
2086 directories, to avoid imposing the performance cost of
2087 --enable-host-shared on the regular compiler.])
2088        fi
2089        ;;
2090    esac
2091 fi
2092 AC_MSG_RESULT($enable_libdiagnostics)
2093 AC_SUBST(enable_libdiagnostics)
2094
2095
2096 # Rust requires -ldl and -lpthread if you are using an old glibc that does not include them by
2097 # default, so we check for them here
2098 # We are doing the test here and not in the gcc/configure to be able to nicely disable the
2099 # build of the Rust frontend in case a dep is missing.
2100 missing_rust_dynlibs=none
2101
2102 save_LIBS="$LIBS"
2103 LIBS=
2104 AC_SEARCH_LIBS([dlopen], [dl])
2105 AC_SEARCH_LIBS([pthread_create], [pthread])
2106 CRAB1_LIBS="$LIBS"
2107 LIBS="$save_LIBS"
2108
2109 if test "$ac_cv_search_dlopen" = no; then
2110     missing_rust_dynlibs="libdl"
2111 fi
2112
2113 if test "$ac_cv_search_pthread_create" = no; then
2114     missing_rust_dynlibs="$missing_rust_dynlibs, libpthread"
2115 fi
2116
2117 AC_SUBST(CRAB1_LIBS, "$CRAB1_LIBS")
2118
2119 # If we are building PIC/PIE host executables, and we are building dependent
2120 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
2121 # code.
2122 host_libs_picflag=
2123 if test "$host_shared" = "yes" -o "$host_pie" = "yes"; then
2124 host_libs_picflag='--with-pic'
2125 fi
2126 AC_SUBST(host_libs_picflag)
2127
2128 # By default, C and C++ are the only stage 1 languages.
2129 stage1_languages=,c,
2130
2131 # Target libraries that we bootstrap.
2132 bootstrap_target_libs=,target-libgcc,
2133
2134 # Figure out what language subdirectories are present.
2135 # Look if the user specified --enable-languages="..."; if not, use
2136 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2137 # go away some day.
2138 # NB:  embedded tabs in this IF block -- do not untabify
2139 if test -d ${srcdir}/gcc; then
2140   if test x"${enable_languages+set}" != xset; then
2141     if test x"${LANGUAGES+set}" = xset; then
2142       enable_languages="${LANGUAGES}"
2143         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
2144     else
2145       enable_languages=default
2146     fi
2147   else
2148     if test x"${enable_languages}" = x ||
2149        test x"${enable_languages}" = xyes;
2150        then
2151       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2152       exit 1
2153     fi
2154   fi
2155   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2156
2157   # 'f95' is the old name for the 'fortran' language. We issue a warning
2158   # and make the substitution.
2159   case ,${enable_languages}, in
2160     *,f95,*)
2161       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2162       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2163       ;;
2164   esac
2165
2166   # If bootstrapping, C++ must be enabled.
2167   case ",$enable_languages,:$enable_bootstrap" in
2168     *,c++,*:*) ;;
2169     *:yes)
2170       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2171         enable_languages="${enable_languages},c++"
2172       else
2173         AC_MSG_ERROR([bootstrapping requires c++ sources])
2174       fi
2175       ;;
2176   esac
2177
2178   # First scan to see if an enabled language requires some other language.
2179   # We assume that a given config-lang.in will list all the language
2180   # front ends it requires, even if some are required indirectly.
2181   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2182     case ${lang_frag} in
2183       ..) ;;
2184       # The odd quoting in the next line works around
2185       # an apparent bug in bash 1.12 on linux.
2186       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2187       *)
2188         # From the config-lang.in, get $language, $lang_requires, and
2189         # $lang_requires_boot_languages.
2190         language=
2191         lang_requires=
2192         lang_requires_boot_languages=
2193         # set srcdir during sourcing lang_frag to the gcc dir.
2194         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2195         # pollutes this shell
2196         saved_srcdir=${srcdir}
2197         srcdir=${srcdir}/gcc . ${lang_frag}
2198         srcdir=${saved_srcdir}
2199         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2200           case ,${enable_languages}, in
2201             *,$other,*) ;;
2202             *,default,*) ;;
2203             *,all,*) ;;
2204             *,$language,*)
2205               echo " \`$other' language required by \`$language'; enabling" 1>&2
2206               enable_languages="${enable_languages},${other}"
2207               ;;
2208           esac
2209         done
2210         for other in ${lang_requires_boot_languages} ; do
2211           if test "$other" != "c"; then
2212             case ,${enable_stage1_languages}, in
2213               *,$other,*) ;;
2214               *,default,*) ;;
2215               *,all,*) ;;
2216               *)
2217                 case ,${enable_languages}, in
2218                   *,$language,*)
2219                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2220                     enable_stage1_languages="$enable_stage1_languages,${other}"
2221                     ;;
2222                 esac
2223                 ;;
2224             esac
2225           fi
2226         done
2227         ;;
2228     esac
2229   done
2230
2231   new_enable_languages=,c,
2232
2233   # If LTO is enabled, add the LTO front end.
2234   if test "$enable_lto" = "yes" ; then
2235     case ,${enable_languages}, in
2236       *,lto,*) ;;
2237       *) enable_languages="${enable_languages},lto" ;;
2238     esac
2239     if test "${build_lto_plugin}" = "yes" ; then
2240       configdirs="$configdirs lto-plugin"
2241     fi
2242   fi
2243
2244   # If we're building an offloading compiler, add the LTO front end.
2245   if test x"$enable_as_accelerator_for" != x ; then
2246     case ,${enable_languages}, in
2247       *,lto,*) ;;
2248       *) enable_languages="${enable_languages},lto" ;;
2249     esac
2250   fi
2251
2252   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2253   potential_languages=,c,
2254
2255   enabled_target_libs=
2256   disabled_target_libs=
2257
2258   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2259     case ${lang_frag} in
2260       ..) ;;
2261       # The odd quoting in the next line works around
2262       # an apparent bug in bash 1.12 on linux.
2263       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2264       *)
2265         # From the config-lang.in, get $language, $target_libs,
2266         # $lang_dirs, $boot_language, and $build_by_default
2267         language=
2268         target_libs=
2269         lang_dirs=
2270         subdir_requires=
2271         boot_language=no
2272         build_by_default=yes
2273         # set srcdir during sourcing.  See above about save & restore
2274         saved_srcdir=${srcdir}
2275         srcdir=${srcdir}/gcc . ${lang_frag}
2276         srcdir=${saved_srcdir}
2277         if test x${language} = x; then
2278           echo "${lang_frag} doesn't set \$language." 1>&2
2279           exit 1
2280         fi
2281
2282         if test "$language" = "c++"; then
2283           boot_language=yes
2284         fi
2285
2286         add_this_lang=no
2287         # C is always enabled, so no need to add it again
2288         if test "$language" != "c"; then
2289           case ,${enable_languages}, in
2290             *,${language},*)
2291               # Language was explicitly selected; include it
2292               add_this_lang=yes
2293               ;;
2294             *,all,*)
2295               # All languages are enabled
2296               add_this_lang=all
2297               ;;
2298             *,default,*)
2299               # 'default' was selected, select it if it is a default language
2300               add_this_lang=${build_by_default}
2301               ;;
2302           esac
2303         fi
2304
2305         # Disable languages that need other directories if these aren't available.
2306         for i in $subdir_requires; do
2307           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2308           case ${add_this_lang} in
2309             yes)
2310               # Specifically requested language; tell them.
2311               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2312               ;;
2313             all)
2314               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2315               add_this_lang=unsupported
2316               ;;
2317             *)
2318               # Silently disable.
2319               add_this_lang=unsupported
2320               ;;
2321           esac
2322         done
2323
2324         # Disable Ada if no preexisting GNAT is available.
2325         case ${add_this_lang}:${language}:${have_gnat} in
2326           yes:ada:no)
2327             # Specifically requested language; tell them.
2328             AC_MSG_ERROR([GNAT is required to build $language])
2329             ;;
2330           all:ada:no)
2331             AC_MSG_WARN([GNAT is required to build $language])
2332             add_this_lang=unsupported
2333             ;;
2334           *:ada:no)
2335             # Silently disable.
2336             add_this_lang=unsupported
2337             ;;
2338         esac
2339
2340         # Disable D if no preexisting GDC is available.
2341         case ${add_this_lang}:${language}:${have_gdc} in
2342           yes:d:no)
2343             # Specifically requested language; tell them.
2344             AC_MSG_ERROR([GDC is required to build $language])
2345            ;;
2346           all:d:no)
2347             AC_MSG_WARN([GDC is required to build $language])
2348             add_this_lang=unsupported
2349             ;;
2350           *:d:no)
2351             # Silently disable.
2352             add_this_lang=unsupported
2353             ;;
2354         esac
2355
2356         # Disable Rust if we are missing some required C libraries for the Rust runtime.
2357         case ${add_this_lang}:${language}:${missing_rust_dynlibs} in
2358           *:rust:none)
2359             # Nothing to do - we're not missing any C libraries
2360             ;;
2361           yes:rust:*)
2362             AC_MSG_ERROR([some C libraries are required to build $language: $missing_rust_dynlibs])
2363             add_this_lang=unsupported
2364             ;;
2365           all:rust:*)
2366             AC_MSG_WARN([some C libraries are required to build $language: $missing_rust_dynlibs])
2367             add_this_lang=unsupported
2368             ;;
2369           *:rust:*)
2370             # Silently disable.
2371             add_this_lang=unsupported
2372             ;;
2373         esac
2374
2375         # Disable jit if -enable-host-shared not specified
2376         # but not if building for Mingw. All code in Windows
2377         # is position independent code (PIC).
2378         case $target in
2379           *mingw*) ;;
2380           *)
2381           case ${add_this_lang}:${language}:${host_shared} in
2382             yes:jit:no)
2383                    # PR jit/64780: explicitly specify --enable-host-shared
2384             AC_MSG_ERROR([
2385 Enabling language "jit" requires --enable-host-shared.
2386
2387 --enable-host-shared typically slows the rest of the compiler down by
2388 a few %, so you must explicitly enable it.
2389
2390 If you want to build both the jit and the regular compiler, it is often
2391 best to do this via two separate configure/builds, in separate
2392 directories, to avoid imposing the performance cost of
2393 --enable-host-shared on the regular compiler.])
2394                     ;;
2395             all:jit:no)
2396               AC_MSG_WARN([--enable-host-shared required to build $language])
2397               add_this_lang=unsupported
2398               ;;
2399             *:jit:no)
2400               # Silently disable.
2401               add_this_lang=unsupported
2402               ;;
2403                 esac
2404           ;;
2405         esac
2406
2407         # Pre-conditions to consider whether cargo being supported.
2408         if test x"$have_cargo" = xyes \
2409           && test x"$build" != x"$host"; then
2410           # Until <https://github.com/Rust-GCC/gccrs/issues/2898>
2411           # "'cargo' should build for the host system" is resolved:
2412           AC_MSG_WARN([use of cargo not yet supported here in Canadian cross configurations])
2413           have_cargo=no
2414         else
2415           # Assume that cargo-produced object files are compatible with what
2416           # we're going to build here.
2417           :
2418         fi
2419         # Disable Rust if cargo is unavailable.
2420         case ${add_this_lang}:${language}:${have_cargo} in
2421           yes:rust:no)
2422             # Specifically requested language; tell them.
2423             AC_MSG_ERROR([cargo is required to build $language])
2424             ;;
2425           all:rust:no)
2426             AC_MSG_WARN([cargo is required to build $language])
2427             add_this_lang=unsupported
2428             ;;
2429           *:rust:no)
2430             # Silently disable.
2431             add_this_lang=unsupported
2432             ;;
2433         esac
2434
2435
2436         # Disable a language that is unsupported by the target.
2437         case "${add_this_lang}: $unsupported_languages " in
2438           no:*) ;;
2439           unsupported:*) ;;
2440           *:*" $language "*)
2441             AC_MSG_WARN([${language} not supported for this target])
2442             add_this_lang=unsupported
2443             ;;
2444         esac
2445
2446         case $add_this_lang in
2447           unsupported)
2448             # Remove language-dependent dirs.
2449             disabled_target_libs="$disabled_target_libs $target_libs"
2450             noconfigdirs="$noconfigdirs $lang_dirs"
2451             ;;
2452           no)
2453             # Remove language-dependent dirs; still show language as supported.
2454             disabled_target_libs="$disabled_target_libs $target_libs"
2455             noconfigdirs="$noconfigdirs $lang_dirs"
2456             potential_languages="${potential_languages}${language},"
2457             ;;
2458           all|yes)
2459             new_enable_languages="${new_enable_languages}${language},"
2460             potential_languages="${potential_languages}${language},"
2461             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2462             enabled_target_libs="$enabled_target_libs $target_libs"
2463             case "${boot_language}:,$enable_stage1_languages," in
2464               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2465                 # Add to (comma-separated) list of stage 1 languages.
2466                 case ",$stage1_languages," in
2467                   *,$language,* | ,yes, | ,all,) ;;
2468                   *) stage1_languages="${stage1_languages}${language}," ;;
2469                 esac
2470                 # We need to bootstrap any supporting libraries.
2471                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2472                 ;;
2473             esac
2474             ;;
2475         esac
2476         ;;
2477     esac
2478   done
2479
2480   # Add target libraries which are only needed for disabled languages
2481   # to noconfigdirs.
2482   if test -n "$disabled_target_libs"; then
2483     for dir in $disabled_target_libs; do
2484       case " $enabled_target_libs " in
2485       *" ${dir} "*) ;;
2486       *) noconfigdirs="$noconfigdirs $dir" ;;
2487       esac
2488     done
2489   fi
2490
2491   AC_ARG_ENABLE(stage1-languages,
2492   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2493                   [choose additional languages to build during
2494                   stage1.  Mostly useful for compiler development])],
2495   [case ,${enable_stage1_languages}, in
2496     ,no,|,,)
2497       # Set it to something that will have no effect in the loop below
2498       enable_stage1_languages=c ;;
2499     ,yes,)
2500       enable_stage1_languages=`echo $new_enable_languages | \
2501         sed -e "s/^,//" -e "s/,$//" ` ;;
2502     *,all,*)
2503       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2504         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2505   esac
2506
2507   # Add "good" languages from enable_stage1_languages to stage1_languages,
2508   # while "bad" languages go in missing_languages.  Leave no duplicates.
2509   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2510     case $potential_languages in
2511       *,$i,*)
2512         case $stage1_languages in
2513           *,$i,*) ;;
2514           *) stage1_languages="$stage1_languages$i," ;;
2515         esac ;;
2516       *)
2517         case $missing_languages in
2518           *,$i,*) ;;
2519           *) missing_languages="$missing_languages$i," ;;
2520         esac ;;
2521      esac
2522   done])
2523
2524   # Remove leading/trailing commas that were added for simplicity
2525   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2526   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2527   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2528   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2529
2530   if test "x$missing_languages" != x; then
2531     AC_MSG_ERROR([
2532 The following requested languages could not be built: ${missing_languages}
2533 Supported languages are: ${potential_languages}])
2534   fi
2535   if test "x$new_enable_languages" != "x$enable_languages"; then
2536     echo The following languages will be built: ${new_enable_languages}
2537     enable_languages="$new_enable_languages"
2538   fi
2539
2540   AC_SUBST(stage1_languages)
2541   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2542 fi
2543
2544 # Handle --disable-<component> generically.
2545 for dir in $configdirs $build_configdirs $target_configdirs ; do
2546   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2547   varname=`echo $dirname | sed -e s/+/_/g`
2548   if eval test x\${enable_${varname}} "=" xno ; then
2549     noconfigdirs="$noconfigdirs $dir"
2550   fi
2551 done
2552
2553 # Check for Boehm's garbage collector
2554 AC_ARG_ENABLE(objc-gc,
2555 [AS_HELP_STRING([--enable-objc-gc],
2556                 [enable use of Boehm's garbage collector with the
2557                  GNU Objective-C runtime])])
2558 AC_ARG_WITH([target-bdw-gc],
2559 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2560                 [specify prefix directory for installed bdw-gc package.
2561                  Equivalent to --with-target-bdw-gc-include=PATH/include
2562                  plus --with-target-bdw-gc-lib=PATH/lib])])
2563 AC_ARG_WITH([target-bdw-gc-include],
2564 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2565                 [specify directories for installed bdw-gc include files])])
2566 AC_ARG_WITH([target-bdw-gc-lib],
2567 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2568                 [specify directories for installed bdw-gc library])])
2569
2570 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2571   AC_MSG_CHECKING([for bdw garbage collector])
2572   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2573     dnl no bdw-gw options, assume default locations
2574     AC_MSG_RESULT([using bdw-gc in default locations])
2575   else
2576     dnl bdw-gw options, first error checking, complete checking in libobjc
2577     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2578       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2579     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2580       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2581     else
2582       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2583     fi
2584   fi
2585 esac
2586
2587 # Disable libitm, libsanitizer, libvtv if we're not building C++
2588 case ,${enable_languages}, in
2589   *,c++,*)
2590     # Disable libitm, libsanitizer if we're not building libstdc++
2591     case "${noconfigdirs}" in
2592       *target-libstdc++-v3*)
2593         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2594         ;;
2595       *) ;;
2596     esac
2597     ;;
2598   *)
2599     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2600     ;;
2601 esac
2602
2603 case ,${enable_languages}, in
2604   *,rust,*)
2605     case " ${noconfigdirs} " in
2606       *\ target-libstdc++-v3\ *)
2607         # Disable target libgrust if we're not building target libstdc++.
2608         noconfigdirs="$noconfigdirs target-libgrust"
2609         ;;
2610     esac
2611     ;;
2612 esac
2613
2614 # If gcc/ is not in the source tree then we'll not be building a
2615 # target compiler, assume in that case we don't want to build any
2616 # target libraries or tools.
2617 #
2618 # This was added primarily for the benefit for binutils-gdb who reuse
2619 # this configure script, but don't always have target tools available.
2620 if test ! -d ${srcdir}/gcc; then
2621    skipdirs="${skipdirs} ${target_configdirs}"
2622 fi
2623
2624 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2625 # $build_configdirs and $target_configdirs.
2626 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2627
2628 notsupp=""
2629 for dir in . $skipdirs $noconfigdirs ; do
2630   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2631   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2632     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2633     if test -r $srcdir/$dirname/configure ; then
2634       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2635         true
2636       else
2637         notsupp="$notsupp $dir"
2638       fi
2639     fi
2640   fi
2641   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2642     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2643     if test -r $srcdir/$dirname/configure ; then
2644       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2645         true
2646       else
2647         notsupp="$notsupp $dir"
2648       fi
2649     fi
2650   fi
2651   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2652     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2653     if test -r $srcdir/$dirname/configure ; then
2654       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2655         true
2656       else
2657         notsupp="$notsupp $dir"
2658       fi
2659     fi
2660   fi
2661 done
2662
2663 # Quietly strip out all directories which aren't configurable in this tree.
2664 # This relies on all configurable subdirectories being autoconfiscated, which
2665 # is now the case.
2666 build_configdirs_all="$build_configdirs"
2667 build_configdirs=
2668 for i in ${build_configdirs_all} ; do
2669   j=`echo $i | sed -e s/build-//g`
2670   if test -f ${srcdir}/$j/configure ; then
2671     build_configdirs="${build_configdirs} $i"
2672   fi
2673 done
2674
2675 configdirs_all="$configdirs"
2676 configdirs=
2677 for i in ${configdirs_all} ; do
2678   if test -f ${srcdir}/$i/configure ; then
2679     configdirs="${configdirs} $i"
2680   fi
2681 done
2682
2683 target_configdirs_all="$target_configdirs"
2684 target_configdirs=
2685 for i in ${target_configdirs_all} ; do
2686   j=`echo $i | sed -e s/target-//g`
2687   if test -f ${srcdir}/$j/configure ; then
2688     target_configdirs="${target_configdirs} $i"
2689   fi
2690 done
2691
2692 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2693 # so we have to add it after the preceding checks.
2694 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2695 then
2696   case " $configdirs " in
2697     *" libiberty "*)
2698       # If we can build libiberty, we can also build libiberty-linker-plugin.
2699       configdirs="$configdirs libiberty-linker-plugin"
2700       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2701         --with-libiberty=../libiberty-linker-plugin";;
2702     *)
2703       AC_MSG_ERROR([libiberty missing]);;
2704   esac
2705 fi
2706
2707 # Sometimes we have special requirements for the host libiberty.
2708 extra_host_libiberty_configure_flags=
2709 case " $configdirs " in
2710   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2711     # When these are to be built as shared libraries, the same applies to
2712     # libiberty.
2713     extra_host_libiberty_configure_flags=--enable-shared
2714     ;;
2715 esac
2716 AC_SUBST(extra_host_libiberty_configure_flags)
2717
2718 # Sometimes we have special requirements for the host zlib.
2719 extra_host_zlib_configure_flags=
2720 case " $configdirs " in
2721   *" bfd "*)
2722     # When bfd is to be built as a shared library, the same applies to
2723     # zlib.
2724     if test "$enable_shared" = "yes"; then
2725       extra_host_zlib_configure_flags=--enable-host-shared
2726     fi
2727     ;;
2728 esac
2729 AC_SUBST(extra_host_zlib_configure_flags)
2730
2731 # Produce a warning message for the subdirs we can't configure.
2732 # This isn't especially interesting in the Cygnus tree, but in the individual
2733 # FSF releases, it's important to let people know when their machine isn't
2734 # supported by the one or two programs in a package.
2735
2736 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2737   # If $appdirs is non-empty, at least one of those directories must still
2738   # be configured, or we error out.  (E.g., if the gas release supports a
2739   # specified target in some subdirs but not the gas subdir, we shouldn't
2740   # pretend that all is well.)
2741   if test -n "$appdirs" ; then
2742     for dir in $appdirs ; do
2743       if test -r $dir/Makefile.in ; then
2744         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2745           appdirs=""
2746           break
2747         fi
2748         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2749           appdirs=""
2750           break
2751         fi
2752       fi
2753     done
2754     if test -n "$appdirs" ; then
2755       echo "*** This configuration is not supported by this package." 1>&2
2756       exit 1
2757     fi
2758   fi
2759   # Okay, some application will build, or we don't care to check.  Still
2760   # notify of subdirs not getting built.
2761   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2762   echo "    ${notsupp}" 1>&2
2763   echo "    (Any other directories should still work fine.)" 1>&2
2764 fi
2765
2766 case "$host" in
2767   *msdosdjgpp*)
2768     enable_gdbtk=no ;;
2769 esac
2770
2771 # To find our prefix, in gcc_cv_tool_prefix.
2772 ACX_TOOL_DIRS
2773
2774 copy_dirs=
2775
2776 AC_ARG_WITH([build-sysroot],
2777   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2778                   [use sysroot as the system root during the build])],
2779   [if test x"$withval" != x ; then
2780      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2781    fi],
2782   [SYSROOT_CFLAGS_FOR_TARGET=])
2783 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2784
2785 AC_ARG_WITH([debug-prefix-map],
2786   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2787                   [map A to B, C to D ... in debug information])],
2788   [if test x"$withval" != x; then
2789      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2790      for debug_map in $withval; do
2791        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2792      done
2793    fi],
2794   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2795 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2796
2797 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2798 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2799 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2800 # We want to ensure that TARGET libraries (which we know are built with
2801 # gcc) are built with "-O2 -g", so include those options when setting
2802 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2803 if test "x$CFLAGS_FOR_TARGET" = x; then
2804   if test "x${is_cross_compiler}" = xyes; then
2805     CFLAGS_FOR_TARGET="-g -O2"
2806   else
2807     CFLAGS_FOR_TARGET=$CFLAGS
2808     case " $CFLAGS " in
2809       *" -O2 "*) ;;
2810       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2811     esac
2812     case " $CFLAGS " in
2813       *" -g "* | *" -g3 "*) ;;
2814       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2815     esac
2816   fi
2817 fi
2818 AC_SUBST(CFLAGS_FOR_TARGET)
2819
2820 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2821   if test "x${is_cross_compiler}" = xyes; then
2822     CXXFLAGS_FOR_TARGET="-g -O2"
2823   else
2824     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2825     case " $CXXFLAGS " in
2826       *" -O2 "*) ;;
2827       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2828     esac
2829     case " $CXXFLAGS " in
2830       *" -g "* | *" -g3 "*) ;;
2831       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2832     esac
2833   fi
2834 fi
2835 AC_SUBST(CXXFLAGS_FOR_TARGET)
2836
2837 AC_SUBST(LDFLAGS_FOR_TARGET)
2838
2839 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2840 # the named directory are copied to $(tooldir)/sys-include.
2841 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2842   if test x${is_cross_compiler} = xno ; then
2843     echo 1>&2 '***' --with-headers is only supported when cross compiling
2844     exit 1
2845   fi
2846   if test x"${with_headers}" != xyes ; then
2847     x=${gcc_cv_tool_prefix}
2848     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2849   fi
2850 fi
2851
2852 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2853 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2854 # are permitted.
2855 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2856   if test x${is_cross_compiler} = xno ; then
2857     echo 1>&2 '***' --with-libs is only supported when cross compiling
2858     exit 1
2859   fi
2860   if test x"${with_libs}" != xyes ; then
2861     # Copy the libraries in reverse order, so that files in the first named
2862     # library override files in subsequent libraries.
2863     x=${gcc_cv_tool_prefix}
2864     for l in ${with_libs}; do
2865       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2866     done
2867   fi
2868 fi
2869
2870 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2871 #
2872 # This is done by determining whether or not the appropriate directory
2873 # is available, and by checking whether or not specific configurations
2874 # have requested that this magic not happen.
2875 #
2876 # The command line options always override the explicit settings in
2877 # configure.ac, and the settings in configure.ac override this magic.
2878 #
2879 # If the default for a toolchain is to use GNU as and ld, and you don't
2880 # want to do that, then you should use the --without-gnu-as and
2881 # --without-gnu-ld options for the configure script.  Similarly, if
2882 # the default is to use the included zlib and you don't want to do that,
2883 # you should use the --with-system-zlib option for the configure script.
2884
2885 if test x${use_gnu_as} = x &&
2886    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2887   with_gnu_as=yes
2888   extra_host_args="$extra_host_args --with-gnu-as"
2889 fi
2890
2891 if test x${use_gnu_ld} = x &&
2892    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2893   with_gnu_ld=yes
2894   extra_host_args="$extra_host_args --with-gnu-ld"
2895 fi
2896
2897 if test x${use_included_zlib} = x &&
2898    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2899   :
2900 else
2901   with_system_zlib=yes
2902   extra_host_args="$extra_host_args --with-system-zlib"
2903 fi
2904
2905 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2906 # can detect this case.
2907
2908 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2909   with_newlib=yes
2910   extra_host_args="$extra_host_args --with-newlib"
2911 fi
2912
2913 # Handle ${copy_dirs}
2914 set fnord ${copy_dirs}
2915 shift
2916 while test $# != 0 ; do
2917   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2918     :
2919   else
2920     echo Copying $1 to $2
2921
2922     # Use the install script to create the directory and all required
2923     # parent directories.
2924     if test -d $2 ; then
2925       :
2926     else
2927       echo >config.temp
2928       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2929     fi
2930
2931     # Copy the directory, assuming we have tar.
2932     # FIXME: Should we use B in the second tar?  Not all systems support it.
2933     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2934
2935     # It is the responsibility of the user to correctly adjust all
2936     # symlinks.  If somebody can figure out how to handle them correctly
2937     # here, feel free to add the code.
2938
2939     echo $1 > $2/COPIED
2940   fi
2941   shift; shift
2942 done
2943
2944 # Determine a target-dependent exec_prefix that the installed
2945 # gcc will search in.  Keep this list sorted by triplet, with
2946 # the *-*-osname triplets last.
2947 md_exec_prefix=
2948 case "${target}" in
2949   i[[34567]]86-pc-msdosdjgpp*)
2950     md_exec_prefix=/dev/env/DJDIR/bin
2951     ;;
2952   *-*-hpux* | \
2953   *-*-nto-qnx* | \
2954   *-*-solaris2*)
2955     md_exec_prefix=/usr/ccs/bin
2956     ;;
2957 esac
2958
2959 extra_arflags_for_target=
2960 extra_nmflags_for_target=
2961 extra_ranlibflags_for_target=
2962 target_makefile_frag=/dev/null
2963 case "${target}" in
2964   spu-*-*)
2965     target_makefile_frag="config/mt-spu"
2966     ;;
2967   loongarch*-*linux* | loongarch*-*gnu*)
2968     target_makefile_frag="config/mt-loongarch-gnu"
2969     ;;
2970   loongarch*-*elf*)
2971     target_makefile_frag="config/mt-loongarch-elf"
2972     ;;
2973   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2974     target_makefile_frag="config/mt-sde"
2975     ;;
2976   mipsisa*-*-elfoabi*)
2977     target_makefile_frag="config/mt-mips-elfoabi"
2978     ;;
2979   mips*-*-*linux* | mips*-*-gnu*)
2980     target_makefile_frag="config/mt-mips-gnu"
2981     ;;
2982   *-*-linux-android*)
2983     target_makefile_frag="config/mt-android"
2984     ;;
2985   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2986     target_makefile_frag="config/mt-gnu"
2987     ;;
2988   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2989     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2990     # commands to handle both 32-bit and 64-bit objects.  These flags are
2991     # harmless if we're using GNU nm or ar.
2992     extra_arflags_for_target=" -X32_64"
2993     extra_nmflags_for_target=" -B -X32_64"
2994     ;;
2995 esac
2996
2997 alphaieee_frag=/dev/null
2998 case $target in
2999   alpha*-*-*)
3000     # This just makes sure to use the -mieee option to build target libs.
3001     # This should probably be set individually by each library.
3002     alphaieee_frag="config/mt-alphaieee"
3003     ;;
3004 esac
3005
3006 # If --enable-target-optspace always use -Os instead of -O2 to build
3007 # the target libraries, similarly if it is not specified, use -Os
3008 # on selected platforms.
3009 ospace_frag=/dev/null
3010 case "${enable_target_optspace}:${target}" in
3011   yes:*)
3012     ospace_frag="config/mt-ospace"
3013     ;;
3014   :d30v-*)
3015     ospace_frag="config/mt-d30v"
3016     ;;
3017   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
3018     ospace_frag="config/mt-ospace"
3019     ;;
3020   no:* | :*)
3021     ;;
3022   *)
3023     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
3024     ;;
3025 esac
3026
3027 # Some systems (e.g., one of the i386-aix systems the gas testers are
3028 # using) don't handle "\$" correctly, so don't use it here.
3029 tooldir='${exec_prefix}'/${target_noncanonical}
3030 build_tooldir=${tooldir}
3031
3032 # Create a .gdbinit file which runs the one in srcdir
3033 # and tells GDB to look there for source files.
3034
3035 if test -r ${srcdir}/.gdbinit ; then
3036   case ${srcdir} in
3037     .) ;;
3038     *) cat > ./.gdbinit <<EOF
3039 # ${NO_EDIT}
3040 dir ${srcdir}
3041 dir .
3042 source ${srcdir}/.gdbinit
3043 EOF
3044     ;;
3045   esac
3046 fi
3047
3048 # Make sure that the compiler is able to generate an executable.  If it
3049 # can't, we are probably in trouble.  We don't care whether we can run the
3050 # executable--we might be using a cross compiler--we only care whether it
3051 # can be created.  At this point the main configure script has set CC.
3052 we_are_ok=no
3053 echo "int main () { return 0; }" > conftest.c
3054 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3055 if test $? = 0 ; then
3056   if test -s conftest || test -s conftest.exe ; then
3057     we_are_ok=yes
3058   fi
3059 fi
3060 case $we_are_ok in
3061   no)
3062     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
3063     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
3064     rm -f conftest*
3065     exit 1
3066     ;;
3067 esac
3068 rm -f conftest*
3069
3070 # Decide which environment variable is used to find dynamic libraries.
3071 case "${host}" in
3072   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
3073   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
3074   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
3075   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
3076 esac
3077
3078 # On systems where the dynamic library environment variable is PATH,
3079 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
3080 # built executables to PATH.
3081 if test "$RPATH_ENVVAR" = PATH; then
3082   GCC_SHLIB_SUBDIR=/shlib
3083 else
3084   GCC_SHLIB_SUBDIR=
3085 fi
3086
3087 # Adjust the toplevel makefile according to whether bootstrap was selected.
3088 case $enable_bootstrap in
3089   yes)
3090     bootstrap_suffix=bootstrap
3091     BUILD_CONFIG=bootstrap-debug
3092     ;;
3093   no)
3094     bootstrap_suffix=no-bootstrap
3095     BUILD_CONFIG=
3096     ;;
3097 esac
3098
3099 AC_MSG_CHECKING(for default BUILD_CONFIG)
3100
3101 AC_ARG_WITH([build-config],
3102   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
3103                   [use config/NAME.mk build configuration])],
3104   [case $with_build_config in
3105    yes) with_build_config= ;;
3106    no) with_build_config= BUILD_CONFIG= ;;
3107    esac])
3108
3109 if test "x${with_build_config}" != x; then
3110   BUILD_CONFIG=$with_build_config
3111 else
3112   case $BUILD_CONFIG in
3113   bootstrap-debug)
3114     if echo "int f (void) { return 0; }" > conftest.c &&
3115        ${CC} -c conftest.c &&
3116        mv conftest.o conftest.o.g0 &&
3117        ${CC} -c -g conftest.c &&
3118        mv conftest.o conftest.o.g &&
3119        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
3120       :
3121     else
3122       BUILD_CONFIG=
3123     fi
3124     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
3125     ;;
3126   esac
3127 fi
3128 AC_MSG_RESULT($BUILD_CONFIG)
3129 AC_SUBST(BUILD_CONFIG)
3130
3131 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
3132 AC_MSG_CHECKING([for --enable-vtable-verify])
3133 AC_ARG_ENABLE(vtable-verify,
3134 [AS_HELP_STRING([--enable-vtable-verify],
3135                 [Enable vtable verification feature])],
3136 [case "$enableval" in
3137  yes) enable_vtable_verify=yes ;;
3138  no)  enable_vtable_verify=no ;;
3139  *)   enable_vtable_verify=no;;
3140  esac],
3141 [enable_vtable_verify=no])
3142 AC_MSG_RESULT($enable_vtable_verify)
3143
3144 # Record target_configdirs and the configure arguments for target and
3145 # build configuration in Makefile.
3146 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
3147 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
3148 bootstrap_fixincludes=no
3149
3150 # If we are building libgomp, bootstrap it.
3151 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
3152   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
3153 fi
3154
3155 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
3156 # or bootstrap-ubsan, bootstrap it.
3157 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
3158   case "$BUILD_CONFIG" in
3159     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
3160       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
3161       bootstrap_fixincludes=yes
3162       ;;
3163   esac
3164 fi
3165
3166 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
3167 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
3168    test "$enable_vtable_verify" != no; then
3169   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
3170 fi
3171
3172 # If we are building libatomic and the list of enabled languages includes the
3173 # D frontend, bootstrap it.
3174 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
3175   case ,${enable_languages}, in
3176     *,d,*)
3177       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
3178       ;;
3179   esac
3180 fi
3181
3182 # Determine whether gdb needs tk/tcl or not.
3183 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
3184 # and in that case we want gdb to be built without tk.  Ugh!
3185 # In fact I believe gdb is the *only* package directly dependent on tk,
3186 # so we should be able to put the 'maybe's in unconditionally and
3187 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
3188 # 100% sure that that's safe though.
3189
3190 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
3191 case "$enable_gdbtk" in
3192   no)
3193     GDB_TK="" ;;
3194   yes)
3195     GDB_TK="${gdb_tk}" ;;
3196   *)
3197     # Only add the dependency on gdbtk when GDBtk is part of the gdb
3198     # distro.  Eventually someone will fix this and move Insight, nee
3199     # gdbtk to a separate directory.
3200     if test -d ${srcdir}/gdb/gdbtk ; then
3201       GDB_TK="${gdb_tk}"
3202     else
3203       GDB_TK=""
3204     fi
3205     ;;
3206 esac
3207 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
3208 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
3209
3210 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
3211 # else does, only include them if one of these is built.  The Makefile
3212 # provides the ordering, so it's enough here to add to the list.
3213 case " ${configdirs} " in
3214   *\ gdb\ *)
3215     configdirs="${configdirs} gnulib gdbsupport"
3216     ;;
3217   *\ gdbserver\ *)
3218     configdirs="${configdirs} gnulib gdbsupport"
3219     ;;
3220   *\ sim\ *)
3221     configdirs="${configdirs} gnulib"
3222     ;;
3223 esac
3224
3225 # Strip out unwanted targets.
3226
3227 # While at that, we remove Makefiles if we were started for recursive
3228 # configuration, so that the top-level Makefile reconfigures them,
3229 # like we used to do when configure itself was recursive.
3230
3231 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3232 # but now we're fixing up the Makefile ourselves with the additional
3233 # commands passed to AC_CONFIG_FILES.  Use separate variables
3234 # extrasub-{build,host,target} not because there is any reason to split
3235 # the substitutions up that way, but only to remain below the limit of
3236 # 99 commands in a script, for HP-UX sed.
3237
3238 # Do not nest @if/@endif or @unless/@endunless pairs, because
3239 # configure will not warn you at all.
3240
3241 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3242   yes:yes:*\ gold\ *:*,c++,*) ;;
3243   yes:yes:*\ gold\ *:*)
3244     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3245     ;;
3246 esac
3247
3248 # Bootstrapping GCC requires libstdc++-v3 so error out if libstdc++ is disabled with bootstrapping
3249 # Note C++ is always enabled for stage1 now.
3250 case "$enable_bootstrap:${noconfigdirs}" in
3251   yes:*target-libstdc++-v3*)
3252     AC_MSG_ERROR([bootstrapping with --disable-libstdcxx is not supported])
3253     ;;
3254 esac
3255
3256
3257 extrasub_build=
3258 for module in ${build_configdirs} ; do
3259   if test -z "${no_recursion}" \
3260      && test -f ${build_subdir}/${module}/Makefile; then
3261     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3262     rm -f ${build_subdir}/${module}/Makefile
3263   fi
3264   extrasub_build="$extrasub_build
3265 /^@if build-$module\$/d
3266 /^@endif build-$module\$/d
3267 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3268 /^@if build-$module-$bootstrap_suffix\$/d
3269 /^@endif build-$module-$bootstrap_suffix\$/d
3270 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3271 done
3272 extrasub_host=
3273 for module in ${configdirs} ; do
3274   if test -z "${no_recursion}"; then
3275     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3276       if test -f ${file}; then
3277         echo 1>&2 "*** removing ${file} to force reconfigure"
3278         rm -f ${file}
3279       fi
3280     done
3281   fi
3282   case ${module},${bootstrap_fixincludes} in
3283     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3284     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3285   esac
3286   extrasub_host="$extrasub_host
3287 /^@if $module\$/d
3288 /^@endif $module\$/d
3289 /^@unless $module\$/,/^@endunless $module\$/d
3290 /^@if $module-$host_bootstrap_suffix\$/d
3291 /^@endif $module-$host_bootstrap_suffix\$/d
3292 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3293 done
3294 extrasub_target=
3295 for module in ${target_configdirs} ; do
3296   if test -z "${no_recursion}" \
3297      && test -f ${target_subdir}/${module}/Makefile; then
3298     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3299     rm -f ${target_subdir}/${module}/Makefile
3300   fi
3301
3302   # We only bootstrap target libraries listed in bootstrap_target_libs.
3303   case $bootstrap_target_libs in
3304     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3305     *) target_bootstrap_suffix=no-bootstrap ;;
3306   esac
3307
3308   extrasub_target="$extrasub_target
3309 /^@if target-$module\$/d
3310 /^@endif target-$module\$/d
3311 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3312 /^@if target-$module-$target_bootstrap_suffix\$/d
3313 /^@endif target-$module-$target_bootstrap_suffix\$/d
3314 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3315 done
3316
3317 # Do the final fixup along with target modules.
3318 extrasub_target="$extrasub_target
3319 /^@if /,/^@endif /d
3320 /^@unless /d
3321 /^@endunless /d"
3322
3323 if test "$enable_pgo_build" != "no"; then
3324   extrasub_build="$extrasub_build
3325 /^@if pgo-build\$/d
3326 /^@endif pgo-build\$/d"
3327 fi
3328
3329 # Create the serialization dependencies.  This uses a temporary file.
3330
3331 AC_ARG_ENABLE([serial-configure],
3332 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3333                 [force sequential configuration of
3334                  sub-packages for the host, target or build
3335                  machine, or all sub-packages])])
3336
3337 case ${enable_serial_configure} in
3338   yes)
3339     enable_serial_build_configure=yes
3340     enable_serial_host_configure=yes
3341     enable_serial_target_configure=yes
3342     ;;
3343 esac
3344
3345 # These force 'configure's to be done one at a time, to avoid problems
3346 # with contention over a shared config.cache.
3347 rm -f serdep.tmp
3348 if test "x${enable_serial_build_configure}" = xyes || test "x${enable_serial_host_configure}" = xyes || test "x${enable_serial_target_configure}" = xyes; then
3349 echo '# serdep.tmp' > serdep.tmp
3350 fi
3351 olditem=
3352 test "x${enable_serial_build_configure}" = xyes &&
3353 for item in ${build_configdirs} ; do
3354   case ${olditem} in
3355     "") ;;
3356     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3357   esac
3358   olditem=${item}
3359 done
3360 olditem=
3361 test "x${enable_serial_host_configure}" = xyes &&
3362 for item in ${configdirs} ; do
3363   case ${olditem} in
3364     "") ;;
3365     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3366   esac
3367   olditem=${item}
3368 done
3369 olditem=
3370 test "x${enable_serial_target_configure}" = xyes &&
3371 for item in ${target_configdirs} ; do
3372   case ${olditem} in
3373     "") ;;
3374     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3375   esac
3376   olditem=${item}
3377 done
3378 serialization_dependencies=serdep.tmp
3379 AC_SUBST_FILE(serialization_dependencies)
3380
3381 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3382 # target, nonopt, and variable assignments.  These are the ones we
3383 # might not want to pass down to subconfigures.  The exception being
3384 # --cache-file=/dev/null, which is used to turn off the use of cache
3385 # files altogether, and which should be passed on to subconfigures.
3386 # Also strip program-prefix, program-suffix, and program-transform-name,
3387 # so that we can pass down a consistent program-transform-name.
3388 hbaseargs=
3389 bbaseargs=
3390 tbaseargs=
3391 keep_next=no
3392 skip_next=no
3393 eval "set -- $ac_configure_args"
3394 for ac_arg
3395 do
3396   if test X"$skip_next" = X"yes"; then
3397     skip_next=no
3398     continue
3399   fi
3400   if test X"$keep_next" = X"yes"; then
3401     case $ac_arg in
3402       *\'*)
3403         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3404     esac
3405     hbaseargs="$hbaseargs '$ac_arg'"
3406     bbaseargs="$bbaseargs '$ac_arg'"
3407     tbaseargs="$tbaseargs '$ac_arg'"
3408     keep_next=no
3409     continue
3410   fi
3411
3412   # Handle separated arguments.  Based on the logic generated by
3413   # autoconf 2.59.
3414   case $ac_arg in
3415     *=* | --config-cache | -C | -disable-* | --disable-* \
3416       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3417       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3418       | -with-* | --with-* | -without-* | --without-* | --x)
3419       separate_arg=no
3420       ;;
3421     -*)
3422       separate_arg=yes
3423       ;;
3424     *)
3425       separate_arg=no
3426       ;;
3427   esac
3428
3429   skip_targ=no
3430   skip_barg=no
3431   case $ac_arg in
3432 changequote(,)
3433   --with-* | --without-*)
3434     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3435
3436     case $libopt in
3437     *[-_]include)
3438       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3439       ;;
3440     *[-_]lib)
3441       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3442       ;;
3443     *[-_]prefix)
3444       lib=`echo "$libopt" | sed 's,[-_]prefix$,,'`
3445       ;;
3446     *[-_]type)
3447       lib=`echo "$libopt" | sed 's,[-_]type$,,'`
3448       ;;
3449     *)
3450       lib=$libopt
3451       ;;
3452     esac
3453 changequote([,])
3454
3455     case $lib in
3456     mpc | mpfr | gmp | isl)
3457       # If we're processing --with-$lib, --with-$lib-include or
3458       # --with-$lib-lib, for one of the libs above, and target is
3459       # different from host, don't pass the current argument to any
3460       # target library's configure.
3461       if test x$is_cross_compiler = xyes; then
3462         skip_targ=yes
3463       fi
3464       ;;
3465     libintl | libiconv)
3466       # We don't want libintl (and co.) in anything but the host arguments.
3467       skip_targ=yes
3468       skip_barg=yes
3469       ;;
3470     esac
3471     ;;
3472   esac
3473
3474   case "$ac_arg" in
3475     --cache-file=/dev/null | \
3476     -cache-file=/dev/null )
3477       # Handled here to avoid the test to skip args below.
3478       hbaseargs="$hbaseargs '$ac_arg'"
3479       bbaseargs="$bbaseargs '$ac_arg'"
3480       tbaseargs="$tbaseargs '$ac_arg'"
3481       # Assert: $separate_arg should always be no.
3482       keep_next=$separate_arg
3483       ;;
3484     --no*)
3485       continue
3486       ;;
3487     --c* | \
3488     --sr* | \
3489     --ho* | \
3490     --bu* | \
3491     --t* | \
3492     --program-* | \
3493     -cache_file* | \
3494     -srcdir* | \
3495     -host* | \
3496     -build* | \
3497     -target* | \
3498     -program-prefix* | \
3499     -program-suffix* | \
3500     -program-transform-name* )
3501       skip_next=$separate_arg
3502       continue
3503       ;;
3504     -*)
3505       # An option.  Add it.
3506       case $ac_arg in
3507         *\'*)
3508           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3509       esac
3510       hbaseargs="$hbaseargs '$ac_arg'"
3511       if test X"$skip_barg" = Xno; then
3512         bbaseargs="$bbaseargs '$ac_arg'"
3513       fi
3514       if test X"$skip_targ" = Xno; then
3515         tbaseargs="$tbaseargs '$ac_arg'"
3516       fi
3517       keep_next=$separate_arg
3518       ;;
3519     *)
3520       # Either a variable assignment, or a nonopt (triplet).  Don't
3521       # pass it down; let the Makefile handle this.
3522       continue
3523       ;;
3524   esac
3525 done
3526 # Remove the initial space we just introduced and, as these will be
3527 # expanded by make, quote '$'.
3528 hbaseargs=`echo "x$hbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3529 bbaseargs=`echo "x$bbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3530
3531 # Add in --program-transform-name, after --program-prefix and
3532 # --program-suffix have been applied to it.  Autoconf has already
3533 # doubled dollar signs and backslashes in program_transform_name; we want
3534 # the backslashes un-doubled, and then the entire thing wrapped in single
3535 # quotes, because this will be expanded first by make and then by the shell.
3536 # Also, because we want to override the logic in subdir configure scripts to
3537 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3538 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3539 ${program_transform_name}
3540 EOF_SED
3541 gcc_transform_name=`cat conftestsed.out`
3542 rm -f conftestsed.out
3543 hbaseargs="$hbaseargs --program-transform-name='${gcc_transform_name}'"
3544 bbaseargs="$bbaseargs --program-transform-name='${gcc_transform_name}'"
3545 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3546 if test "$silent" = yes; then
3547   bbaseargs="$bbaseargs --silent"
3548   hbaseargs="$hbaseargs --silent"
3549   tbaseargs="$tbaseargs --silent"
3550 fi
3551
3552 bbaseargs="$bbaseargs --disable-option-checking"
3553 hbaseargs="$hbaseargs --disable-option-checking"
3554 tbaseargs="$tbaseargs --disable-option-checking"
3555
3556 if test "$enable_year2038" = no; then
3557   bbaseargs="$bbaseargs --disable-year2038"
3558   hbaseargs="$hbaseargs --disable-year2038"
3559   tbaseargs="$tbaseargs --disable-year2038"
3560 fi
3561
3562 # Record and document user additions to sub configure arguments.
3563 AC_ARG_VAR([build_configargs],
3564            [additional configure arguments for build directories])
3565 AC_ARG_VAR([host_configargs],
3566            [additional configure arguments for host directories])
3567 AC_ARG_VAR([target_configargs],
3568            [additional configure arguments for target directories])
3569
3570 # For the build-side libraries, we just need to pretend we're native,
3571 # and not use the same cache file.  Multilibs are neither needed nor
3572 # desired.  We can't even use the same cache file for all build-side
3573 # libraries, as they're compiled differently; some with C, some with
3574 # C++ or with different feature-enabling options.
3575 build_configargs="$build_configargs --cache-file=./config.cache ${bbaseargs}"
3576
3577 # For host modules, accept cache file option, or specification as blank.
3578 case "${cache_file}" in
3579 "") # empty
3580   cache_file_option="" ;;
3581 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3582   cache_file_option="--cache-file=${cache_file}" ;;
3583 *) # relative path
3584   cache_file_option="--cache-file=../${cache_file}" ;;
3585 esac
3586
3587 # Host dirs don't like to share a cache file either, horribly enough.
3588 # This seems to be due to autoconf 2.5x stupidity.
3589 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${hbaseargs}"
3590
3591 target_configargs="$target_configargs ${tbaseargs}"
3592
3593 # Passing a --with-cross-host argument lets the target libraries know
3594 # whether they are being built with a cross-compiler or being built
3595 # native.  However, it would be better to use other mechanisms to make the
3596 # sorts of decisions they want to make on this basis.  Please consider
3597 # this option to be deprecated.  FIXME.
3598 if test x${is_cross_compiler} = xyes ; then
3599   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3600 fi
3601
3602 # Special user-friendly check for native x86_64-linux build, if
3603 # multilib is not explicitly enabled.
3604 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3605   x86_64-*linux*:yes:$build:$build:)
3606     # Make sure we have a development environment that handles 32-bit
3607     dev64=no
3608     echo "int main () { return 0; }" > conftest.c
3609     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3610     if test $? = 0 ; then
3611       if test -s conftest || test -s conftest.exe ; then
3612         dev64=yes
3613       fi
3614     fi
3615     rm -f conftest*
3616     if test x${dev64} != xyes ; then
3617       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3618     fi
3619     ;;
3620 esac
3621
3622 # Default to --enable-multilib.
3623 if test x${enable_multilib} = x ; then
3624   target_configargs="--enable-multilib ${target_configargs}"
3625 fi
3626
3627 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3628 # changed from the earlier setting of with_newlib.
3629 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3630   target_configargs="--with-newlib ${target_configargs}"
3631 fi
3632
3633 # Different target subdirs use different values of certain variables
3634 # (notably CXX).  Worse, multilibs use *lots* of different values.
3635 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3636 # it doesn't automatically accept command-line overrides of them.
3637 # This means it's not safe for target subdirs to share a cache file,
3638 # which is disgusting, but there you have it.  Hopefully this can be
3639 # fixed in future.  It's still worthwhile to use a cache file for each
3640 # directory.  I think.
3641
3642 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3643 # We need to pass --target, as newer autoconf's requires consistency
3644 # for target_alias and gcc doesn't manage it consistently.
3645 target_configargs="--cache-file=./config.cache ${target_configargs}"
3646
3647 FLAGS_FOR_TARGET=
3648 case " $target_configdirs " in
3649  *" newlib "*)
3650   case " $target_configargs " in
3651   *" --with-newlib "*)
3652    case "$target" in
3653     *-cygwin*)
3654       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3655       ;;
3656    esac
3657
3658    # If we're not building GCC, don't discard standard headers.
3659    if test -d ${srcdir}/gcc; then
3660      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3661
3662      if test "${build}" != "${host}"; then
3663        # On Canadian crosses, CC_FOR_TARGET will have already been set
3664        # by `configure', so we won't have an opportunity to add -Bgcc/
3665        # to it.  This is right: we don't want to search that directory
3666        # for binaries, but we want the header files in there, so add
3667        # them explicitly.
3668        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3669
3670        # Someone might think of using the pre-installed headers on
3671        # Canadian crosses, in case the installed compiler is not fully
3672        # compatible with the compiler being built.  In this case, it
3673        # would be better to flag an error than risking having
3674        # incompatible object files being constructed.  We can't
3675        # guarantee that an error will be flagged, but let's hope the
3676        # compiler will do it, when presented with incompatible header
3677        # files.
3678      fi
3679    fi
3680
3681    case "${target}-${is_cross_compiler}" in
3682    i[[3456789]]86-*-linux*-no)
3683       # Here host == target, so we don't need to build gcc,
3684       # so we don't want to discard standard headers.
3685       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3686       ;;
3687    *)
3688       # If we're building newlib, use its generic headers last, but search
3689       # for any libc-related directories first (so make it the last -B
3690       # switch).
3691       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3692
3693       # If we're building libgloss, find the startup file, simulator library
3694       # and linker script.
3695       case " $target_configdirs " in
3696         *" libgloss "*)
3697         # Look for startup file, simulator library and maybe linker script.
3698         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3699         # Look for libnosys.a in case the target needs it.
3700         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3701         # Most targets have the linker script in the source directory.
3702         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3703         ;;
3704       esac
3705       ;;
3706    esac
3707    ;;
3708   esac
3709   ;;
3710 esac
3711
3712 case "$target" in
3713   x86_64-*mingw* | *-w64-mingw*)
3714   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3715   # however, use a symlink named 'mingw' in ${prefix} .
3716     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3717     ;;
3718   *-mingw*)
3719   # MinGW can't be handled as Cygwin above since it does not use newlib.
3720     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3721     ;;
3722 esac
3723
3724 # Allow the user to override the flags for
3725 # our build compiler if desired.
3726 if test x"${build}" = x"${host}" ; then
3727   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3728   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3729   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3730   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3731 fi
3732
3733 # On Canadian crosses, we'll be searching the right directories for
3734 # the previously-installed cross compiler, so don't bother to add
3735 # flags for directories within the install tree of the compiler
3736 # being built; programs in there won't even run.
3737 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3738   # Search for pre-installed headers if nothing else fits.
3739   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3740 fi
3741
3742 if test "x${use_gnu_ld}" = x &&
3743    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3744   # Arrange for us to find uninstalled linker scripts.
3745   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3746 fi
3747
3748 # Search for other target-specific linker scripts and such.
3749 case "${target}" in
3750   mep*)
3751     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3752     ;;
3753   # The VxWorks support for shared libraries is getting in
3754   # incrementally.  Make sure it doesn't get activated implicitly:
3755   *vxworks*)
3756     if test "${enable_shared-unset}" = unset ; then
3757       enable_shared=no
3758       # So the build of libraries knows ...
3759       target_configargs="${target_configargs} --disable-shared"
3760       # So gcc knows ...
3761       host_configargs="${host_configargs} --disable-shared"
3762     fi
3763     ;;
3764 esac
3765
3766 # Makefile fragments.
3767 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3768 do
3769   eval fragval=\$$frag
3770   if test $fragval != /dev/null; then
3771     eval $frag=${srcdir}/$fragval
3772   fi
3773 done
3774 AC_SUBST_FILE(host_makefile_frag)
3775 AC_SUBST_FILE(target_makefile_frag)
3776 AC_SUBST_FILE(alphaieee_frag)
3777 AC_SUBST_FILE(ospace_frag)
3778
3779 # Miscellanea: directories, flags, etc.
3780 AC_SUBST(RPATH_ENVVAR)
3781 AC_SUBST(GCC_SHLIB_SUBDIR)
3782 AC_SUBST(tooldir)
3783 AC_SUBST(build_tooldir)
3784 AC_SUBST(CONFIGURE_GDB_TK)
3785 AC_SUBST(GDB_TK)
3786 AC_SUBST(INSTALL_GDB_TK)
3787
3788 # Build module lists & subconfigure args.
3789 AC_SUBST(build_configargs)
3790 AC_SUBST(build_configdirs)
3791
3792 # Host module lists & subconfigure args.
3793 AC_SUBST(host_configargs)
3794 AC_SUBST(configdirs)
3795 AC_SUBST(target_configdirs)
3796
3797 # Target module lists & subconfigure args.
3798 AC_SUBST(target_configargs)
3799
3800
3801 # Build tools.
3802 AC_SUBST(AR_FOR_BUILD)
3803 AC_SUBST(AS_FOR_BUILD)
3804 AC_SUBST(CC_FOR_BUILD)
3805 AC_SUBST(CFLAGS_FOR_BUILD)
3806 AC_SUBST(CPP_FOR_BUILD)
3807 AC_SUBST(CPPFLAGS_FOR_BUILD)
3808 AC_SUBST(CXXFLAGS_FOR_BUILD)
3809 AC_SUBST(CXX_FOR_BUILD)
3810 AC_SUBST(DLLTOOL_FOR_BUILD)
3811 AC_SUBST(DSYMUTIL_FOR_BUILD)
3812 AC_SUBST(GFORTRAN_FOR_BUILD)
3813 AC_SUBST(GOC_FOR_BUILD)
3814 AC_SUBST(GDC_FOR_BUILD)
3815 AC_SUBST(LDFLAGS_FOR_BUILD)
3816 AC_SUBST(LD_FOR_BUILD)
3817 AC_SUBST(NM_FOR_BUILD)
3818 AC_SUBST(RANLIB_FOR_BUILD)
3819 AC_SUBST(WINDMC_FOR_BUILD)
3820 AC_SUBST(WINDRES_FOR_BUILD)
3821
3822 # Generate default definitions for YACC, M4, LEX and other programs that run
3823 # on the build machine.  These are used if the Makefile can't locate these
3824 # programs in objdir.
3825 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3826
3827 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3828 case " $build_configdirs " in
3829   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3830 esac
3831
3832 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3833 case " $build_configdirs " in
3834   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3835 esac
3836
3837 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3838 case " $build_configdirs " in
3839   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3840 esac
3841
3842 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3843 case " $build_configdirs " in
3844   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3845   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3846 esac
3847
3848 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3849 case " $build_configdirs " in
3850   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3851 esac
3852
3853 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3854 case " $build_configdirs " in
3855   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3856   *)
3857 changequote(,)
3858     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3859     # higher, else we use the "missing" dummy.
3860     if ${MAKEINFO} --version \
3861        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3862       :
3863     else
3864       MAKEINFO="$MISSING makeinfo"
3865     fi
3866     ;;
3867 changequote([,])
3868 esac
3869
3870 # FIXME: expect and dejagnu may become build tools?
3871
3872 AC_CHECK_PROGS(EXPECT, expect, expect)
3873 case " $configdirs " in
3874   *" expect "*)
3875     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3876     ;;
3877 esac
3878
3879 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3880 case " $configdirs " in
3881   *" dejagnu "*)
3882     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3883     ;;
3884 esac
3885
3886
3887 # Host tools.
3888 NCN_STRICT_CHECK_TOOLS(AR, ar)
3889 NCN_STRICT_CHECK_TOOLS(AS, as)
3890 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3891 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3892 NCN_STRICT_CHECK_TOOLS(LD, ld)
3893 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3894 NCN_STRICT_CHECK_TOOLS(NM, nm)
3895 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3896 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3897 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3898 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3899 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3900 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3901 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3902 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3903 AC_SUBST(CC)
3904 AC_SUBST(CXX)
3905 AC_SUBST(CFLAGS)
3906 AC_SUBST(CXXFLAGS)
3907 AC_SUBST(GDC)
3908 AC_SUBST(GDCFLAGS)
3909 GDCFLAGS=${GDCFLAGS-${CFLAGS}}
3910 AC_SUBST(PKG_CONFIG_PATH)
3911
3912 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3913 AR_PLUGIN_OPTION=
3914 RANLIB_PLUGIN_OPTION=
3915 if test -n "$PLUGIN_OPTION"; then
3916   if $AR --help 2>&1 | grep -q "\--plugin"; then
3917     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3918   fi
3919   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3920     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3921   fi
3922 fi
3923 AC_SUBST(AR_PLUGIN_OPTION)
3924 AC_SUBST(RANLIB_PLUGIN_OPTION)
3925
3926 # Target tools.
3927 AC_ARG_WITH([build-time-tools],
3928   [AS_HELP_STRING([--with-build-time-tools=PATH],
3929                   [use given path to find target tools during the build])],
3930   [case x"$withval" in
3931      x/*) ;;
3932      *)
3933        with_build_time_tools=
3934        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3935        ;;
3936    esac],
3937   [with_build_time_tools=])
3938
3939 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3940 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3941 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3942 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3943 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3944 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3945 NCN_STRICT_CHECK_TARGET_TOOLS(GM2_FOR_TARGET, gm2)
3946
3947 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3948 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3949 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3950 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3951 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3952 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3953 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3954 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3955 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3956 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3957 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3958 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3959 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3960 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3961 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3962
3963 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3964
3965 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3966 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3967 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3968 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3969 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3970                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3971                 c++)
3972 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3973                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3974                 c++)
3975 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3976 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3977 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3978 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3979                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3980 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3981                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3982 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3983                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3984 GCC_TARGET_TOOL(gm2, GM2_FOR_TARGET, GM2,
3985                 [gcc/gm2 -B$$r/$(HOST_SUBDIR)/gcc/], m2)
3986 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3987 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3988 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3989 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3990 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3991 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3992 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3993 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3994 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3995 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3996 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3997
3998 AC_SUBST(FLAGS_FOR_TARGET)
3999 AC_SUBST(RAW_CXX_FOR_TARGET)
4000
4001 # Certain tools may need extra flags.
4002 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
4003 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
4004 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
4005
4006 # When building target libraries, except in a Canadian cross, we use
4007 # the same toolchain as the compiler we just built.
4008 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
4009 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
4010 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
4011 if test $host = $build; then
4012   case " $configdirs " in
4013     *" gcc "*)
4014       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
4015       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
4016       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
4017       ;;
4018   esac
4019 fi
4020
4021 AC_SUBST(COMPILER_AS_FOR_TARGET)
4022 AC_SUBST(COMPILER_LD_FOR_TARGET)
4023 AC_SUBST(COMPILER_NM_FOR_TARGET)
4024
4025 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
4026 AC_ARG_ENABLE(maintainer-mode,
4027 [AS_HELP_STRING([--enable-maintainer-mode],
4028                 [enable make rules and dependencies not useful
4029                  (and sometimes confusing) to the casual installer])],
4030       USE_MAINTAINER_MODE=$enableval,
4031       USE_MAINTAINER_MODE=no)
4032 AC_MSG_RESULT($USE_MAINTAINER_MODE)
4033 AC_SUBST(MAINTAINER_MODE_TRUE)
4034 AC_SUBST(MAINTAINER_MODE_FALSE)
4035 if test "$USE_MAINTAINER_MODE" = yes; then
4036   MAINTAINER_MODE_TRUE=
4037   MAINTAINER_MODE_FALSE='#'
4038 else
4039   MAINTAINER_MODE_TRUE='#'
4040   MAINTAINER_MODE_FALSE=
4041 fi
4042 MAINT=$MAINTAINER_MODE_TRUE
4043 AC_SUBST(MAINT)dnl
4044
4045 # ---------------------
4046 # GCC bootstrap support
4047 # ---------------------
4048
4049 # Stage specific cflags for build.
4050 stage1_cflags="-g"
4051 case $build in
4052   vax-*-*)
4053     case ${GCC} in
4054       yes) stage1_cflags="-g -Wa,-J" ;;
4055       *) stage1_cflags="-g -J" ;;
4056     esac ;;
4057 esac
4058
4059 AC_SUBST(stage1_cflags)
4060
4061 # Enable --enable-checking in stage1 of the compiler.
4062 AC_ARG_ENABLE(stage1-checking,
4063 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
4064                 [choose additional checking for stage1 of the compiler])],
4065 [stage1_checking=--enable-checking=${enable_stage1_checking}],
4066 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
4067   # For --disable-checking or implicit --enable-checking=release, avoid
4068   # setting --enable-checking=gc in the default stage1 checking for LTO
4069   # bootstraps.  See PR62077.
4070   case $BUILD_CONFIG in
4071     *lto*)
4072       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
4073     *)
4074       stage1_checking=--enable-checking=yes,types;;
4075   esac
4076   if test "x$enable_checking" = x && \
4077      test -d ${srcdir}/gcc && \
4078      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
4079     stage1_checking=--enable-checking=yes,types,extra
4080   fi
4081 else
4082   stage1_checking=--enable-checking=$enable_checking,types
4083 fi])
4084 AC_SUBST(stage1_checking)
4085
4086 # Enable -Werror in bootstrap stage2 and later.
4087 AC_ARG_ENABLE(werror,
4088 [AS_HELP_STRING([--enable-werror],
4089                 [enable -Werror in bootstrap stage2 and later])],
4090 [
4091 case ${enable_werror} in
4092   yes) stage2_werror_flag="--enable-werror-always" ;;
4093   *) stage2_werror_flag="" ;;
4094 esac
4095 ],
4096 [
4097 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
4098   case $BUILD_CONFIG in
4099   bootstrap-debug)
4100       stage2_werror_flag="--enable-werror-always" ;;
4101   "")
4102       stage2_werror_flag="--enable-werror-always" ;;
4103   esac
4104 fi
4105 ])
4106
4107 AC_SUBST(stage2_werror_flag)
4108
4109 # Specify what files to not compare during bootstrap.
4110
4111 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
4112 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/M2Version*"
4113 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/SYSTEM*"
4114 compare_exclusions="$compare_exclusions | gcc/m2/gm2version*"
4115 case "$target" in
4116   hppa*64*-*-hpux*) ;;
4117   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
4118 esac
4119 AC_SUBST(compare_exclusions)
4120
4121 AC_CONFIG_FILES([Makefile],
4122   [sed "$extrasub_build" Makefile |
4123    sed "$extrasub_host" |
4124    sed "$extrasub_target" > mf$$
4125    mv -f mf$$ Makefile],
4126   [extrasub_build="$extrasub_build"
4127    extrasub_host="$extrasub_host"
4128    extrasub_target="$extrasub_target"])
4129 AC_OUTPUT