configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include(config/gcc-plugin.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT
  36 AC_CONFIG_SRCDIR([move-if-change])
  37 AC_DISABLE_OPTION_CHECKING
  38
  39 progname=$0
  40 # if PWD already has a value, it is probably wrong.
  41 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  42
  43 # Export original configure arguments for use by sub-configures.
  44 # Quote arguments with shell meta charatcers.
  45 TOPLEVEL_CONFIGURE_ARGUMENTS=
  46 set -- "$progname" "$@"
  47 for ac_arg
  48 do
  49   case "$ac_arg" in
  50   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  51     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  52     # if the argument is of the form -foo=baz, quote the baz part only
  53     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  54   *) ;;
  55   esac
  56   # Add the quoted argument to the list.
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  58 done
  59 if test "$silent" = yes; then
  60   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  61 fi
  62 # Remove the initial space we just introduced and, as these will be
  63 # expanded by make, quote '$'.
  64 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  65 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  66
  67 # Find the build, host, and target systems.
  68 ACX_NONCANONICAL_BUILD
  69 ACX_NONCANONICAL_HOST
  70 ACX_NONCANONICAL_TARGET
  71
  72 dnl Autoconf 2.5x and later will set a default program prefix if
  73 dnl --target was used, even if it was the same as --host.  Disable
  74 dnl that behavior.  This must be done before AC_CANONICAL_TARGET
  75 dnl to take effect.
  76 test "$host_noncanonical" = "$target_noncanonical" &&
  77   test "$program_prefix$program_suffix$program_transform_name" = \
  78     NONENONEs,x,x, &&
  79   program_transform_name=s,y,y,
  80
  81 AC_CANONICAL_TARGET
  82 AC_ARG_PROGRAM
  83
  84 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  85 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  86
  87 # Get 'install' or 'install-sh' and its variants.
  88 AC_PROG_INSTALL
  89 ACX_PROG_LN
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_AWK
  93
  94 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  95
  96 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  97 # a relative path.
  98 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  99   INSTALL="${srcpwd}/install-sh -c"
 100 fi
 101
 102 # Set srcdir to "." if that's what it is.
 103 # This is important for multilib support.
 104 pwd=`${PWDCMD-pwd}`
 105 if test "${pwd}" = "${srcpwd}" ; then
 106   srcdir=.
 107 fi
 108
 109 topsrcdir=$srcpwd
 110
 111 extra_host_args=
 112
 113 ### To add a new directory to the tree, first choose whether it is a target
 114 ### or a host dependent tool.  Then put it into the appropriate list
 115 ### (library or tools, host or target), doing a dependency sort.
 116
 117 # Subdirs will be configured in the order listed in build_configdirs,
 118 # configdirs, or target_configdirs; see the serialization section below.
 119
 120 # Dependency sorting is only needed when *configuration* must be done in
 121 # a particular order.  In all cases a dependency should be specified in
 122 # the Makefile, whether or not it's implicitly specified here.
 123
 124 # Double entries in build_configdirs, configdirs, or target_configdirs may
 125 # cause circular dependencies and break everything horribly.
 126
 127 # these library is used by various programs built for the build
 128 # environment
 129 #
 130 build_libs="build-libiberty build-libcpp"
 131
 132 # these tools are built for the build environment
 133 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 134
 135 # these libraries are used by various programs built for the host environment
 136 #f
 137 host_libs="gettext libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe libgrust "
 138
 139 # these tools are built for the host environment
 140 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 141 # know that we are building the simulator.
 142 # binutils, gas and ld appear in that order because it makes sense to run
 143 # "make check" in that particular order.
 144 # If --enable-gold is used, "gold" may replace "ld".
 145 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gm2tools gotools c++tools"
 146
 147 # these libraries are built for the target environment, and are built after
 148 # the host libraries and the host tools (which may be a cross compiler)
 149 # Note that libiberty is not a target library.
 150 target_libraries="target-libgcc \
 151                 target-libbacktrace \
 152                 target-libgloss \
 153                 target-newlib \
 154                 target-libgomp \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgm2 \
 167                 target-libgo \
 168                 target-libgrust \
 169                 target-libphobos \
 170                 target-zlib"
 171
 172 # these tools are built using the target libraries, and are intended to
 173 # run only in the target environment
 174 #
 175 # note: any program that *uses* libraries that are in the "target_libraries"
 176 # list belongs in this list.
 177 #
 178 target_tools="target-rda"
 179
 180 ################################################################################
 181
 182 ## All tools belong in one of the four categories, and are assigned above
 183 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 184 ## is important because configure will choke if they ever get through.
 185 ## ${configdirs} is directories we build using the host tools.
 186 ## ${target_configdirs} is directories we build using the target tools.
 187 configdirs=`echo ${host_libs} ${host_tools}`
 188 target_configdirs=`echo ${target_libraries} ${target_tools}`
 189 build_configdirs=`echo ${build_libs} ${build_tools}`
 190
 191 m4_divert_text([PARSE_ARGS],
 192 [case $srcdir in
 193   *" "*)
 194 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 195     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 196 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 197     ;;
 198 esac
 199 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 200 ])
 201
 202 ################################################################################
 203
 204 srcname="gnu development package"
 205
 206 # This gets set non-empty for some net releases of packages.
 207 appdirs=""
 208
 209 # Define is_cross_compiler to save on calls to 'test'.
 210 is_cross_compiler=
 211 if test x"${host}" = x"${target}" ; then
 212   is_cross_compiler=no
 213 else
 214   is_cross_compiler=yes
 215 fi
 216
 217 # Find the build and target subdir names.
 218 GCC_TOPLEV_SUBDIRS
 219 # Be sure to cover against remnants of an in-tree build.
 220 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 221   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 222 Use a pristine source tree when building in a separate tree])
 223 fi
 224
 225 # Skipdirs are removed silently.
 226 skipdirs=
 227 # Noconfigdirs are removed loudly.
 228 noconfigdirs=""
 229
 230 use_gnu_ld=
 231 # Make sure we don't let GNU ld be added if we didn't want it.
 232 if test x$with_gnu_ld = xno ; then
 233   use_gnu_ld=no
 234   noconfigdirs="$noconfigdirs ld gold"
 235 fi
 236
 237 use_gnu_as=
 238 # Make sure we don't let GNU as be added if we didn't want it.
 239 if test x$with_gnu_as = xno ; then
 240   use_gnu_as=no
 241   noconfigdirs="$noconfigdirs gas"
 242 fi
 243
 244 use_included_zlib=
 245 AC_ARG_WITH(system-zlib,
 246 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 247 # Make sure we don't let ZLIB be added if we didn't want it.
 248 if test x$with_system_zlib = xyes ; then
 249   use_included_zlib=no
 250   noconfigdirs="$noconfigdirs zlib"
 251 fi
 252
 253 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 254 # is provided.
 255 if test x$with_system_readline = xyes ; then
 256   noconfigdirs="$noconfigdirs readline"
 257 fi
 258
 259 AC_ARG_WITH(zstd,
 260 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 261
 262 # some tools are so dependent upon X11 that if we're not building with X,
 263 # it's not even worth trying to configure, much less build, that tool.
 264
 265 case ${with_x} in
 266   yes | "") ;; # the default value for this tree is that X11 is available
 267   no)
 268     skipdirs="${skipdirs} tk itcl libgui"
 269     # We won't be able to build gdbtk without X.
 270     enable_gdbtk=no
 271     ;;
 272   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 273 esac
 274
 275 # Some are only suitable for cross toolchains.
 276 # Remove these if host=target.
 277 cross_only="target-libgloss target-newlib target-opcodes"
 278
 279 case $is_cross_compiler in
 280   no) skipdirs="${skipdirs} ${cross_only}" ;;
 281 esac
 282
 283 # If both --with-headers and --with-libs are specified, default to
 284 # --without-newlib.
 285 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 286    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 287   if test x"${with_newlib}" = x ; then
 288     with_newlib=no
 289   fi
 290 fi
 291
 292 # Recognize --with-newlib/--without-newlib.
 293 case ${with_newlib} in
 294   no) skipdirs="${skipdirs} target-newlib" ;;
 295   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 296 esac
 297
 298 AC_ARG_ENABLE(as-accelerator-for,
 299 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 300                 [build as offload target compiler.
 301                 Specify offload host triple by ARG])])
 302
 303 AC_ARG_ENABLE(offload-targets,
 304 [AS_HELP_STRING([--enable-offload-targets=LIST],
 305                 [enable offloading to devices from comma-separated LIST of
 306                 TARGET[=DIR]. Use optional path to find offload target compiler
 307                 during the build])],
 308 [
 309   if test x"$enable_offload_targets" = x; then
 310     AC_MSG_ERROR([no offload targets specified])
 311   fi
 312 ], [enable_offload_targets=])
 313
 314 AC_ARG_ENABLE(offload-defaulted,
 315 [AS_HELP_STRING([--enable-offload-defaulted]
 316                 [If enabled, configured but not installed offload compilers and
 317                 libgomp plugins are silently ignored.  Useful for distribution
 318                 compilers where those are in separate optional packages.])],
 319 [enable_offload_defaulted=$enableval],
 320 [enable_offload_defaulted=])
 321
 322 # Handle --enable-gold, --enable-ld.
 323 # --disable-gold [--enable-ld]
 324 #     Build only ld.  Default option.
 325 # --enable-gold [--enable-ld]
 326 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 327 #     as "ld.bfd" and "ld".
 328 # --enable-gold=default [--enable-ld]
 329 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 330 #     install ld as "ld.bfd".
 331 # --enable-gold[=default] --disable-ld
 332 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 333 # --enable-gold --enable-ld=default
 334 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 335 #     and ld.bfd).
 336 #     In other words, ld is default
 337 # --enable-gold=default --enable-ld=default
 338 #     Error.
 339
 340 default_ld=
 341 AC_ARG_ENABLE(gold,
 342 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 343                 [build gold @<:@ARG={default,yes,no}@:>@])],
 344 ENABLE_GOLD=$enableval,
 345 ENABLE_GOLD=no)
 346 case "${ENABLE_GOLD}" in
 347   yes|default)
 348     # Check for ELF target.
 349     is_elf=no
 350     case "${target}" in
 351       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 352       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 353       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 354       | *-*-solaris2* | *-*-nto* | *-*-nacl* | *-*-haiku*)
 355         case "${target}" in
 356           *-*-linux*aout* | *-*-linux*oldld*)
 357             ;;
 358           *)
 359             is_elf=yes
 360             ;;
 361         esac
 362     esac
 363
 364     if test "$is_elf" = "yes"; then
 365       # Check for target supported by gold.
 366       case "${target}" in
 367         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 368         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 369           configdirs="$configdirs gold"
 370           if test x${ENABLE_GOLD} = xdefault; then
 371             default_ld=gold
 372           fi
 373           ENABLE_GOLD=yes
 374           ;;
 375       esac
 376     fi
 377     ;;
 378   no)
 379     ;;
 380   *)
 381     AC_MSG_ERROR([invalid --enable-gold argument])
 382     ;;
 383 esac
 384
 385 AC_ARG_ENABLE(ld,
 386 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 387                 [build ld @<:@ARG={default,yes,no}@:>@])],
 388 ENABLE_LD=$enableval,
 389 ENABLE_LD=yes)
 390
 391 case "${ENABLE_LD}" in
 392   default)
 393     if test x${default_ld} != x; then
 394       AC_MSG_ERROR([either gold or ld can be the default ld])
 395     fi
 396     ;;
 397   yes)
 398     ;;
 399   no)
 400     if test x${ENABLE_GOLD} != xyes; then
 401       AC_MSG_WARN([neither ld nor gold are enabled])
 402     fi
 403     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 404     ;;
 405   *)
 406     AC_MSG_ERROR([invalid --enable-ld argument])
 407     ;;
 408 esac
 409
 410 AC_ARG_ENABLE(gprofng,
 411 [AS_HELP_STRING([[--enable-gprofng[=ARG]]],
 412                 [build gprofng @<:@ARG={yes,no}@:>@])],
 413 enable_gprofng=$enableval,
 414 enable_gprofng=yes)
 415 if test "$enable_gprofng" = "yes"; then
 416   case "${target}" in
 417     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux*)
 418     configdirs="$configdirs gprofng"
 419     ;;
 420   esac
 421 fi
 422
 423
 424 # PR gas/19109
 425 # Decide the default method for compressing debug sections.
 426 # Provide a configure time option to override our default.
 427 AC_ARG_ENABLE(compressed_debug_sections,
 428 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 429                 [Enable compressed debug sections for gas, gold or ld by
 430                  default])],
 431 [
 432   if test x"$enable_compressed_debug_sections" = xyes; then
 433     AC_MSG_ERROR([no program with compressed debug sections specified])
 434   fi
 435 ], [enable_compressed_debug_sections=])
 436
 437 # Select default compression algorithm.
 438 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 439 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 440                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 441 [], [default_compressed_debug_sections_algorithm=])
 442
 443 # Configure extra directories which are host specific
 444
 445 case "${host}" in
 446   *-cygwin*)
 447     configdirs="$configdirs libtermcap" ;;
 448 esac
 449
 450 # A target can indicate whether a language isn't supported for some reason.
 451 # Only spaces may be used in this macro; not newlines or tabs.
 452 unsupported_languages=
 453
 454 # Remove more programs from consideration, based on the host or
 455 # target this usually means that a port of the program doesn't
 456 # exist yet.
 457
 458 case "${host}" in
 459   i[[3456789]]86-*-msdosdjgpp*)
 460     noconfigdirs="$noconfigdirs tcl tk itcl"
 461     ;;
 462 esac
 463
 464 # Default to --disable-year2038 until we can handle differences between
 465 # projects that use gnulib (which understands year 2038) and projects that
 466 # do not (like BFD).
 467 AC_ARG_ENABLE(year2038,
 468 AS_HELP_STRING([--enable-year2038],
 469   [enable support for timestamps past the year 2038]),
 470 ENABLE_YEAR2038=$enableval,
 471 ENABLE_YEAR2038=no)
 472 enable_year2038=
 473 if test "${ENABLE_YEAR2038}" = "no" ; then
 474   enable_year2038=no
 475 fi
 476
 477 AC_ARG_ENABLE(libquadmath,
 478 AS_HELP_STRING([--disable-libquadmath],
 479   [do not build libquadmath directory]),
 480 ENABLE_LIBQUADMATH=$enableval,
 481 ENABLE_LIBQUADMATH=yes)
 482 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 483   noconfigdirs="$noconfigdirs target-libquadmath"
 484 fi
 485
 486
 487 AC_ARG_ENABLE(libquadmath-support,
 488 AS_HELP_STRING([--disable-libquadmath-support],
 489   [disable libquadmath support for Fortran]),
 490 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 491 ENABLE_LIBQUADMATH_SUPPORT=yes)
 492 enable_libquadmath_support=
 493 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 494   enable_libquadmath_support=no
 495 fi
 496
 497
 498 AC_ARG_ENABLE(libada,
 499 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 500 ENABLE_LIBADA=$enableval,
 501 ENABLE_LIBADA=yes)
 502 if test "${ENABLE_LIBADA}" != "yes" ; then
 503   noconfigdirs="$noconfigdirs gnattools"
 504 fi
 505
 506 AC_ARG_ENABLE(libgm2,
 507 [AS_HELP_STRING([--enable-libgm2], [build libgm2 directory])],
 508 ENABLE_LIBGM2=$enableval,
 509 ENABLE_LIBGM2=no)
 510 if test "${ENABLE_LIBGM2}" != "yes" ; then
 511   noconfigdirs="$noconfigdirs gm2tools"
 512 fi
 513
 514 AC_ARG_ENABLE(libssp,
 515 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 516 ENABLE_LIBSSP=$enableval,
 517 ENABLE_LIBSSP=yes)
 518
 519 AC_ARG_ENABLE(libstdcxx,
 520 AS_HELP_STRING([--disable-libstdcxx],
 521   [do not build libstdc++-v3 directory]),
 522 ENABLE_LIBSTDCXX=$enableval,
 523 ENABLE_LIBSTDCXX=default)
 524 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 525   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 526 fi]
 527
 528 # Enable libgomp by default on hosted POSIX systems, and a few others.
 529 if test x$enable_libgomp = x ; then
 530     case "${target}" in
 531     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 532         ;;
 533     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 534         ;;
 535     *-*-solaris2* | *-*-hpux11*)
 536         ;;
 537     *-*-darwin* | *-*-aix*)
 538         ;;
 539     nvptx*-*-* | amdgcn*-*-*)
 540         ;;
 541     *)
 542         noconfigdirs="$noconfigdirs target-libgomp"
 543         ;;
 544     esac
 545 fi
 546
 547 # Disable libatomic on unsupported systems.
 548 if test -d ${srcdir}/libatomic; then
 549     if test x$enable_libatomic = x; then
 550         AC_MSG_CHECKING([for libatomic support])
 551         if (srcdir=${srcdir}/libatomic; \
 552                 . ${srcdir}/configure.tgt; \
 553                 test -n "$UNSUPPORTED")
 554         then
 555             AC_MSG_RESULT([no])
 556             noconfigdirs="$noconfigdirs target-libatomic"
 557         else
 558             AC_MSG_RESULT([yes])
 559         fi
 560     fi
 561 fi
 562
 563 # Disable libitm on unsupported systems.
 564 if test -d ${srcdir}/libitm; then
 565     if test x$enable_libitm = x; then
 566         AC_MSG_CHECKING([for libitm support])
 567         if (srcdir=${srcdir}/libitm; \
 568                 . ${srcdir}/configure.tgt; \
 569                 test -n "$UNSUPPORTED")
 570         then
 571             AC_MSG_RESULT([no])
 572             noconfigdirs="$noconfigdirs target-libitm"
 573         else
 574             AC_MSG_RESULT([yes])
 575         fi
 576     fi
 577 fi
 578
 579 # Disable libsanitizer on unsupported systems.
 580 if test -d ${srcdir}/libsanitizer; then
 581     if test x$enable_libsanitizer = x; then
 582         AC_MSG_CHECKING([for libsanitizer support])
 583         if (srcdir=${srcdir}/libsanitizer; \
 584                 . ${srcdir}/configure.tgt; \
 585                 test -n "$UNSUPPORTED")
 586         then
 587             AC_MSG_RESULT([no])
 588             noconfigdirs="$noconfigdirs target-libsanitizer"
 589         else
 590             AC_MSG_RESULT([yes])
 591         fi
 592     fi
 593 fi
 594
 595 # Disable libvtv on unsupported systems.
 596 if test -d ${srcdir}/libvtv; then
 597     if test x$enable_libvtv = x; then
 598         AC_MSG_CHECKING([for libvtv support])
 599         if (srcdir=${srcdir}/libvtv; \
 600                 . ${srcdir}/configure.tgt; \
 601                 test "$VTV_SUPPORTED" != "yes")
 602         then
 603             AC_MSG_RESULT([no])
 604             noconfigdirs="$noconfigdirs target-libvtv"
 605         else
 606             AC_MSG_RESULT([yes])
 607         fi
 608     fi
 609 fi
 610
 611 # Disable libquadmath for some systems.
 612 case "${target}" in
 613   avr-*-*)
 614     noconfigdirs="$noconfigdirs target-libquadmath"
 615     ;;
 616   # libquadmath is unused on AIX and libquadmath build process use of
 617   # LD_LIBRARY_PATH can break AIX bootstrap.
 618   powerpc-*-aix* | rs6000-*-aix*)
 619     noconfigdirs="$noconfigdirs target-libquadmath"
 620     ;;
 621 esac
 622
 623 # Disable libssp for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     # No hosted I/O support.
 627     noconfigdirs="$noconfigdirs target-libssp"
 628     ;;
 629   bpf-*-*)
 630     noconfigdirs="$noconfigdirs target-libssp"
 631     ;;
 632   powerpc-*-aix* | rs6000-*-aix*)
 633     noconfigdirs="$noconfigdirs target-libssp"
 634     ;;
 635   pru-*-*)
 636     # No hosted I/O support.
 637     noconfigdirs="$noconfigdirs target-libssp"
 638     ;;
 639   rl78-*-*)
 640     # libssp uses a misaligned load to trigger a fault, but the RL78
 641     # doesn't fault for those - instead, it gives a build-time error
 642     # for explicit misaligned loads.
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   visium-*-*)
 646     # No hosted I/O support.
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649 esac
 650
 651 # Disable libstdc++-v3 for some systems.
 652 # Allow user to override this if they pass --enable-libstdcxx
 653 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 654   case "${target}" in
 655     *-*-vxworks*)
 656       # VxWorks uses the Dinkumware C++ library.
 657       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 658       ;;
 659     amdgcn*-*-*)
 660       # Not ported/fails to build when using newlib.
 661       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 662       ;;
 663     arm*-wince-pe*)
 664       # the C++ libraries don't build on top of CE's C libraries
 665       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 666       ;;
 667     avr-*-*)
 668       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 669       ;;
 670     bpf-*-*)
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     ft32-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676   esac
 677 fi
 678
 679 # Disable C++ on systems where it is known to not work.
 680 # For testing, you can override this with --enable-languages=c++.
 681 case ,${enable_languages}, in
 682   *,c++,*)
 683     ;;
 684   *)
 685       case "${target}" in
 686         bpf-*-*)
 687           unsupported_languages="$unsupported_languages c++"
 688           ;;
 689       esac
 690       ;;
 691 esac
 692
 693 # Disable Objc on systems where it is known to not work.
 694 # For testing, you can override this with --enable-languages=objc.
 695 case ,${enable_languages}, in
 696   *,objc,*)
 697     ;;
 698   *)
 699       case "${target}" in
 700         bpf-*-*)
 701           unsupported_languages="$unsupported_languages objc"
 702           ;;
 703       esac
 704       ;;
 705 esac
 706
 707 # Disable D on systems where it is known to not work.
 708 # For testing, you can override this with --enable-languages=d.
 709 case ,${enable_languages}, in
 710   *,d,*)
 711     ;;
 712   *)
 713     case "${target}" in
 714       bpf-*-*)
 715         unsupported_languages="$unsupported_languages d"
 716         ;;
 717     esac
 718     ;;
 719 esac
 720
 721 # Disable libphobos on unsupported systems.
 722 # For testing, you can override this with --enable-libphobos.
 723 if test -d ${srcdir}/libphobos; then
 724     if test x$enable_libphobos = x; then
 725         AC_MSG_CHECKING([for libphobos support])
 726         if (srcdir=${srcdir}/libphobos; \
 727                 . ${srcdir}/configure.tgt; \
 728                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 729         then
 730             AC_MSG_RESULT([no])
 731             noconfigdirs="$noconfigdirs target-libphobos"
 732         else
 733             AC_MSG_RESULT([yes])
 734         fi
 735     fi
 736 fi
 737
 738 # Disable Fortran for some systems.
 739 case "${target}" in
 740   mmix-*-*)
 741     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 742     unsupported_languages="$unsupported_languages fortran"
 743     ;;
 744   bpf-*-*)
 745     unsupported_languages="$unsupported_languages fortran"
 746     ;;
 747 esac
 748
 749 # Disable libffi for some systems.
 750 case "${target}" in
 751   powerpc-*-darwin*)
 752     ;;
 753   i[[3456789]]86-*-darwin*)
 754     ;;
 755   x86_64-*-darwin[[912]]*)
 756     ;;
 757   *-*-darwin*)
 758     noconfigdirs="$noconfigdirs target-libffi"
 759     ;;
 760   *-*-netware*)
 761     noconfigdirs="$noconfigdirs target-libffi"
 762     ;;
 763   *-*-phoenix*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   *-*-rtems*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   *-*-tpf*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   *-*-uclinux*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   *-*-vxworks*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   aarch64*-*-freebsd*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   alpha*-*-*vms*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   arm*-*-freebsd*)
 785     noconfigdirs="$noconfigdirs target-libffi"
 786     ;;
 787   arm-wince-pe)
 788     noconfigdirs="$noconfigdirs target-libffi"
 789     ;;
 790   arm*-*-symbianelf*)
 791     noconfigdirs="$noconfigdirs target-libffi"
 792     ;;
 793   bpf-*-*)
 794     noconfigdirs="$noconfigdirs target-libffi"
 795     ;;
 796   cris-*-* | crisv32-*-*)
 797     case "${target}" in
 798       *-*-linux*)
 799         ;;
 800       *) # See PR46792 regarding target-libffi.
 801         noconfigdirs="$noconfigdirs target-libffi";;
 802     esac
 803     ;;
 804   hppa*64*-*-hpux*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807   hppa*-hp-hpux11*)
 808     ;;
 809   hppa*-*-hpux*)
 810     noconfigdirs="$noconfigdirs target-libffi"
 811     ;;
 812   ia64*-*-*vms*)
 813     noconfigdirs="$noconfigdirs target-libffi"
 814     ;;
 815   i[[3456789]]86-w64-mingw*)
 816     noconfigdirs="$noconfigdirs target-libffi"
 817     ;;
 818   i[[3456789]]86-*-mingw*)
 819     noconfigdirs="$noconfigdirs target-libffi"
 820     ;;
 821   x86_64-*-mingw*)
 822     noconfigdirs="$noconfigdirs target-libffi"
 823     ;;
 824   mmix-*-*)
 825     noconfigdirs="$noconfigdirs target-libffi"
 826     ;;
 827   powerpc-*-aix*)
 828     ;;
 829   rs6000-*-aix*)
 830     ;;
 831   ft32-*-*)
 832     noconfigdirs="$noconfigdirs target-libffi"
 833     ;;
 834   *-*-lynxos*)
 835     noconfigdirs="$noconfigdirs target-libffi"
 836     ;;
 837 esac
 838
 839 # Disable the go frontend on systems where it is known to not work. Please keep
 840 # this in sync with contrib/config-list.mk.
 841 case "${target}" in
 842 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 843     unsupported_languages="$unsupported_languages go"
 844     ;;
 845 esac
 846
 847 # Only allow gdbserver on some systems.
 848 if test -d ${srcdir}/gdbserver; then
 849     if test x$enable_gdbserver = x; then
 850         AC_MSG_CHECKING([for gdbserver support])
 851         if (srcdir=${srcdir}/gdbserver; \
 852                 . ${srcdir}/configure.srv; \
 853                 test -n "$UNSUPPORTED")
 854         then
 855             AC_MSG_RESULT([no])
 856             noconfigdirs="$noconfigdirs gdbserver"
 857         else
 858             AC_MSG_RESULT([yes])
 859         fi
 860     fi
 861 fi
 862
 863 # Disable libgo for some systems where it is known to not work.
 864 # For testing, you can easily override this with --enable-libgo.
 865 if test x$enable_libgo = x; then
 866     case "${target}" in
 867     *-*-darwin*)
 868         # PR 46986
 869         noconfigdirs="$noconfigdirs target-libgo"
 870         ;;
 871     *-*-cygwin* | *-*-mingw*)
 872         noconfigdirs="$noconfigdirs target-libgo"
 873         ;;
 874     bpf-*-*)
 875         noconfigdirs="$noconfigdirs target-libgo"
 876         ;;
 877     esac
 878 fi
 879
 880 # Default libgloss CPU subdirectory.
 881 libgloss_dir="$target_cpu"
 882
 883 case "${target}" in
 884   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 885     libgloss_dir=wince
 886     ;;
 887   aarch64*-*-* )
 888     libgloss_dir=aarch64
 889     ;;
 890   arm*-*-*)
 891     libgloss_dir=arm
 892     ;;
 893   cris-*-* | crisv32-*-*)
 894     libgloss_dir=cris
 895     ;;
 896   kvx-*-elf)
 897     libgloss_dir=kvx-elf
 898     ;;
 899   kvx-*-mbr)
 900     libgloss_dir=kvx-mbr
 901     ;;
 902   kvx-*-cos)
 903     libgloss_dir=kvx-cos
 904     ;;
 905   hppa*-*-*)
 906     libgloss_dir=pa
 907     ;;
 908   i[[3456789]]86-*-*)
 909     libgloss_dir=i386
 910     ;;
 911   loongarch*-*-*)
 912     libgloss_dir=loongarch
 913     ;;
 914   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 915     libgloss_dir=m68hc11
 916     ;;
 917   m68*-*-* | fido-*-*)
 918     libgloss_dir=m68k
 919     ;;
 920   mips*-*-*)
 921     libgloss_dir=mips
 922     ;;
 923   powerpc*-*-*)
 924     libgloss_dir=rs6000
 925     ;;
 926   pru-*-*)
 927     libgloss_dir=pru
 928     ;;
 929   sparc*-*-*)
 930     libgloss_dir=sparc
 931     ;;
 932 esac
 933
 934 # Disable newlib and libgloss for various target OSes.
 935 case "${target}" in
 936   alpha*-dec-osf*)
 937     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 938     ;;
 939   i[[3456789]]86-*-linux*)
 940     # This section makes it possible to build newlib natively on linux.
 941     # If we are using a cross compiler then don't configure newlib.
 942     if test x${is_cross_compiler} != xno ; then
 943       noconfigdirs="$noconfigdirs target-newlib"
 944     fi
 945     noconfigdirs="$noconfigdirs target-libgloss"
 946     # If we are not using a cross compiler, do configure newlib.
 947     # Note however, that newlib will only be configured in this situation
 948     # if the --with-newlib option has been given, because otherwise
 949     # 'target-newlib' will appear in skipdirs.
 950     ;;
 951   i[[3456789]]86-*-rdos*)
 952     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 953     ;;
 954   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 955     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 956     ;;
 957   sparc-*-sunos4*)
 958     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 959     ;;
 960   bpf-*-*)
 961     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 962     ;;
 963   *-*-aix*)
 964     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 965     ;;
 966   *-*-beos*)
 967     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 968     ;;
 969   *-*-chorusos)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   *-*-dragonfly*)
 973     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 974     ;;
 975   *-*-freebsd*)
 976     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 977     ;;
 978   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 979     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 980     ;;
 981   *-*-lynxos*)
 982     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 983     ;;
 984   *-*-mingw*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   *-*-netbsd*)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990   *-*-netware*)
 991     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 992     ;;
 993   *-*-tpf*)
 994     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 995     ;;
 996   *-*-uclinux*)
 997     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 998     ;;
 999   *-*-vxworks*)
1000     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1001     ;;
1002 esac
1003
1004 case "${target}" in
1005   *-*-chorusos)
1006     ;;
1007   aarch64-*-darwin*)
1008     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1009     noconfigdirs="$noconfigdirs sim target-rda"
1010     ;;
1011   amdgcn*-*-*)
1012     ;;
1013   arm-*-darwin*)
1014     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1015     noconfigdirs="$noconfigdirs sim target-rda"
1016     ;;
1017   powerpc-*-darwin*)
1018     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1019     noconfigdirs="$noconfigdirs sim target-rda"
1020     ;;
1021   i[[3456789]]86-*-darwin*)
1022     noconfigdirs="$noconfigdirs ld gprof"
1023     noconfigdirs="$noconfigdirs sim target-rda"
1024     ;;
1025   x86_64-*-darwin[[912]]*)
1026     noconfigdirs="$noconfigdirs ld gas gprof"
1027     noconfigdirs="$noconfigdirs sim target-rda"
1028     ;;
1029   *-*-darwin*)
1030     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1031     noconfigdirs="$noconfigdirs sim target-rda"
1032     ;;
1033   *-*-dragonfly*)
1034     ;;
1035   *-*-freebsd*)
1036     if test "x$with_gmp" = x \
1037         && ! test -d ${srcdir}/gmp \
1038         && test -f /usr/local/include/gmp.h; then
1039       with_gmp=/usr/local
1040     fi
1041     ;;
1042   *-*-kaos*)
1043     # Remove unsupported stuff on all kaOS configurations.
1044     noconfigdirs="$noconfigdirs target-libgloss"
1045     ;;
1046   *-*-netbsd*)
1047     ;;
1048   *-*-netware*)
1049     ;;
1050   *-*-phoenix*)
1051     noconfigdirs="$noconfigdirs target-libgloss"
1052     ;;
1053   *-*-rtems*)
1054     noconfigdirs="$noconfigdirs target-libgloss"
1055     ;;
1056     # The tpf target doesn't support gdb yet.
1057   *-*-tpf*)
1058     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1059     ;;
1060   *-*-uclinux*)
1061     noconfigdirs="$noconfigdirs target-rda"
1062     ;;
1063   *-*-vxworks*)
1064     ;;
1065   alpha*-dec-osf*)
1066     # ld works, but does not support shared libraries.
1067     # gas doesn't generate exception information.
1068     noconfigdirs="$noconfigdirs gas ld"
1069     ;;
1070   alpha*-*-*vms*)
1071     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1072     ;;
1073   alpha*-*-*)
1074     # newlib is not 64 bit ready
1075     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1076     ;;
1077   bpf-*-*)
1078     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1079     ;;
1080   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1081     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1082     ;;
1083   arc*-*-*)
1084     noconfigdirs="$noconfigdirs sim"
1085     ;;
1086   arm-*-pe*)
1087     noconfigdirs="$noconfigdirs target-libgloss"
1088     ;;
1089   arm-*-riscix*)
1090     noconfigdirs="$noconfigdirs ld target-libgloss"
1091     ;;
1092   avr-*-*)
1093     if test x${with_avrlibc} != xno; then
1094       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1095     fi
1096     ;;
1097   c4x-*-* | tic4x-*-*)
1098     noconfigdirs="$noconfigdirs target-libgloss"
1099     ;;
1100   tic54x-*-*)
1101     noconfigdirs="$noconfigdirs target-libgloss gdb"
1102     ;;
1103   d10v-*-*)
1104     noconfigdirs="$noconfigdirs target-libgloss"
1105     ;;
1106   d30v-*-*)
1107     noconfigdirs="$noconfigdirs gdb"
1108     ;;
1109   fr30-*-elf*)
1110     noconfigdirs="$noconfigdirs gdb"
1111     ;;
1112   ft32-*-*)
1113     noconfigdirs="$noconfigdirs target-rda gprof"
1114     ;;
1115   moxie-*-*)
1116     noconfigdirs="$noconfigdirs"
1117     ;;
1118   h8300*-*-*)
1119     noconfigdirs="$noconfigdirs target-libgloss"
1120     ;;
1121   h8500-*-*)
1122     noconfigdirs="$noconfigdirs target-libgloss"
1123     ;;
1124   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1125     ;;
1126   hppa*64*-*-hpux*)
1127     noconfigdirs="$noconfigdirs gdb"
1128     ;;
1129   hppa*-*-hpux11*)
1130     noconfigdirs="$noconfigdirs gdb ld"
1131     ;;
1132   hppa*64*-*-linux*)
1133     ;;
1134   hppa*-*-linux*)
1135     ;;
1136   hppa*-*-*elf* | \
1137   hppa*-*-lites* | \
1138   hppa*-*-openbsd* | \
1139   hppa*64*-*-*)
1140     ;;
1141   hppa*-*-pro*)
1142     ;;
1143   hppa*-*-*)
1144     noconfigdirs="$noconfigdirs ld"
1145     ;;
1146   i960-*-*)
1147     noconfigdirs="$noconfigdirs gdb"
1148     ;;
1149   ia64*-*-elf*)
1150     # No gdb support yet.
1151     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1152     ;;
1153   ia64*-**-hpux*)
1154     # No ld support yet.
1155     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1156     ;;
1157   ia64*-*-*vms*)
1158     # No ld support yet.
1159     noconfigdirs="$noconfigdirs libgui itcl ld"
1160     ;;
1161   i[[3456789]]86-w64-mingw*)
1162     ;;
1163   i[[3456789]]86-*-mingw*)
1164     target_configdirs="$target_configdirs target-winsup"
1165     ;;
1166   *-*-cygwin*)
1167     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1168     noconfigdirs="$noconfigdirs target-libgloss"
1169     # always build newlib if winsup directory is present.
1170     if test -d "$srcdir/winsup/cygwin"; then
1171       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1172     elif test -d "$srcdir/newlib"; then
1173       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1174     fi
1175     ;;
1176   i[[3456789]]86-*-pe)
1177     noconfigdirs="$noconfigdirs target-libgloss"
1178     ;;
1179   i[[3456789]]86-*-sco3.2v5*)
1180     # The linker does not yet know about weak symbols in COFF,
1181     # and is not configured to handle mixed ELF and COFF.
1182     noconfigdirs="$noconfigdirs ld target-libgloss"
1183     ;;
1184   i[[3456789]]86-*-sco*)
1185     noconfigdirs="$noconfigdirs gprof target-libgloss"
1186     ;;
1187   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1188     noconfigdirs="$noconfigdirs target-libgloss"
1189     ;;
1190   i[[3456789]]86-*-sysv4*)
1191     noconfigdirs="$noconfigdirs target-libgloss"
1192     ;;
1193   i[[3456789]]86-*-beos*)
1194     noconfigdirs="$noconfigdirs gdb"
1195     ;;
1196   i[[3456789]]86-*-rdos*)
1197     noconfigdirs="$noconfigdirs gdb"
1198     ;;
1199   kvx-*-*)
1200     noconfigdirs="$noconfigdirs gdb gdbserver sim"
1201     ;;
1202   mmix-*-*)
1203     noconfigdirs="$noconfigdirs gdb"
1204     ;;
1205   mt-*-*)
1206     noconfigdirs="$noconfigdirs sim"
1207     ;;
1208   nfp-*-*)
1209     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1210     noconfigdirs="$noconfigdirs $target_libraries"
1211     ;;
1212   pdp11-*-*)
1213     noconfigdirs="$noconfigdirs gdb gprof"
1214     ;;
1215   powerpc-*-aix*)
1216     # copied from rs6000-*-* entry
1217     noconfigdirs="$noconfigdirs gprof"
1218     ;;
1219   powerpc*-*-winnt* | powerpc*-*-pe*)
1220     target_configdirs="$target_configdirs target-winsup"
1221     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1222     # always build newlib.
1223     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1224     ;;
1225     # This is temporary until we can link against shared libraries
1226   powerpcle-*-solaris*)
1227     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1228     ;;
1229   powerpc-*-beos*)
1230     noconfigdirs="$noconfigdirs gdb"
1231     ;;
1232   rs6000-*-lynxos*)
1233     noconfigdirs="$noconfigdirs gprof"
1234     ;;
1235   rs6000-*-aix*)
1236     noconfigdirs="$noconfigdirs gprof"
1237     ;;
1238   rs6000-*-*)
1239     noconfigdirs="$noconfigdirs gprof"
1240     ;;
1241   m68k-apollo-*)
1242     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1243     ;;
1244   microblaze*)
1245     noconfigdirs="$noconfigdirs gprof"
1246     ;;
1247   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1248     if test x$with_newlib = xyes; then
1249       noconfigdirs="$noconfigdirs gprof"
1250     fi
1251     ;;
1252   mips*-*-irix5*)
1253     noconfigdirs="$noconfigdirs gprof target-libgloss"
1254     ;;
1255   mips*-*-irix6*)
1256     noconfigdirs="$noconfigdirs gprof target-libgloss"
1257     ;;
1258   mips*-*-bsd*)
1259     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1260     ;;
1261   mips*-*-linux*)
1262     ;;
1263   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1264   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1265     noconfigdirs="$noconfigdirs ld gas gprof"
1266     ;;
1267   mips*-*-*)
1268     noconfigdirs="$noconfigdirs gprof"
1269     ;;
1270   nvptx*-*-*)
1271     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1272     ;;
1273   sh-*-*)
1274     case "${target}" in
1275       sh*-*-elf)
1276          ;;
1277       *)
1278          noconfigdirs="$noconfigdirs target-libgloss" ;;
1279     esac
1280     ;;
1281   sparc-*-sunos4*)
1282     if test x${is_cross_compiler} = xno ; then
1283            use_gnu_ld=no
1284     fi
1285     ;;
1286   tic6x-*-*)
1287     noconfigdirs="$noconfigdirs sim"
1288     ;;
1289   tilepro*-*-* | tilegx*-*-*)
1290     noconfigdirs="$noconfigdirs sim"
1291     ;;
1292   v810-*-*)
1293     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1294     ;;
1295   vax-*-*)
1296     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1297     ;;
1298   wasm32-*-*)
1299     noconfigdirs="$noconfigdirs ld"
1300     ;;
1301   loongarch*-*-linux*)
1302     ;;
1303   loongarch*-*-*)
1304     noconfigdirs="$noconfigdirs gprof"
1305     ;;
1306 esac
1307
1308 # If we aren't building newlib, then don't build libgloss, since libgloss
1309 # depends upon some newlib header files.
1310 case "${noconfigdirs}" in
1311   *target-libgloss*) ;;
1312   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1313 esac
1314
1315 # Work in distributions that contain no compiler tools, like Autoconf.
1316 host_makefile_frag=/dev/null
1317 if test -d ${srcdir}/config ; then
1318 case "${host}" in
1319   i[[3456789]]86-*-msdosdjgpp*)
1320     host_makefile_frag="config/mh-djgpp"
1321     ;;
1322   *-cygwin*)
1323     ACX_CHECK_CYGWIN_CAT_WORKS
1324     host_makefile_frag="config/mh-cygwin"
1325     ;;
1326   *-mingw*)
1327     host_makefile_frag="config/mh-mingw"
1328     ;;
1329   alpha*-linux*)
1330     host_makefile_frag="config/mh-alpha-linux"
1331     ;;
1332   hppa*-hp-hpux*)
1333     host_makefile_frag="config/mh-pa"
1334     ;;
1335   hppa*-*)
1336     host_makefile_frag="config/mh-pa"
1337     ;;
1338   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1339     host_makefile_frag="config/mh-darwin"
1340     ;;
1341   powerpc-*-aix*)
1342     host_makefile_frag="config/mh-ppc-aix"
1343     ;;
1344   rs6000-*-aix*)
1345     host_makefile_frag="config/mh-ppc-aix"
1346     ;;
1347 esac
1348 fi
1349
1350 if test "${build}" != "${host}" ; then
1351   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1352   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1353   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1354   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1355   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1356   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1357   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1358   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1359   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1360   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1361   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1362   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1363   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1364   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1365   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1366 else
1367   AR_FOR_BUILD="\$(AR)"
1368   AS_FOR_BUILD="\$(AS)"
1369   CC_FOR_BUILD="\$(CC)"
1370   CXX_FOR_BUILD="\$(CXX)"
1371   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1372   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1373   GOC_FOR_BUILD="\$(GOC)"
1374   GDC_FOR_BUILD="\$(GDC)"
1375   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1376   LD_FOR_BUILD="\$(LD)"
1377   NM_FOR_BUILD="\$(NM)"
1378   RANLIB_FOR_BUILD="\$(RANLIB)"
1379   WINDRES_FOR_BUILD="\$(WINDRES)"
1380   WINDMC_FOR_BUILD="\$(WINDMC)"
1381 fi
1382
1383 AC_PROG_CC_C99
1384 AC_PROG_CXX
1385
1386 # We must set the default linker to the linker used by gcc for the correct
1387 # operation of libtool.  If LD is not defined and we are using gcc, try to
1388 # set the LD default to the ld used by gcc.
1389 if test -z "$LD"; then
1390   if test "$GCC" = yes; then
1391     case $build in
1392     *-*-mingw*)
1393       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1394     *)
1395       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1396     esac
1397     case $gcc_prog_ld in
1398     # Accept absolute paths.
1399     [[\\/]* | [A-Za-z]:[\\/]*)]
1400       LD="$gcc_prog_ld" ;;
1401     esac
1402   fi
1403 fi
1404
1405 # Check whether -static-libstdc++ -static-libgcc is supported.
1406 have_static_libs=no
1407 if test "$GCC" = yes; then
1408   saved_LDFLAGS="$LDFLAGS"
1409
1410   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1411   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1412   AC_LANG_PUSH(C++)
1413   AC_LINK_IFELSE([AC_LANG_SOURCE([
1414 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1415 #error -static-libstdc++ not implemented
1416 #endif
1417 int main() {}])],
1418     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1419     [AC_MSG_RESULT([no])])
1420   AC_LANG_POP(C++)
1421
1422   LDFLAGS="$saved_LDFLAGS"
1423 fi
1424
1425 ACX_PROG_GNAT
1426 ACX_PROG_GDC
1427 ACX_PROG_CMP_IGNORE_INITIAL
1428
1429 AC_ARG_ENABLE([bootstrap],
1430 [AS_HELP_STRING([--enable-bootstrap],
1431                 [enable bootstrapping @<:@yes if native build@:>@])],,
1432 enable_bootstrap=default)
1433
1434 # Issue errors and warnings for invalid/strange bootstrap combinations.
1435 if test -r $srcdir/gcc/configure; then
1436   have_compiler=yes
1437 else
1438   have_compiler=no
1439 fi
1440
1441 case "$have_compiler:$host:$target:$enable_bootstrap" in
1442   *:*:*:no) ;;
1443
1444   # Default behavior.  Enable bootstrap if we have a compiler
1445   # and we are in a native configuration.
1446   yes:$build:$build:default)
1447     enable_bootstrap=yes ;;
1448
1449   *:*:*:default)
1450     enable_bootstrap=no ;;
1451
1452   # We have a compiler and we are in a native configuration, bootstrap is ok
1453   yes:$build:$build:yes)
1454     ;;
1455
1456   # Other configurations, but we have a compiler.  Assume the user knows
1457   # what he's doing.
1458   yes:*:*:yes)
1459     AC_MSG_WARN([trying to bootstrap a cross compiler])
1460     ;;
1461
1462   # No compiler: if they passed --enable-bootstrap explicitly, fail
1463   no:*:*:yes)
1464     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1465
1466   # Fail if wrong command line
1467   *)
1468     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1469     ;;
1470 esac
1471
1472 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1473 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1474 # require C++11 (or higher).
1475 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1476   CXX="$CXX -std=c++11"
1477 elif test "$have_compiler" = yes; then
1478   AX_CXX_COMPILE_STDCXX(11)
1479
1480   if test "${build}" != "${host}"; then
1481     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1482   fi
1483 fi
1484
1485 AC_ARG_ENABLE([pgo-build],
1486 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1487                 [enable the PGO build])],
1488 [enable_pgo_build=$enableval],
1489 [enable_pgo_build=no])
1490
1491 # Issue errors and warnings for invalid/strange PGO build combinations.
1492 case "$have_compiler:$host:$target:$enable_pgo_build" in
1493   *:*:*:no) ;;
1494
1495   # Allow the PGO build only if we aren't building a compiler and
1496   # we are in a native configuration.
1497   no:$build:$build:yes | no:$build:$build:lto) ;;
1498
1499   # Disallow the PGO bootstrap if we are building a compiler.
1500   yes:*:*:yes | yes:*:*:lto)
1501     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1502
1503   *)
1504     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1505     ;;
1506 esac
1507
1508 if test "$enable_pgo_build" != "no"; then
1509   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1510   old_CFLAGS="$CFLAGS"
1511   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1512   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1513   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1514                     [PGO_BUILD_GEN_CFLAGS=])
1515   CFLAGS="$old_CFLAGS"
1516   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1517     AC_MSG_RESULT([yes])
1518     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1519   else
1520     AC_MSG_RESULT([no])
1521     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1522   fi
1523
1524   if test "$enable_pgo_build" = "lto"; then
1525     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1526     old_CFLAGS="$CFLAGS"
1527     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1528     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1529     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1530                       [PGO_BUILD_LTO_CFLAGS=])
1531     CFLAGS="$old_CFLAGS"
1532     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1533       AC_MSG_RESULT([yes])
1534     else
1535       AC_MSG_RESULT([no])
1536       AC_MSG_WARN([LTO is disabled for the PGO build])
1537     fi
1538   fi
1539 fi
1540 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1541 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1542 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1543
1544 # Used for setting $lt_cv_objdir
1545 _LT_CHECK_OBJDIR
1546
1547 # Check for GMP, MPFR and MPC
1548 require_gmp=no
1549 require_mpc=no
1550 if test -d ${srcdir}/gcc ; then
1551   require_gmp=yes
1552   require_mpc=yes
1553 fi
1554 if test -d ${srcdir}/gdb ; then
1555   if test "x$enable_gdb" != xno; then
1556    require_gmp=yes
1557   fi
1558 fi
1559
1560 gmplibs="-lmpfr -lgmp"
1561 if test x"$require_mpc" = "xyes" ; then
1562   gmplibs="-lmpc $gmplibs"
1563 fi
1564 gmpinc=
1565 have_gmp=no
1566
1567 # Specify a location for mpc
1568 # check for this first so it ends up on the link line before mpfr.
1569 AC_ARG_WITH(mpc,
1570 [AS_HELP_STRING([--with-mpc=PATH],
1571                 [specify prefix directory for installed MPC package.
1572                  Equivalent to --with-mpc-include=PATH/include
1573                  plus --with-mpc-lib=PATH/lib])])
1574 AC_ARG_WITH(mpc-include,
1575 [AS_HELP_STRING([--with-mpc-include=PATH],
1576                 [specify directory for installed MPC include files])])
1577 AC_ARG_WITH(mpc-lib,
1578 [AS_HELP_STRING([--with-mpc-lib=PATH],
1579                 [specify directory for the installed MPC library])])
1580
1581 if test "x$with_mpc" != x; then
1582   gmplibs="-L$with_mpc/lib $gmplibs"
1583   gmpinc="-I$with_mpc/include $gmpinc"
1584 fi
1585 if test "x$with_mpc_include" != x; then
1586   gmpinc="-I$with_mpc_include $gmpinc"
1587 fi
1588 if test "x$with_mpc_lib" != x; then
1589   gmplibs="-L$with_mpc_lib $gmplibs"
1590 fi
1591 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1592   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1593   gmpinc='-I$$s/mpc/src '"$gmpinc"
1594   # Do not test the mpc version.  Assume that it is sufficient, since
1595   # it is in the source tree, and the library has not been built yet
1596   # but it would be included on the link line in the version check below
1597   # hence making the test fail.
1598   have_gmp=yes
1599 fi
1600
1601 # Specify a location for mpfr
1602 # check for this first so it ends up on the link line before gmp.
1603 AC_ARG_WITH(mpfr,
1604 [AS_HELP_STRING([--with-mpfr=PATH],
1605                 [specify prefix directory for installed MPFR package.
1606                  Equivalent to --with-mpfr-include=PATH/include
1607                  plus --with-mpfr-lib=PATH/lib])])
1608 AC_ARG_WITH(mpfr-include,
1609 [AS_HELP_STRING([--with-mpfr-include=PATH],
1610                 [specify directory for installed MPFR include files])])
1611 AC_ARG_WITH(mpfr-lib,
1612 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1613                 [specify directory for the installed MPFR library])])
1614
1615 if test "x$with_mpfr" != x; then
1616   gmplibs="-L$with_mpfr/lib $gmplibs"
1617   gmpinc="-I$with_mpfr/include $gmpinc"
1618 fi
1619 if test "x$with_mpfr_include" != x; then
1620   gmpinc="-I$with_mpfr_include $gmpinc"
1621 fi
1622 if test "x$with_mpfr_lib" != x; then
1623   gmplibs="-L$with_mpfr_lib $gmplibs"
1624 fi
1625 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1626   # MPFR v3.1.0 moved the sources into a src sub-directory.
1627   if ! test -d ${srcdir}/mpfr/src; then
1628     AC_MSG_ERROR([dnl
1629 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1630   fi
1631   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1632   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1633   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1634   # Do not test the mpfr version.  Assume that it is sufficient, since
1635   # it is in the source tree, and the library has not been built yet
1636   # but it would be included on the link line in the version check below
1637   # hence making the test fail.
1638   have_gmp=yes
1639 fi
1640
1641 # Specify a location for gmp
1642 AC_ARG_WITH(gmp,
1643 [AS_HELP_STRING([--with-gmp=PATH],
1644                 [specify prefix directory for the installed GMP package.
1645                  Equivalent to --with-gmp-include=PATH/include
1646                  plus --with-gmp-lib=PATH/lib])])
1647 AC_ARG_WITH(gmp-include,
1648 [AS_HELP_STRING([--with-gmp-include=PATH],
1649                 [specify directory for installed GMP include files])])
1650 AC_ARG_WITH(gmp-lib,
1651 [AS_HELP_STRING([--with-gmp-lib=PATH],
1652                 [specify directory for the installed GMP library])])
1653
1654
1655 if test "x$with_gmp" != x; then
1656   gmplibs="-L$with_gmp/lib $gmplibs"
1657   gmpinc="-I$with_gmp/include $gmpinc"
1658 fi
1659 if test "x$with_gmp_include" != x; then
1660   gmpinc="-I$with_gmp_include $gmpinc"
1661 fi
1662 if test "x$with_gmp_lib" != x; then
1663   gmplibs="-L$with_gmp_lib $gmplibs"
1664 fi
1665 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1666   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1667   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1668   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1669   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1670   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1671   # Do not test the gmp version.  Assume that it is sufficient, since
1672   # it is in the source tree, and the library has not been built yet
1673   # but it would be included on the link line in the version check below
1674   # hence making the test fail.
1675   have_gmp=yes
1676 fi
1677
1678 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1679   have_gmp=yes
1680   saved_CFLAGS="$CFLAGS"
1681   CFLAGS="$CFLAGS $gmpinc"
1682   # Check for the recommended and required versions of GMP.
1683   AC_MSG_CHECKING([for the correct version of gmp.h])
1684   AC_TRY_COMPILE([#include "gmp.h"],[
1685   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1686   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1687   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1688   choke me
1689   #endif
1690   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1691   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1692   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1693   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1694   choke me
1695   #endif
1696   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1697    [AC_MSG_RESULT([no]); have_gmp=no])
1698
1699   # If we have GMP, check the MPFR version.
1700   if test x"$have_gmp" = xyes; then
1701     # Check for the recommended and required versions of MPFR.
1702     AC_MSG_CHECKING([for the correct version of mpfr.h])
1703     AC_TRY_COMPILE([#include <gmp.h>
1704     #include <mpfr.h>],[
1705     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1706     choke me
1707     #endif
1708     ], [AC_TRY_COMPILE([#include <gmp.h>
1709     #include <mpfr.h>],[
1710     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1711     choke me
1712     #endif
1713     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1714      [AC_MSG_RESULT([no]); have_gmp=no])
1715   fi
1716
1717   # Check for the MPC header version.
1718   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1719     # Check for the recommended and required versions of MPC.
1720     AC_MSG_CHECKING([for the correct version of mpc.h])
1721     AC_TRY_COMPILE([#include <mpc.h>],[
1722     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1723     choke me
1724     #endif
1725     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1726     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1727     choke me
1728     #endif
1729     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1730      [AC_MSG_RESULT([no]); have_gmp=no])
1731   fi
1732
1733   # Now check the MPFR library.
1734   if test x"$have_gmp" = xyes; then
1735     saved_LIBS="$LIBS"
1736     LIBS="$LIBS $gmplibs"
1737     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1738     AC_TRY_LINK([#include <mpfr.h>],[
1739     mpfr_t n;
1740     mpfr_t x;
1741     int t;
1742     mpfr_init (n);
1743     mpfr_init (x);
1744     mpfr_atan2 (n, n, x, MPFR_RNDN);
1745     mpfr_erfc (n, x, MPFR_RNDN);
1746     mpfr_subnormalize (x, t, MPFR_RNDN);
1747     mpfr_clear(n);
1748     mpfr_clear(x);
1749     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1750     LIBS="$saved_LIBS"
1751   fi
1752
1753   # Now check the MPC library
1754   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1755     saved_LIBS="$LIBS"
1756     LIBS="$LIBS $gmplibs"
1757     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1758     AC_TRY_LINK([#include <mpc.h>],[
1759     mpc_t c;
1760     mpc_init2 (c, 53);
1761     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1762     mpc_cosh (c, c, MPC_RNDNN);
1763     mpc_pow (c, c, c, MPC_RNDNN);
1764     mpc_acosh (c, c, MPC_RNDNN);
1765     mpc_clear (c);
1766     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1767     LIBS="$saved_LIBS"
1768   fi
1769
1770   CFLAGS="$saved_CFLAGS"
1771
1772 # The library versions listed in the error message below should match
1773 # the HARD-minimums enforced above.
1774   if test x$have_gmp != xyes; then
1775     if test -d ${srcdir}/gcc ; then
1776       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1777 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1778 their locations.  Source code for these libraries can be found at
1779 their respective hosting sites as well as at
1780 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1781 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1782 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1783 make sure that you have installed both the libraries and the header
1784 files.  They may be located in separate packages.])
1785     else
1786       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1787 Try the --with-gmp and/or --with-mpfr options to specify
1788 their locations.  If you obtained GMP and/or MPFR from a vendor
1789 distribution package, make sure that you have installed both the libraries
1790 and the header files.  They may be located in separate packages.])
1791     fi
1792   fi
1793 fi
1794
1795 # Flags needed for both GMP, MPFR and/or MPC.
1796 AC_SUBST(gmplibs)
1797 AC_SUBST(gmpinc)
1798 AC_SUBST(extra_mpfr_configure_flags)
1799 AC_SUBST(extra_mpc_gmp_configure_flags)
1800 AC_SUBST(extra_mpc_mpfr_configure_flags)
1801 AC_SUBST(extra_isl_gmp_configure_flags)
1802
1803 # Libraries to use for stage1 or when not bootstrapping.
1804 AC_ARG_WITH(stage1-libs,
1805 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1806 [if test "$withval" = "no" -o "$withval" = "yes"; then
1807    stage1_libs=
1808  else
1809    stage1_libs=$withval
1810  fi],
1811 [stage1_libs=])
1812 AC_SUBST(stage1_libs)
1813
1814 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1815 # default is yes if gcc is being built; no otherwise.  The reason for
1816 # this default is that gdb is sometimes linked against GNU Source
1817 # Highlight, which is a shared library that uses C++ exceptions.  In
1818 # this case, -static-libstdc++ will cause crashes.
1819 AC_ARG_WITH(static-standard-libraries,
1820 [AS_HELP_STRING([--with-static-standard-libraries],
1821                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1822 [], [with_static_standard_libraries=auto])
1823 if test "$with_static_standard_libraries" = auto; then
1824   with_static_standard_libraries=$have_compiler
1825 fi
1826
1827 # Linker flags to use for stage1 or when not bootstrapping.
1828 AC_ARG_WITH(stage1-ldflags,
1829 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1830 [if test "$withval" = "no" -o "$withval" = "yes"; then
1831    stage1_ldflags=
1832  else
1833    stage1_ldflags=$withval
1834  fi],
1835 [stage1_ldflags=
1836  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1837  # if supported.  But if the user explicitly specified the libraries to use,
1838  # trust that they are doing what they want.
1839  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1840      -a "$have_static_libs" = yes; then
1841    stage1_ldflags="-static-libstdc++ -static-libgcc"
1842  fi])
1843 AC_SUBST(stage1_ldflags)
1844
1845 # Libraries to use for stage2 and later builds.
1846 AC_ARG_WITH(boot-libs,
1847 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1848 [if test "$withval" = "no" -o "$withval" = "yes"; then
1849    poststage1_libs=
1850  else
1851    poststage1_libs=$withval
1852  fi],
1853 [poststage1_libs=])
1854 AC_SUBST(poststage1_libs)
1855
1856 # Linker flags to use for stage2 and later builds.
1857 AC_ARG_WITH(boot-ldflags,
1858 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1859                 [linker flags for stage2 and later])],
1860 [if test "$withval" = "no" -o "$withval" = "yes"; then
1861    poststage1_ldflags=
1862  else
1863    poststage1_ldflags=$withval
1864  fi],
1865 [poststage1_ldflags=
1866  # In stages 2 and 3, default to linking libstdc++ and libgcc
1867  # statically.  But if the user explicitly specified the libraries to
1868  # use, trust that they are doing what they want.
1869  if test "$poststage1_libs" = ""; then
1870    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1871  fi])
1872 case $target in
1873   *-darwin2* | *-darwin1[[56789]]*)
1874     # For these versions, we default to using embedded rpaths.
1875     if test "x$enable_darwin_at_rpath" != "xno"; then
1876       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1877     fi
1878   ;;
1879   *-darwin*)
1880     # For these versions, we only use embedded rpaths on demand.
1881     if test "x$enable_darwin_at_rpath" = "xyes"; then
1882       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1883     fi
1884   ;;
1885 esac
1886 AC_SUBST(poststage1_ldflags)
1887
1888 # GCC GRAPHITE dependency isl.
1889 # Basic setup is inlined here, actual checks are in config/isl.m4
1890
1891 AC_ARG_WITH(isl,
1892   [AS_HELP_STRING(
1893    [--with-isl=PATH],
1894    [Specify prefix directory for the installed isl package.
1895     Equivalent to --with-isl-include=PATH/include
1896     plus --with-isl-lib=PATH/lib])])
1897
1898 # Treat --without-isl as a request to disable
1899 # GRAPHITE support and skip all following checks.
1900 if test "x$with_isl" != "xno"; then
1901   # Check for isl
1902   dnl Provide configure switches and initialize islinc & isllibs
1903   dnl with user input.
1904   ISL_INIT_FLAGS
1905   dnl The versions of isl that work for Graphite
1906   ISL_CHECK_VERSION()
1907   dnl Only execute fail-action, if isl has been requested.
1908   ISL_IF_FAILED([
1909     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1910 fi
1911
1912 # If the isl check failed, disable builds of in-tree variant of isl
1913 if test "x$with_isl" = xno ||
1914    test "x$gcc_cv_isl" = xno; then
1915   noconfigdirs="$noconfigdirs isl"
1916   islinc=
1917 fi
1918
1919 AC_SUBST(isllibs)
1920 AC_SUBST(islinc)
1921
1922 # Check for LTO support.
1923 AC_ARG_ENABLE(lto,
1924 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1925 enable_lto=$enableval,
1926 enable_lto=yes; default_enable_lto=yes)
1927
1928 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1929   build_lto_plugin=yes
1930 ],[if test x"$default_enable_lto" = x"yes" ; then
1931     case $target in
1932       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1933       # On other non-ELF platforms, LTO has yet to be validated.
1934       *) enable_lto=no ;;
1935     esac
1936   else
1937   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1938   # It would also be nice to check the binutils support, but we don't
1939   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1940   # warn during gcc/ subconfigure; unless you're bootstrapping with
1941   # -flto it won't be needed until after installation anyway.
1942     case $target in
1943       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1944       *) if test x"$enable_lto" = x"yes"; then
1945         AC_MSG_ERROR([LTO support is not enabled for this target.])
1946         fi
1947       ;;
1948     esac
1949   fi
1950   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1951   # Build it unless LTO was explicitly disabled.
1952   case $target in
1953     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1954     *) ;;
1955   esac
1956 ])
1957
1958 AC_ARG_ENABLE(linker-plugin-configure-flags,
1959   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1960     [additional flags for configuring linker plugins @<:@none@:>@])],
1961   extra_linker_plugin_configure_flags=$enableval,
1962   extra_linker_plugin_configure_flags=)
1963 AC_SUBST(extra_linker_plugin_configure_flags)
1964 AC_ARG_ENABLE(linker-plugin-flags,
1965   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1966     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1967   extra_linker_plugin_flags=$enableval,
1968   extra_linker_plugin_flags=)
1969 AC_SUBST(extra_linker_plugin_flags)
1970
1971 # Handle --enable-host-pie
1972 # If host PIE executables are the default (or must be forced on) for some host,
1973 # we must pass that configuration to the gcc directory.
1974 gcc_host_pie=
1975 AC_ARG_ENABLE(host-pie,
1976 [AS_HELP_STRING([--enable-host-pie],
1977                 [build position independent host executables])],
1978 [host_pie=$enableval
1979  case $host in
1980    *-*-darwin2*)
1981      if test x$host_pie != xyes ; then
1982        # for Darwin20+ this is required.
1983        AC_MSG_WARN([PIE executables are required for the configured host, host-pie setting ignored.])
1984        host_pie=yes
1985        gcc_host_pie=--enable-host-pie
1986      fi ;;
1987   *) ;;
1988  esac],
1989 [case $host in
1990   *-*-darwin2*)
1991     # Default to PIE (mandatory for aarch64).
1992     host_pie=yes
1993     gcc_host_pie=--enable-host-pie
1994     ;;
1995   *) host_pie=no ;;
1996  esac])
1997
1998 AC_SUBST(host_pie)
1999 AC_SUBST(gcc_host_pie)
2000
2001 # Enable --enable-host-shared.
2002 # Checked early to determine whether jit is an 'all' language
2003 AC_ARG_ENABLE(host-shared,
2004 [AS_HELP_STRING([--enable-host-shared],
2005                 [build host code as shared libraries])],
2006 [host_shared=$enableval
2007  case $host in
2008    x86_64-*-darwin* | aarch64-*-darwin*)
2009      if test x$host_shared != xyes ; then
2010        # PIC is the default, and actually cannot be switched off.
2011        AC_MSG_WARN([PIC code is required for the configured host; host-shared setting ignored.])
2012        host_shared=yes
2013      fi ;;
2014    *-*-darwin*)
2015      if test x$host_pie = xyes -a x$host_shared != xyes ; then
2016        AC_MSG_WARN([PIC code is required for PIE host executables host-shared setting ignored.])
2017        host_shared=yes
2018      fi ;;
2019   *) ;;
2020  esac],
2021 [case $host in
2022   # 64B x86_64 and Aarch64 Darwin default to PIC.
2023   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
2024   # 32B and powerpc64 Darwin must use PIC to link PIE exes.
2025   *-*-darwin*) host_shared=$host_pie ;;
2026   *) host_shared=no;;
2027  esac])
2028
2029 AC_SUBST(host_shared)
2030
2031 if test x$host_shared = xyes; then
2032   case $host in
2033     *-*-darwin*)
2034       # Since host shared is the default for 64b Darwin, and also enabled for
2035       # host_pie, ensure that we present the PIE flag when host_pie is active.
2036       if test x$host_pie = xyes; then
2037         PICFLAG=-fPIE
2038       fi
2039       ;;
2040     *)
2041       PICFLAG=-fPIC
2042       ;;
2043   esac
2044 elif test x$host_pie = xyes; then
2045   PICFLAG=-fPIE
2046 else
2047   PICFLAG=
2048 fi
2049
2050 AC_SUBST(PICFLAG)
2051
2052 # If we are building PIC/PIE host executables, and we are building dependent
2053 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
2054 # code.
2055 host_libs_picflag=
2056 if test "$host_shared" = "yes" -o "$host_pie" = "yes"; then
2057 host_libs_picflag='--with-pic'
2058 fi
2059 AC_SUBST(host_libs_picflag)
2060
2061 # By default, C and C++ are the only stage 1 languages.
2062 stage1_languages=,c,
2063
2064 # Target libraries that we bootstrap.
2065 bootstrap_target_libs=,target-libgcc,
2066
2067 # Figure out what language subdirectories are present.
2068 # Look if the user specified --enable-languages="..."; if not, use
2069 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2070 # go away some day.
2071 # NB:  embedded tabs in this IF block -- do not untabify
2072 if test -d ${srcdir}/gcc; then
2073   if test x"${enable_languages+set}" != xset; then
2074     if test x"${LANGUAGES+set}" = xset; then
2075       enable_languages="${LANGUAGES}"
2076         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
2077     else
2078       enable_languages=default
2079     fi
2080   else
2081     if test x"${enable_languages}" = x ||
2082        test x"${enable_languages}" = xyes;
2083        then
2084       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2085       exit 1
2086     fi
2087   fi
2088   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2089
2090   # 'f95' is the old name for the 'fortran' language. We issue a warning
2091   # and make the substitution.
2092   case ,${enable_languages}, in
2093     *,f95,*)
2094       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2095       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2096       ;;
2097   esac
2098
2099   # If bootstrapping, C++ must be enabled.
2100   case ",$enable_languages,:$enable_bootstrap" in
2101     *,c++,*:*) ;;
2102     *:yes)
2103       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2104         enable_languages="${enable_languages},c++"
2105       else
2106         AC_MSG_ERROR([bootstrapping requires c++ sources])
2107       fi
2108       ;;
2109   esac
2110
2111   # First scan to see if an enabled language requires some other language.
2112   # We assume that a given config-lang.in will list all the language
2113   # front ends it requires, even if some are required indirectly.
2114   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2115     case ${lang_frag} in
2116       ..) ;;
2117       # The odd quoting in the next line works around
2118       # an apparent bug in bash 1.12 on linux.
2119       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2120       *)
2121         # From the config-lang.in, get $language, $lang_requires, and
2122         # $lang_requires_boot_languages.
2123         language=
2124         lang_requires=
2125         lang_requires_boot_languages=
2126         # set srcdir during sourcing lang_frag to the gcc dir.
2127         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2128         # polutes this shell
2129         saved_srcdir=${srcdir}
2130         srcdir=${srcdir}/gcc . ${lang_frag}
2131         srcdir=${saved_srcdir}
2132         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2133           case ,${enable_languages}, in
2134             *,$other,*) ;;
2135             *,default,*) ;;
2136             *,all,*) ;;
2137             *,$language,*)
2138               echo " \`$other' language required by \`$language'; enabling" 1>&2
2139               enable_languages="${enable_languages},${other}"
2140               ;;
2141           esac
2142         done
2143         for other in ${lang_requires_boot_languages} ; do
2144           if test "$other" != "c"; then
2145             case ,${enable_stage1_languages}, in
2146               *,$other,*) ;;
2147               *,default,*) ;;
2148               *,all,*) ;;
2149               *)
2150                 case ,${enable_languages}, in
2151                   *,$language,*)
2152                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2153                     enable_stage1_languages="$enable_stage1_languages,${other}"
2154                     ;;
2155                 esac
2156                 ;;
2157             esac
2158           fi
2159         done
2160         ;;
2161     esac
2162   done
2163
2164   new_enable_languages=,c,
2165
2166   # If LTO is enabled, add the LTO front end.
2167   if test "$enable_lto" = "yes" ; then
2168     case ,${enable_languages}, in
2169       *,lto,*) ;;
2170       *) enable_languages="${enable_languages},lto" ;;
2171     esac
2172     if test "${build_lto_plugin}" = "yes" ; then
2173       configdirs="$configdirs lto-plugin"
2174     fi
2175   fi
2176
2177   # If we're building an offloading compiler, add the LTO front end.
2178   if test x"$enable_as_accelerator_for" != x ; then
2179     case ,${enable_languages}, in
2180       *,lto,*) ;;
2181       *) enable_languages="${enable_languages},lto" ;;
2182     esac
2183   fi
2184
2185   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2186   potential_languages=,c,
2187
2188   enabled_target_libs=
2189   disabled_target_libs=
2190
2191   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2192     case ${lang_frag} in
2193       ..) ;;
2194       # The odd quoting in the next line works around
2195       # an apparent bug in bash 1.12 on linux.
2196       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2197       *)
2198         # From the config-lang.in, get $language, $target_libs,
2199         # $lang_dirs, $boot_language, and $build_by_default
2200         language=
2201         target_libs=
2202         lang_dirs=
2203         subdir_requires=
2204         boot_language=no
2205         build_by_default=yes
2206         # set srcdir during sourcing.  See above about save & restore
2207         saved_srcdir=${srcdir}
2208         srcdir=${srcdir}/gcc . ${lang_frag}
2209         srcdir=${saved_srcdir}
2210         if test x${language} = x; then
2211           echo "${lang_frag} doesn't set \$language." 1>&2
2212           exit 1
2213         fi
2214
2215         if test "$language" = "c++"; then
2216           boot_language=yes
2217         fi
2218
2219         add_this_lang=no
2220         # C is always enabled, so no need to add it again
2221         if test "$language" != "c"; then
2222           case ,${enable_languages}, in
2223             *,${language},*)
2224               # Language was explicitly selected; include it
2225               add_this_lang=yes
2226               ;;
2227             *,all,*)
2228               # All languages are enabled
2229               add_this_lang=all
2230               ;;
2231             *,default,*)
2232               # 'default' was selected, select it if it is a default language
2233               add_this_lang=${build_by_default}
2234               ;;
2235           esac
2236         fi
2237
2238         # Disable languages that need other directories if these aren't available.
2239         for i in $subdir_requires; do
2240           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2241           case ${add_this_lang} in
2242             yes)
2243               # Specifically requested language; tell them.
2244               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2245               ;;
2246             all)
2247               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2248               add_this_lang=unsupported
2249               ;;
2250             *)
2251               # Silently disable.
2252               add_this_lang=unsupported
2253               ;;
2254           esac
2255         done
2256
2257         # Disable Ada if no preexisting GNAT is available.
2258         case ${add_this_lang}:${language}:${have_gnat} in
2259           yes:ada:no)
2260             # Specifically requested language; tell them.
2261             AC_MSG_ERROR([GNAT is required to build $language])
2262             ;;
2263           all:ada:no)
2264             AC_MSG_WARN([GNAT is required to build $language])
2265             add_this_lang=unsupported
2266             ;;
2267           *:ada:no)
2268             # Silently disable.
2269             add_this_lang=unsupported
2270             ;;
2271         esac
2272
2273         # Disable D if no preexisting GDC is available.
2274         case ${add_this_lang}:${language}:${have_gdc} in
2275           yes:d:no)
2276             # Specifically requested language; tell them.
2277             AC_MSG_ERROR([GDC is required to build $language])
2278            ;;
2279           all:d:no)
2280             AC_MSG_WARN([GDC is required to build $language])
2281             add_this_lang=unsupported
2282             ;;
2283           *:d:no)
2284             # Silently disable.
2285             add_this_lang=unsupported
2286             ;;
2287         esac
2288
2289         # Disable jit if -enable-host-shared not specified
2290         # but not if building for Mingw. All code in Windows
2291         # is position independent code (PIC).
2292         case $target in
2293           *mingw*) ;;
2294           *)
2295           case ${add_this_lang}:${language}:${host_shared} in
2296             yes:jit:no)
2297                    # PR jit/64780: explicitly specify --enable-host-shared
2298             AC_MSG_ERROR([
2299 Enabling language "jit" requires --enable-host-shared.
2300
2301 --enable-host-shared typically slows the rest of the compiler down by
2302 a few %, so you must explicitly enable it.
2303
2304 If you want to build both the jit and the regular compiler, it is often
2305 best to do this via two separate configure/builds, in separate
2306 directories, to avoid imposing the performance cost of
2307 --enable-host-shared on the regular compiler.])
2308                     ;;
2309             all:jit:no)
2310               AC_MSG_WARN([--enable-host-shared required to build $language])
2311               add_this_lang=unsupported
2312               ;;
2313             *:jit:no)
2314               # Silently disable.
2315               add_this_lang=unsupported
2316               ;;
2317                 esac
2318           ;;
2319         esac
2320
2321         # Disable a language that is unsupported by the target.
2322         case "${add_this_lang}: $unsupported_languages " in
2323           no:*) ;;
2324           unsupported:*) ;;
2325           *:*" $language "*)
2326             AC_MSG_WARN([${language} not supported for this target])
2327             add_this_lang=unsupported
2328             ;;
2329         esac
2330
2331         case $add_this_lang in
2332           unsupported)
2333             # Remove language-dependent dirs.
2334             disabled_target_libs="$disabled_target_libs $target_libs"
2335             noconfigdirs="$noconfigdirs $lang_dirs"
2336             ;;
2337           no)
2338             # Remove language-dependent dirs; still show language as supported.
2339             disabled_target_libs="$disabled_target_libs $target_libs"
2340             noconfigdirs="$noconfigdirs $lang_dirs"
2341             potential_languages="${potential_languages}${language},"
2342             ;;
2343           all|yes)
2344             new_enable_languages="${new_enable_languages}${language},"
2345             potential_languages="${potential_languages}${language},"
2346             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2347             enabled_target_libs="$enabled_target_libs $target_libs"
2348             case "${boot_language}:,$enable_stage1_languages," in
2349               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2350                 # Add to (comma-separated) list of stage 1 languages.
2351                 case ",$stage1_languages," in
2352                   *,$language,* | ,yes, | ,all,) ;;
2353                   *) stage1_languages="${stage1_languages}${language}," ;;
2354                 esac
2355                 # We need to bootstrap any supporting libraries.
2356                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2357                 ;;
2358             esac
2359             ;;
2360         esac
2361         ;;
2362     esac
2363   done
2364
2365   # Add target libraries which are only needed for disabled languages
2366   # to noconfigdirs.
2367   if test -n "$disabled_target_libs"; then
2368     for dir in $disabled_target_libs; do
2369       case " $enabled_target_libs " in
2370       *" ${dir} "*) ;;
2371       *) noconfigdirs="$noconfigdirs $dir" ;;
2372       esac
2373     done
2374   fi
2375
2376   AC_ARG_ENABLE(stage1-languages,
2377   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2378                   [choose additional languages to build during
2379                   stage1.  Mostly useful for compiler development])],
2380   [case ,${enable_stage1_languages}, in
2381     ,no,|,,)
2382       # Set it to something that will have no effect in the loop below
2383       enable_stage1_languages=c ;;
2384     ,yes,)
2385       enable_stage1_languages=`echo $new_enable_languages | \
2386         sed -e "s/^,//" -e "s/,$//" ` ;;
2387     *,all,*)
2388       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2389         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2390   esac
2391
2392   # Add "good" languages from enable_stage1_languages to stage1_languages,
2393   # while "bad" languages go in missing_languages.  Leave no duplicates.
2394   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2395     case $potential_languages in
2396       *,$i,*)
2397         case $stage1_languages in
2398           *,$i,*) ;;
2399           *) stage1_languages="$stage1_languages$i," ;;
2400         esac ;;
2401       *)
2402         case $missing_languages in
2403           *,$i,*) ;;
2404           *) missing_languages="$missing_languages$i," ;;
2405         esac ;;
2406      esac
2407   done])
2408
2409   # Remove leading/trailing commas that were added for simplicity
2410   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2411   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2412   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2413   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2414
2415   if test "x$missing_languages" != x; then
2416     AC_MSG_ERROR([
2417 The following requested languages could not be built: ${missing_languages}
2418 Supported languages are: ${potential_languages}])
2419   fi
2420   if test "x$new_enable_languages" != "x$enable_languages"; then
2421     echo The following languages will be built: ${new_enable_languages}
2422     enable_languages="$new_enable_languages"
2423   fi
2424
2425   AC_SUBST(stage1_languages)
2426   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2427 fi
2428
2429 # Handle --disable-<component> generically.
2430 for dir in $configdirs $build_configdirs $target_configdirs ; do
2431   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2432   varname=`echo $dirname | sed -e s/+/_/g`
2433   if eval test x\${enable_${varname}} "=" xno ; then
2434     noconfigdirs="$noconfigdirs $dir"
2435   fi
2436 done
2437
2438 # Check for Boehm's garbage collector
2439 AC_ARG_ENABLE(objc-gc,
2440 [AS_HELP_STRING([--enable-objc-gc],
2441                 [enable use of Boehm's garbage collector with the
2442                  GNU Objective-C runtime])])
2443 AC_ARG_WITH([target-bdw-gc],
2444 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2445                 [specify prefix directory for installed bdw-gc package.
2446                  Equivalent to --with-target-bdw-gc-include=PATH/include
2447                  plus --with-target-bdw-gc-lib=PATH/lib])])
2448 AC_ARG_WITH([target-bdw-gc-include],
2449 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2450                 [specify directories for installed bdw-gc include files])])
2451 AC_ARG_WITH([target-bdw-gc-lib],
2452 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2453                 [specify directories for installed bdw-gc library])])
2454
2455 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2456   AC_MSG_CHECKING([for bdw garbage collector])
2457   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2458     dnl no bdw-gw options, assume default locations
2459     AC_MSG_RESULT([using bdw-gc in default locations])
2460   else
2461     dnl bdw-gw options, first error checking, complete checking in libobjc
2462     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2463       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2464     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2465       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2466     else
2467       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2468     fi
2469   fi
2470 esac
2471
2472 # Disable libitm, libsanitizer, libvtv if we're not building C++
2473 case ,${enable_languages}, in
2474   *,c++,*)
2475     # Disable libitm, libsanitizer if we're not building libstdc++
2476     case "${noconfigdirs}" in
2477       *target-libstdc++-v3*)
2478         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2479         ;;
2480       *) ;;
2481     esac
2482     ;;
2483   *)
2484     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2485     ;;
2486 esac
2487
2488 case ,${enable_languages}, in
2489   *,rust,*)
2490     case " ${noconfigdirs} " in
2491       *\ target-libstdc++-v3\ *)
2492         # Disable target libgrust if we're not building target libstdc++.
2493         noconfigdirs="$noconfigdirs target-libgrust"
2494         ;;
2495     esac
2496     ;;
2497 esac
2498
2499 # If gcc/ is not in the source tree then we'll not be building a
2500 # target compiler, assume in that case we don't want to build any
2501 # target libraries or tools.
2502 #
2503 # This was added primarily for the benefit for binutils-gdb who reuse
2504 # this configure script, but don't always have target tools available.
2505 if test ! -d ${srcdir}/gcc; then
2506    skipdirs="${skipdirs} ${target_configdirs}"
2507 fi
2508
2509 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2510 # $build_configdirs and $target_configdirs.
2511 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2512
2513 notsupp=""
2514 for dir in . $skipdirs $noconfigdirs ; do
2515   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2516   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2517     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2518     if test -r $srcdir/$dirname/configure ; then
2519       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2520         true
2521       else
2522         notsupp="$notsupp $dir"
2523       fi
2524     fi
2525   fi
2526   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2527     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2528     if test -r $srcdir/$dirname/configure ; then
2529       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2530         true
2531       else
2532         notsupp="$notsupp $dir"
2533       fi
2534     fi
2535   fi
2536   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2537     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2538     if test -r $srcdir/$dirname/configure ; then
2539       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2540         true
2541       else
2542         notsupp="$notsupp $dir"
2543       fi
2544     fi
2545   fi
2546 done
2547
2548 # Quietly strip out all directories which aren't configurable in this tree.
2549 # This relies on all configurable subdirectories being autoconfiscated, which
2550 # is now the case.
2551 build_configdirs_all="$build_configdirs"
2552 build_configdirs=
2553 for i in ${build_configdirs_all} ; do
2554   j=`echo $i | sed -e s/build-//g`
2555   if test -f ${srcdir}/$j/configure ; then
2556     build_configdirs="${build_configdirs} $i"
2557   fi
2558 done
2559
2560 configdirs_all="$configdirs"
2561 configdirs=
2562 for i in ${configdirs_all} ; do
2563   if test -f ${srcdir}/$i/configure ; then
2564     configdirs="${configdirs} $i"
2565   fi
2566 done
2567
2568 target_configdirs_all="$target_configdirs"
2569 target_configdirs=
2570 for i in ${target_configdirs_all} ; do
2571   j=`echo $i | sed -e s/target-//g`
2572   if test -f ${srcdir}/$j/configure ; then
2573     target_configdirs="${target_configdirs} $i"
2574   fi
2575 done
2576
2577 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2578 # so we have to add it after the preceding checks.
2579 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2580 then
2581   case " $configdirs " in
2582     *" libiberty "*)
2583       # If we can build libiberty, we can also build libiberty-linker-plugin.
2584       configdirs="$configdirs libiberty-linker-plugin"
2585       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2586         --with-libiberty=../libiberty-linker-plugin";;
2587     *)
2588       AC_MSG_ERROR([libiberty missing]);;
2589   esac
2590 fi
2591
2592 # Sometimes we have special requirements for the host libiberty.
2593 extra_host_libiberty_configure_flags=
2594 case " $configdirs " in
2595   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2596     # When these are to be built as shared libraries, the same applies to
2597     # libiberty.
2598     extra_host_libiberty_configure_flags=--enable-shared
2599     ;;
2600 esac
2601 AC_SUBST(extra_host_libiberty_configure_flags)
2602
2603 # Sometimes we have special requirements for the host zlib.
2604 extra_host_zlib_configure_flags=
2605 case " $configdirs " in
2606   *" bfd "*)
2607     # When bfd is to be built as a shared library, the same applies to
2608     # zlib.
2609     if test "$enable_shared" = "yes"; then
2610       extra_host_zlib_configure_flags=--enable-host-shared
2611     fi
2612     ;;
2613 esac
2614 AC_SUBST(extra_host_zlib_configure_flags)
2615
2616 # Produce a warning message for the subdirs we can't configure.
2617 # This isn't especially interesting in the Cygnus tree, but in the individual
2618 # FSF releases, it's important to let people know when their machine isn't
2619 # supported by the one or two programs in a package.
2620
2621 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2622   # If $appdirs is non-empty, at least one of those directories must still
2623   # be configured, or we error out.  (E.g., if the gas release supports a
2624   # specified target in some subdirs but not the gas subdir, we shouldn't
2625   # pretend that all is well.)
2626   if test -n "$appdirs" ; then
2627     for dir in $appdirs ; do
2628       if test -r $dir/Makefile.in ; then
2629         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2630           appdirs=""
2631           break
2632         fi
2633         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2634           appdirs=""
2635           break
2636         fi
2637       fi
2638     done
2639     if test -n "$appdirs" ; then
2640       echo "*** This configuration is not supported by this package." 1>&2
2641       exit 1
2642     fi
2643   fi
2644   # Okay, some application will build, or we don't care to check.  Still
2645   # notify of subdirs not getting built.
2646   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2647   echo "    ${notsupp}" 1>&2
2648   echo "    (Any other directories should still work fine.)" 1>&2
2649 fi
2650
2651 case "$host" in
2652   *msdosdjgpp*)
2653     enable_gdbtk=no ;;
2654 esac
2655
2656 # To find our prefix, in gcc_cv_tool_prefix.
2657 ACX_TOOL_DIRS
2658
2659 copy_dirs=
2660
2661 AC_ARG_WITH([build-sysroot],
2662   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2663                   [use sysroot as the system root during the build])],
2664   [if test x"$withval" != x ; then
2665      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2666    fi],
2667   [SYSROOT_CFLAGS_FOR_TARGET=])
2668 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2669
2670 AC_ARG_WITH([debug-prefix-map],
2671   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2672                   [map A to B, C to D ... in debug information])],
2673   [if test x"$withval" != x; then
2674      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2675      for debug_map in $withval; do
2676        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2677      done
2678    fi],
2679   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2680 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2681
2682 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2683 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2684 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2685 # We want to ensure that TARGET libraries (which we know are built with
2686 # gcc) are built with "-O2 -g", so include those options when setting
2687 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2688 if test "x$CFLAGS_FOR_TARGET" = x; then
2689   if test "x${is_cross_compiler}" = xyes; then
2690     CFLAGS_FOR_TARGET="-g -O2"
2691   else
2692     CFLAGS_FOR_TARGET=$CFLAGS
2693     case " $CFLAGS " in
2694       *" -O2 "*) ;;
2695       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2696     esac
2697     case " $CFLAGS " in
2698       *" -g "* | *" -g3 "*) ;;
2699       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2700     esac
2701   fi
2702 fi
2703 AC_SUBST(CFLAGS_FOR_TARGET)
2704
2705 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2706   if test "x${is_cross_compiler}" = xyes; then
2707     CXXFLAGS_FOR_TARGET="-g -O2"
2708   else
2709     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2710     case " $CXXFLAGS " in
2711       *" -O2 "*) ;;
2712       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2713     esac
2714     case " $CXXFLAGS " in
2715       *" -g "* | *" -g3 "*) ;;
2716       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2717     esac
2718   fi
2719 fi
2720 AC_SUBST(CXXFLAGS_FOR_TARGET)
2721
2722 AC_SUBST(LDFLAGS_FOR_TARGET)
2723
2724 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2725 # the named directory are copied to $(tooldir)/sys-include.
2726 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2727   if test x${is_cross_compiler} = xno ; then
2728     echo 1>&2 '***' --with-headers is only supported when cross compiling
2729     exit 1
2730   fi
2731   if test x"${with_headers}" != xyes ; then
2732     x=${gcc_cv_tool_prefix}
2733     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2734   fi
2735 fi
2736
2737 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2738 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2739 # are permitted.
2740 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2741   if test x${is_cross_compiler} = xno ; then
2742     echo 1>&2 '***' --with-libs is only supported when cross compiling
2743     exit 1
2744   fi
2745   if test x"${with_libs}" != xyes ; then
2746     # Copy the libraries in reverse order, so that files in the first named
2747     # library override files in subsequent libraries.
2748     x=${gcc_cv_tool_prefix}
2749     for l in ${with_libs}; do
2750       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2751     done
2752   fi
2753 fi
2754
2755 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2756 #
2757 # This is done by determining whether or not the appropriate directory
2758 # is available, and by checking whether or not specific configurations
2759 # have requested that this magic not happen.
2760 #
2761 # The command line options always override the explicit settings in
2762 # configure.ac, and the settings in configure.ac override this magic.
2763 #
2764 # If the default for a toolchain is to use GNU as and ld, and you don't
2765 # want to do that, then you should use the --without-gnu-as and
2766 # --without-gnu-ld options for the configure script.  Similarly, if
2767 # the default is to use the included zlib and you don't want to do that,
2768 # you should use the --with-system-zlib option for the configure script.
2769
2770 if test x${use_gnu_as} = x &&
2771    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2772   with_gnu_as=yes
2773   extra_host_args="$extra_host_args --with-gnu-as"
2774 fi
2775
2776 if test x${use_gnu_ld} = x &&
2777    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2778   with_gnu_ld=yes
2779   extra_host_args="$extra_host_args --with-gnu-ld"
2780 fi
2781
2782 if test x${use_included_zlib} = x &&
2783    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2784   :
2785 else
2786   with_system_zlib=yes
2787   extra_host_args="$extra_host_args --with-system-zlib"
2788 fi
2789
2790 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2791 # can detect this case.
2792
2793 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2794   with_newlib=yes
2795   extra_host_args="$extra_host_args --with-newlib"
2796 fi
2797
2798 # Handle ${copy_dirs}
2799 set fnord ${copy_dirs}
2800 shift
2801 while test $# != 0 ; do
2802   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2803     :
2804   else
2805     echo Copying $1 to $2
2806
2807     # Use the install script to create the directory and all required
2808     # parent directories.
2809     if test -d $2 ; then
2810       :
2811     else
2812       echo >config.temp
2813       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2814     fi
2815
2816     # Copy the directory, assuming we have tar.
2817     # FIXME: Should we use B in the second tar?  Not all systems support it.
2818     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2819
2820     # It is the responsibility of the user to correctly adjust all
2821     # symlinks.  If somebody can figure out how to handle them correctly
2822     # here, feel free to add the code.
2823
2824     echo $1 > $2/COPIED
2825   fi
2826   shift; shift
2827 done
2828
2829 # Determine a target-dependent exec_prefix that the installed
2830 # gcc will search in.  Keep this list sorted by triplet, with
2831 # the *-*-osname triplets last.
2832 md_exec_prefix=
2833 case "${target}" in
2834   i[[34567]]86-pc-msdosdjgpp*)
2835     md_exec_prefix=/dev/env/DJDIR/bin
2836     ;;
2837   *-*-hpux* | \
2838   *-*-nto-qnx* | \
2839   *-*-solaris2*)
2840     md_exec_prefix=/usr/ccs/bin
2841     ;;
2842 esac
2843
2844 extra_arflags_for_target=
2845 extra_nmflags_for_target=
2846 extra_ranlibflags_for_target=
2847 target_makefile_frag=/dev/null
2848 case "${target}" in
2849   spu-*-*)
2850     target_makefile_frag="config/mt-spu"
2851     ;;
2852   loongarch*-*linux* | loongarch*-*gnu*)
2853     target_makefile_frag="config/mt-loongarch-gnu"
2854     ;;
2855   loongarch*-*elf*)
2856     target_makefile_frag="config/mt-loongarch-elf"
2857     ;;
2858   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2859     target_makefile_frag="config/mt-sde"
2860     ;;
2861   mipsisa*-*-elfoabi*)
2862     target_makefile_frag="config/mt-mips-elfoabi"
2863     ;;
2864   mips*-*-*linux* | mips*-*-gnu*)
2865     target_makefile_frag="config/mt-mips-gnu"
2866     ;;
2867   nios2-*-elf*)
2868     target_makefile_frag="config/mt-nios2-elf"
2869     ;;
2870   *-*-linux-android*)
2871     target_makefile_frag="config/mt-android"
2872     ;;
2873   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2874     target_makefile_frag="config/mt-gnu"
2875     ;;
2876   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2877     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2878     # commands to handle both 32-bit and 64-bit objects.  These flags are
2879     # harmless if we're using GNU nm or ar.
2880     extra_arflags_for_target=" -X32_64"
2881     extra_nmflags_for_target=" -B -X32_64"
2882     ;;
2883 esac
2884
2885 alphaieee_frag=/dev/null
2886 case $target in
2887   alpha*-*-*)
2888     # This just makes sure to use the -mieee option to build target libs.
2889     # This should probably be set individually by each library.
2890     alphaieee_frag="config/mt-alphaieee"
2891     ;;
2892 esac
2893
2894 # If --enable-target-optspace always use -Os instead of -O2 to build
2895 # the target libraries, similarly if it is not specified, use -Os
2896 # on selected platforms.
2897 ospace_frag=/dev/null
2898 case "${enable_target_optspace}:${target}" in
2899   yes:*)
2900     ospace_frag="config/mt-ospace"
2901     ;;
2902   :d30v-*)
2903     ospace_frag="config/mt-d30v"
2904     ;;
2905   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2906     ospace_frag="config/mt-ospace"
2907     ;;
2908   no:* | :*)
2909     ;;
2910   *)
2911     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2912     ;;
2913 esac
2914
2915 # Some systems (e.g., one of the i386-aix systems the gas testers are
2916 # using) don't handle "\$" correctly, so don't use it here.
2917 tooldir='${exec_prefix}'/${target_noncanonical}
2918 build_tooldir=${tooldir}
2919
2920 # Create a .gdbinit file which runs the one in srcdir
2921 # and tells GDB to look there for source files.
2922
2923 if test -r ${srcdir}/.gdbinit ; then
2924   case ${srcdir} in
2925     .) ;;
2926     *) cat > ./.gdbinit <<EOF
2927 # ${NO_EDIT}
2928 dir ${srcdir}
2929 dir .
2930 source ${srcdir}/.gdbinit
2931 EOF
2932     ;;
2933   esac
2934 fi
2935
2936 # Make sure that the compiler is able to generate an executable.  If it
2937 # can't, we are probably in trouble.  We don't care whether we can run the
2938 # executable--we might be using a cross compiler--we only care whether it
2939 # can be created.  At this point the main configure script has set CC.
2940 we_are_ok=no
2941 echo "int main () { return 0; }" > conftest.c
2942 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2943 if test $? = 0 ; then
2944   if test -s conftest || test -s conftest.exe ; then
2945     we_are_ok=yes
2946   fi
2947 fi
2948 case $we_are_ok in
2949   no)
2950     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2951     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2952     rm -f conftest*
2953     exit 1
2954     ;;
2955 esac
2956 rm -f conftest*
2957
2958 # Decide which environment variable is used to find dynamic libraries.
2959 case "${host}" in
2960   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2961   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2962   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2963   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2964 esac
2965
2966 # On systems where the dynamic library environment variable is PATH,
2967 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2968 # built executables to PATH.
2969 if test "$RPATH_ENVVAR" = PATH; then
2970   GCC_SHLIB_SUBDIR=/shlib
2971 else
2972   GCC_SHLIB_SUBDIR=
2973 fi
2974
2975 # Adjust the toplevel makefile according to whether bootstrap was selected.
2976 case $enable_bootstrap in
2977   yes)
2978     bootstrap_suffix=bootstrap
2979     BUILD_CONFIG=bootstrap-debug
2980     ;;
2981   no)
2982     bootstrap_suffix=no-bootstrap
2983     BUILD_CONFIG=
2984     ;;
2985 esac
2986
2987 AC_MSG_CHECKING(for default BUILD_CONFIG)
2988
2989 AC_ARG_WITH([build-config],
2990   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2991                   [use config/NAME.mk build configuration])],
2992   [case $with_build_config in
2993    yes) with_build_config= ;;
2994    no) with_build_config= BUILD_CONFIG= ;;
2995    esac])
2996
2997 if test "x${with_build_config}" != x; then
2998   BUILD_CONFIG=$with_build_config
2999 else
3000   case $BUILD_CONFIG in
3001   bootstrap-debug)
3002     if echo "int f (void) { return 0; }" > conftest.c &&
3003        ${CC} -c conftest.c &&
3004        mv conftest.o conftest.o.g0 &&
3005        ${CC} -c -g conftest.c &&
3006        mv conftest.o conftest.o.g &&
3007        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
3008       :
3009     else
3010       BUILD_CONFIG=
3011     fi
3012     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
3013     ;;
3014   esac
3015 fi
3016 AC_MSG_RESULT($BUILD_CONFIG)
3017 AC_SUBST(BUILD_CONFIG)
3018
3019 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
3020 AC_MSG_CHECKING([for --enable-vtable-verify])
3021 AC_ARG_ENABLE(vtable-verify,
3022 [AS_HELP_STRING([--enable-vtable-verify],
3023                 [Enable vtable verification feature])],
3024 [case "$enableval" in
3025  yes) enable_vtable_verify=yes ;;
3026  no)  enable_vtable_verify=no ;;
3027  *)   enable_vtable_verify=no;;
3028  esac],
3029 [enable_vtable_verify=no])
3030 AC_MSG_RESULT($enable_vtable_verify)
3031
3032 # Record target_configdirs and the configure arguments for target and
3033 # build configuration in Makefile.
3034 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
3035 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
3036 bootstrap_fixincludes=no
3037
3038 # If we are building libgomp, bootstrap it.
3039 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
3040   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
3041 fi
3042
3043 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
3044 # or bootstrap-ubsan, bootstrap it.
3045 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
3046   case "$BUILD_CONFIG" in
3047     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
3048       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
3049       bootstrap_fixincludes=yes
3050       ;;
3051   esac
3052 fi
3053
3054 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
3055 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
3056    test "$enable_vtable_verify" != no; then
3057   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
3058 fi
3059
3060 # If we are building libatomic and the list of enabled languages includes the
3061 # D frontend, bootstrap it.
3062 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
3063   case ,${enable_languages}, in
3064     *,d,*)
3065       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
3066       ;;
3067   esac
3068 fi
3069
3070 # Determine whether gdb needs tk/tcl or not.
3071 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
3072 # and in that case we want gdb to be built without tk.  Ugh!
3073 # In fact I believe gdb is the *only* package directly dependent on tk,
3074 # so we should be able to put the 'maybe's in unconditionally and
3075 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
3076 # 100% sure that that's safe though.
3077
3078 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
3079 case "$enable_gdbtk" in
3080   no)
3081     GDB_TK="" ;;
3082   yes)
3083     GDB_TK="${gdb_tk}" ;;
3084   *)
3085     # Only add the dependency on gdbtk when GDBtk is part of the gdb
3086     # distro.  Eventually someone will fix this and move Insight, nee
3087     # gdbtk to a separate directory.
3088     if test -d ${srcdir}/gdb/gdbtk ; then
3089       GDB_TK="${gdb_tk}"
3090     else
3091       GDB_TK=""
3092     fi
3093     ;;
3094 esac
3095 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
3096 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
3097
3098 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
3099 # else does, only include them if one of these is built.  The Makefile
3100 # provides the ordering, so it's enough here to add to the list.
3101 case " ${configdirs} " in
3102   *\ gdb\ *)
3103     configdirs="${configdirs} gnulib gdbsupport"
3104     ;;
3105   *\ gdbserver\ *)
3106     configdirs="${configdirs} gnulib gdbsupport"
3107     ;;
3108   *\ sim\ *)
3109     configdirs="${configdirs} gnulib"
3110     ;;
3111 esac
3112
3113 # Strip out unwanted targets.
3114
3115 # While at that, we remove Makefiles if we were started for recursive
3116 # configuration, so that the top-level Makefile reconfigures them,
3117 # like we used to do when configure itself was recursive.
3118
3119 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3120 # but now we're fixing up the Makefile ourselves with the additional
3121 # commands passed to AC_CONFIG_FILES.  Use separate variables
3122 # extrasub-{build,host,target} not because there is any reason to split
3123 # the substitutions up that way, but only to remain below the limit of
3124 # 99 commands in a script, for HP-UX sed.
3125
3126 # Do not nest @if/@endif or @unless/@endunless pairs, because
3127 # configure will not warn you at all.
3128
3129 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3130   yes:yes:*\ gold\ *:*,c++,*) ;;
3131   yes:yes:*\ gold\ *:*)
3132     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3133     ;;
3134 esac
3135
3136 extrasub_build=
3137 for module in ${build_configdirs} ; do
3138   if test -z "${no_recursion}" \
3139      && test -f ${build_subdir}/${module}/Makefile; then
3140     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3141     rm -f ${build_subdir}/${module}/Makefile
3142   fi
3143   extrasub_build="$extrasub_build
3144 /^@if build-$module\$/d
3145 /^@endif build-$module\$/d
3146 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3147 /^@if build-$module-$bootstrap_suffix\$/d
3148 /^@endif build-$module-$bootstrap_suffix\$/d
3149 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3150 done
3151 extrasub_host=
3152 for module in ${configdirs} ; do
3153   if test -z "${no_recursion}"; then
3154     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3155       if test -f ${file}; then
3156         echo 1>&2 "*** removing ${file} to force reconfigure"
3157         rm -f ${file}
3158       fi
3159     done
3160   fi
3161   case ${module},${bootstrap_fixincludes} in
3162     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3163     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3164   esac
3165   extrasub_host="$extrasub_host
3166 /^@if $module\$/d
3167 /^@endif $module\$/d
3168 /^@unless $module\$/,/^@endunless $module\$/d
3169 /^@if $module-$host_bootstrap_suffix\$/d
3170 /^@endif $module-$host_bootstrap_suffix\$/d
3171 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3172 done
3173 extrasub_target=
3174 for module in ${target_configdirs} ; do
3175   if test -z "${no_recursion}" \
3176      && test -f ${target_subdir}/${module}/Makefile; then
3177     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3178     rm -f ${target_subdir}/${module}/Makefile
3179   fi
3180
3181   # We only bootstrap target libraries listed in bootstrap_target_libs.
3182   case $bootstrap_target_libs in
3183     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3184     *) target_bootstrap_suffix=no-bootstrap ;;
3185   esac
3186
3187   extrasub_target="$extrasub_target
3188 /^@if target-$module\$/d
3189 /^@endif target-$module\$/d
3190 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3191 /^@if target-$module-$target_bootstrap_suffix\$/d
3192 /^@endif target-$module-$target_bootstrap_suffix\$/d
3193 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3194 done
3195
3196 # Do the final fixup along with target modules.
3197 extrasub_target="$extrasub_target
3198 /^@if /,/^@endif /d
3199 /^@unless /d
3200 /^@endunless /d"
3201
3202 if test "$enable_pgo_build" != "no"; then
3203   extrasub_build="$extrasub_build
3204 /^@if pgo-build\$/d
3205 /^@endif pgo-build\$/d"
3206 fi
3207
3208 # Create the serialization dependencies.  This uses a temporary file.
3209
3210 AC_ARG_ENABLE([serial-configure],
3211 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3212                 [force sequential configuration of
3213                  sub-packages for the host, target or build
3214                  machine, or all sub-packages])])
3215
3216 case ${enable_serial_configure} in
3217   yes)
3218     enable_serial_build_configure=yes
3219     enable_serial_host_configure=yes
3220     enable_serial_target_configure=yes
3221     ;;
3222 esac
3223
3224 # These force 'configure's to be done one at a time, to avoid problems
3225 # with contention over a shared config.cache.
3226 rm -f serdep.tmp
3227 if test "x${enable_serial_build_configure}" = xyes || test "x${enable_serial_host_configure}" = xyes || test "x${enable_serial_target_configure}" = xyes; then
3228 echo '# serdep.tmp' > serdep.tmp
3229 fi
3230 olditem=
3231 test "x${enable_serial_build_configure}" = xyes &&
3232 for item in ${build_configdirs} ; do
3233   case ${olditem} in
3234     "") ;;
3235     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3236   esac
3237   olditem=${item}
3238 done
3239 olditem=
3240 test "x${enable_serial_host_configure}" = xyes &&
3241 for item in ${configdirs} ; do
3242   case ${olditem} in
3243     "") ;;
3244     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3245   esac
3246   olditem=${item}
3247 done
3248 olditem=
3249 test "x${enable_serial_target_configure}" = xyes &&
3250 for item in ${target_configdirs} ; do
3251   case ${olditem} in
3252     "") ;;
3253     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3254   esac
3255   olditem=${item}
3256 done
3257 serialization_dependencies=serdep.tmp
3258 AC_SUBST_FILE(serialization_dependencies)
3259
3260 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3261 # target, nonopt, and variable assignments.  These are the ones we
3262 # might not want to pass down to subconfigures.  The exception being
3263 # --cache-file=/dev/null, which is used to turn off the use of cache
3264 # files altogether, and which should be passed on to subconfigures.
3265 # Also strip program-prefix, program-suffix, and program-transform-name,
3266 # so that we can pass down a consistent program-transform-name.
3267 hbaseargs=
3268 bbaseargs=
3269 tbaseargs=
3270 keep_next=no
3271 skip_next=no
3272 eval "set -- $ac_configure_args"
3273 for ac_arg
3274 do
3275   if test X"$skip_next" = X"yes"; then
3276     skip_next=no
3277     continue
3278   fi
3279   if test X"$keep_next" = X"yes"; then
3280     case $ac_arg in
3281       *\'*)
3282         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3283     esac
3284     hbaseargs="$hbaseargs '$ac_arg'"
3285     bbaseargs="$bbaseargs '$ac_arg'"
3286     tbaseargs="$tbaseargs '$ac_arg'"
3287     keep_next=no
3288     continue
3289   fi
3290
3291   # Handle separated arguments.  Based on the logic generated by
3292   # autoconf 2.59.
3293   case $ac_arg in
3294     *=* | --config-cache | -C | -disable-* | --disable-* \
3295       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3296       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3297       | -with-* | --with-* | -without-* | --without-* | --x)
3298       separate_arg=no
3299       ;;
3300     -*)
3301       separate_arg=yes
3302       ;;
3303     *)
3304       separate_arg=no
3305       ;;
3306   esac
3307
3308   skip_targ=no
3309   skip_barg=no
3310   case $ac_arg in
3311 changequote(,)
3312   --with-* | --without-*)
3313     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3314
3315     case $libopt in
3316     *[-_]include)
3317       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3318       ;;
3319     *[-_]lib)
3320       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3321       ;;
3322     *[-_]prefix)
3323       lib=`echo "$libopt" | sed 's,[-_]prefix$,,'`
3324       ;;
3325     *[-_]type)
3326       lib=`echo "$libopt" | sed 's,[-_]type$,,'`
3327       ;;
3328     *)
3329       lib=$libopt
3330       ;;
3331     esac
3332 changequote([,])
3333
3334     case $lib in
3335     mpc | mpfr | gmp | isl)
3336       # If we're processing --with-$lib, --with-$lib-include or
3337       # --with-$lib-lib, for one of the libs above, and target is
3338       # different from host, don't pass the current argument to any
3339       # target library's configure.
3340       if test x$is_cross_compiler = xyes; then
3341         skip_targ=yes
3342       fi
3343       ;;
3344     libintl | libiconv)
3345       # We don't want libintl (and co.) in anything but the host arguments.
3346       skip_targ=yes
3347       skip_barg=yes
3348       ;;
3349     esac
3350     ;;
3351   esac
3352
3353   case "$ac_arg" in
3354     --cache-file=/dev/null | \
3355     -cache-file=/dev/null )
3356       # Handled here to avoid the test to skip args below.
3357       hbaseargs="$hbaseargs '$ac_arg'"
3358       bbaseargs="$bbaseargs '$ac_arg'"
3359       tbaseargs="$tbaseargs '$ac_arg'"
3360       # Assert: $separate_arg should always be no.
3361       keep_next=$separate_arg
3362       ;;
3363     --no*)
3364       continue
3365       ;;
3366     --c* | \
3367     --sr* | \
3368     --ho* | \
3369     --bu* | \
3370     --t* | \
3371     --program-* | \
3372     -cache_file* | \
3373     -srcdir* | \
3374     -host* | \
3375     -build* | \
3376     -target* | \
3377     -program-prefix* | \
3378     -program-suffix* | \
3379     -program-transform-name* )
3380       skip_next=$separate_arg
3381       continue
3382       ;;
3383     -*)
3384       # An option.  Add it.
3385       case $ac_arg in
3386         *\'*)
3387           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3388       esac
3389       hbaseargs="$hbaseargs '$ac_arg'"
3390       if test X"$skip_barg" = Xno; then
3391         bbaseargs="$bbaseargs '$ac_arg'"
3392       fi
3393       if test X"$skip_targ" = Xno; then
3394         tbaseargs="$tbaseargs '$ac_arg'"
3395       fi
3396       keep_next=$separate_arg
3397       ;;
3398     *)
3399       # Either a variable assignment, or a nonopt (triplet).  Don't
3400       # pass it down; let the Makefile handle this.
3401       continue
3402       ;;
3403   esac
3404 done
3405 # Remove the initial space we just introduced and, as these will be
3406 # expanded by make, quote '$'.
3407 hbaseargs=`echo "x$hbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3408 bbaseargs=`echo "x$bbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3409
3410 # Add in --program-transform-name, after --program-prefix and
3411 # --program-suffix have been applied to it.  Autoconf has already
3412 # doubled dollar signs and backslashes in program_transform_name; we want
3413 # the backslashes un-doubled, and then the entire thing wrapped in single
3414 # quotes, because this will be expanded first by make and then by the shell.
3415 # Also, because we want to override the logic in subdir configure scripts to
3416 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3417 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3418 ${program_transform_name}
3419 EOF_SED
3420 gcc_transform_name=`cat conftestsed.out`
3421 rm -f conftestsed.out
3422 hbaseargs="$hbaseargs --program-transform-name='${gcc_transform_name}'"
3423 bbaseargs="$bbaseargs --program-transform-name='${gcc_transform_name}'"
3424 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3425 if test "$silent" = yes; then
3426   bbaseargs="$bbaseargs --silent"
3427   hbaseargs="$hbaseargs --silent"
3428   tbaseargs="$tbaseargs --silent"
3429 fi
3430
3431 bbaseargs="$bbaseargs --disable-option-checking"
3432 hbaseargs="$hbaseargs --disable-option-checking"
3433 tbaseargs="$tbaseargs --disable-option-checking"
3434
3435 if test "$enable_year2038" = no; then
3436   bbaseargs="$bbaseargs --disable-year2038"
3437   hbaseargs="$hbaseargs --disable-year2038"
3438   tbaseargs="$tbaseargs --disable-year2038"
3439 fi
3440
3441 # Record and document user additions to sub configure arguments.
3442 AC_ARG_VAR([build_configargs],
3443            [additional configure arguments for build directories])
3444 AC_ARG_VAR([host_configargs],
3445            [additional configure arguments for host directories])
3446 AC_ARG_VAR([target_configargs],
3447            [additional configure arguments for target directories])
3448
3449 # For the build-side libraries, we just need to pretend we're native,
3450 # and not use the same cache file.  Multilibs are neither needed nor
3451 # desired.  We can't even use the same cache file for all build-side
3452 # libraries, as they're compiled differently; some with C, some with
3453 # C++ or with different feature-enabling options.
3454 build_configargs="$build_configargs --cache-file=./config.cache ${bbaseargs}"
3455
3456 # For host modules, accept cache file option, or specification as blank.
3457 case "${cache_file}" in
3458 "") # empty
3459   cache_file_option="" ;;
3460 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3461   cache_file_option="--cache-file=${cache_file}" ;;
3462 *) # relative path
3463   cache_file_option="--cache-file=../${cache_file}" ;;
3464 esac
3465
3466 # Host dirs don't like to share a cache file either, horribly enough.
3467 # This seems to be due to autoconf 2.5x stupidity.
3468 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${hbaseargs}"
3469
3470 target_configargs="$target_configargs ${tbaseargs}"
3471
3472 # Passing a --with-cross-host argument lets the target libraries know
3473 # whether they are being built with a cross-compiler or being built
3474 # native.  However, it would be better to use other mechanisms to make the
3475 # sorts of decisions they want to make on this basis.  Please consider
3476 # this option to be deprecated.  FIXME.
3477 if test x${is_cross_compiler} = xyes ; then
3478   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3479 fi
3480
3481 # Special user-friendly check for native x86_64-linux build, if
3482 # multilib is not explicitly enabled.
3483 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3484   x86_64-*linux*:yes:$build:$build:)
3485     # Make sure we have a development environment that handles 32-bit
3486     dev64=no
3487     echo "int main () { return 0; }" > conftest.c
3488     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3489     if test $? = 0 ; then
3490       if test -s conftest || test -s conftest.exe ; then
3491         dev64=yes
3492       fi
3493     fi
3494     rm -f conftest*
3495     if test x${dev64} != xyes ; then
3496       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3497     fi
3498     ;;
3499 esac
3500
3501 # Default to --enable-multilib.
3502 if test x${enable_multilib} = x ; then
3503   target_configargs="--enable-multilib ${target_configargs}"
3504 fi
3505
3506 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3507 # changed from the earlier setting of with_newlib.
3508 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3509   target_configargs="--with-newlib ${target_configargs}"
3510 fi
3511
3512 # Different target subdirs use different values of certain variables
3513 # (notably CXX).  Worse, multilibs use *lots* of different values.
3514 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3515 # it doesn't automatically accept command-line overrides of them.
3516 # This means it's not safe for target subdirs to share a cache file,
3517 # which is disgusting, but there you have it.  Hopefully this can be
3518 # fixed in future.  It's still worthwhile to use a cache file for each
3519 # directory.  I think.
3520
3521 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3522 # We need to pass --target, as newer autoconf's requires consistency
3523 # for target_alias and gcc doesn't manage it consistently.
3524 target_configargs="--cache-file=./config.cache ${target_configargs}"
3525
3526 FLAGS_FOR_TARGET=
3527 case " $target_configdirs " in
3528  *" newlib "*)
3529   case " $target_configargs " in
3530   *" --with-newlib "*)
3531    case "$target" in
3532     *-cygwin*)
3533       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3534       ;;
3535    esac
3536
3537    # If we're not building GCC, don't discard standard headers.
3538    if test -d ${srcdir}/gcc; then
3539      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3540
3541      if test "${build}" != "${host}"; then
3542        # On Canadian crosses, CC_FOR_TARGET will have already been set
3543        # by `configure', so we won't have an opportunity to add -Bgcc/
3544        # to it.  This is right: we don't want to search that directory
3545        # for binaries, but we want the header files in there, so add
3546        # them explicitly.
3547        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3548
3549        # Someone might think of using the pre-installed headers on
3550        # Canadian crosses, in case the installed compiler is not fully
3551        # compatible with the compiler being built.  In this case, it
3552        # would be better to flag an error than risking having
3553        # incompatible object files being constructed.  We can't
3554        # guarantee that an error will be flagged, but let's hope the
3555        # compiler will do it, when presented with incompatible header
3556        # files.
3557      fi
3558    fi
3559
3560    case "${target}-${is_cross_compiler}" in
3561    i[[3456789]]86-*-linux*-no)
3562       # Here host == target, so we don't need to build gcc,
3563       # so we don't want to discard standard headers.
3564       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3565       ;;
3566    *)
3567       # If we're building newlib, use its generic headers last, but search
3568       # for any libc-related directories first (so make it the last -B
3569       # switch).
3570       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3571
3572       # If we're building libgloss, find the startup file, simulator library
3573       # and linker script.
3574       case " $target_configdirs " in
3575         *" libgloss "*)
3576         # Look for startup file, simulator library and maybe linker script.
3577         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3578         # Look for libnosys.a in case the target needs it.
3579         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3580         # Most targets have the linker script in the source directory.
3581         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3582         ;;
3583       esac
3584       ;;
3585    esac
3586    ;;
3587   esac
3588   ;;
3589 esac
3590
3591 case "$target" in
3592   x86_64-*mingw* | *-w64-mingw*)
3593   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3594   # however, use a symlink named 'mingw' in ${prefix} .
3595     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3596     ;;
3597   *-mingw*)
3598   # MinGW can't be handled as Cygwin above since it does not use newlib.
3599     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3600     ;;
3601 esac
3602
3603 # Allow the user to override the flags for
3604 # our build compiler if desired.
3605 if test x"${build}" = x"${host}" ; then
3606   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3607   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3608   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3609   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3610 fi
3611
3612 # On Canadian crosses, we'll be searching the right directories for
3613 # the previously-installed cross compiler, so don't bother to add
3614 # flags for directories within the install tree of the compiler
3615 # being built; programs in there won't even run.
3616 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3617   # Search for pre-installed headers if nothing else fits.
3618   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3619 fi
3620
3621 if test "x${use_gnu_ld}" = x &&
3622    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3623   # Arrange for us to find uninstalled linker scripts.
3624   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3625 fi
3626
3627 # Search for other target-specific linker scripts and such.
3628 case "${target}" in
3629   mep*)
3630     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3631     ;;
3632   # The VxWorks support for shared libraries is getting in
3633   # incrementally.  Make sure it doesn't get activated implicitly:
3634   *vxworks*)
3635     if test "${enable_shared-unset}" = unset ; then
3636       enable_shared=no
3637       # So the build of libraries knows ...
3638       target_configargs="${target_configargs} --disable-shared"
3639       # So gcc knows ...
3640       host_configargs="${host_configargs} --disable-shared"
3641     fi
3642     ;;
3643 esac
3644
3645 # Makefile fragments.
3646 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3647 do
3648   eval fragval=\$$frag
3649   if test $fragval != /dev/null; then
3650     eval $frag=${srcdir}/$fragval
3651   fi
3652 done
3653 AC_SUBST_FILE(host_makefile_frag)
3654 AC_SUBST_FILE(target_makefile_frag)
3655 AC_SUBST_FILE(alphaieee_frag)
3656 AC_SUBST_FILE(ospace_frag)
3657
3658 # Miscellanea: directories, flags, etc.
3659 AC_SUBST(RPATH_ENVVAR)
3660 AC_SUBST(GCC_SHLIB_SUBDIR)
3661 AC_SUBST(tooldir)
3662 AC_SUBST(build_tooldir)
3663 AC_SUBST(CONFIGURE_GDB_TK)
3664 AC_SUBST(GDB_TK)
3665 AC_SUBST(INSTALL_GDB_TK)
3666
3667 # Build module lists & subconfigure args.
3668 AC_SUBST(build_configargs)
3669 AC_SUBST(build_configdirs)
3670
3671 # Host module lists & subconfigure args.
3672 AC_SUBST(host_configargs)
3673 AC_SUBST(configdirs)
3674 AC_SUBST(target_configdirs)
3675
3676 # Target module lists & subconfigure args.
3677 AC_SUBST(target_configargs)
3678
3679
3680 # Build tools.
3681 AC_SUBST(AR_FOR_BUILD)
3682 AC_SUBST(AS_FOR_BUILD)
3683 AC_SUBST(CC_FOR_BUILD)
3684 AC_SUBST(CFLAGS_FOR_BUILD)
3685 AC_SUBST(CPP_FOR_BUILD)
3686 AC_SUBST(CPPFLAGS_FOR_BUILD)
3687 AC_SUBST(CXXFLAGS_FOR_BUILD)
3688 AC_SUBST(CXX_FOR_BUILD)
3689 AC_SUBST(DLLTOOL_FOR_BUILD)
3690 AC_SUBST(DSYMUTIL_FOR_BUILD)
3691 AC_SUBST(GFORTRAN_FOR_BUILD)
3692 AC_SUBST(GOC_FOR_BUILD)
3693 AC_SUBST(GDC_FOR_BUILD)
3694 AC_SUBST(LDFLAGS_FOR_BUILD)
3695 AC_SUBST(LD_FOR_BUILD)
3696 AC_SUBST(NM_FOR_BUILD)
3697 AC_SUBST(RANLIB_FOR_BUILD)
3698 AC_SUBST(WINDMC_FOR_BUILD)
3699 AC_SUBST(WINDRES_FOR_BUILD)
3700
3701 # Generate default definitions for YACC, M4, LEX and other programs that run
3702 # on the build machine.  These are used if the Makefile can't locate these
3703 # programs in objdir.
3704 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3705
3706 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3707 case " $build_configdirs " in
3708   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3709 esac
3710
3711 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3712 case " $build_configdirs " in
3713   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3714 esac
3715
3716 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3717 case " $build_configdirs " in
3718   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3719 esac
3720
3721 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3722 case " $build_configdirs " in
3723   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3724   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3725 esac
3726
3727 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3728 case " $build_configdirs " in
3729   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3730 esac
3731
3732 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3733 case " $build_configdirs " in
3734   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3735   *)
3736 changequote(,)
3737     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3738     # higher, else we use the "missing" dummy.
3739     if ${MAKEINFO} --version \
3740        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3741       :
3742     else
3743       MAKEINFO="$MISSING makeinfo"
3744     fi
3745     ;;
3746 changequote([,])
3747 esac
3748
3749 # FIXME: expect and dejagnu may become build tools?
3750
3751 AC_CHECK_PROGS(EXPECT, expect, expect)
3752 case " $configdirs " in
3753   *" expect "*)
3754     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3755     ;;
3756 esac
3757
3758 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3759 case " $configdirs " in
3760   *" dejagnu "*)
3761     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3762     ;;
3763 esac
3764
3765
3766 # Host tools.
3767 NCN_STRICT_CHECK_TOOLS(AR, ar)
3768 NCN_STRICT_CHECK_TOOLS(AS, as)
3769 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3770 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3771 NCN_STRICT_CHECK_TOOLS(LD, ld)
3772 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3773 NCN_STRICT_CHECK_TOOLS(NM, nm)
3774 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3775 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3776 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3777 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3778 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3779 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3780 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3781 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3782 AC_SUBST(CC)
3783 AC_SUBST(CXX)
3784 AC_SUBST(CFLAGS)
3785 AC_SUBST(CXXFLAGS)
3786 AC_SUBST(GDC)
3787 AC_SUBST(GDCFLAGS)
3788 GDCFLAGS=${GDCFLAGS-${CFLAGS}}
3789 AC_SUBST(PKG_CONFIG_PATH)
3790
3791 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3792 AR_PLUGIN_OPTION=
3793 RANLIB_PLUGIN_OPTION=
3794 if test -n "$PLUGIN_OPTION"; then
3795   if $AR --help 2>&1 | grep -q "\--plugin"; then
3796     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3797   fi
3798   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3799     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3800   fi
3801 fi
3802 AC_SUBST(AR_PLUGIN_OPTION)
3803 AC_SUBST(RANLIB_PLUGIN_OPTION)
3804
3805 # Target tools.
3806 AC_ARG_WITH([build-time-tools],
3807   [AS_HELP_STRING([--with-build-time-tools=PATH],
3808                   [use given path to find target tools during the build])],
3809   [case x"$withval" in
3810      x/*) ;;
3811      *)
3812        with_build_time_tools=
3813        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3814        ;;
3815    esac],
3816   [with_build_time_tools=])
3817
3818 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3819 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3820 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3821 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3822 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3823 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3824 NCN_STRICT_CHECK_TARGET_TOOLS(GM2_FOR_TARGET, gm2)
3825
3826 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3827 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3828 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3829 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3830 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3831 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3832 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3833 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3834 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3835 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3836 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3837 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3838 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3839 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3840 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3841
3842 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3843
3844 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3845 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3846 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3847 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3848 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3849                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3850                 c++)
3851 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3852                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3853                 c++)
3854 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3855 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3856 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3857 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3858                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3859 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3860                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3861 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3862                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3863 GCC_TARGET_TOOL(gm2, GM2_FOR_TARGET, GM2,
3864                 [gcc/gm2 -B$$r/$(HOST_SUBDIR)/gcc/], m2)
3865 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3866 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3867 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3868 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3869 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3870 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3871 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3872 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3873 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3874 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3875 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3876
3877 AC_SUBST(FLAGS_FOR_TARGET)
3878 AC_SUBST(RAW_CXX_FOR_TARGET)
3879
3880 # Certain tools may need extra flags.
3881 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3882 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3883 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3884
3885 # When building target libraries, except in a Canadian cross, we use
3886 # the same toolchain as the compiler we just built.
3887 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3888 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3889 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3890 if test $host = $build; then
3891   case " $configdirs " in
3892     *" gcc "*)
3893       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3894       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3895       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3896       ;;
3897   esac
3898 fi
3899
3900 AC_SUBST(COMPILER_AS_FOR_TARGET)
3901 AC_SUBST(COMPILER_LD_FOR_TARGET)
3902 AC_SUBST(COMPILER_NM_FOR_TARGET)
3903
3904 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3905 AC_ARG_ENABLE(maintainer-mode,
3906 [AS_HELP_STRING([--enable-maintainer-mode],
3907                 [enable make rules and dependencies not useful
3908                  (and sometimes confusing) to the casual installer])],
3909       USE_MAINTAINER_MODE=$enableval,
3910       USE_MAINTAINER_MODE=no)
3911 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3912 AC_SUBST(MAINTAINER_MODE_TRUE)
3913 AC_SUBST(MAINTAINER_MODE_FALSE)
3914 if test "$USE_MAINTAINER_MODE" = yes; then
3915   MAINTAINER_MODE_TRUE=
3916   MAINTAINER_MODE_FALSE='#'
3917 else
3918   MAINTAINER_MODE_TRUE='#'
3919   MAINTAINER_MODE_FALSE=
3920 fi
3921 MAINT=$MAINTAINER_MODE_TRUE
3922 AC_SUBST(MAINT)dnl
3923
3924 # ---------------------
3925 # GCC bootstrap support
3926 # ---------------------
3927
3928 # Stage specific cflags for build.
3929 stage1_cflags="-g"
3930 case $build in
3931   vax-*-*)
3932     case ${GCC} in
3933       yes) stage1_cflags="-g -Wa,-J" ;;
3934       *) stage1_cflags="-g -J" ;;
3935     esac ;;
3936 esac
3937
3938 AC_SUBST(stage1_cflags)
3939
3940 # Enable --enable-checking in stage1 of the compiler.
3941 AC_ARG_ENABLE(stage1-checking,
3942 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3943                 [choose additional checking for stage1 of the compiler])],
3944 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3945 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3946   # For --disable-checking or implicit --enable-checking=release, avoid
3947   # setting --enable-checking=gc in the default stage1 checking for LTO
3948   # bootstraps.  See PR62077.
3949   case $BUILD_CONFIG in
3950     *lto*)
3951       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3952     *)
3953       stage1_checking=--enable-checking=yes,types;;
3954   esac
3955   if test "x$enable_checking" = x && \
3956      test -d ${srcdir}/gcc && \
3957      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3958     stage1_checking=--enable-checking=yes,types,extra
3959   fi
3960 else
3961   stage1_checking=--enable-checking=$enable_checking,types
3962 fi])
3963 AC_SUBST(stage1_checking)
3964
3965 # Enable -Werror in bootstrap stage2 and later.
3966 AC_ARG_ENABLE(werror,
3967 [AS_HELP_STRING([--enable-werror],
3968                 [enable -Werror in bootstrap stage2 and later])],
3969 [
3970 case ${enable_werror} in
3971   yes) stage2_werror_flag="--enable-werror-always" ;;
3972   *) stage2_werror_flag="" ;;
3973 esac
3974 ],
3975 [
3976 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3977   case $BUILD_CONFIG in
3978   bootstrap-debug)
3979       stage2_werror_flag="--enable-werror-always" ;;
3980   "")
3981       stage2_werror_flag="--enable-werror-always" ;;
3982   esac
3983 fi
3984 ])
3985
3986 AC_SUBST(stage2_werror_flag)
3987
3988 # Specify what files to not compare during bootstrap.
3989
3990 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3991 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/M2Version*"
3992 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/SYSTEM*"
3993 compare_exclusions="$compare_exclusions | gcc/m2/gm2version*"
3994 case "$target" in
3995   hppa*64*-*-hpux*) ;;
3996   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3997 esac
3998 AC_SUBST(compare_exclusions)
3999
4000 AC_CONFIG_FILES([Makefile],
4001   [sed "$extrasub_build" Makefile |
4002    sed "$extrasub_host" |
4003    sed "$extrasub_target" > mf$$
4004    mv -f mf$$ Makefile],
4005   [extrasub_build="$extrasub_build"
4006    extrasub_host="$extrasub_host"
4007    extrasub_target="$extrasub_target"])
4008 AC_OUTPUT