ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ldmain.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_CANONICAL_BUILD
   9 AC_ISC_POSIX
  10
  11 changequote(,)dnl
  12 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  13 changequote([,])dnl
  14 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  15 AM_MAINTAINER_MODE
  16
  17 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  18 AC_ARG_ENABLE(targets,
  19 [  --enable-targets        alternative target configurations],
  20 [case "${enableval}" in
  21   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(64-bit-bfd,
  27 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  28 [case "${enableval}" in
  29   yes)  want64=true  ;;
  30   no)   want64=false ;;
  31   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  32 esac],[want64=false])dnl
  33
  34 AC_ARG_WITH(sysroot,
  35 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  36 [
  37  case ${with_sysroot} in
  38  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  39  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  40  esac
  41
  42  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  43  use_sysroot=yes
  44
  45  if test "x$prefix" = xNONE; then
  46   test_prefix=/usr/local
  47  else
  48   test_prefix=$prefix
  49  fi
  50  if test "x$exec_prefix" = xNONE; then
  51   test_exec_prefix=$test_prefix
  52  else
  53   test_exec_prefix=$exec_prefix
  54  fi
  55  case ${TARGET_SYSTEM_ROOT} in
  56  "${test_prefix}"|"${test_prefix}/"*|\
  57  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  58  '${prefix}'|'${prefix}/'*|\
  59  '${exec_prefix}'|'${exec_prefix}/'*)
  60    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  61    TARGET_SYSTEM_ROOT_DEFINE="$t"
  62    ;;
  63  esac
  64 ], [
  65  use_sysroot=no
  66  TARGET_SYSTEM_ROOT=
  67  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  68 ])
  69 AC_SUBST(use_sysroot)
  70 AC_SUBST(TARGET_SYSTEM_ROOT)
  71 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  72
  73 dnl Use --enable-gold to decide if this linker should be the default.
  74 dnl "install_as_default" is set to false if gold is the default linker.
  75 dnl "installed_linker" is the installed BFD linker name.
  76 AC_ARG_ENABLE(gold,
  77 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
  78 [case "${enableval}" in
  79  default)
  80    install_as_default=no
  81    installed_linker=ld.bfd
  82    ;;
  83  yes|no)
  84    install_as_default=yes
  85    installed_linker=ld.bfd
  86    ;;
  87  *)
  88    AC_MSG_ERROR([invalid --enable-gold argument])
  89    ;;
  90  esac],
  91 [install_as_default=yes
  92  installed_linker=ld.bfd])
  93 AC_SUBST(install_as_default)
  94 AC_SUBST(installed_linker)
  95
  96 AC_ARG_ENABLE([got],
  97 AS_HELP_STRING([--enable-got=<type>],
  98                [GOT handling scheme (target, single, negative, multigot)]),
  99 [case "${enableval}" in
 100   target | single | negative | multigot)  got_handling=$enableval ;;
 101   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 102 esac],
 103 [got_handling=target])
 104
 105 case "${got_handling}" in
 106   target)
 107     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 108               [Define to choose default GOT handling scheme]) ;;
 109   single)
 110     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 111               [Define to choose default GOT handling scheme]) ;;
 112   negative)
 113     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 114               [Define to choose default GOT handling scheme]) ;;
 115   multigot)
 116     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 117               [Define to choose default GOT handling scheme]) ;;
 118   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 119 esac
 120
 121 AM_BINUTILS_WARNINGS
 122
 123 AM_LC_MESSAGES
 124
 125 AC_CONFIG_HEADERS([config.h:config.in])
 126
 127 # PR 14072
 128 AH_VERBATIM([00_CONFIG_H_CHECK],
 129 [/* Check that config.h is #included before system headers
 130    (this works only for glibc, but that should be enough).  */
 131 #if defined(__GLIBC__) && !defined(__CONFIG_H__)
 132 #  error config.h must be #included before system headers
 133 #endif
 134 #define __CONFIG_H__ 1])
 135
 136 if test -z "$target" ; then
 137     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 138 fi
 139 if test -z "$host" ; then
 140     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 141 fi
 142
 143 # host-specific stuff:
 144
 145 AC_PROG_CC
 146 AC_PROG_CXX
 147 AC_GNU_SOURCE
 148 AC_USE_SYSTEM_EXTENSIONS
 149 ACX_LARGEFILE
 150 AC_PROG_INSTALL
 151
 152 LT_INIT
 153
 154 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it uk"
 155 ZW_GNU_GETTEXT_SISTER_DIR
 156 AM_PO_SUBDIRS
 157
 158 AC_EXEEXT
 159
 160 AC_PROG_YACC
 161 AM_PROG_LEX
 162
 163 AM_MAINTAINER_MODE
 164 AM_CONDITIONAL(GENINSRC_NEVER, false)
 165 ACX_PROG_CMP_IGNORE_INITIAL
 166
 167 . ${srcdir}/configure.host
 168
 169 AC_SUBST(HDEFINES)
 170 AC_SUBST(HOSTING_CRT0)
 171 AC_SUBST(HOSTING_LIBS)
 172 AC_SUBST(NATIVE_LIB_DIRS)
 173
 174 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 175 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 176 ACX_HEADER_STRING
 177 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 178 AC_CHECK_FUNCS(open lseek close)
 179 AC_HEADER_DIRENT
 180
 181 # Check for dlopen support and enable plugins if possible.
 182 enable_plugins=yes
 183 AC_CHECK_HEADER([dlfcn.h],[],[enable_plugins=no],[AC_INCLUDES_DEFAULT])
 184 AC_SEARCH_LIBS([dlopen],[dl],[],[enable_plugins=no],[])
 185 AC_CHECK_FUNCS([dlopen dlsym dlclose],[],[enable_plugins=no])
 186 # We also support plugins on Windows (MinGW).
 187 if test x$enable_plugins = xno ; then
 188   AC_CHECK_HEADERS([windows.h],[enable_plugins=yes],[],[AC_INCLUDES_DEFAULT])
 189 fi
 190 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$enable_plugins = xyes])
 191
 192 AC_ARG_ENABLE(initfini-array,
 193         [  --enable-initfini-array      use .init_array/.fini_array sections],
 194         [], [
 195 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
 196                  gcc_cv_initfini_array, [dnl
 197   if test "x${build}" = "x${target}" ; then
 198     AC_RUN_IFELSE([AC_LANG_SOURCE([
 199 static int x = -1;
 200 int main (void) { return x; }
 201 int foo (void) { x = 0; }
 202 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;])],
 203              [gcc_cv_initfini_array=yes], [gcc_cv_initfini_array=no],
 204              [gcc_cv_initfini_array=no])
 205    else
 206      gcc_cv_initfini_array=no
 207    fi])
 208   enable_initfini_array=$gcc_cv_initfini_array
 209 ])
 210 AC_SUBST(enable_initfini_array)
 211 if test $enable_initfini_array = yes; then
 212   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 213     [Define .init_array/.fini_array sections are available and working.])
 214 fi
 215
 216 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 217 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 218 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 219 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 220 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 221 if test $ld_cv_decl_getopt_unistd_h = yes; then
 222   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 223             [Is the prototype for getopt in <unistd.h> in the expected format?])
 224 fi
 225
 226 BFD_BINARY_FOPEN
 227
 228 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 229
 230 # Link in zlib if we can.  This is needed only for the bootstrap tests
 231 # right now, since those tests use libbfd, which depends on zlib.
 232 AM_ZLIB
 233
 234 # When converting linker scripts into strings for use in emulation
 235 # files, use astring.sed if the compiler supports ANSI string
 236 # concatenation, or ostring.sed otherwise.  This is to support the
 237 # broken Microsoft MSVC compiler, which limits the length of string
 238 # constants, while still supporting pre-ANSI compilers which do not
 239 # support string concatenation.
 240 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 241 AC_CACHE_VAL(ld_cv_string_concatenation,
 242 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 243   ld_cv_string_concatenation=yes,
 244   ld_cv_string_concatenation=no)])
 245 AC_MSG_RESULT($ld_cv_string_concatenation)
 246 if test "$ld_cv_string_concatenation" = "yes"; then
 247   STRINGIFY=astring.sed
 248 else
 249   STRINGIFY=ostring.sed
 250 fi
 251 AC_SUBST(STRINGIFY)
 252
 253 # target-specific stuff:
 254
 255 all_targets=
 256 EMUL=
 257 all_emuls=
 258 all_emul_extras=
 259 all_libpath=
 260
 261 dnl We need to get an arbitrary number of tdir definitions into
 262 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 263 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 264 dnl file.
 265 rm -f tdirs
 266
 267 # If the host is 64-bit, then we enable 64-bit targets by default.
 268 # This is consistent with what ../bfd/configure.in does.
 269 if test x${want64} = xfalse; then
 270   AC_CHECK_SIZEOF(void *)
 271   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 272     want64=true
 273   fi
 274 fi
 275
 276 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 277 do
 278   if test "$targ_alias" = "all"; then
 279     all_targets=true
 280   else
 281     # Canonicalize the secondary target names.
 282     result=`$ac_config_sub $targ_alias 2>/dev/null`
 283     if test -n "$result"; then
 284         targ=$result
 285     else
 286         targ=$targ_alias
 287     fi
 288
 289     . ${srcdir}/configure.tgt
 290
 291     if test "$targ" = "$target"; then
 292       EMUL=$targ_emul
 293     fi
 294
 295     if test x${want64} = xfalse; then
 296       . ${srcdir}/../bfd/config.bfd
 297     fi
 298
 299     if test x${want64} = xtrue; then
 300       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 301       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 302     fi
 303
 304     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 305         case " $all_emuls " in
 306         *" e${i}.o "*) ;;
 307         *)
 308           all_emuls="$all_emuls e${i}.o"
 309           eval result=\$tdir_$i
 310           test -z "$result" && result=$targ_alias
 311           echo tdir_$i=$result >> tdirs
 312           ;;
 313         esac
 314     done
 315
 316     for i in $targ_emul $targ_extra_libpath; do
 317         case " $all_libpath " in
 318         *" ${i} "*) ;;
 319         *)
 320           if test -z "$all_libpath"; then
 321             all_libpath=${i}
 322           else
 323             all_libpath="$all_libpath ${i}"
 324           fi
 325           ;;
 326         esac
 327     done
 328
 329     for i in $targ_extra_ofiles; do
 330         case " $all_emul_extras " in
 331         *" ${i} "*) ;;
 332         *)
 333           all_emul_extras="$all_emul_extras ${i}"
 334           ;;
 335         esac
 336     done
 337   fi
 338 done
 339
 340 AC_SUBST(EMUL)
 341
 342 TDIRS=tdirs
 343 AC_SUBST_FILE(TDIRS)
 344
 345 if test x${all_targets} = xtrue; then
 346   if test x${want64} = xtrue; then
 347     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 348   else
 349     EMULATION_OFILES='$(ALL_EMULATIONS)'
 350   fi
 351   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 352 else
 353   EMULATION_OFILES=$all_emuls
 354   EMUL_EXTRA_OFILES=$all_emul_extras
 355 fi
 356 AC_SUBST(EMULATION_OFILES)
 357 AC_SUBST(EMUL_EXTRA_OFILES)
 358 AC_SUBST(LIB_PATH)
 359
 360 EMULATION_LIBPATH=$all_libpath
 361 AC_SUBST(EMULATION_LIBPATH)
 362
 363 if test x${enable_static} = xno; then
 364   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 365 else
 366   TESTBFDLIB="../bfd/.libs/libbfd.a"
 367 fi
 368 AC_SUBST(TESTBFDLIB)
 369
 370 target_vendor=${target_vendor=$host_vendor}
 371 case "$target_vendor" in
 372   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 373   *)  EXTRA_SHLIB_EXTENSION= ;;
 374 esac
 375
 376 case "$target_os" in
 377   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 378 esac
 379
 380 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 381   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 382    [Additional extension a shared object might have.])
 383 fi
 384
 385 dnl Required by html, pdf, install-pdf and install-html
 386 AC_SUBST(datarootdir)
 387 AC_SUBST(docdir)
 388 AC_SUBST(htmldir)
 389 AC_SUBST(pdfdir)
 390
 391 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 392 AC_OUTPUT