gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.13)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25 AM_MAINTAINER_MODE
  26
  27 AC_PROG_CC
  28 AC_AIX
  29 AC_ISC_POSIX
  30 AM_PROG_CC_STDC
  31
  32 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  33 AC_CANONICAL_SYSTEM
  34
  35 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  36 dnl link with the correct libraries.
  37 ALL_LINGUAS=
  38 CY_GNU_GETTEXT
  39
  40 dnl List of object files added by configure.
  41
  42 CONFIG_OBS=
  43 CONFIG_DEPS=
  44 CONFIG_SRCS=
  45 CONFIG_INITS=
  46 ENABLE_CFLAGS=
  47 CONFIG_ALL=
  48 CONFIG_CLEAN=
  49 CONFIG_INSTALL=
  50 CONFIG_UNINSTALL=
  51
  52 configdirs="doc testsuite"
  53
  54 AC_ARG_ENABLE(multi-ice,
  55 [  --enable-multi-ice            Build the multi-ice-gdb-server],
  56 [case "${enableval}" in
  57     yes ) enable_multi_ice="yes" ;;
  58     no)  enable_multi_ice="no" ;;
  59     *) AC_MSG_ERROR(Bad value for --enable-multi-ice: ${enableval}) ;;
  60   esac
  61 ])
  62
  63 if test "${enable_multi_ice}" = "yes"; then
  64   configdirs="${configdirs} multi-ice"
  65 fi
  66
  67 dnl
  68 changequote(,)dnl
  69
  70 . ${srcdir}/configure.host
  71
  72 . ${srcdir}/configure.tgt
  73
  74 targ=${target} ; . ${srcdir}/../bfd/config.bfd
  75
  76 dnl
  77 changequote([,])dnl
  78
  79 dnl use BFD to determine the default architecture and byte order
  80 dnl (bfd_vec->byteorder provides the latter).
  81 targ=${target}
  82 . ${srcdir}/../bfd/config.bfd
  83
  84 dnl We only want the first arch, if there is more than one.
  85 targ_archs=`echo ${targ_archs} | sed -e 's/ .*//;'`
  86
  87 if test x"${targ_archs}" != x ; then
  88     AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, ${targ_archs})
  89 fi
  90 if test x"${targ_defvec}" != x ; then
  91     AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, ${targ_defvec})
  92 fi
  93
  94 AC_PROG_AWK
  95 AC_PROG_INSTALL
  96 AC_CHECK_TOOL(AR, ar)
  97 AC_CHECK_TOOL(RANLIB, ranlib, :)
  98 AC_CHECK_TOOL(DLLTOOL, dlltool)
  99 AC_CHECK_TOOL(WINDRES, windres)
 100 AC_PROG_YACC
 101
 102 dnl MiG is needed for the Hurd.
 103 AC_CHECK_TOOL(MIG, mig)
 104
 105 AC_ARG_PROGRAM
 106
 107 AC_TYPE_SIGNAL
 108
 109 AC_HEADER_STDC
 110
 111 dnl Solaris 7 needs _MSE_INT_H defined to avoid a clash between <widec.h>
 112 dnl and <wchar.h> that causes AC_CHECK_HEADERS to think <curses.h> doesn't
 113 dnl exist.
 114
 115 case $host_os in solaris2.7 | solaris2.8) case "$GCC" in yes)
 116     AC_DEFINE(_MSE_INT_H)
 117 esac; esac
 118
 119 AC_CHECK_HEADERS(ctype.h endian.h link.h thread_db.h proc_service.h \
 120         memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
 121         string.h sys/procfs.h sys/ptrace.h sys/reg.h stdint.h \
 122         term.h termio.h termios.h unistd.h wait.h sys/wait.h \
 123         wchar.h wctype.h asm/debugreg.h sys/debugreg.h sys/select.h \
 124         time.h sys/ioctl.h sys/user.h \
 125         dirent.h sys/ndir.h sys/dir.h ndir.h \
 126         curses.h ncurses.h \
 127         poll.h sys/poll.h)
 128 AC_HEADER_STAT
 129
 130 AC_C_CONST
 131
 132 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc poll sigprocmask)
 133 AC_FUNC_ALLOCA
 134
 135 # See if machine/reg.h supports the %fs and %gs i386 segment registers.
 136 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 137 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 138 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 139 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 140 if test $gdb_cv_struct_reg_r_fs = yes; then
 141   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 142 fi
 143 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 144 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 145 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 146 if test $gdb_cv_struct_reg_r_gs = yes; then
 147   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 148 fi
 149
 150 dnl See if ptrace.h provides the PTRACE_GETREGS request.
 151 AC_MSG_CHECKING(for PTRACE_GETREGS)
 152 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 153 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 154                 [PTRACE_GETREGS;],
 155                 [gdb_cv_have_ptrace_getregs=yes],
 156                 [gdb_cv_have_ptrace_getregs=no])])
 157 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 158 if test $gdb_cv_have_ptrace_getregs = yes; then
 159   AC_DEFINE(HAVE_PTRACE_GETREGS)
 160 fi
 161
 162 dnl See if ptrace.h provides the PTRACE_GETFPXREGS request.
 163 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 164 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 165 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 166                 [PTRACE_GETFPXREGS;],
 167                 [gdb_cv_have_ptrace_getfpxregs=yes],
 168                 [gdb_cv_have_ptrace_getfpxregs=no])])
 169 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 170 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 171   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 172 fi
 173
 174 AC_CHECK_LIB(socket, socketpair)
 175 AC_CHECK_FUNCS(socketpair)
 176
 177
 178 BFD_NEED_DECLARATION(malloc)
 179 BFD_NEED_DECLARATION(realloc)
 180 BFD_NEED_DECLARATION(free)
 181 BFD_NEED_DECLARATION(strerror)
 182 BFD_NEED_DECLARATION(strdup)
 183 BFD_NEED_DECLARATION(strstr)
 184
 185
 186 # The following save_state_t checkery is only necessary for HPUX
 187 # versions earlier than 10.20.  When those fade from memory, this
 188 # could be expunged. --jsm 1999-03-22
 189
 190 AC_MSG_CHECKING(for HPUX save_state structure)
 191 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 192                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 193 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 194                 gdb_cv_hpux_sswide=no)
 195 if test $gdb_cv_hpux_savestate = yes
 196 then
 197   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 198 fi
 199 if test $gdb_cv_hpux_sswide = yes
 200 then
 201   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 202 fi
 203 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 204
 205
 206 # If we are configured native on GNU/Linux, work around problems with
 207 # sys/procfs.h
 208 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 209
 210 if test "${target}" = "${host}"; then
 211   case "${host}" in
 212   i[[3456]]86-*-linux*)
 213         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 214         AC_DEFINE(sys_quotactl)
 215         ;;
 216   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5*)
 217       AC_DEFINE(NEW_PROC_API)
 218       ;;
 219   *-*-solaris2.[[678]])
 220       AC_DEFINE(NEW_PROC_API)
 221       ;;
 222   esac
 223 fi
 224
 225 if test "$ac_cv_header_sys_procfs_h" = yes; then
 226   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 227   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 228   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 229   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 230   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 231   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 232   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 233   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 234
 235   dnl Check for broken prfpregset_t type
 236
 237   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 238   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 239   dnl instead of the struct itself).  We detect this here, and work
 240   dnl around it in lin-thread.c.
 241
 242   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 243     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 244     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 245       [AC_TRY_RUN([#include <sys/procfs.h>
 246        int main ()
 247        {
 248          if (sizeof (prfpregset_t) == sizeof (void *))
 249            return 1;
 250          return 0;
 251        }],
 252        gdb_cv_prfpregset_t_broken=no,
 253        gdb_cv_prfpregset_t_broken=yes,
 254        gdb_cv_prfpregset_t_broken=yes)])
 255     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 256     if test $gdb_cv_prfpregset_t_broken = yes; then
 257       AC_DEFINE(PRFPREGSET_T_BROKEN)
 258     fi
 259   fi
 260
 261   dnl Check for PIOCSET ioctl entry
 262
 263   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 264   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 265   [AC_TRY_COMPILE([#include <unistd.h>
 266 #include <sys/types.h>
 267 #include <sys/procfs.h>
 268 ], [
 269     int dummy;;
 270     dummy = ioctl(0, PIOCSET, &dummy);
 271   ],
 272   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 273   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 274   if test $gdb_cv_have_procfs_piocset = yes; then
 275     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 276   fi
 277 fi
 278
 279 dnl See if host has libm.  This is usually needed by simulators.
 280 AC_CHECK_LIB(m, main)
 281
 282 dnl Solaris puts wctype in /usr/lib/libw.a before Solaris 2.6.
 283 dnl
 284 dnl A bug in GNU ld 2.9.1 causes a problem if we link in -lw
 285 dnl under Solaris 2.6 because it is some funky empty library.
 286 dnl So only link in libw if we have to.
 287 AC_CHECK_LIB(c, wctype,: ,AC_CHECK_LIB(w, wctype))
 288
 289 dnl See if compiler supports "long long" type.
 290
 291 AC_MSG_CHECKING(for long long support in compiler)
 292 AC_CACHE_VAL(gdb_cv_c_long_long,
 293 [AC_TRY_COMPILE(, [
 294   extern long long foo;
 295   switch (foo & 2) { case 0: return 1; }
 296 ],
 297 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 298 AC_MSG_RESULT($gdb_cv_c_long_long)
 299 if test $gdb_cv_c_long_long = yes; then
 300   AC_DEFINE(CC_HAS_LONG_LONG)
 301 fi
 302
 303 dnl See if the compiler and runtime support printing long long
 304
 305 AC_MSG_CHECKING(for long long support in printf)
 306 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 307 [AC_TRY_RUN([
 308 int main () {
 309   char buf[32];
 310   long long l = 0;
 311   l = (l << 16) + 0x0123;
 312   l = (l << 16) + 0x4567;
 313   l = (l << 16) + 0x89ab;
 314   l = (l << 16) + 0xcdef;
 315   sprintf (buf, "0x%016llx", l);
 316   return (strcmp ("0x0123456789abcdef", buf));
 317 }],
 318 gdb_cv_printf_has_long_long=yes,
 319 gdb_cv_printf_has_long_long=no,
 320 gdb_cv_printf_has_long_long=no)])
 321 if test $gdb_cv_printf_has_long_long = yes; then
 322   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 323 fi
 324 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 325
 326 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 327 dnl because autoconf complains about cross-compilation issues.  However, this
 328 dnl code uses the same variables as the macro for compatibility.
 329
 330 AC_MSG_CHECKING(for long double support in compiler)
 331 AC_CACHE_VAL(ac_cv_c_long_double,
 332 [AC_TRY_COMPILE(, [long double foo;],
 333 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 334 AC_MSG_RESULT($ac_cv_c_long_double)
 335 if test $ac_cv_c_long_double = yes; then
 336   AC_DEFINE(HAVE_LONG_DOUBLE)
 337 fi
 338
 339 dnl See if the compiler and runtime support printing long doubles
 340
 341 AC_MSG_CHECKING(for long double support in printf)
 342 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 343 [AC_TRY_RUN([
 344 int main () {
 345   char buf[16];
 346   long double f = 3.141592653;
 347   sprintf (buf, "%Lg", f);
 348   return (strncmp ("3.14159", buf, 7));
 349 }],
 350 gdb_cv_printf_has_long_double=yes,
 351 gdb_cv_printf_has_long_double=no,
 352 gdb_cv_printf_has_long_double=no)])
 353 if test $gdb_cv_printf_has_long_double = yes; then
 354   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 355 fi
 356 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 357
 358 dnl See if the compiler and runtime support scanning long doubles
 359
 360 AC_MSG_CHECKING(for long double support in scanf)
 361 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 362 [AC_TRY_RUN([
 363 int main () {
 364   char *buf = "3.141592653";
 365   long double f = 0;
 366   sscanf (buf, "%Lg", &f);
 367   return !(f > 3.14159 && f < 3.14160);
 368 }],
 369 gdb_cv_scanf_has_long_double=yes,
 370 gdb_cv_scanf_has_long_double=no,
 371 gdb_cv_scanf_has_long_double=no)])
 372 if test $gdb_cv_scanf_has_long_double = yes; then
 373   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 374 fi
 375 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 376
 377 AC_FUNC_MMAP
 378
 379 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 380 dnl we must explicitly test for version 1 of the library because version 0
 381 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 382
 383 dnl Note that we only want this if we are both native (host == target), and
 384 dnl not doing a canadian cross build (build == host).
 385
 386 if test ${build} = ${host} -a ${host} = ${target} ; then
 387    case ${host_os} in
 388    hpux*)
 389       AC_MSG_CHECKING(for HPUX/OSF thread support)
 390       if test -f /usr/include/dce/cma_config.h ; then
 391          if test "$GCC" = "yes" ; then
 392             AC_MSG_RESULT(yes)
 393             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 394             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 395             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 396          else
 397             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 398          fi
 399       else
 400          AC_MSG_RESULT(no)
 401       fi
 402       ;;
 403    solaris*)
 404       AC_MSG_CHECKING(for Solaris thread debugging library)
 405       if test -f /usr/lib/libthread_db.so.1 ; then
 406          AC_MSG_RESULT(yes)
 407          AC_DEFINE(HAVE_THREAD_DB_LIB)
 408          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 409          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 410          AC_CHECK_LIB(dl, dlopen)
 411          if test "$GCC" = "yes" ; then
 412             # The GNU linker requires the -export-dynamic option to make
 413             # all symbols visible in the dynamic symbol table.
 414             hold_ldflags=$LDFLAGS
 415             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 416             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 417             AC_TRY_LINK(, [int i;], found=yes, found=no)
 418             LDFLAGS=$hold_ldflags
 419             AC_MSG_RESULT($found)
 420             if test $found = yes; then
 421                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 422             fi
 423          fi
 424          # Sun randomly tweaked the prototypes in <proc_service.h>
 425          # at one point.
 426          AC_MSG_CHECKING(if <proc_service.h> is old)
 427          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 428             AC_TRY_COMPILE([
 429                 #include <proc_service.h>
 430                 ps_err_e ps_pdwrite
 431                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 432             ],, gdb_cv_proc_service_is_old=no,
 433                 gdb_cv_proc_service_is_old=yes)
 434          ])
 435          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 436          if test $gdb_cv_proc_service_is_old = yes; then
 437             AC_DEFINE(PROC_SERVICE_IS_OLD)
 438          fi
 439       else
 440          AC_MSG_RESULT(no)
 441       fi
 442       ;;
 443    esac
 444    AC_SUBST(CONFIG_LDFLAGS)
 445 fi
 446
 447 dnl Handle optional features that can be enabled.
 448
 449 dnl Handle MI sub-directory configury.
 450 AC_ARG_ENABLE(gdbmi,
 451 [  --enable-gdbmi            Enable GDB-MI interface],
 452 [
 453   case "${enable_gdbmi}" in
 454     yes | no) ;;
 455     "")  enable_gdbmi=yes ;;
 456     *)
 457       AC_MSG_ERROR(Bad value for --enable-gdbmi: ${enableval})
 458     ;;
 459   esac
 460 ])
 461 case ${enable_gdbmi} in
 462   "yes" )
 463     if test -d "${srcdir}/mi" ; then
 464       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_MI_OBS)"
 465       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_MI_DEPS)"
 466       CONFIG_SRCS="${CONFIG_SRS} \$(SUBDIR_MI_SRCS)"
 467       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_MI_INITS)"
 468       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_MI_CFLAGS)"
 469       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_MI_ALL)"
 470       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_MI_CLEAN)"
 471       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_MI_INSTALL)"
 472       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_MI_UNINSTALL)"
 473     fi
 474     ;;
 475 esac
 476
 477 AC_ARG_ENABLE(tui,
 478 [  --enable-tui            Enable full-screen terminal user interface],
 479 [
 480   case "${enable_tui}" in
 481     yes | no) ;;
 482     "")  enable_tui=yes ;;
 483     *)
 484       AC_MSG_ERROR(Bad value for --enable-tui: ${enableval})
 485     ;;
 486   esac
 487 ])
 488 case ${enable_tui} in
 489   "yes" )
 490     if test -d "${srcdir}/tui" ; then
 491       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_TUI_OBS)"
 492       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_TUI_DEPS)"
 493       CONFIG_SRCS="${CONFIG_SRS} \$(SUBDIR_TUI_SRCS)"
 494       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_TUI_INITS)"
 495       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_TUI_CFLAGS)"
 496       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_TUI_ALL)"
 497       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_TUI_CLEAN)"
 498       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_TUI_INSTALL)"
 499       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_TUI_UNINSTALL)"
 500     fi
 501     ;;
 502 esac
 503
 504 AC_ARG_ENABLE(netrom,
 505 [  --enable-netrom         Enable NetROM support],
 506 [case "${enableval}" in
 507 yes)    enable_netrom=yes ;;
 508 no)     enable_netrom=no ;;
 509 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 510 esac])
 511
 512 if test "${enable_netrom}" = "yes"; then
 513         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 514         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 515 fi
 516
 517
 518 # Don't add -Wall or -Wunused, they include -Wunused-parameter which
 519 # causes noise.
 520 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
 521 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized"
 522 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
 523 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
 524 # -Wchar-subscripts -Wuninitialized -Wtraditional -Wshadow -Wcast-qual
 525 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
 526 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
 527 # -Woverloaded-virtual -Winline -Werror"
 528 AC_ARG_ENABLE(build-warnings,
 529 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 530 [case "${enableval}" in
 531   yes)  ;;
 532   no)   build_warnings="-w";;
 533   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 534         build_warnings="${build_warnings} ${t}";;
 535   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 536         build_warnings="${t} ${build_warnings}";;
 537   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 538 esac
 539 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 540   echo "Setting compiler warning flags = $build_warnings" 6>&1
 541 fi])dnl
 542 WARN_CFLAGS=""
 543 WERROR_CFLAGS=""
 544 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 545 then
 546     AC_MSG_CHECKING(compiler warning flags)
 547     # Separate out the -Werror flag as some files just cannot be
 548     # compiled with it enabled.
 549     for w in ${build_warnings}; do
 550         case $w in
 551         -Werr*) WERROR_CFLAGS=-Werror ;;
 552         *) # Check that GCC accepts it
 553             if $CC $w 2>&1 | grep 'unrecognized option' > /dev/null; then
 554                 :
 555             else
 556                 WARN_CFLAGS="${WARN_CFLAGS} $w"
 557             fi
 558         esac
 559     done
 560     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
 561 fi
 562 AC_SUBST(WARN_CFLAGS)
 563 AC_SUBST(WERROR_CFLAGS)
 564
 565 MMALLOC_CFLAGS=
 566 MMALLOC=
 567 AC_SUBST(MMALLOC_CFLAGS)
 568 AC_SUBST(MMALLOC)
 569
 570 AC_ARG_WITH(mmalloc,
 571 [  --with-mmalloc          Use memory mapped malloc package],
 572 [case "${withval}" in
 573   yes)  want_mmalloc=true ;;
 574   no)   want_mmalloc=false;;
 575   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 576 esac],[want_mmalloc=false])dnl
 577
 578 if test x$want_mmalloc = xtrue; then
 579    AC_DEFINE(USE_MMALLOC)
 580    AC_DEFINE(MMCHECK_FORCE)
 581    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 582    MMALLOC='../mmalloc/libmmalloc.a'
 583 fi
 584
 585 AC_ARG_WITH(included-regex,
 586 [  --with-included-regex          Use included regex],
 587 [case "${withval}" in
 588   yes)  want_included_regex=true ;;
 589   no)   want_included_regex=false;;
 590   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-included-regex option) ;;
 591 esac],[want_included_regex=true])dnl
 592
 593 if test $want_included_regex = false; then
 594   AC_MSG_CHECKING(for GNU regex)
 595   AC_CACHE_VAL(gdb_cv_have_gnu_regex,
 596 [AC_TRY_COMPILE([#include <gnu-versions.h>
 597 #include <sys/types.h>
 598 #include <regex.h>],
 599 [#if !defined _GNU_REGEX_INTERFACE_VERSION || !defined __GLIBC__ || __GLIBC__ < 2
 600 #error No valid GNU regex.
 601 #endif
 602 ],
 603                 [gdb_cv_have_gnu_regex=yes],
 604                 [gdb_cv_have_gnu_regex=no])])
 605   AC_MSG_RESULT($gdb_cv_have_gnu_regex)
 606   if test $gdb_cv_have_gnu_regex = no; then
 607         want_included_regex=true
 608   fi
 609 fi
 610
 611 if test x${want_included_regex} = xtrue; then
 612     REGEX="gnu-regex.o"
 613     AC_DEFINE(USE_INCLUDED_REGEX)
 614 fi
 615 AC_SUBST(REGEX)
 616
 617 # In the Cygwin environment, we need some additional flags.
 618 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
 619 [AC_EGREP_CPP(lose, [
 620 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
 621 lose
 622 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
 623
 624
 625 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
 626 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
 627 case ${host} in
 628   *go32* ) SER_HARDWIRE=ser-go32.o ;;
 629   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
 630 esac
 631 AC_SUBST(SER_HARDWIRE)
 632
 633
 634 dnl Figure out which term library to use.
 635 if test x$gdb_host = xgo32; then
 636   TERM_LIB=
 637 else
 638 if test x$gdb_cv_os_cygwin = xyes; then
 639   TERM_LIB='`if test -r ../libtermcap/libtermcap.a; then echo ../libtermcap/libtermcap.a; else echo -ltermcap; fi`'
 640 else
 641   TERM_LIB=
 642   AC_CHECK_LIB(ncurses, tgetent, TERM_LIB=-lncurses,
 643     AC_CHECK_LIB(Hcurses, tgetent, TERM_LIB=-lHcurses,
 644       AC_CHECK_LIB(termlib, tgetent, TERM_LIB=-ltermlib,
 645         AC_CHECK_LIB(termcap, tgetent, TERM_LIB=-ltermcap,
 646           AC_CHECK_LIB(curses, tgetent, TERM_LIB=-lcurses,
 647             AC_CHECK_LIB(terminfo, tgetent, TERM_LIB=-lterminfo))))))
 648
 649   if test "x$TERM_LIB" = x
 650   then
 651     AC_MSG_ERROR(Could not find a term library, e.g. termcap or termlib!)
 652   fi
 653 fi
 654 fi
 655 AC_SUBST(TERM_LIB)
 656
 657 # libreadline needs libuser32.a in a cygwin environment
 658 WIN32LIBS=
 659 if test x$gdb_cv_os_cygwin = xyes; then
 660     WIN32LIBS="-luser32"
 661     case "${target}" in
 662         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
 663         ;;
 664     esac
 665 fi
 666 AC_SUBST(WIN32LIBS)
 667
 668 LIBGUI="../libgui/src/libgui.a"
 669 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 670 AC_SUBST(LIBGUI)
 671 AC_SUBST(GUI_CFLAGS_X)
 672
 673 AC_ARG_WITH(cpu,
 674 [  --with-cpu=CPU          Set the default CPU variant to debug],
 675 [case "${target}" in
 676   powerpc-* | powerpcle-* )
 677     ## It would be nice to keep this table in sync with the one in
 678     ## gcc/configure.
 679     case "${with_cpu}" in
 680       ppc-uisa | rs6000 | 403 | 403GC | 505 | 860 | 601 | 602 | 603 \
 681       | 604 | 750 )
 682         ## Those are all handled in variants in rs6000-tdep.c, so they're fine.
 683       ;;
 684       common | power | power2 | rios | rios1 | rios2 | rsc | rsc1 )
 685         ## These are all RS6000 variants, as far as GDB is concerned.
 686         with_cpu=rs6000
 687       ;;
 688       603e | ec603e )
 689         with_cpu=603
 690       ;;
 691       604e )
 692         with_cpu=604
 693       ;;
 694       * )
 695         AC_MSG_WARN(GDB: unknown --with-cpu value: \`${with_cpu}'; using \`ppc-uisa'.)
 696         with_cpu=ppc-uisa
 697       ;;
 698     esac
 699   ;;
 700   * )
 701     AC_MSG_WARN(GDB may ignore the --with-cpu flag for ${target} targets)
 702   ;;
 703 esac
 704 AC_DEFINE_UNQUOTED(TARGET_CPU_DEFAULT, "${with_cpu}")
 705 ],)
 706
 707
 708 AC_ARG_ENABLE(gdbtk,
 709 [  --enable-gdbtk          Enable GDBTK GUI front end],
 710 [case "${enableval}" in
 711     yes)
 712         case "$host" in
 713         *go32*)
 714             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 715             enable_gdbtk=no ;;
 716         *windows*)
 717             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 718             enable_gdbtk=no ;;
 719         *)
 720             enable_gdbtk=yes ;;
 721         esac ;;
 722     no)
 723         enable_gdbtk=no  ;;
 724     *)
 725         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 726 esac],
 727 [
 728 # Default is on for everything but go32 and Cygwin
 729 case "$host" in
 730     *go32* | *windows*)
 731         ;;
 732     *)
 733         if test -d "${srcdir}/gdbtk" ; then
 734             enable_gdbtk=yes
 735         fi
 736         ;;
 737 esac
 738 ])
 739
 740 WIN32LDAPP=
 741 AC_SUBST(WIN32LIBS)
 742 AC_SUBST(WIN32LDAPP)
 743
 744 configdir="unix"
 745
 746 GDBTKLIBS=
 747 if test "${enable_gdbtk}" = "yes"; then
 748
 749     CY_AC_PATH_TCLCONFIG
 750     if test -z "${no_tcl}"; then
 751         CY_AC_LOAD_TCLCONFIG
 752         CY_AC_PATH_TKCONFIG
 753
 754         # If $no_tk is nonempty, then we can't do Tk, and there is no
 755         # point to doing Tcl.
 756         if test -z "${no_tk}"; then
 757            CY_AC_LOAD_TKCONFIG
 758            CY_AC_PATH_TCLH
 759            CY_AC_PATH_TKH
 760            CY_AC_PATH_ITCLH
 761            CY_AC_PATH_ITKH
 762            CY_AC_PATH_TIXH
 763
 764            # now look for Itcl library stuff
 765
 766            CY_AC_PATH_ITCLCONFIG
 767            if test -z "${no_itcl}"; then
 768              CY_AC_LOAD_ITCLCONFIG
 769              case "${host}" in
 770              *-*-cygwin*)
 771                 itcldir=../itcl/itcl/win/
 772                 ;;
 773              *)
 774                 itcldir=../itcl/itcl/unix/
 775                 ;;
 776              esac
 777
 778
 779              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
 780              ITCL_DEPS="${itcldir}${ITCL_LIB_FILE}"
 781            fi
 782
 783
 784            # now look for Itk library stuff
 785            CY_AC_PATH_ITKCONFIG
 786            if test -z "${no_itcl}"; then
 787              CY_AC_LOAD_ITKCONFIG
 788
 789              case "${host}" in
 790                *-*-cygwin*)
 791                  itkdir=../itcl/itk/win/
 792                  ;;
 793                *)
 794                  itkdir=../itcl/itk/unix/
 795                  ;;
 796                esac
 797
 798              ITKLIB="${ITK_BUILD_LIB_SPEC}"
 799              ITK_DEPS="${itkdir}${ITK_LIB_FILE}"
 800            fi
 801
 802            # now look for Tix library stuff
 803            CY_AC_PATH_TIXCONFIG
 804            if test -z "${no_tix}"; then
 805              CY_AC_LOAD_TIXCONFIG
 806              TIXLIB="${TIX_BUILD_LIB_SPEC}"
 807              TIX_DEPS="${TIX_BUILD_LOCATION}/${TIX_LIB_FILE}"
 808            fi
 809
 810            ENABLE_CFLAGS="$ENABLE_CFLAGS -DGDBTK"
 811            # Tcl/Tk 8.1 require -fwritable strings.  I don't
 812            # know whether 8.2 will or not, but I bet it will.
 813            # I don't have to worry about 7.x since we don't support it.
 814            GDBTK_CFLAGS=""
 815            if test "$GCC" = "yes"; then
 816                if test "$TCL_VERSION" != "8.0" ; then
 817                    GDBTK_CFLAGS="-fwritable-strings"
 818                fi
 819            fi
 820
 821            # Include some libraries that Tcl and Tk want.
 822            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 823            CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(ITK_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 824            # Yes, the ordering seems wrong here.  But it isn't.
 825            # TK_LIBS is the list of libraries that need to be linked
 826            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 827            # were in LIBS then any link tests after this point would
 828            # try to include things like `$(LIBGUI)', which wouldn't work.
 829            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 830            CONFIG_SRCS="${CONFIG_SRCS} gdbtk/generic/gdbtk.c gdbtk/generic/gdbtk-cmds.c gdbtk/generic/gdbtk-hooks.c gdbtk/generic/gdbtk-varobj.c gdbtk/generic/gdbtk-wrapper.c"
 831            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o gdbtk-varobj.o gdbtk-wrapper.o"
 832            CONFIG_INITS="${CONFIG_INITS} gdbtk/generic/gdbtk.c gdbtk/generic/gdbtk-cmds.c gdbtk/generic/gdbtk-hooks.c gdbtk/generic/gdbtk-varobj.c gdbtk/generic/gdbtk-wrapper.c"
 833            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
 834            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
 835            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
 836            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
 837
 838            if test x$gdb_cv_os_cygwin = xyes; then
 839               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
 840               WIN32LDAPP="-Wl,--subsystem,console"
 841               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 842            fi
 843         fi
 844     fi
 845 fi
 846
 847 AC_SUBST(X_CFLAGS)
 848 AC_SUBST(X_LDFLAGS)
 849 AC_SUBST(X_LIBS)
 850 AC_SUBST(ITCLLIB)
 851 AC_SUBST(ITCL_DEPS)
 852 AC_SUBST(ITKLIB)
 853 AC_SUBST(ITK_DEPS)
 854 AC_SUBST(TIXLIB)
 855 AC_SUBST(TIX_DEPS)
 856 AC_SUBST(GDBTKLIBS)
 857 AC_SUBST(GDBTK_CFLAGS)
 858
 859 AC_PATH_X
 860
 861
 862 # Unlike the sim directory, whether a simulator is linked is controlled by
 863 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
 864 # This code just checks for a few cases where we'd like to ignore those
 865 # definitions, even when they're present in the '.mt' file.  These cases
 866 # are when --disable-sim is specified, or if the simulator directory is
 867 # not part of the soruce tree.
 868 #
 869 AC_ARG_ENABLE(sim,
 870 [  --enable-sim            Link gdb with simulator],
 871 [echo "enable_sim = $enable_sim";
 872  echo "enableval = ${enableval}";
 873  case "${enableval}" in
 874   yes) ignore_sim=false ;;
 875   no)  ignore_sim=true ;;
 876   *)   ignore_sim=false ;;
 877  esac],
 878 [ignore_sim=false])
 879
 880 if test ! -d "${srcdir}/../sim"; then
 881   ignore_sim=true
 882 fi
 883
 884 if test "${ignore_sim}" = "true"; then
 885     IGNORE_SIM="SIM="
 886     IGNORE_SIM_OBS="SIM_OBS="
 887 else
 888     IGNORE_SIM=""
 889     IGNORE_SIM_OBS=""
 890     AC_DEFINE(WITH_SIM)
 891 fi
 892 AC_SUBST(IGNORE_SIM)
 893 AC_SUBST(IGNORE_SIM_OBS)
 894
 895 AC_SUBST(ENABLE_CFLAGS)
 896
 897 AC_SUBST(CONFIG_OBS)
 898 AC_SUBST(CONFIG_DEPS)
 899 AC_SUBST(CONFIG_SRCS)
 900 AC_SUBST(CONFIG_INITS)
 901 AC_SUBST(CONFIG_ALL)
 902 AC_SUBST(CONFIG_CLEAN)
 903 AC_SUBST(CONFIG_INSTALL)
 904 AC_SUBST(CONFIG_UNINSTALL)
 905
 906 # Begin stuff to support --enable-shared
 907 AC_ARG_ENABLE(shared,
 908 [  --enable-shared         Use shared libraries],
 909 [case "${enableval}" in
 910   yes) shared=true ;;
 911   no)  shared=false ;;
 912   *) shared=true ;;
 913 esac])dnl
 914
 915 HLDFLAGS=
 916 HLDENV=
 917 # If we have shared libraries, try to set rpath reasonably.
 918 if test "${shared}" = "true"; then
 919   case "${host}" in
 920   *-*-hpux*)
 921     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 922     ;;
 923   *-*-irix5* | *-*-irix6*)
 924     HLDFLAGS='-Wl,-rpath,$(libdir)'
 925     ;;
 926   *-*-linux*aout*)
 927     ;;
 928   *-*-linux* | *-pc-linux-gnu*)
 929     HLDFLAGS='-Wl,-rpath,$(libdir)'
 930     ;;
 931   *-*-solaris*)
 932     HLDFLAGS='-R $(libdir)'
 933     ;;
 934   *-*-sysv4*)
 935     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 936     ;;
 937   esac
 938 fi
 939
 940 # On SunOS, if the linker supports the -rpath option, use it to
 941 # prevent ../bfd and ../opcodes from being included in the run time
 942 # search path.
 943 case "${host}" in
 944   *-*-sunos*)
 945     echo 'main () { }' > conftest.c
 946     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 947     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 948       :
 949     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 950       :
 951     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 952       :
 953     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 954       :
 955     elif test "${shared}" = "true"; then
 956       HLDFLAGS='-Wl,-rpath=$(libdir)'
 957     else
 958       HLDFLAGS='-Wl,-rpath='
 959     fi
 960     rm -f conftest.t conftest.c conftest
 961     ;;
 962 esac
 963 AC_SUBST(HLDFLAGS)
 964 AC_SUBST(HLDENV)
 965 # End stuff to support --enable-shared
 966
 967 # target_subdir is used by the testsuite to find the target libraries.
 968 target_subdir=
 969 if test "${host}" != "${target}"; then
 970     target_subdir="${target_alias}/"
 971 fi
 972 AC_SUBST(target_subdir)
 973
 974 frags=
 975 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 976 if test ! -f ${host_makefile_frag}; then
 977 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 978 fi
 979 frags="$frags $host_makefile_frag"
 980
 981 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 982 if test ! -f ${target_makefile_frag}; then
 983 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 984 fi
 985 frags="$frags $target_makefile_frag"
 986
 987 AC_SUBST_FILE(host_makefile_frag)
 988 AC_SUBST_FILE(target_makefile_frag)
 989 AC_SUBST(frags)
 990
 991 changequote(,)dnl
 992 hostfile=`sed -n '
 993 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 994 ' ${host_makefile_frag}`
 995
 996 targetfile=`sed -n '
 997 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 998 ' ${target_makefile_frag}`
 999
1000 GDB_MULTI_ARCH=`sed -n '
1001 s/GDB_MULTI_ARCH[       ]*=[    ]*\([^  ]*\)[   ]*/\1/p
1002 ' ${target_makefile_frag}`
1003
1004 # these really aren't orthogonal true/false values of the same condition,
1005 # but shells are slow enough that I like to reuse the test conditions
1006 # whenever possible
1007 if test "${target}" = "${host}"; then
1008 nativefile=`sed -n '
1009 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1010 ' ${host_makefile_frag}`
1011 # else
1012 # GDBserver is only useful in a "native" enviroment
1013 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
1014 fi
1015 changequote([,])
1016
1017 # New targets should just set gdb_multi_arch=yes in configure.tgt.
1018 # Old targets being converted can either do that or set GDB_MULTI_ARCH
1019 # in the target specific makefile frag.  Eventually gdb_multi_arch=yes
1020 # will be the default.
1021 if test x"${GDB_MULTI_ARCH}" = x ; then
1022     case "${gdb_multi_arch}" in
1023     yes ) GDB_MULTI_ARCH=GDB_MULTI_ARCH_PURE ;;
1024     no ) GDB_MULTI_ARCH=0 ;;
1025     0|1|2 ) GDB_MULTI_ARCH=${gdb_multi_arch} ;;
1026     esac
1027 fi
1028 if test x"${GDB_MULTI_ARCH}" != x ; then
1029     AC_DEFINE_UNQUOTED(GDB_MULTI_ARCH, ${GDB_MULTI_ARCH})
1030 fi
1031 # Warn the user when they use an old pratice
1032 case "${GDB_MULTI_ARCH}" in
1033     "" ) ;;
1034     0 | GDB_MULTI_ARCH_PARTIAL | 1 | GDB_MULTI_ARCH_TM | 2 )
1035         AC_MSG_WARN("GDB: Target is not pure multi-arch") ;;
1036     GDB_MULTI_ARCH_PURE )
1037         if test x"${targetfile}" != x ; then
1038             AC_MSG_WARN("GDB: Ingoring TM_FILE in ${target_makefile_frag}")
1039             targetfile=""
1040         fi ;;
1041     *)  AC_MSG_ERROR("GDB: Unknown GDB_MULTI_ARCH value ${GDB_MULTI_ARCH}");;
1042 esac
1043
1044
1045 SUBDIRS="doc testsuite nlm"
1046 if test "${enable_multi_ice}" = "yes"; then
1047   SUBDIRS="${SUBDIRS} multi-ice"
1048 fi
1049
1050 AC_SUBST(SUBDIRS)
1051
1052 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1053 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1054 # version.
1055
1056 files=
1057 links=
1058
1059 rm -f xm.h
1060 xm_h=""
1061 if test "${hostfile}" != ""; then
1062     xm_h=xm.h
1063     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1064     files="${files} ${GDB_XM_FILE}"
1065     links="${links} xm.h"
1066     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1067 fi
1068 AC_SUBST(xm_h)
1069
1070 rm -f tm.h
1071 tm_h=""
1072 if test "${targetfile}" != ""; then
1073     tm_h=tm.h
1074     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1075     files="${files} ${GDB_TM_FILE}"
1076     links="${links} tm.h"
1077     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1078 fi
1079 AC_SUBST(tm_h)
1080
1081 rm -f nm.h
1082 nm_h=""
1083 if test "${nativefile}" != ""; then
1084     nm_h=nm.h
1085     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1086     files="${files} ${GDB_NM_FILE}"
1087     links="${links} nm.h"
1088     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1089 fi
1090 AC_SUBST(nm_h)
1091
1092 AC_PROG_LN_S
1093
1094 AC_LINK_FILES($files, $links)
1095
1096 dnl Check for exe extension set on certain hosts (e.g. Win32)
1097 AC_EXEEXT
1098
1099 AC_CONFIG_SUBDIRS($configdirs)
1100 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1101 [
1102 dnl Autoconf doesn't provide a mechanism for modifying definitions
1103 dnl provided by makefile fragments.
1104 dnl
1105 if test "${nativefile}" = ""; then
1106 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
1107         < Makefile > Makefile.tem
1108 mv -f Makefile.tem Makefile
1109 fi
1110
1111 changequote(,)dnl
1112 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1113 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1114 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1115 mv -f Makefile.tmp Makefile
1116 changequote([,])dnl
1117
1118
1119 case x$CONFIG_HEADERS in
1120 xconfig.h:config.in)
1121 echo > stamp-h ;;
1122 esac
1123 ],
1124 [
1125 gdb_host_cpu=$gdb_host_cpu
1126 gdb_target_cpu=$gdb_target_cpu
1127 nativefile=$nativefile
1128 ])
1129
1130 exit 0