libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([xmalloc.c])
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  65 # rely on it - libiberty is built before texinfo.
  66 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  67 if test "x$MAKEINFO" = "x"; then
  68     MAKEINFO="@echo makeinfo missing; true"
  69     BUILD_INFO=
  70 else
  71     BUILD_INFO=info
  72     case "$MAKEINFO" in
  73       */missing\ makeinfo*)
  74         BUILD_INFO=
  75         AC_MSG_WARN([
  76 *** Makeinfo is missing. Info documentation will not be built.])
  77         ;;
  78       *)
  79         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  80           x*\ [[1-3]].* )
  81             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  82             BUILD_INFO=
  83             AC_MSG_WARN([
  84 *** Makeinfo is too old. Info documentation will not be built.])
  85           ;;
  86         esac
  87         ;;
  88     esac
  89 fi
  90 AC_SUBST(MAKEINFO)
  91 AC_SUBST(BUILD_INFO)
  92
  93 AC_CHECK_PROG(PERL, perl, perl, )
  94 if test x"$PERL" = x""; then
  95   HAVE_PERL='#'
  96 else
  97   HAVE_PERL=''
  98 fi
  99 AC_SUBST(HAVE_PERL)
 100
 101 AC_CANONICAL_HOST
 102
 103 dnl When we start using automake:
 104 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 105
 106 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 107 dnl to call AC_CHECK_PROG.
 108 AC_CHECK_TOOL(AR, ar)
 109 AC_CHECK_TOOL(RANLIB, ranlib, :)
 110
 111 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 112 # Add --enable-multilib to configure.
 113 # Default to --enable-multilib
 114 AC_ARG_ENABLE(multilib,
 115 [  --enable-multilib       build many library versions (default)],
 116 [case "$enableval" in
 117   yes) multilib=yes ;;
 118   no)  multilib=no ;;
 119   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 120  esac],
 121               [multilib=yes])
 122
 123 # Even if the default multilib is not a cross compilation,
 124 # it may be that some of the other multilibs are.
 125 if test $cross_compiling = no && test $multilib = yes \
 126    && test "x${with_multisubdir}" != x ; then
 127    cross_compiling=maybe
 128 fi
 129
 130 # We may wish to install the target headers somewhere.
 131 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 132 dnl install-libiberty is disabled by default
 133
 134 AC_ARG_ENABLE(install-libiberty,
 135 [  --enable-install-libiberty       Install headers and library for end users],
 136 enable_install_libiberty=$enableval,
 137 enable_install_libiberty=no)dnl
 138
 139 # Option parsed, now set things appropriately.
 140 case x"$enable_install_libiberty" in
 141   xyes|x)
 142     target_header_dir=libiberty
 143     ;;
 144   xno)
 145     target_header_dir=
 146     ;;
 147   *)
 148     # This could be sanity-checked in various ways...
 149     target_header_dir="${enable_install_libiberty}"
 150     ;;
 151 esac
 152 AC_MSG_RESULT($enable_install_libiberty)
 153 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 154
 155 GCC_NO_EXECUTABLES
 156 AC_PROG_CC
 157 AC_GNU_SOURCE
 158 AC_SYS_LARGEFILE
 159 AC_PROG_CPP_WERROR
 160
 161 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 162                           -Wstrict-prototypes \
 163                           -Wshadow=local], [ac_libiberty_warn_cflags])
 164 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 165
 166 AC_PROG_CC_C_O
 167 # autoconf is lame and doesn't give us any substitution variable for this.
 168 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 169   NO_MINUS_C_MINUS_O=yes
 170 else
 171   OUTPUT_OPTION='-o $@'
 172 fi
 173 AC_SUBST(NO_MINUS_C_MINUS_O)
 174 AC_SUBST(OUTPUT_OPTION)
 175
 176 AC_C_CONST
 177 AC_C_INLINE
 178 AC_C_BIGENDIAN
 179
 180 dnl When we start using libtool:
 181 dnl Default to a non shared library.  This may be overridden by the
 182 dnl configure option --enable-shared.
 183 dnl AM_DISABLE_SHARED
 184
 185 dnl When we start using libtool:
 186 dnl AM_PROG_LIBTOOL
 187
 188 dnl When we start using automake:
 189 dnl AM_CONFIG_HEADER(config.h:config.in)
 190 AC_CONFIG_HEADER(config.h:config.in)
 191
 192 dnl When we start using automake:
 193 dnl AM_MAINTAINER_MODE
 194 dnl AC_EXEEXT
 195
 196 dnl When we start using automake:
 197 dnl AM_PROG_INSTALL
 198 AC_PROG_INSTALL
 199
 200 # Don't build the shared library for build.
 201 if [[ -n "${with_build_subdir}" ]]; then
 202   enable_shared=no
 203 fi
 204
 205 frag=
 206 case "${host}" in
 207   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 208                         frag=mh-aix ;;
 209   *-*-cxux7*)           frag=mh-cxux7 ;;
 210   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 211   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 212   i370-*-opened*)       frag=mh-openedition ;;
 213   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 214 esac
 215
 216 if [[ -n "${frag}" ]]; then
 217   frag=${libiberty_topdir}/libiberty/config/$frag
 218 fi
 219
 220 GCC_PICFLAG
 221
 222 # If they didn't specify --enable-shared, don't generate shared libs.
 223 case "${enable_shared}" in
 224   yes) shared=yes ;;
 225   no) shared=no ;;
 226   "") shared=no ;;
 227   *) shared=yes ;;
 228 esac
 229
 230 # ...unless --enable-host-shared was passed from top-level config:
 231 if [[ "${enable_host_shared}" = "yes" ]]; then
 232   shared=yes
 233 fi
 234
 235 if [[ "${shared}" != "yes" ]]; then
 236   PICFLAG=
 237 fi
 238 AC_SUBST(PICFLAG)
 239
 240 NOASANFLAG=
 241 case " ${CFLAGS} " in
 242   *\ -fsanitize=address\ *) NOASANFLAG=-fno-sanitize=address ;;
 243 esac
 244 AC_SUBST(NOASANFLAG)
 245
 246 echo "# Warning: this fragment is automatically generated" > temp-frag
 247
 248 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 249   echo "Appending ${frag} to xhost-mkfrag"
 250   echo "# Following fragment copied from ${frag}" >> temp-frag
 251   cat ${frag} >> temp-frag
 252 fi
 253
 254 # record if we want to build shared libs.
 255 if [[ "${shared}" = "yes" ]]; then
 256   echo enable_shared = yes >> temp-frag
 257 else
 258   echo enable_shared = no >> temp-frag
 259 fi
 260
 261 frag=xhost-mkfrag
 262 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 263
 264 host_makefile_frag=${frag}
 265 AC_SUBST_FILE(host_makefile_frag)
 266
 267 # It's OK to check for header files.  Although the compiler may not be
 268 # able to link anything, it had better be able to at least compile
 269 # something.
 270 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 271 AC_HEADER_SYS_WAIT
 272 AC_HEADER_TIME
 273
 274 libiberty_AC_DECLARE_ERRNO
 275
 276 # Determine sizes of some types.
 277 AC_CHECK_SIZEOF([int])
 278 AC_CHECK_SIZEOF([long])
 279 AC_CHECK_SIZEOF([size_t])
 280
 281 # Check for presense of long long
 282 AC_CHECK_TYPE([long long],
 283   [AC_DEFINE(HAVE_LONG_LONG, 1, [Define if you have the `long long' type.]) AC_CHECK_SIZEOF([long long])],
 284   [])
 285
 286 # Look for a 64-bit type.
 287 AC_MSG_CHECKING([for a 64-bit type])
 288 AC_CACHE_VAL(liberty_cv_uint64,
 289 [AC_TRY_COMPILE(
 290 [#ifdef HAVE_STDINT_H
 291 #include <stdint.h>
 292 #endif],
 293 [extern uint64_t foo;],
 294 liberty_cv_uint64=uint64_t,
 295 [AC_TRY_COMPILE(
 296 [#ifdef HAVE_LIMITS_H
 297 #include <limits.h>
 298 #endif
 299 #ifndef CHAR_BIT
 300 #define CHAR_BIT 8
 301 #endif],
 302 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 303 liberty_cv_uint64="unsigned long",
 304 [AC_TRY_COMPILE(
 305 [#ifdef HAVE_LIMITS_H
 306 #include <limits.h>
 307 #endif
 308 #ifndef CHAR_BIT
 309 #define CHAR_BIT 8
 310 #endif],
 311 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 312 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 313 AC_MSG_RESULT($liberty_cv_uint64)
 314 if test "$liberty_cv_uint64" != none; then
 315   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 316                      [Define to an unsigned 64-bit type available in the compiler.])
 317 fi
 318
 319 AC_TYPE_INTPTR_T
 320 AC_TYPE_UINTPTR_T
 321 AC_TYPE_SSIZE_T
 322
 323 # Given the above check, we always have uintptr_t or a fallback
 324 # definition.  So define HAVE_UINTPTR_T in case any imported code
 325 # relies on it.
 326 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 327
 328 AC_TYPE_PID_T
 329
 330 # This is the list of functions which libiberty will provide if they
 331 # are not available on the host.
 332
 333 funcs="asprintf"
 334 funcs="$funcs atexit"
 335 funcs="$funcs basename"
 336 funcs="$funcs bcmp"
 337 funcs="$funcs bcopy"
 338 funcs="$funcs bsearch"
 339 funcs="$funcs bzero"
 340 funcs="$funcs calloc"
 341 funcs="$funcs clock"
 342 funcs="$funcs ffs"
 343 funcs="$funcs getcwd"
 344 funcs="$funcs getpagesize"
 345 funcs="$funcs gettimeofday"
 346 funcs="$funcs index"
 347 funcs="$funcs insque"
 348 funcs="$funcs memchr"
 349 funcs="$funcs memcmp"
 350 funcs="$funcs memcpy"
 351 funcs="$funcs memmem"
 352 funcs="$funcs memmove"
 353 funcs="$funcs mempcpy"
 354 funcs="$funcs memset"
 355 funcs="$funcs mkstemps"
 356 funcs="$funcs putenv"
 357 funcs="$funcs random"
 358 funcs="$funcs rename"
 359 funcs="$funcs rindex"
 360 funcs="$funcs setenv"
 361 funcs="$funcs snprintf"
 362 funcs="$funcs sigsetmask"
 363 funcs="$funcs stpcpy"
 364 funcs="$funcs stpncpy"
 365 funcs="$funcs strcasecmp"
 366 funcs="$funcs strchr"
 367 funcs="$funcs strdup"
 368 funcs="$funcs strncasecmp"
 369 funcs="$funcs strndup"
 370 funcs="$funcs strnlen"
 371 funcs="$funcs strrchr"
 372 funcs="$funcs strstr"
 373 funcs="$funcs strtod"
 374 funcs="$funcs strtol"
 375 funcs="$funcs strtoul"
 376 funcs="$funcs strtoll"
 377 funcs="$funcs strtoull"
 378 funcs="$funcs strverscmp"
 379 funcs="$funcs tmpnam"
 380 funcs="$funcs vasprintf"
 381 funcs="$funcs vfprintf"
 382 funcs="$funcs vprintf"
 383 funcs="$funcs vsnprintf"
 384 funcs="$funcs vsprintf"
 385 funcs="$funcs waitpid"
 386 funcs="$funcs setproctitle"
 387
 388 # Also in the old function.def file: alloca, vfork, getopt.
 389
 390 vars="sys_errlist sys_nerr sys_siglist"
 391
 392 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 393  getsysinfo gettimeofday on_exit pipe2 psignal pstat_getdynamic pstat_getstatic \
 394  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 395  sysmp table times wait3 wait4"
 396
 397 # These are neither executed nor required, but they help keep
 398 # autoheader happy without adding a bunch of text to acconfig.h.
 399 if test "x" = "y"; then
 400   AC_CHECK_FUNCS(asprintf atexit \
 401     basename bcmp bcopy bsearch bzero \
 402     calloc canonicalize_file_name clock \
 403     dup3 \
 404     ffs __fsetlocking \
 405     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 406     index insque \
 407     memchr memcmp memcpy memmem memmove memset mkstemps \
 408     on_exit \
 409     pipe2 psignal pstat_getdynamic pstat_getstatic putenv \
 410     random realpath rename rindex \
 411     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 412      stpcpy stpncpy strcasecmp strchr strdup \
 413      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 414      strtol strtoul strtoll strtoull strverscmp sysconf sysctl sysmp \
 415     table times tmpnam \
 416     vasprintf vfprintf vprintf vsprintf \
 417     wait3 wait4 waitpid)
 418   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf, strtol, strtoul, strtoll, strtoull, strnlen])
 419   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 420   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 421   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 422 fi
 423
 424 # For each of these functions, if the host does not provide the
 425 # function we want to put FN.o in LIBOBJS, and if the host does
 426 # provide the function, we want to define HAVE_FN in config.h.
 427
 428 setobjs=
 429 CHECK=
 430 if test -n "${with_target_subdir}"; then
 431
 432   # We are being configured as a target library.  AC_REPLACE_FUNCS
 433   # may not work correctly, because the compiler may not be able to
 434   # link executables.  Note that we may still be being configured
 435   # native.
 436
 437   # If we are being configured for newlib, we know which functions
 438   # newlib provide and which ones we will be expected to provide.
 439
 440   if test "x${with_newlib}" = "xyes"; then
 441     AC_LIBOBJ([asprintf])
 442     AC_LIBOBJ([basename])
 443     AC_LIBOBJ([insque])
 444     AC_LIBOBJ([random])
 445     AC_LIBOBJ([strdup])
 446     AC_LIBOBJ([vasprintf])
 447
 448     for f in $funcs; do
 449       case "$f" in
 450         asprintf | basename | insque | random | strdup | vasprintf)
 451           ;;
 452         *)
 453           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 454           AC_DEFINE_UNQUOTED($n)
 455           ;;
 456       esac
 457     done
 458
 459     # newlib doesnt provide any of the variables in $vars, so we
 460     # dont have to check them here.
 461
 462     # Of the functions in $checkfuncs, newlib only has strerror.
 463     AC_DEFINE(HAVE_STRERROR)
 464
 465     setobjs=yes
 466
 467   fi
 468
 469   # If we are being configured for Mingw, we know which functions
 470   # Mingw provides and which ones we will be expected to provide.
 471
 472   case "${host}" in
 473   *-*-mingw*)
 474     AC_LIBOBJ([asprintf])
 475     AC_LIBOBJ([basename])
 476     AC_LIBOBJ([bcmp])
 477     AC_LIBOBJ([bcopy])
 478     AC_LIBOBJ([bzero])
 479     AC_LIBOBJ([clock])
 480     AC_LIBOBJ([ffs])
 481     AC_LIBOBJ([getpagesize])
 482     AC_LIBOBJ([index])
 483     AC_LIBOBJ([insque])
 484     AC_LIBOBJ([mempcpy])
 485     AC_LIBOBJ([mkstemps])
 486     AC_LIBOBJ([random])
 487     AC_LIBOBJ([rindex])
 488     AC_LIBOBJ([sigsetmask])
 489     AC_LIBOBJ([stpcpy])
 490     AC_LIBOBJ([stpncpy])
 491     AC_LIBOBJ([strndup])
 492     AC_LIBOBJ([strnlen])
 493     AC_LIBOBJ([strverscmp])
 494     AC_LIBOBJ([vasprintf])
 495     AC_LIBOBJ([waitpid])
 496
 497     for f in $funcs; do
 498       case "$f" in
 499         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 500           ;;
 501         *)
 502           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 503           AC_DEFINE_UNQUOTED($n)
 504           ;;
 505       esac
 506     done
 507
 508     # Mingw doesnt provide any of the variables in $vars, so we
 509     # dont have to check them here.
 510
 511     # Of the functions in $checkfuncs, Mingw only has strerror.
 512     AC_DEFINE(HAVE_STRERROR)
 513
 514     setobjs=yes
 515     ;;
 516
 517   *-*-msdosdjgpp)
 518     AC_LIBOBJ([vasprintf])
 519     AC_LIBOBJ([vsnprintf])
 520     AC_LIBOBJ([snprintf])
 521     AC_LIBOBJ([asprintf])
 522
 523     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 524              getcwd getpagesize getrusage gettimeofday \
 525              index insque memchr memcmp memcpy memmove memset psignal \
 526              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 527              strchr strdup strerror strncasecmp strrchr strstr strtod \
 528              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 529              vsprintf waitpid
 530     do
 531       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 532       AC_DEFINE_UNQUOTED($n)
 533     done
 534
 535
 536     setobjs=yes
 537     ;;
 538
 539   esac
 540
 541 else
 542
 543    # Not a target library, so we set things up to run the test suite.
 544    CHECK=really-check
 545
 546 fi
 547
 548 AC_SUBST(CHECK)
 549 AC_SUBST(target_header_dir)
 550
 551 case "${host}" in
 552   *-*-cygwin* | *-*-mingw*)
 553     AC_DEFINE(HAVE_SYS_ERRLIST)
 554     AC_DEFINE(HAVE_SYS_NERR)
 555     ;;
 556 esac
 557
 558 if test -z "${setobjs}"; then
 559   case "${host}" in
 560
 561   *-*-vxworks*)
 562     # Handle VxWorks configuration specially, since on VxWorks the
 563     # libraries are actually on the target board, not in the file
 564     # system.
 565     AC_LIBOBJ([basename])
 566     AC_LIBOBJ([getpagesize])
 567     AC_LIBOBJ([insque])
 568     AC_LIBOBJ([random])
 569     AC_LIBOBJ([strcasecmp])
 570     AC_LIBOBJ([strncasecmp])
 571     AC_LIBOBJ([strdup])
 572     AC_LIBOBJ([vfork])
 573     AC_LIBOBJ([waitpid])
 574     AC_LIBOBJ([vasprintf])
 575     for f in $funcs; do
 576       case "$f" in
 577         basename | getpagesize | insque | random | strcasecmp)
 578           ;;
 579         strncasecmp | strdup | vfork | waitpid | vasprintf)
 580           ;;
 581         *)
 582           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 583           AC_DEFINE_UNQUOTED($n)
 584           ;;
 585       esac
 586     done
 587
 588     # VxWorks doesn't provide any of the variables in $vars, so we
 589     # don't have to check them here.
 590
 591     # Of the functions in $checkfuncs, VxWorks only has strerror.
 592     AC_DEFINE(HAVE_STRERROR)
 593
 594     setobjs=yes
 595     ;;
 596
 597   esac
 598 fi
 599
 600 if test -z "${setobjs}"; then
 601
 602   case "${host}" in
 603
 604   *-*-android*)
 605     # On android, getpagesize is defined in unistd.h as a static inline
 606     # function, which AC_CHECK_FUNCS does not handle properly.
 607     ac_cv_func_getpagesize=yes
 608     ;;
 609
 610   *-*-mingw32*)
 611     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 612     # macros, so the test below won't find them.
 613     libiberty_cv_var_sys_nerr=yes
 614     libiberty_cv_var_sys_errlist=yes
 615     ;;
 616
 617   *-*-msdosdjgpp*)
 618     # vfork and fork are stubs.
 619     ac_cv_func_vfork_works=no
 620     ;;
 621
 622   *-*-uwin*)
 623     # Under some versions of uwin, vfork is notoriously buggy and the test
 624     # can hang configure; on other versions, vfork exists just as a stub.
 625     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 626     ac_cv_func_vfork_works=no
 627     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 628     # macros (actually, these are imported from a DLL, but the end effect
 629     # is the same), so the test below won't find them.
 630     libiberty_cv_var_sys_nerr=yes
 631     libiberty_cv_var_sys_errlist=yes
 632     ;;
 633
 634   *-*-*vms*)
 635     # Under VMS, vfork works very different than on Unix. The standard test
 636     # won't work, and it isn't easily adaptable. It makes more sense to
 637     # just force it.
 638     ac_cv_func_vfork_works=yes
 639     ;;
 640
 641   esac
 642
 643   # We haven't set the list of objects yet.  Use the standard autoconf
 644   # tests.  This will only work if the compiler works.
 645   AC_ISC_POSIX
 646   AC_REPLACE_FUNCS($funcs)
 647   libiberty_AC_FUNC_C_ALLOCA
 648   AC_FUNC_FORK
 649   if test $ac_cv_func_vfork_works = no; then
 650     AC_LIBOBJ([vfork])
 651   fi
 652   # We only need _doprnt if we might use it to implement v*printf.
 653   if test $ac_cv_func_vprintf != yes \
 654      || test $ac_cv_func_vfprintf != yes \
 655      || test $ac_cv_func_vsprintf != yes; then
 656     AC_REPLACE_FUNCS(_doprnt)
 657   else
 658     AC_CHECK_FUNCS(_doprnt)
 659   fi
 660
 661   for v in $vars; do
 662     AC_MSG_CHECKING([for $v])
 663     AC_CACHE_VAL(libiberty_cv_var_$v,
 664       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 665                       [eval "libiberty_cv_var_$v=yes"],
 666                       [eval "libiberty_cv_var_$v=no"])])
 667     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 668       AC_MSG_RESULT(yes)
 669       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 670       AC_DEFINE_UNQUOTED($n)
 671     else
 672       AC_MSG_RESULT(no)
 673     fi
 674   done
 675
 676   # special check for _system_configuration because AIX <4.3.2 do not
 677   # contain the `physmem' member.
 678   AC_MSG_CHECKING([for external symbol _system_configuration])
 679   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 680                         [[double x = _system_configuration.physmem;]])],
 681     [AC_MSG_RESULT([yes])
 682     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 683               [Define if you have the _system_configuration variable.])],
 684     [AC_MSG_RESULT([no])])
 685
 686   AC_CHECK_FUNCS($checkfuncs)
 687   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 688   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 689   AC_CHECK_DECLS([strtol, strtoul, strtoll, strtoull])
 690   AC_CHECK_DECLS([strverscmp])
 691   AC_CHECK_DECLS([strnlen])
 692   libiberty_NEED_DECLARATION(canonicalize_file_name)
 693 fi
 694
 695 # Figure out which version of pexecute to use.
 696 case "${host}" in
 697      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 698      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 699      *-*-msdos*)                pexecute=pex-msdos  ;;
 700      *)                         pexecute=pex-unix   ;;
 701 esac
 702 AC_SUBST(pexecute)
 703
 704 libiberty_AC_FUNC_STRNCMP
 705
 706 # Install a library built with a cross compiler in $(tooldir) rather
 707 # than $(libdir).
 708 if test -z "${with_cross_host}"; then
 709   INSTALL_DEST=libdir
 710 else
 711   INSTALL_DEST=tooldir
 712 fi
 713 AC_SUBST(INSTALL_DEST)
 714
 715 m4_pattern_allow(LIBOBJS)
 716 L=""
 717 for l in x $LIBOBJS; do
 718   case $l in
 719     x) ;;
 720     *) L="$L ./$l" ;;
 721   esac
 722 done
 723 LIBOBJS="$L"
 724
 725 dnl Required by html and install-html
 726 AC_SUBST(datarootdir)
 727 AC_SUBST(docdir)
 728 AC_SUBST(htmldir)
 729
 730 # We need multilib support, but only if configuring for the target.
 731 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 732 AC_CONFIG_COMMANDS([default],
 733   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 734 if test -n "$CONFIG_FILES"; then
 735   if test -n "${with_target_subdir}"; then
 736     # FIXME: We shouldn't need to set ac_file
 737     ac_file=Makefile
 738     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 739     . ${libiberty_topdir}/config-ml.in
 740   fi
 741 fi]],
 742 [[srcdir=${srcdir}
 743 host=${host}
 744 target=${target}
 745 with_target_subdir=${with_target_subdir}
 746 with_multisubdir=${with_multisubdir}
 747 ac_configure_args="--enable-multilib ${ac_configure_args}"
 748 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 749 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 750 libiberty_topdir=${libiberty_topdir}
 751 ]])
 752 AC_OUTPUT