gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_GNU_SOURCE
  31 AC_SYS_LARGEFILE
  32
  33 AC_CANONICAL_SYSTEM
  34
  35 AC_PROG_INSTALL
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_PROG_RANLIB
  38
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 AC_HEADER_STDC
  46
  47 # Set the 'development' global.
  48 . $srcdir/../../bfd/development.sh
  49
  50 # Enable -lmcheck by default (it provides cheap-enough memory
  51 # mangling), but turn it off for releases.
  52 if $development; then
  53   libmcheck_default=yes
  54 else
  55   libmcheck_default=no
  56 fi
  57 GDB_AC_LIBMCHECK(${libmcheck_default})
  58
  59 if $development; then
  60   srv_selftest_objs="common/selftest.o"
  61   AC_DEFINE(GDB_SELF_TEST, 1,
  62             [Define if self-testing features should be enabled])
  63 fi
  64
  65 ACX_NONCANONICAL_TARGET
  66 ACX_NONCANONICAL_HOST
  67
  68 # Dependency checking.
  69 ZW_CREATE_DEPDIR
  70
  71 # Create sub-directories for objects and dependencies.
  72 CONFIG_SRC_SUBDIR="arch common"
  73 AC_SUBST(CONFIG_SRC_SUBDIR)
  74
  75 AC_CONFIG_COMMANDS([gdbdepdir],[
  76   for subdir in ${CONFIG_SRC_SUBDIR}
  77   do
  78       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  79   done],
  80   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  81
  82 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  83
  84 gnulib_extra_configure_args=
  85 # If large-file support is disabled, make sure gnulib does the same.
  86 if test "$enable_largefile" = no; then
  87 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  88 fi
  89
  90 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  91 # to find the the source subdir to be configured directly under
  92 # gdbserver/.  We need to build gnulib under some other directory not
  93 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  94 # build it in the same directory, when building in the source dir.
  95 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  96                   ["$gnulib_extra_configure_args"])
  97
  98 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  99
 100 AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl
 101                  proc_service.h sys/procfs.h linux/elf.h dnl
 102                  fcntl.h signal.h sys/file.h dnl
 103                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
 104                  netinet/tcp.h arpa/inet.h)
 105 AC_FUNC_FORK
 106 AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns)
 107
 108 GDB_AC_COMMON
 109
 110 # Check the return and argument types of ptrace.
 111 GDB_AC_PTRACE
 112
 113 # Check for UST
 114 ustlibs=""
 115 ustinc=""
 116
 117 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 118                           Equivalent to --with-ust-include=PATH/include
 119                           plus --with-ust-lib=PATH/lib])
 120 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 121 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 122
 123 case $with_ust in
 124   no)
 125     ustlibs=
 126     ustinc=
 127     ;;
 128   "" | yes)
 129     ustlibs=" -lust "
 130     ustinc=""
 131     ;;
 132   *)
 133     ustlibs="-L$with_ust/lib -lust"
 134     ustinc="-I$with_ust/include "
 135     ;;
 136 esac
 137 if test "x$with_ust_include" != x; then
 138   ustinc="-I$with_ust_include "
 139 fi
 140 if test "x$with_ust_lib" != x; then
 141   ustlibs="-L$with_ust_lib -lust"
 142 fi
 143
 144 if test "x$with_ust" != "xno"; then
 145   saved_CFLAGS="$CFLAGS"
 146   CFLAGS="$CFLAGS $ustinc"
 147   AC_MSG_CHECKING([for ust])
 148   AC_TRY_COMPILE([
 149 #define CONFIG_UST_GDB_INTEGRATION
 150 #include <ust/ust.h>
 151   ],[],
 152   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 153   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 154   CFLAGS="$saved_CFLAGS"
 155 fi
 156
 157 # Flags needed for UST
 158 AC_SUBST(ustlibs)
 159 AC_SUBST(ustinc)
 160
 161 AM_GDB_WARNINGS
 162 dnl The codebase isn't clean yet with this flag.
 163 case " $WARN_CFLAGS " in
 164 *" -Wmissing-prototypes "*)
 165   WARN_CFLAGS="$WARN_CFLAGS -Wno-missing-prototypes"
 166   ;;
 167 esac
 168
 169 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 170 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 171 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 172 dnl augment LIBS.
 173 old_LIBS="$LIBS"
 174 LIBS="$LIBS -ldl"
 175 AC_CHECK_FUNCS(dladdr)
 176 LIBS="$old_LIBS"
 177
 178 libiberty_INIT
 179
 180 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 181
 182 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 183
 184 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
 185 # Older amd64 Linux's don't have the fs_base and gs_base members of
 186 # `struct user_regs_struct'.
 187 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
 188      [], [], [#include <sys/types.h>
 189 #include <sys/user.h>])
 190
 191
 192 AC_CHECK_TYPES(socklen_t, [], [],
 193 [#include <sys/types.h>
 194 #include <sys/socket.h>
 195 ])
 196
 197 case "${target}" in
 198   *-android*)
 199     # Starting with NDK version 9, <elf.h> actually includes definitions
 200     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 201     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 202     # leading to conflicts with the defintions from <linux/elf.h>.
 203     # This makes it impossible for us to include both <elf.h> and
 204     # <linux/elf.h>, which means that, in practice, we do not have
 205     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 206     # Therefore, do not try to auto-detect availability, as it would
 207     # get it wrong on this platform.
 208     ;;
 209   *)
 210     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 211     #include <elf.h>
 212     )
 213 esac
 214
 215 ACX_PKGVERSION([GDB])
 216 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 217 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 218 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 219
 220 # Check for various supplementary target information (beyond the
 221 # triplet) which might affect the choices in configure.srv.
 222 case "${target}" in
 223 changequote(,)dnl
 224   i[34567]86-*-linux*)
 225 changequote([,])dnl
 226     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 227                    [save_CPPFLAGS="$CPPFLAGS"
 228                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 229                     AC_EGREP_CPP([got it], [
 230 #if __x86_64__
 231 got it
 232 #endif
 233                  ], [gdb_cv_i386_is_x86_64=yes],
 234                     [gdb_cv_i386_is_x86_64=no])
 235                     CPPFLAGS="$save_CPPFLAGS"])
 236     ;;
 237
 238   x86_64-*-linux*)
 239     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 240                    [save_CPPFLAGS="$CPPFLAGS"
 241                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 242                     AC_EGREP_CPP([got it], [
 243 #if __x86_64__ && __ILP32__
 244 got it
 245 #endif
 246                  ], [gdb_cv_x86_is_x32=yes],
 247                     [gdb_cv_x86_is_x32=no])
 248                     CPPFLAGS="$save_CPPFLAGS"])
 249     ;;
 250
 251   m68k-*-*)
 252     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 253                    [save_CPPFLAGS="$CPPFLAGS"
 254                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 255                     AC_EGREP_CPP([got it], [
 256 #ifdef __mcoldfire__
 257 got it
 258 #endif
 259                  ], [gdb_cv_m68k_is_coldfire=yes],
 260                     [gdb_cv_m68k_is_coldfire=no])
 261                     CPPFLAGS="$save_CPPFLAGS"])
 262     ;;
 263 esac
 264
 265 . ${srcdir}/configure.srv
 266
 267 # Add in the common host objects.
 268 . ${srcdir}/../common/common.host
 269 srv_host_obs="$common_host_obs"
 270
 271 if test "${srv_mingwce}" = "yes"; then
 272   LIBS="$LIBS -lws2"
 273 elif test "${srv_mingw}" = "yes"; then
 274   LIBS="$LIBS -lws2_32"
 275 elif test "${srv_qnx}" = "yes"; then
 276   LIBS="$LIBS -lsocket"
 277 elif test "${srv_lynxos}" = "yes"; then
 278   LIBS="$LIBS -lnetinet"
 279 fi
 280
 281 if test "${srv_mingw}" = "yes"; then
 282   AC_DEFINE(USE_WIN32API, 1,
 283             [Define if we should use the Windows API, instead of the
 284              POSIX API.  On Windows, we use the Windows API when
 285              building for MinGW, but the POSIX API when building
 286              for Cygwin.])
 287 fi
 288
 289 if test "${srv_linux_usrregs}" = "yes"; then
 290   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 291             [Define if the target supports PTRACE_PEEKUSR for register ]
 292             [access.])
 293 fi
 294
 295 if test "${srv_linux_regsets}" = "yes"; then
 296   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 297             [Define if the target supports register sets.])
 298
 299   AC_MSG_CHECKING(for PTRACE_GETREGS)
 300   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 301   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 302                   [PTRACE_GETREGS;],
 303                   [gdbsrv_cv_have_ptrace_getregs=yes],
 304                   [gdbsrv_cv_have_ptrace_getregs=no])])
 305   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 306   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 307     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 308               [Define if the target supports PTRACE_GETREGS for register ]
 309               [access.])
 310   fi
 311
 312   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 313   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 314   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 315                   [PTRACE_GETFPXREGS;],
 316                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 317                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 318   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 319   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 320     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 321               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 322               [register access.])
 323   fi
 324 fi
 325
 326 if test "${srv_linux_btrace}" = "yes"; then
 327   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 328             [Define if the target supports branch tracing.])
 329 fi
 330
 331 if test "$ac_cv_header_sys_procfs_h" = yes; then
 332   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 333   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 334   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 335   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 336   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 337 fi
 338
 339 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 340 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 341   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 342 fi
 343
 344 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 345 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 346   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 347 fi
 348
 349 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 350 dnl needs it (and gdbreplay doesn't).
 351 old_LIBS="$LIBS"
 352 AC_CHECK_LIB(dl, dlopen)
 353 LIBS="$old_LIBS"
 354
 355 srv_thread_depfiles=
 356 srv_libs=
 357
 358 if test "$srv_linux_thread_db" = "yes"; then
 359   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 360     srv_libs="-ldl"
 361     AC_MSG_CHECKING(for the dynamic export flag)
 362     old_LDFLAGS="$LDFLAGS"
 363     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 364     # supported there.
 365     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 366     LDFLAGS="$LDFLAGS $RDYNAMIC"
 367     AC_TRY_LINK([], [],
 368                 [found="-Wl,--dynamic-list"
 369                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 370                 [RDYNAMIC="-rdynamic"
 371                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 372                  AC_TRY_LINK([], [],
 373                              [found="-rdynamic"],
 374                              [found="no"
 375                               RDYNAMIC=""])])
 376     AC_SUBST(RDYNAMIC)
 377     LDFLAGS="$old_LDFLAGS"
 378     AC_MSG_RESULT($found)
 379   else
 380     srv_libs="-lthread_db"
 381   fi
 382
 383   srv_thread_depfiles="thread-db.o proc-service.o"
 384   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 385   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 386   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 387                   [gdbsrv_cv_have_td_version=yes],
 388                   [gdbsrv_cv_have_td_version=no])])
 389   if test $gdbsrv_cv_have_td_version = yes; then
 390     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 391   fi
 392 fi
 393
 394 AC_ARG_WITH(libthread-db,
 395 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 396 [srv_libthread_db_path="${withval}"
 397   srv_libs="$srv_libthread_db_path"
 398 ])
 399
 400 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 401   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 402 fi
 403
 404 if test "$srv_xmlfiles" != ""; then
 405   srv_xmlbuiltin="xml-builtin.o"
 406   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 407
 408   tmp_xmlfiles=$srv_xmlfiles
 409   srv_xmlfiles=""
 410   for f in $tmp_xmlfiles; do
 411     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 412   done
 413 fi
 414
 415 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs $srv_selftest_objs"
 416 GDBSERVER_LIBS="$srv_libs"
 417
 418 dnl Check whether the target supports __sync_*_compare_and_swap.
 419 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 420                 gdbsrv_cv_have_sync_builtins, [
 421 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 422                 gdbsrv_cv_have_sync_builtins=yes,
 423                 gdbsrv_cv_have_sync_builtins=no)])
 424 if test $gdbsrv_cv_have_sync_builtins = yes; then
 425   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 426     [Define to 1 if the target supports __sync_*_compare_and_swap])
 427 fi
 428
 429 dnl Check for -fvisibility=hidden support in the compiler.
 430 saved_cflags="$CFLAGS"
 431 CFLAGS="$CFLAGS -fvisibility=hidden"
 432 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 433                         [gdbsrv_cv_have_visibility_hidden=yes],
 434                         [gdbsrv_cv_have_visibility_hidden=no])
 435 CFLAGS="$saved_cflags"
 436
 437 dnl Check if we can disable the virtual address space randomization.
 438 dnl The functionality of setarch -R.
 439 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 440 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 441 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 442 #       define ADDR_NO_RANDOMIZE 0x0040000
 443 #      endif
 444        /* Test the flag could be set and stays set.  */
 445        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 446        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 447            return 1])])
 448 AC_RUN_IFELSE([PERSONALITY_TEST],
 449               [gdbsrv_cv_have_personality=true],
 450               [gdbsrv_cv_have_personality=false],
 451               [AC_LINK_IFELSE([PERSONALITY_TEST],
 452                               [gdbsrv_cv_have_personality=true],
 453                               [gdbsrv_cv_have_personality=false])])
 454 if $gdbsrv_cv_have_personality
 455 then
 456     AC_DEFINE([HAVE_PERSONALITY], 1,
 457               [Define if you support the personality syscall.])
 458 fi
 459
 460
 461 IPA_DEPFILES=""
 462 extra_libraries=""
 463
 464 # check whether to enable the inprocess agent
 465 if test "$ipa_obj" != "" \
 466    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 467    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 468    have_ipa=true
 469 else
 470    have_ipa=false
 471 fi
 472
 473 AC_ARG_ENABLE(inprocess-agent,
 474 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 475 [case "$enableval" in
 476   yes) want_ipa=true ;;
 477   no) want_ipa=false ;;
 478   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 479 esac],
 480 [want_ipa=$have_ipa])
 481
 482 if $want_ipa ; then
 483    if $have_ipa ; then
 484      IPA_DEPFILES="$ipa_obj"
 485      extra_libraries="$extra_libraries libinproctrace.so"
 486    else
 487      AC_MSG_ERROR([inprocess agent not supported for this target])
 488    fi
 489 fi
 490
 491 AC_SUBST(GDBSERVER_DEPFILES)
 492 AC_SUBST(GDBSERVER_LIBS)
 493 AC_SUBST(srv_xmlbuiltin)
 494 AC_SUBST(srv_xmlfiles)
 495 AC_SUBST(IPA_DEPFILES)
 496 AC_SUBST(extra_libraries)
 497
 498 GNULIB=build-gnulib-gdbserver/import
 499
 500 GNULIB_STDINT_H=
 501 if test x"$STDINT_H" != x; then
 502   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 503 fi
 504 AC_SUBST(GNULIB_STDINT_H)
 505
 506 AC_CONFIG_FILES([Makefile],
 507 [case x$CONFIG_HEADERS in
 508 xconfig.h:config.in)
 509 echo > stamp-h ;;
 510 esac
 511 ])
 512
 513 AC_OUTPUT