gdb/testsuite/gdb.arch/ftrace-insn-reloc.exp

   1 # Copyright 2015-2024 Free Software Foundation, Inc.
   2 # This program is free software; you can redistribute it and/or modify
   3 # it under the terms of the GNU General Public License as published by
   4 # the Free Software Foundation; either version 3 of the License, or
   5 # (at your option) any later version.
   6 #
   7 # This program is distributed in the hope that it will be useful,
   8 # but WITHOUT ANY WARRANTY; without even the implied warranty of
   9 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10 # GNU General Public License for more details.
  11 #
  12 # You should have received a copy of the GNU General Public License
  13 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14
  15 load_lib "trace-support.exp"
  16
  17 standard_testfile insn-reloc.c
  18
  19 # Some targets have leading underscores on assembly symbols.
  20 set additional_flags [gdb_target_symbol_prefix_flags]
  21
  22 if [prepare_for_testing "failed to prepare" $testfile-no-ipa $srcfile \
  23         [list debug $additional_flags]] {
  24     return -1
  25 }
  26
  27 if ![runto_main] {
  28     return -1
  29 }
  30
  31 if ![gdb_target_supports_trace] {
  32     unsupported "target does not support trace"
  33     return -1
  34 }
  35
  36 require allow_in_proc_agent
  37 set libipa [get_in_proc_agent]
  38
  39 # Can't use prepare_for_testing, because that splits compiling into
  40 # building objects and then linking, and we'd fail with "linker input
  41 # file unused because linking not done" when building the object.
  42
  43 if { [gdb_compile "$srcdir/$subdir/$srcfile" $binfile \
  44           executable [list debug $additional_flags shlib=$libipa] ] != "" } {
  45     untested "failed to compile"
  46     return -1
  47 }
  48 clean_restart $testfile
  49 set remote_libipa [gdb_load_shlib $libipa]
  50
  51 if ![runto_main] {
  52     return 0
  53 }
  54
  55 gdb_reinitialize_dir $srcdir/$subdir
  56
  57 if { [gdb_test "info sharedlibrary" ".*[file tail $libipa].*" "IPA loaded"] != 0 } {
  58     untested "could not find IPA lib loaded"
  59     return 1
  60 }
  61
  62 # Read function name from testcases[N].
  63
  64 proc read_testcase { n } {
  65     global gdb_prompt
  66
  67     set result -1
  68     gdb_test_multiple "print testcases\[${n}\]" "read name of test case ${n}" {
  69         -re "\[$\].*= .*<(.*)>.*$gdb_prompt $" {
  70             set result $expect_out(1,string)
  71         }
  72         -re "$gdb_prompt $" { }
  73     }
  74
  75     return $result
  76 }
  77
  78 set n_testcases [gdb_readexpr "n_testcases"]
  79
  80 if { ${n_testcases} == 0 } {
  81     untested "no instruction relocation to test"
  82     return 1
  83 }
  84
  85 # Set a fast tracepoint on each set_point${i} symbol.  There is one for
  86 # each testcase.
  87 for { set i 0 } { ${i} < ${n_testcases} } { incr i } {
  88     set testcase [read_testcase $i]
  89
  90     gdb_test "ftrace *set_point$i" "Fast tracepoint .*" \
  91         "fast tracepoint on ${testcase}"
  92 }
  93
  94 gdb_test "break pass" ".*" ""
  95 gdb_test "break fail" ".*" ""
  96
  97 gdb_test_no_output "tstart" "start trace experiment"
  98
  99 # Make sure we have hit the pass breakpoint for each testcase.
 100 for { set i 0 } { ${i} < ${n_testcases} } { incr i } {
 101     set testcase [read_testcase $i]
 102
 103     gdb_test "continue" \
 104         ".*Breakpoint \[0-9\]+, pass \(\).*" \
 105         "relocated instruction at ${testcase}"
 106 }
 107
 108 gdb_test "tstatus" ".*Collected ${n_testcases} trace frames.*" "check on trace status"
 109
 110 gdb_test "tstop" "" ""