gdb/testsuite/gdb.base/branch-to-self.exp

   1 # This testcase is part of GDB, the GNU debugger.
   2 #
   3 # Copyright 2016-2024 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 require {!target_info exists gdb,nosignals}
  19
  20 standard_testfile
  21
  22 if { [build_executable ${testfile}.exp ${testfile} $srcfile {debug}] == -1 } {
  23     return -1
  24 }
  25
  26 with_test_prefix "single-step" {
  27     global testfile
  28
  29     clean_restart ${testfile}
  30     if ![runto_main] {
  31         return -1
  32     }
  33     set line_num [gdb_get_line_number "loop-line" ${testfile}.c]
  34
  35     gdb_test "break ${testfile}.c:${line_num}" "Breakpoint .*" \
  36         "set breakpoint"
  37     gdb_continue_to_breakpoint "hit breakpoint"
  38
  39     set stepi_count 1
  40     gdb_test_multiple "stepi" "" {
  41         -re -wrap ".*${testfile}.c:${line_num}.*" {
  42             pass $gdb_test_name
  43         }
  44         -re -wrap "" {
  45             if { $stepi_count == 10 } {
  46                 fail $gdb_test_name
  47             } else {
  48                 incr stepi_count
  49                 send_gdb "stepi\n"
  50                 exp_continue
  51             }
  52         }
  53     }
  54 }
  55
  56 with_test_prefix "break-cond" {
  57     global testfile
  58
  59     foreach_with_prefix side {"host" "target"} {
  60
  61         clean_restart ${testfile}
  62
  63         if ![runto_main] {
  64             return -1
  65         }
  66
  67         set test "set breakpoint condition-evaluation $side"
  68         gdb_test_multiple $test $test {
  69             -re "warning: Target does not support breakpoint condition evaluation.\r\nUsing host evaluation mode instead.\r\n$gdb_prompt $" {
  70                 # Target doesn't support breakpoint condition
  71                 # evaluation on its side.  Skip the test.
  72                 continue
  73             }
  74             -re "^$test\r\n$gdb_prompt $" {
  75             }
  76         }
  77
  78         set line_num [gdb_get_line_number "loop-line" ${testfile}.c]
  79         gdb_test "break ${testfile}.c:${line_num} if counter > 3" \
  80             "Breakpoint .*" "set breakpoint with condition"
  81
  82         gdb_continue_to_breakpoint "continue to break"
  83
  84         gdb_test "p counter" ".* = 5"
  85     }
  86 }