gdb/testsuite/gdb.base/index-cache.exp

   1 #   Copyright 2018-2024 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # This test checks that the index-cache feature generates the expected files at
  17 # the expected location.
  18
  19 standard_testfile .c -2.c
  20
  21 if { [build_executable "failed to prepare" $testfile [list $srcfile $srcfile2] \
  22           {debug build-id}] } {
  23     return
  24 }
  25
  26 # The index cache won't be used in certain circumstances, for which we must
  27 # account in this test:
  28 #
  29 #  - the binary already has an index section
  30 #  - we use the -readnow switch
  31 set has_index_section [exec_has_index_section $binfile]
  32 set uses_readnow [expr [string first "-readnow" $GDBFLAGS] != -1]
  33 set expecting_index_cache_use [expr !$has_index_section && !$uses_readnow]
  34
  35 # List the files in DIR on the host (where GDB-under-test runs).
  36 # Return a list of two elements:
  37 #   - 0 on success, -1 on failure
  38 #   - the list of files on success, empty on failure
  39
  40 proc ls_host { dir } {
  41     lassign [remote_exec host ls "-1 $dir"] ret output
  42
  43     if { $ret != 0 } {
  44         fail "failed to list files on host in $dir"
  45         return -1
  46     }
  47
  48     # ls -1 returns a list separated by \r\n.  split will return a bunch of
  49     # empty entries (it treats a sequence of split characters as separate
  50     # fields, plus there is a \r\n at the end of the result).  Ignore empty
  51     # list elements.
  52     set filtered {}
  53     set files [split $output \r\n]
  54
  55     foreach file $files {
  56         if { $file != "" } {
  57             lappend filtered $file
  58         }
  59     }
  60
  61     return [list 0 $filtered]
  62 }
  63
  64 # Execute "show index-cache stats" and verify the output against expected
  65 # values.
  66
  67 proc check_cache_stats { expected_hits expected_misses } {
  68     # This test wants to check the cache, so make sure it has completed
  69     # its work.
  70     gdb_test_no_output "maintenance wait-for-index-cache"
  71
  72     set re [multi_line \
  73         "  Cache hits .this session.: $expected_hits" \
  74         "Cache misses .this session.: $expected_misses" \
  75     ]
  76
  77     gdb_test "show index-cache stats" $re "check index-cache stats"
  78 }
  79
  80 # Run CODE using a fresh GDB configured based on the other parameters.
  81
  82 proc run_test_with_flags { cache_dir cache_enabled code } {
  83     global GDBFLAGS testfile
  84
  85     save_vars { GDBFLAGS } {
  86         set GDBFLAGS "$GDBFLAGS -iex \"set index-cache directory $cache_dir\""
  87         set GDBFLAGS "$GDBFLAGS -iex \"set index-cache enabled $cache_enabled\""
  88
  89         clean_restart
  90
  91         gdb_test_no_output "maint set dwarf synchronous on"
  92
  93         gdb_load $::binfile
  94
  95         uplevel 1 $code
  96     }
  97 }
  98
  99 # Test administrative stuff.
 100
 101 proc_with_prefix test_basic_stuff { } {
 102     global testfile
 103
 104     clean_restart ${testfile}
 105
 106     # Check that the index cache is disabled by default.
 107     gdb_test \
 108         "show index-cache enabled" \
 109         "The index cache is off." \
 110         "index-cache is disabled by default"
 111
 112     # Test that we can enable it and "show index-cache enabled" reflects that.
 113     gdb_test_no_output "set index-cache enabled on" "enable index cache"
 114     gdb_test \
 115         "show index-cache enabled" \
 116         "The index cache is on." \
 117         "index-cache is now enabled"
 118
 119     with_test_prefix "deprecated commands" {
 120         gdb_test "set index-cache off" ".*is deprecated.*" "disable index cache"
 121         gdb_test \
 122             "show index-cache enabled" \
 123             "The index cache is off." \
 124             "index-cache is now disabled"
 125         gdb_test "set index-cache on" ".*is deprecated.*" "enable index cache"
 126         gdb_test \
 127             "show index-cache enabled" \
 128             "The index cache is on." \
 129             "index-cache is now enabled"
 130     }
 131
 132     # Test the "set/show index-cache directory" commands.
 133     gdb_test "set index-cache directory" "Argument required.*" "set index-cache directory without arg"
 134     gdb_test_no_output "set index-cache directory /tmp" "change the index cache directory"
 135     gdb_test \
 136         "show index-cache directory" \
 137         "The directory of the index cache is \"/tmp\"."  \
 138         "show index cache directory"
 139 }
 140
 141 # Test loading a binary with the cache disabled.  No file should be created.
 142
 143 proc_with_prefix test_cache_disabled { cache_dir test_prefix } {
 144     with_test_prefix $test_prefix {
 145         lassign [ls_host $cache_dir] ret files_before
 146
 147         run_test_with_flags $cache_dir off {
 148             lassign [ls_host $cache_dir] ret files_after
 149
 150             set nfiles_created [expr [llength $files_after] - [llength $files_before]]
 151             gdb_assert "$nfiles_created == 0" "no files were created"
 152
 153             # Trigger expansion of symtab containing main, if not already done.
 154             gdb_test "ptype main" "^type = int \\(void\\)"
 155
 156             # Trigger expansion of symtab not containing main.
 157             gdb_test "ptype foo" "^type = int \\(void\\)"
 158
 159             # Look for non-existent function.
 160             gdb_test "ptype foobar" "^No symbol \"foobar\" in current context\\."
 161
 162             check_cache_stats 0 0
 163         }
 164     }
 165 }
 166
 167 # Test a cache miss.  We expect to have at least one file in the cache if the
 168 # index cache is going to be used (see expecting_index_cache_use) and a cache
 169 # miss in the stats.  If the cache is not going to be used, we expect to have
 170 # no files and no cache hits nor misses.
 171
 172 proc_with_prefix test_cache_enabled_miss { cache_dir } {
 173     global testfile expecting_index_cache_use
 174
 175     lassign [ls_host $cache_dir] ret files_before
 176
 177     run_test_with_flags $cache_dir on {
 178
 179         lassign [ls_host $cache_dir] ret files_after
 180         set nfiles_created [expr [llength $files_after] - [llength $files_before]]
 181         if { $expecting_index_cache_use } {
 182             gdb_assert "$nfiles_created > 0" "at least one file was created"
 183         } else {
 184             gdb_assert "$nfiles_created == 0" "no file was created"
 185         }
 186
 187         set build_id [get_build_id  [standard_output_file ${testfile}]]
 188         if { $build_id == "" } {
 189             fail "couldn't get executable build id"
 190             return
 191         }
 192
 193         set expected_created_file [list "${build_id}.gdb-index"]
 194         set found_idx [lsearch -exact $files_after $expected_created_file]
 195         if { $expecting_index_cache_use } {
 196             gdb_assert "$found_idx >= 0" "expected file is there"
 197         } else {
 198             gdb_assert "$found_idx == -1" "no index cache file generated"
 199         }
 200
 201         remote_exec host rm "-f $cache_dir/$expected_created_file"
 202
 203         # Trigger expansion of symtab containing main, if not already done.
 204         gdb_test "ptype main" "^type = int \\(void\\)"
 205
 206         # Trigger expansion of symtab not containing main.
 207         gdb_test "ptype foo" "^type = int \\(void\\)"
 208
 209         # Look for non-existent function.
 210         gdb_test "ptype foobar" "^No symbol \"foobar\" in current context\\."
 211
 212         if { $expecting_index_cache_use } {
 213             check_cache_stats 0 1
 214         } else {
 215             check_cache_stats 0 0
 216         }
 217     }
 218 }
 219
 220
 221 # Test a cache hit.  We should have at least one file in the cache if the index
 222 # cache is going to be used (see expecting_index_cache_use) and a cache hit in
 223 # the stats.  If the cache is not going to be used, we expect to have no files
 224 # and no cache hits nor misses.
 225
 226 proc_with_prefix test_cache_enabled_hit { cache_dir } {
 227     global expecting_index_cache_use
 228
 229     # Just to populate the cache.
 230     with_test_prefix "populate cache" {
 231         run_test_with_flags $cache_dir on {}
 232     }
 233
 234     lassign [ls_host $cache_dir] ret files_before
 235
 236     run_test_with_flags $cache_dir on {
 237         lassign [ls_host $cache_dir] ret files_after
 238         set nfiles_created [expr [llength $files_after] - [llength $files_before]]
 239         gdb_assert "$nfiles_created == 0" "no files were created"
 240
 241         # Trigger expansion of symtab containing main, if not already done.
 242         gdb_test "ptype main" "^type = int \\(void\\)"
 243
 244         # Trigger expansion of symtab not containing main.
 245         gdb_test "ptype foo" "^type = int \\(void\\)"
 246
 247         # Look for non-existent function.
 248         gdb_test "ptype foobar" "^No symbol \"foobar\" in current context\\."
 249
 250         if { $expecting_index_cache_use } {
 251             check_cache_stats 1 0
 252         } else {
 253             check_cache_stats 0 0
 254         }
 255     }
 256 }
 257
 258 test_basic_stuff
 259
 260 # The cache dir should be on the host (possibly remote), so we can't use the
 261 # standard output directory for that (it's on the build machine).
 262 lassign [remote_exec host mktemp -d] ret cache_dir
 263
 264 if { $ret != 0 } {
 265     fail "couldn't create temporary cache dir"
 266     return
 267 }
 268
 269 # The ouput of mktemp contains an end of line, remove it.
 270 set cache_dir [string trimright $cache_dir \r\n]
 271
 272 test_cache_disabled $cache_dir "before populate"
 273 test_cache_enabled_miss $cache_dir
 274 test_cache_enabled_hit $cache_dir
 275
 276 # Test again with the cache disabled, now that it is populated.
 277 test_cache_disabled $cache_dir "after populate"
 278
 279 lassign [remote_exec host "sh -c" [quote_for_host rm $cache_dir/*.gdb-index]] ret
 280 if { $ret != 0 && $expecting_index_cache_use } {
 281     fail "couldn't remove files in temporary cache dir"
 282     return
 283 }
 284
 285 lassign [remote_exec host rmdir "$cache_dir"] ret
 286 if { $ret != 0 } {
 287     fail "couldn't remove temporary cache dir"
 288     return
 289 }