gdb/testsuite/gdb.base/reggroups.exp

   1 # This testcase is part of GDB, the GNU debugger.
   2
   3 # Copyright 2017-2024 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # Test listing reggroups and the registers in each group.
  19
  20 standard_testfile
  21
  22 if {[prepare_for_testing "failed to prepare" $testfile $srcfile debug]} {
  23     return -1
  24 }
  25
  26 if {![runto_main]} {
  27     return 0
  28 }
  29
  30 set invalid_register_re "Invalid register \[^\r\n\]*"
  31
  32 # Fetch all reggroups from 'maint print reggroups'.
  33
  34 proc fetch_reggroups {test} {
  35     global gdb_prompt
  36
  37     set reggroups {}
  38     gdb_test_multiple "maint print reggroups" $test {
  39         -re "maint print reggroups\r\n" {
  40             exp_continue
  41         }
  42         -re "^Group\[ \t\]+Type\[ \t\]+\r\n" {
  43             exp_continue
  44         }
  45         -re "^(\[_0-9a-zA-Z-\]+)\[ \t\]+(user|internal)\[ \t\]+\r\n" {
  46             lappend reggroups $expect_out(1,string)
  47             exp_continue
  48         }
  49         -re "$gdb_prompt $" {
  50             gdb_assert "[llength $reggroups] != 0" $test
  51         }
  52     }
  53
  54     verbose -log "found reggroups: $reggroups"
  55     return $reggroups
  56 }
  57
  58 # Fetch all registers for a reggroup from 'info reg <reggroup>'.
  59
  60 proc fetch_reggroup_regs {reggroup test} {
  61     global gdb_prompt
  62     global invalid_register_re
  63
  64     # The command info reg <reggroup> will return something like the following:
  65     #
  66     # r0             0x0      0^M
  67     # r1             0x7fdffc 0x7fdffc^M
  68     # r2             0x7fe000 0x7fe000^M
  69     # npc            0x23a8   0x23a8 <main+12>^M
  70     # sr             0x8401   [ SM CY FO CID=0 ]^M
  71     #
  72     # We parse out and return the reg names, this is done by detecting
  73     # that for each line we have a register name followed by a $hex number.
  74     #
  75     # Note: we will not return vector registers, but I think this is ok because
  76     # for testing purposes we just want to ensure we get some registers and dont
  77     # fail.  Example vector register:
  78     #
  79     # xmm0           {v4_float = {0x0, 0x0, 0x0, 0x0}, v2_double = {0x0, ... }}
  80     #
  81     set regs {}
  82     set have_invalid_register_fail 0
  83     set re_regname "\[0-9a-zA-Z_-\]+"
  84     set re_hws "\[ \t\]+"
  85     set re_hs "\[^\n\r\]+"
  86     set re_eol "\r\n"
  87     set re_lookahead_eol "(?=$re_eol)"
  88     gdb_test_multiple "info reg $reggroup" $test -lbl {
  89         -re "^info reg $reggroup" {
  90             exp_continue
  91         }
  92         -re "^${re_eol}($re_regname)$re_hws$::hex$re_hws${re_hs}$re_lookahead_eol" {
  93             lappend regs $expect_out(1,string)
  94             exp_continue
  95         }
  96         -re $invalid_register_re {
  97             set have_invalid_register_fail 1
  98             exp_continue
  99         }
 100         -re -wrap "" {
 101             if { $have_invalid_register_fail } {
 102                 fail "$test (unexpected invalid register response)"
 103             } else {
 104                 pass $test
 105             }
 106         }
 107     }
 108
 109     verbose -log "found regs in reggroup $reggroup: [join $regs]"
 110     return $regs
 111 }
 112
 113 set reggroups [fetch_reggroups "fetch reggroups"]
 114 set regcount 0
 115 foreach reggroup $reggroups {
 116     set regs [fetch_reggroup_regs $reggroup "fetch reggroup regs $reggroup"]
 117     set regcount [expr $regcount + [llength $regs]]
 118 }
 119
 120 gdb_assert "[llength $regcount] != 0" "system has reggroup registers"
 121
 122 # If this fails it means that probably someone changed the error text returned
 123 # for an invalid register argument.  If that happens we should fix the pattern
 124 # here and in the fetch_reggroup_regs procedure above.
 125 gdb_test "info reg invalid-reggroup" $invalid_register_re \
 126     "info reg invalid-reggroup should report 'Invalid register'"