gdb/testsuite/gdb.dwarf2/implref-array.exp

   1 # Copyright 2016-2024 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Test a C++ reference marked with DW_OP_GNU_implicit_pointer.
  17 # The referenced value is a global array whose location is a DW_OP_addr.
  18
  19 require allow_cplus_tests
  20
  21 load_lib dwarf.exp
  22
  23 # This test can only be run on targets which support DWARF-2 and use gas.
  24 require dwarf2_support
  25
  26 # We'll place the output of Dwarf::assemble in implref-array.S.
  27 standard_testfile .c .S
  28
  29 # ${testfile} is now "implref-array".  srcfile2 is "implref-array.S".
  30 set executable ${testfile}
  31 set asm_file [standard_output_file ${srcfile2}]
  32
  33 # We need to know the size of integer and address types in order
  34 # to write some of the debugging info we'd like to generate.
  35 #
  36 # For that, we ask GDB by debugging our implref-array program.
  37 # Any program would do, but since we already have implref-array
  38 # specifically for this testcase, might as well use that.
  39 if { [prepare_for_testing "failed to prepare" ${testfile} ${srcfile}] } {
  40     return -1
  41 }
  42
  43 set array_length [get_valueof "/u" "sizeof(array) / sizeof(array\[0\])" -1]
  44
  45 # Create the DWARF.  We need a regular variable which represents the array, and
  46 # a reference to it that'll be marked with DW_OP_GNU_implicit_pointer.
  47 # The variable must be global so that its name is an exported symbol that we
  48 # can reference from the DWARF using gdb_target_symbol.
  49 Dwarf::assemble ${asm_file} {
  50     global array_length
  51
  52     cu {} {
  53         DW_TAG_compile_unit {
  54             {DW_AT_language @DW_LANG_C_plus_plus}
  55         } {
  56             declare_labels int_label sizetype_label array_label variable_label ref_label
  57             set int_size [get_sizeof "int" -1]
  58             set upper_bound [expr ${array_length} - 1]
  59
  60             # gdb always assumes references are implemented as pointers.
  61             set addr_size [get_sizeof "void *" -1]
  62
  63             int_label: DW_TAG_base_type {
  64                 {DW_AT_byte_size ${int_size} DW_FORM_udata}
  65                 {DW_AT_encoding @DW_ATE_signed}
  66                 {DW_AT_name "int"}
  67             }
  68
  69             sizetype_label: DW_TAG_base_type {
  70                 {DW_AT_byte_size ${int_size} DW_FORM_udata}
  71                 {DW_AT_encoding @DW_ATE_unsigned}
  72                 {DW_AT_name "sizetype"}
  73             }
  74
  75             array_label: DW_TAG_array_type {
  76                     {DW_AT_type :${int_label}}
  77             } {
  78                 DW_TAG_subrange_type {
  79                     {DW_AT_type :${sizetype_label}}
  80                     {DW_AT_lower_bound 0 DW_FORM_udata}
  81                     {DW_AT_upper_bound ${upper_bound} DW_FORM_udata}
  82                 }
  83             }
  84
  85             ref_label: DW_TAG_reference_type {
  86                 {DW_AT_byte_size ${addr_size} DW_FORM_udata}
  87                 {DW_AT_type :${array_label}}
  88             }
  89
  90             variable_label: DW_TAG_variable {
  91                 {DW_AT_name "array"}
  92                 {DW_AT_type :${array_label}}
  93                 {DW_AT_external 1 DW_FORM_flag}
  94                 {DW_AT_location {DW_OP_addr [gdb_target_symbol "array"]} SPECIAL_expr}
  95             }
  96
  97             DW_TAG_subprogram {
  98                 {MACRO_AT_func { "main" }}
  99                 {DW_AT_type :${int_label}}
 100                 {DW_AT_external 1 DW_FORM_flag}
 101             } {
 102                 DW_TAG_variable {
 103                     {DW_AT_name "ref"}
 104                     {DW_AT_type :${ref_label}}
 105                     {DW_AT_location {DW_OP_GNU_implicit_pointer ${variable_label} 0} SPECIAL_expr}
 106                 }
 107             }
 108         }
 109     }
 110 }
 111
 112 if [prepare_for_testing "failed to prepare" ${executable} [list ${asm_file} ${srcfile}] {}] {
 113     return -1
 114 }
 115
 116 # DW_OP_GNU_implicit_pointer implementation requires a valid frame.
 117 if ![runto_main] {
 118     return -1
 119 }
 120
 121 # This matches e.g. '(int (&)[5])'
 122 set ref_type [format {\(int \(&\)\[%d\]\)} ${array_length}]
 123
 124 # This matches e.g. '(int (*)[5])'
 125 set ptr_type [format {\(int \(\*\)\[%d\]\)} ${array_length}]
 126
 127 # Contents of the array.  Trim leading/trailing whitespace, '{' and '}'
 128 # since they confuse TCL to no end.
 129 set contents [get_valueof "" "array" ""]
 130 set contents [string trim ${contents}]
 131 set contents [string trim ${contents} "{}"]
 132
 133 # Address of the referenced value.
 134 set address [get_hexadecimal_valueof "&array" ""]
 135
 136 # Doing 'print ref' should show us e.g. '(int (&)[5]) 0xdeadbeef: {0, 1, 2, 3, 4}'.
 137 gdb_test "print ref" " = ${ref_type} @${address}: \\{${contents}\\}"
 138
 139 # Doing 'print &ref' should show us e.g. '(int (*)[5]) 0xdeadbeef <array>'.
 140 gdb_test "print &ref" " = ${ptr_type} ${address} <array>"
 141
 142 # gdb assumes C++ references are implemented as pointers, and print &(&ref)
 143 # shows us the underlying pointer's address.  Since in this case there's no
 144 # physical pointer, gdb should tell us so.
 145 gdb_test "print &(&ref)" "Attempt to take address of value not located in memory."
 146
 147 # Test assignment through the synthetic reference.
 148 set first_value 10
 149 gdb_test_no_output "set (ref\[0\] = ${first_value})"
 150
 151 # This matches '{10, 1, 2, 3, 4}'.
 152 set new_contents [format {\{%d, 1, 2, 3, 4\}} ${first_value}]
 153
 154 # Doing 'print ref' should now show us e.g.
 155 # '(int (&)[5]) <synthetic pointer>: {10, 1, 2, 3, 4}'.
 156 gdb_test "print ref" " = ${ref_type} @${address}: ${new_contents}" "print ref after assignment"
 157 gdb_test "print array" " = ${new_contents}" "print array after assignment"
 158
 159 # Test treating the array as a pointer.
 160 set second_value 20
 161 set new_contents [format {\{%d, %d, 2, 3, 4\}} ${first_value} ${second_value}]
 162
 163 gdb_test "print *ref" " = ${first_value}"
 164 gdb_test_no_output "set (*(ref + 1) = ${second_value})"
 165 gdb_test "print ref\[1\]" " = ${second_value}"
 166 gdb_test "print array" " = ${new_contents}" "print array after second assignment"