gdb/testsuite/gdb.server/server-run.exp

   1 # This testcase is part of GDB, the GNU debugger.
   2
   3 # Copyright 2005-2024 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # Test the basic functionality of gdbserver.
  19
  20 load_lib gdbserver-support.exp
  21
  22 standard_testfile server.c
  23
  24 require allow_gdbserver_tests
  25
  26 if {[build_executable $testfile.exp $testfile $srcfile debug] == -1} {
  27     return -1
  28 }
  29
  30 save_vars { GDBFLAGS } {
  31     # If GDB and GDBserver are both running locally, set the sysroot to avoid
  32     # reading files via the remote protocol.
  33     if { ![is_remote host] && ![is_remote target] } {
  34         set GDBFLAGS "$GDBFLAGS -ex \"set sysroot\""
  35     }
  36
  37     clean_restart $binfile
  38 }
  39
  40 # Make sure we're disconnected, in case we're testing with an
  41 # extended-remote board, therefore already connected.
  42 gdb_test "disconnect" ".*"
  43
  44 gdbserver_run ""
  45
  46 # We are now stopped at the program's entry point.  On targets which use
  47 # SVR4 dynamic linking, we should have automatically loaded symbols for
  48 # the dynamic linker.
  49 if { [istarget *-*-linux*] } {
  50     gdb_test "info shared" "From.*To.*" "loaded dynamic linker"
  51 }
  52
  53 gdb_breakpoint main
  54 gdb_test "continue" "Breakpoint.* main .*" "continue to main"
  55
  56 if { [istarget "aarch64*-*-*"]
  57      || [istarget "arm*-*-*"]
  58      || [istarget "csky*-*-*"]
  59      || [istarget "loongarch*-*-*"]
  60      || [istarget "riscv*-*-*"] } {
  61     set pc_regname "pc"
  62 } elseif { [is_amd64_regs_target] } {
  63     set pc_regname "rip"
  64 } elseif { [is_x86_like_target] } {
  65     set pc_regname "eip"
  66 } elseif { [istarget "tic6x-*-*"] } {
  67     set pc_regname "PC"
  68 }
  69
  70 # Sending the PC register in advance is good practice.  Test that this is
  71 # actually done for the targets where gdbserver is supposed to.
  72 set expedited_pc_test_name "send PC as expedited register in stop reply"
  73 if { [info exists pc_regname] } {
  74     set seen_line false
  75     gdb_test_multiple "maintenance print remote-registers" \
  76              $expedited_pc_test_name -lbl {
  77         -re "${pc_regname}\[\[:space:\]\]+${decimal}.*${decimal}\[\[:space:\]\]+yes" {
  78             set seen_line true
  79             exp_continue
  80         }
  81         -re "\r\n$gdb_prompt $" {
  82             gdb_assert { $seen_line } $gdb_test_name
  83         }
  84     }
  85 } else {
  86     untested $expedited_pc_test_name
  87 }