gdb/testsuite/gdb.server/solib-list.exp

   1 # Copyright 2010-2024 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  15
  16 # In some cases gdbserver cannot find the DT_DEBUG library list on its own and
  17 # it needs to fall back to GDB solib-svr4.c look up via symbols from the main
  18 # executable.
  19 # gdbserver :1234 ld-linux-x86-64.so.2 /bin/prog
  20 # gdb /bin/prog
  21 # (gdb) target remote ...
  22
  23 load_lib gdbserver-support.exp
  24 load_lib prelink-support.exp
  25
  26 require allow_gdbserver_tests allow_shlib_tests
  27
  28 standard_testfile solib-list-main.c
  29 set srclibfile ${testfile}-lib.c
  30 set binlibfile [standard_output_file ${testfile}.so]
  31
  32 if { [gdb_compile_shlib "${srcdir}/${subdir}/${srclibfile}" "${binlibfile}" {debug}] != ""
  33      || [gdb_compile "${srcdir}/${subdir}/${srcfile}" "${binfile}" executable "shlib=${binlibfile} build-id"] != "" } {
  34     untested "failed to compile"
  35     return -1
  36 }
  37
  38 set interp_system [section_get ${binfile} .interp]
  39 verbose -log "system interpreter is: $interp_system"
  40
  41 foreach nonstop { 0 1 } { with_test_prefix "non-stop $nonstop" {
  42     save_vars { GDBFLAGS } {
  43         # If GDB and GDBserver are both running locally, set the sysroot to avoid
  44         # reading files via the remote protocol.
  45         if { ![is_remote host] && ![is_remote target] } {
  46             set GDBFLAGS "$GDBFLAGS -ex \"set sysroot\""
  47         }
  48
  49         clean_restart
  50     }
  51
  52     gdb_load_shlib ${binlibfile}
  53
  54     set target_binfile [gdb_remote_download target $binfile]
  55     set host_binfile [gdb_remote_download host $binfile]
  56
  57     # When testing remote, the file path we receive may be only the file name,
  58     # "solib-list".  ld-linux doesn't seem to be able to find the file when
  59     # passing just the file name, it wants either the absolute path or a
  60     # relative path with at least one directory component.  Calling readlink on
  61     # the target to get the full path will make it happy.
  62     set target_binfile [lindex [remote_exec target "readlink -f $target_binfile"] 1]
  63
  64     # Make sure we're disconnected, in case we're testing with an
  65     # extended-remote board, therefore already connected.
  66     gdb_test "disconnect" ".*"
  67
  68     gdb_test "set non-stop $nonstop"
  69
  70     # It is required for the non-stop mode, GDB would try to step over
  71     # _dl_debug_state breakpoint will still only ld.so loaded in gdbserver.
  72     # But GDB having symbols from the main executable it would try to use
  73     # displaced-stepping buffer at unmapped that time address _start.
  74     gdb_test "set displaced-stepping off"
  75
  76     # Unset last_loaded_file because we want GDBserver spawn
  77     # ${interp_system} not ${last_loaded_file}.
  78     global last_loaded_file
  79     unset -nocomplain last_loaded_file
  80
  81     # Note we pass ${interp_system}, the program gdbserver spawns, as
  82     # argument here, instead of using gdb_load, because we don't want
  83     # to download the interpreter to the target (it's already there)
  84     # or to the test output directory.
  85     set res [gdbserver_spawn "${interp_system} ${target_binfile}"]
  86     set gdbserver_protocol [lindex $res 0]
  87     set gdbserver_gdbport [lindex $res 1]
  88
  89     # Load BINFILE after gdbserver_spawn (so that gdbserver executes ld.so)
  90     # but before "target remote" below so that qSymbol data get already
  91     # initialized from BINFILE (and not from ld.so first needing a change to
  92     # BINFILE later).
  93     gdb_test "file ${host_binfile}" {Reading symbols from .*\.\.\..*} "file binfile"
  94
  95     set test "target $gdbserver_protocol"
  96     set ok 0
  97     set new_symbol_table 0
  98     gdb_test_multiple "target $gdbserver_protocol $gdbserver_gdbport" $test {
  99         -re "Remote debugging using" {
 100             set ok 1
 101             exp_continue
 102         }
 103         -re {.*Load new symbol table from ".*"\? \(y or n\) } {
 104             set new_symbol_table 1
 105             send_gdb "y\n" answer
 106             exp_continue
 107         }
 108         -re ".*\r\n$gdb_prompt " {
 109             # Do not anchor end, there may be more output in non-stop mode.
 110             if ($ok) {
 111                 pass $test
 112             } else {
 113                 fail $test
 114             }
 115         }
 116     }
 117     gdb_assert {$new_symbol_table == 1}
 118
 119     gdb_test "continue" "Program received signal SIGUSR1, .*"
 120     gdb_test "sharedlibrary" ".*"
 121     gdb_test "p libvar" " = 23"
 122 }}