gdb/testsuite/gdb.threads/manythreads.exp

   1 # manythreads.exp -- Expect script to test stopping many threads
   2 # Copyright (C) 2004-2024 Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 # This file was written by Jeff Johnston. (jjohnstn@redhat.com)
  18
  19 # This test requires sending ^C to interrupt the running target.
  20 require {!target_info exists gdb,nointerrupts}
  21
  22 standard_testfile
  23
  24 set opts { debug }
  25 if [info exists DEBUG] {
  26     # make check RUNTESTFLAGS='gdb.threads/manythreads.exp DEBUG=1'
  27     lappend opts "additional_flags=-DDEBUG"
  28 }
  29
  30 if {[gdb_compile_pthreads "${srcdir}/${subdir}/${srcfile}" "${binfile}" executable $opts] != "" } {
  31     return -1
  32 }
  33
  34 clean_restart ${binfile}
  35 gdb_test_no_output "set print sevenbit-strings"
  36 runto_main
  37
  38 # We'll need this when we send_gdb a ^C to GDB.  Need to do it before we
  39 # run the program and gdb starts saving and restoring tty states.
  40 gdb_test "shell stty intr '^C'" ".*"
  41
  42 set message "first continue"
  43 gdb_test_multiple "continue" "first continue" {
  44   -re "error:.*$gdb_prompt $" {
  45     fail "$message"
  46   }
  47   -re "Continuing" {
  48     pass "$message"
  49   }
  50 }
  51
  52 # Wait one second.  This is better than the TCL "after" command, because
  53 # we don't lose GDB's output while we do it.
  54 remote_expect host 1 { timeout { } }
  55
  56 # Send a Ctrl-C and wait for the SIGINT.
  57
  58 proc interrupt_and_wait { message } {
  59     global gdb_prompt
  60
  61     send_gdb "\003"
  62
  63     set saw_signal 0
  64     set order_ok 1
  65     gdb_test_multiple "" $message {
  66         -re "\r\n\\\[New \[^\r\n\]*(?=\r\n)" {
  67             # Note if GDB emits [New Thread ...] output between
  68             # "Thread NNN received signal" and the prompt, it's a
  69             # regression.
  70             #
  71             # GDB makes sure to notify about signal stops, end of
  72             # stepping ranges, etc., only after updating the thread
  73             # list, otherwise that stop info would be easy to miss.
  74             #
  75             # A BROKEN example would be:
  76             #
  77             #  ... pages of new threads output ...
  78             #  [New Thread NNN]
  79             #  ^C
  80             #  ... more new threads output ...
  81             #  [New Thread NNN]
  82             #  [New Thread NNN]
  83             #  Thread NNN received signal SIGINT, Interrupt.
  84             #  [New Thread NNN]
  85             #  [New Thread NNN]
  86             #  ... pages of new threads output ...
  87             #  [Switching to Thread NNN]
  88             #  foo () at foo.c:31
  89             #  31      bar ();
  90             #
  91             if { $saw_signal } {
  92                 set order_ok 0
  93             }
  94             exp_continue
  95         }
  96         -re "\r\n\\\[\[^\r\n]* exited\\\](?=\r\n)" {
  97             exp_continue
  98         }
  99         -re "\r\n\[^\r\n]* received signal SIGINT\[^\r\n\]*(?=\r\n)" {
 100             set saw_signal 1
 101             exp_continue
 102         }
 103         -re -wrap "" {
 104             gdb_assert {$saw_signal && $order_ok} $gdb_test_name
 105         }
 106     }
 107 }
 108
 109 # Send a Ctrl-C and verify that we can do info threads and continue
 110 interrupt_and_wait "stop threads 1"
 111
 112 set cmd "info threads"
 113 set ok 0
 114 gdb_test_multiple $cmd $cmd {
 115     -re " 1 *${tdlabel_re} " {
 116         set ok 1
 117         exp_continue
 118     }
 119     -re ".*\r\n" {
 120         # Eat this line and continue, to prevent the buffer overflowing.
 121         exp_continue
 122     }
 123     -re "$gdb_prompt $" {
 124         if { $ok } {
 125             pass $cmd
 126         } else {
 127             fail $cmd
 128         }
 129     }
 130 }
 131
 132 gdb_test_no_output "thread name zardoz" "give a name to the thread"
 133 gdb_test "info threads" ".*zardoz.*" "check thread name"
 134
 135 set message "second continue"
 136 gdb_test_multiple "continue" "second continue" {
 137   -re "error:.*$gdb_prompt $" {
 138     fail "$message"
 139   }
 140   -re "Continuing" {
 141     pass "$message"
 142   }
 143 }
 144
 145 # Wait another second.  If the program stops on its own, GDB has failed
 146 # to handle duplicate SIGINTs sent to multiple threads.
 147 set failed 0
 148 remote_expect host 1 {
 149   -re "\\\[New \[^\]\]*\\\]\r\n" {
 150     exp_continue -continue_timer
 151   }
 152   -re "\\\[\[^\]\]* exited\\\]\r\n" {
 153     exp_continue -continue_timer
 154   }
 155   -re " received signal SIGINT.*$gdb_prompt $" {
 156     if { $failed == 0 } {
 157       fail "check for duplicate SIGINT"
 158     }
 159     send_gdb "continue\n"
 160     set failed 1
 161     exp_continue
 162   }
 163   timeout {
 164     if { $failed == 0 } {
 165       pass "check for duplicate SIGINT"
 166     }
 167   }
 168 }
 169
 170 # Send another Ctrl-C and verify that we can do info threads and quit
 171 interrupt_and_wait "stop threads 2"
 172
 173 gdb_test_multiple "quit" "GDB exits after stopping multithreaded program" {
 174     -re "Quit anyway\\? \\(y or n\\) $" {
 175         send_gdb "y\n"
 176         exp_continue
 177     }
 178     eof {
 179         pass "GDB exits after stopping multithreaded program"
 180     }
 181     timeout {
 182         fail "GDB exits after stopping multithreaded program (timeout)"
 183     }
 184 }
 185