gdb/testsuite/gdb.threads/wp-replication.exp

   1 # This testcase is part of GDB, the GNU debugger.
   2
   3 # Copyright 2009-2024 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # Check that hardware watchpoints get correctly replicated to all
  19 # existing threads when hardware watchpoints are created.  This test
  20 # creates one hardware watchpoint per thread until a maximum is
  21 # reached.  It originally addresses a deficiency seen on embedded
  22 # powerpc targets with slotted hardware *point designs.
  23
  24 set NR_THREADS 10
  25 set NR_TRIGGERS_PER_THREAD 2
  26
  27 # This test verifies that a hardware watchpoint gets replicated to
  28 # every existing thread and is detected properly.  This test is
  29 # only meaningful on a target with hardware watchpoint support.
  30 require allow_hw_watchpoint_tests
  31
  32 standard_testfile
  33 if {[gdb_compile_pthreads "${srcdir}/${subdir}/${srcfile}" "${binfile}" executable [list debug "additional_flags=-DNR_THREADS=$NR_THREADS -DNR_TRIGGERS_PER_THREAD=$NR_TRIGGERS_PER_THREAD"]] != "" } {
  34     return -1
  35 }
  36
  37 clean_restart ${binfile}
  38
  39 # Force hardware watchpoints to be used.
  40 gdb_test_no_output "set can-use-hw-watchpoints 1" ""
  41
  42 # Run to `main' where we begin our tests.
  43 if {![runto_main]} {
  44     return 0
  45 }
  46
  47 # Set some default values.
  48 set hwatch_count 0
  49 set count 0
  50
  51 # Count the number of hardware watchpoints available on
  52 # this target.
  53
  54 # So we get an immediate warning/error if the target doesn't support a
  55 # hardware watchpoint or run out of hardware resource.
  56 gdb_test_no_output "set breakpoint always-inserted on"
  57
  58 while { $count < $NR_THREADS } {
  59     # Some targets do resource counting as we insert watchpoints.
  60     # Such targets won't cause a watchpoint insertion failure, but
  61     # will switch to software watchpoints silently.  We check for
  62     # both cases here.
  63     gdb_test_multiple "watch watched_data\[$hwatch_count\]" \
  64         "watch watched_data\[$hwatch_count\]" {
  65             -re ".*Could not insert hardware watchpoint.*$gdb_prompt $" {
  66                 # End the loop.
  67                 set count $NR_THREADS
  68             }
  69             -re "Hardware watchpoint .*$gdb_prompt $" {
  70                 incr hwatch_count
  71             }
  72             -re "Watchpoint .*$gdb_prompt $" {
  73                 # End the loop.
  74                 set count $NR_THREADS
  75             }
  76         }
  77     incr count
  78 }
  79
  80 gdb_test_no_output "set breakpoint always-inserted off"
  81
  82 # Target cannot insert hardware watchpoints.  It should have reported
  83 # (through board settings) that it did not support them in the first place.
  84 # Just exit.
  85 if { $hwatch_count == 0} {
  86   fail "no hardware watchpoints available"
  87   return 0
  88 }
  89
  90 # Set the testcase's internal variable indicating the number of
  91 # hardware watchpoints the target supports.
  92 gdb_test_no_output "set var hw_watch_count=${hwatch_count}" \
  93                    "set var hw_watch_count=${hwatch_count}"
  94
  95 # At this point, we know how many hardware watchpoints
  96 # the target supports.  Use that to do further testing.
  97 delete_breakpoints
  98
  99 # Prepare to create all the threads.
 100 gdb_test "break thread_started" \
 101          "Breakpoint \[0-9\]+ at .*: file .*${srcfile}, line .*" \
 102          "breakpoint on thread_started"
 103
 104 # Move all threads to where they're supposed to be for testing.
 105 for { set i 0 } { $i < $NR_THREADS } { incr i } {
 106
 107     # We want to set the maximum number of hardware watchpoints
 108     # and make sure the target can handle that without an error.
 109     # That will show us the watchpoints got replicated to all the
 110     # threads correctly, and that no new watchpoints got created
 111     # in the background for a specific thread.
 112     if {$i < $hwatch_count} {
 113       gdb_test "watch watched_data\[$i\]" \
 114         "Hardware watchpoint .*"
 115     } else {
 116       verbose -log "Not setting watchpoint for watched_data\[$i\]\n"
 117     }
 118
 119     gdb_test continue "Continuing\\..*Breakpoint \[0-9\]+, thread_started \\(\\) at .*$srcfile.*" \
 120     "Thread $i hit breakpoint at thread_started"
 121 }
 122
 123 # Let the threads run and change the watched data, leading
 124 # to watchpoint triggers.
 125 gdb_test_no_output "set var test_ready=1" \
 126       "set var test_ready=1"
 127
 128 # Set the number of expected watchpoint triggers.
 129 set TRIGGERS [expr "$NR_THREADS * $hwatch_count * $NR_TRIGGERS_PER_THREAD"]
 130
 131 # Move the threads and hit the watchpoints TRIGGERS times.
 132 for { set i 1 } { $i <= $TRIGGERS } { incr i } {
 133     gdb_test continue "Continuing\\..*Hardware watchpoint \[0-9\]+: watched_data\[\[0-9\]+\].*Old value = \[0-9\]+.*New value = \[0-9\]+.*thread_function \\(arg=$hex\\) at .*$srcfile.*" \
 134     "Continue to watchpoint trigger $i out of ${TRIGGERS} on watched_data"
 135 }