opcodes/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2024 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([opcodes], [BFD_VERSION])
  22 AC_CONFIG_SRCDIR([z8k-dis.c])
  23
  24 AC_CANONICAL_TARGET
  25
  26 AM_INIT_AUTOMAKE
  27 AM_SILENT_RULES([yes])
  28
  29 AC_PROG_CC
  30 AC_USE_SYSTEM_EXTENSIONS
  31
  32 dnl These must be called before LT_INIT, because it may want
  33 dnl to call AC_CHECK_PROG.
  34 AC_CHECK_TOOL(AR, ar)
  35 AC_CHECK_TOOL(RANLIB, ranlib, :)
  36
  37 dnl Default to a non shared library.  This may be overridden by the
  38 dnl configure option --enable-shared.
  39 AC_DISABLE_SHARED
  40
  41 LT_INIT
  42
  43 ac_checking=
  44 . ${srcdir}/../bfd/development.sh
  45 test "$development" = true && ac_checking=yes
  46 AC_ARG_ENABLE(checking,
  47 [  --enable-checking       enable run-time checks],
  48 [case "${enableval}" in
  49   no|none)  ac_checking= ;;
  50   *)        ac_checking=yes ;;
  51 esac])dnl
  52 if test x$ac_checking != x ; then
  53   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  54 fi
  55
  56 AC_ARG_ENABLE(targets,
  57 [  --enable-targets        alternative target configurations],
  58 [case "${enableval}" in
  59   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  60             ;;
  61   no)       enable_targets= ;;
  62   *)        enable_targets=$enableval ;;
  63 esac])dnl
  64
  65 AM_BINUTILS_WARNINGS
  66
  67 AC_CONFIG_HEADERS(config.h:config.in)
  68
  69 # PR 14072
  70 AH_VERBATIM([00_CONFIG_H_CHECK],
  71 [/* Check that config.h is #included before system headers
  72    (this works only for glibc, but that should be enough).  */
  73 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  74 #  error config.h must be #included before system headers
  75 #endif
  76 #define __CONFIG_H__ 1])
  77
  78 if test -z "$target" ; then
  79     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  80 fi
  81
  82 AM_MAINTAINER_MODE
  83 AM_INSTALL_LIBBFD
  84 AC_EXEEXT
  85
  86 # host-specific stuff:
  87
  88 ALL_LINGUAS="da de es fi fr ga id it nl pt_BR ro sr sv tr uk vi zh_CN"
  89 ZW_GNU_GETTEXT_SISTER_DIR
  90 AM_PO_SUBDIRS
  91
  92 . ${srcdir}/../bfd/configure.host
  93
  94 BFD_CC_FOR_BUILD
  95 BFD_64_BIT
  96
  97 AC_SUBST(HDEFINES)
  98 AC_PROG_INSTALL
  99
 100 AC_CHECK_DECLS([basename, stpcpy])
 101
 102 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 103 # since sigsetjmp might only be defined as a macro.
 104 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 105 [AC_TRY_COMPILE([
 106 #include <setjmp.h>
 107 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 108 bfd_cv_func_sigsetjmp=yes, bfd_cv_func_sigsetjmp=no)])
 109 if test $bfd_cv_func_sigsetjmp = yes; then
 110   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 111 fi
 112
 113 cgen_maint=no
 114 cgendir='$(srcdir)/../../cgen'
 115 if test -r ${srcdir}/../cgen/iformat.scm; then
 116     cgendir='$(srcdir)/../cgen'
 117 fi
 118
 119 AC_ARG_ENABLE(cgen-maint,
 120 [  --enable-cgen-maint[=dir]    build cgen generated files],
 121 [case "${enableval}" in
 122   yes)  cgen_maint=yes ;;
 123   no)   cgen_maint=no ;;
 124   *)
 125         # Argument is a directory where cgen can be found.  In some
 126         # future world cgen could be installable, but right now this
 127         # is not the case.  Instead we assume the directory is a path
 128         # to the cgen source tree.
 129         cgen_maint=yes
 130         if test -r ${enableval}/iformat.scm; then
 131           # This looks like a cgen source tree.
 132           cgendir=${enableval}
 133         else
 134           AC_MSG_ERROR(${enableval} doesn't look like a cgen source tree)
 135         fi
 136         ;;
 137 esac])dnl
 138 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 139 AC_SUBST(cgendir)
 140
 141 using_cgen=no
 142
 143 # Check if linker supports --as-needed and --no-as-needed options
 144 AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed,
 145         [bfd_cv_ld_as_needed=no
 146         if $LD --help 2>/dev/null | grep as-needed > /dev/null; then
 147                 bfd_cv_ld_as_needed=yes
 148         fi
 149         ])
 150
 151 LT_LIB_M
 152
 153 #Libs for generator progs
 154 if test "x$cross_compiling" = "xno"; then
 155   BUILD_LIBS=../libiberty/libiberty.a
 156   BUILD_LIB_DEPS=$BUILD_LIBS
 157 else
 158   # if cross-compiling, assume that the system provides -liberty
 159   # and that the version is compatible with new headers.
 160   BUILD_LIBS=-liberty
 161   BUILD_LIB_DEPS=
 162 fi
 163 BUILD_LIBS="$BUILD_LIBS $LIBINTL"
 164 BUILD_LIB_DEPS="$BUILD_LIB_DEPS $LIBINTL_DEP"
 165
 166 AC_SUBST(BUILD_LIBS)
 167 AC_SUBST(BUILD_LIB_DEPS)
 168
 169 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 170 SHARED_LDFLAGS=
 171 SHARED_LIBADD=
 172 SHARED_DEPENDENCIES=
 173 if test "$enable_shared" = "yes"; then
 174 # When building a shared libopcodes, link against the pic version of libiberty
 175 # so that apps that use libopcodes won't need libiberty just to satisfy any
 176 # libopcodes references.
 177 # We can't do that if a pic libiberty is unavailable since including non-pic
 178 # code would insert text relocations into libopcodes.
 179 # Note that linking against libbfd as we do here, which is itself linked
 180 # against libiberty, may not satisfy all the libopcodes libiberty references
 181 # since libbfd may not pull in the entirety of libiberty.
 182 # Also, jam libintl into the right place in all of this: after libiberty,
 183 # which uses it, but before -lcygwin, which it uses.
 184 changequote(,)dnl
 185   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 186 changequote([,])dnl
 187   if test -n "$x"; then
 188     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 189   fi
 190 fi
 191
 192 SHARED_LIBADD="$SHARED_LIBADD $LTLIBINTL"
 193
 194 if test "$enable_shared" = "yes"; then
 195   case "${host}" in
 196     *-*-cygwin*)
 197       SHARED_LDFLAGS="-no-undefined"
 198       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty $SHARED_LIBADD"
 199       ;;
 200     *)
 201       SHARED_LIBADD="../bfd/libbfd.la ${SHARED_LIBADD}"
 202       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 203       ;;
 204   esac
 205
 206   if test -n "$SHARED_LIBADD"; then
 207     if test -n "$LIBM"; then
 208       if test x"$bfd_cv_ld_as_needed" = xyes; then
 209         # Link against libm only when needed.  Put -lc, -lm inside -Wl
 210         # to stop libtool reordering these options.
 211         SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed"
 212       else
 213         SHARED_LIBADD="$SHARED_LIBADD $LIBM"
 214       fi
 215     fi
 216   fi
 217 fi
 218 AC_SUBST(SHARED_LDFLAGS)
 219 AC_SUBST(SHARED_LIBADD)
 220 AC_SUBST(SHARED_DEPENDENCIES)
 221
 222 # target-specific stuff:
 223
 224 # Canonicalize the secondary target names.
 225 if test -n "$enable_targets" ; then
 226     for targ in `echo $enable_targets | sed 's/,/ /g'`
 227     do
 228         result=`$ac_config_sub $targ 2>/dev/null`
 229         if test -n "$result" ; then
 230             canon_targets="$canon_targets $result"
 231         else
 232             # Allow targets that config.sub doesn't recognize, like "all".
 233             canon_targets="$canon_targets $targ"
 234         fi
 235     done
 236 fi
 237
 238 all_targets=false
 239 selarchs=
 240 for targ in $target $canon_targets
 241 do
 242     if test "x$targ" = "xall" ; then
 243         all_targets=true
 244     else
 245         . $srcdir/../bfd/config.bfd
 246         selarchs="$selarchs $targ_archs"
 247     fi
 248 done
 249
 250 # Utility var, documents generic cgen support files.
 251
 252 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 253
 254 # We don't do any links based on the target system, just makefile config.
 255
 256 if test x${all_targets} = xfalse ; then
 257
 258     # Target architecture .o files.
 259     ta=
 260
 261     for arch in $selarchs
 262     do
 263         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 264         archdefs="$archdefs -DARCH_$ad"
 265         case "$arch" in
 266         bfd_aarch64_arch)       ta="$ta aarch64-asm.lo aarch64-dis.lo aarch64-opc.lo aarch64-asm-2.lo aarch64-dis-2.lo aarch64-opc-2.lo" ;;
 267         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 268         bfd_amdgcn_arch)        ;;
 269         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 270         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 271         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 272         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 273         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 274         bfd_cris_arch)          ta="$ta cris-desc.lo cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 275         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 276         bfd_csky_arch)          ta="$ta csky-dis.lo" ;;
 277         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 278         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 279         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 280         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 281         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 282         bfd_ft32_arch)          ta="$ta ft32-opc.lo ft32-dis.lo" ;;
 283         bfd_moxie_arch)         ta="$ta moxie-dis.lo moxie-opc.lo" ;;
 284         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 285         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 286         bfd_i386_arch|bfd_iamcu_arch)
 287                                 ta="$ta i386-dis.lo" ;;
 288         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 289         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 290         bfd_epiphany_arch)      ta="$ta epiphany-asm.lo epiphany-desc.lo epiphany-dis.lo epiphany-ibld.lo epiphany-opc.lo" using_cgen=yes ;;
 291         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 292         bfd_kvx_arch)           ta="$ta kvx-opc.lo kvx-dis.lo" ;;
 293         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 294         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 295         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 296         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 297         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 298         bfd_m9s12x_arch)        ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 299         bfd_m9s12xg_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 300         bfd_s12z_arch)          ta="$ta s12z-dis.lo s12z-opc.lo" ;;
 301         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 302         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 303         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 304         bfd_metag_arch)         ta="$ta metag-dis.lo" ;;
 305         bfd_microblaze_arch)    ta="$ta microblaze-dis.lo" ;;
 306         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo micromips-opc.lo" ;;
 307         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 308         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 309         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 310         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 311         bfd_msp430_arch)        ta="$ta msp430-dis.lo msp430-decode.lo" ;;
 312         bfd_nds32_arch)         ta="$ta nds32-asm.lo nds32-dis.lo" ;;
 313         bfd_nfp_arch)           ta="$ta nfp-dis.lo" ;;
 314         bfd_nios2_arch)         ta="$ta nios2-dis.lo nios2-opc.lo" ;;
 315         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 316         bfd_or1k_arch)          ta="$ta or1k-asm.lo or1k-desc.lo or1k-dis.lo or1k-ibld.lo or1k-opc.lo" using_cgen=yes ;;
 317         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 318         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 319         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 320         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 321         bfd_pru_arch)           ta="$ta pru-dis.lo pru-opc.lo" ;;
 322         bfd_pyramid_arch)       ;;
 323         bfd_romp_arch)          ;;
 324         bfd_riscv_arch)         ta="$ta riscv-dis.lo riscv-opc.lo" ;;
 325         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 326         bfd_rl78_arch)          ta="$ta rl78-dis.lo rl78-decode.lo";;
 327         bfd_rx_arch)            ta="$ta rx-dis.lo rx-decode.lo";;
 328         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 329         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 330         bfd_sh_arch)            ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 331         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 332         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 333         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 334         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 335         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 336         bfd_tic6x_arch)         ta="$ta tic6x-dis.lo" ;;
 337         bfd_tilegx_arch)        ta="$ta tilegx-dis.lo tilegx-opc.lo" ;;
 338         bfd_tilepro_arch)       ta="$ta tilepro-dis.lo tilepro-opc.lo" ;;
 339         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 340         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 341         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 342         bfd_v850_rh850_arch)    ta="$ta v850-opc.lo v850-dis.lo" ;;
 343         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 344         bfd_visium_arch)        ta="$ta visium-dis.lo visium-opc.lo" ;;
 345         bfd_wasm32_arch)        ta="$ta wasm32-dis.lo" ;;
 346         bfd_xgate_arch)         ta="$ta xgate-dis.lo xgate-opc.lo" ;;
 347         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 348         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 349         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 350         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 351         bfd_bpf_arch)           ta="$ta bpf-dis.lo bpf-opc.lo" ;;
 352         bfd_loongarch_arch)     ta="$ta loongarch-dis.lo loongarch-opc.lo loongarch-coder.lo" ;;
 353
 354         "")                     ;;
 355         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 356         esac
 357     done
 358
 359     if test $using_cgen = yes ; then
 360         ta="$ta $cgen_files"
 361     fi
 362
 363     # Weed out duplicate .o files.
 364     f=""
 365     for i in $ta ; do
 366         case " $f " in
 367         *" $i "*) ;;
 368         *) f="$f $i" ;;
 369         esac
 370     done
 371     ta="$f"
 372
 373     # And duplicate -D flags.
 374     f=""
 375     for i in $archdefs ; do
 376         case " $f " in
 377         *" $i "*) ;;
 378         *) f="$f $i" ;;
 379         esac
 380     done
 381     archdefs="$f"
 382
 383     BFD_MACHINES="$ta"
 384
 385 else    # all_targets is true
 386     archdefs=-DARCH_all
 387     if test "$enable_64_bit_bfd" = "yes" ; then
 388         BFD_MACHINES='$(ALL32_MACHINES) $(ALL64_MACHINES)'
 389     else
 390         BFD_MACHINES='$(ALL32_MACHINES)'
 391     fi
 392 fi
 393
 394 AC_SUBST(archdefs)
 395 AC_SUBST(BFD_MACHINES)
 396
 397 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 398 AC_OUTPUT
 399
 400 GNU_MAKE_JOBSERVER