configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include(config/gcc-plugin.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT
  36 AC_CONFIG_SRCDIR([move-if-change])
  37 AC_DISABLE_OPTION_CHECKING
  38
  39 progname=$0
  40 # if PWD already has a value, it is probably wrong.
  41 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  42
  43 # Export original configure arguments for use by sub-configures.
  44 # Quote arguments with shell meta charatcers.
  45 TOPLEVEL_CONFIGURE_ARGUMENTS=
  46 set -- "$progname" "$@"
  47 for ac_arg
  48 do
  49   case "$ac_arg" in
  50   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  51     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  52     # if the argument is of the form -foo=baz, quote the baz part only
  53     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  54   *) ;;
  55   esac
  56   # Add the quoted argument to the list.
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  58 done
  59 if test "$silent" = yes; then
  60   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  61 fi
  62 # Remove the initial space we just introduced and, as these will be
  63 # expanded by make, quote '$'.
  64 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  65 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  66
  67 # Find the build, host, and target systems.
  68 ACX_NONCANONICAL_BUILD
  69 ACX_NONCANONICAL_HOST
  70 ACX_NONCANONICAL_TARGET
  71
  72 dnl Autoconf 2.5x and later will set a default program prefix if
  73 dnl --target was used, even if it was the same as --host.  Disable
  74 dnl that behavior.  This must be done before AC_CANONICAL_TARGET
  75 dnl to take effect.
  76 test "$host_noncanonical" = "$target_noncanonical" &&
  77   test "$program_prefix$program_suffix$program_transform_name" = \
  78     NONENONEs,x,x, &&
  79   program_transform_name=s,y,y,
  80
  81 AC_CANONICAL_TARGET
  82 AC_ARG_PROGRAM
  83
  84 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  85 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  86
  87 # Get 'install' or 'install-sh' and its variants.
  88 AC_PROG_INSTALL
  89 ACX_PROG_LN
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_AWK
  93
  94 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  95
  96 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  97 # a relative path.
  98 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  99   INSTALL="${srcpwd}/install-sh -c"
 100 fi
 101
 102 # Set srcdir to "." if that's what it is.
 103 # This is important for multilib support.
 104 pwd=`${PWDCMD-pwd}`
 105 if test "${pwd}" = "${srcpwd}" ; then
 106   srcdir=.
 107 fi
 108
 109 topsrcdir=$srcpwd
 110
 111 extra_host_args=
 112
 113 ### To add a new directory to the tree, first choose whether it is a target
 114 ### or a host dependent tool.  Then put it into the appropriate list
 115 ### (library or tools, host or target), doing a dependency sort.
 116
 117 # Subdirs will be configured in the order listed in build_configdirs,
 118 # configdirs, or target_configdirs; see the serialization section below.
 119
 120 # Dependency sorting is only needed when *configuration* must be done in
 121 # a particular order.  In all cases a dependency should be specified in
 122 # the Makefile, whether or not it's implicitly specified here.
 123
 124 # Double entries in build_configdirs, configdirs, or target_configdirs may
 125 # cause circular dependencies and break everything horribly.
 126
 127 # these library is used by various programs built for the build
 128 # environment
 129 #
 130 build_libs="build-libiberty build-libcpp"
 131
 132 # these tools are built for the build environment
 133 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 134
 135 # these libraries are used by various programs built for the host environment
 136 #f
 137 host_libs="gettext libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe libgrust "
 138
 139 # these tools are built for the host environment
 140 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 141 # know that we are building the simulator.
 142 # binutils, gas and ld appear in that order because it makes sense to run
 143 # "make check" in that particular order.
 144 # If --enable-gold is used, "gold" may replace "ld".
 145 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gm2tools gotools c++tools"
 146
 147 # these libraries are built for the target environment, and are built after
 148 # the host libraries and the host tools (which may be a cross compiler)
 149 # Note that libiberty is not a target library.
 150 target_libraries="target-libgcc \
 151                 target-libbacktrace \
 152                 target-libgloss \
 153                 target-newlib \
 154                 target-libgomp \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgm2 \
 167                 target-libgo \
 168                 target-libgrust \
 169                 target-libphobos \
 170                 target-zlib"
 171
 172 # these tools are built using the target libraries, and are intended to
 173 # run only in the target environment
 174 #
 175 # note: any program that *uses* libraries that are in the "target_libraries"
 176 # list belongs in this list.
 177 #
 178 target_tools="target-rda"
 179
 180 ################################################################################
 181
 182 ## All tools belong in one of the four categories, and are assigned above
 183 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 184 ## is important because configure will choke if they ever get through.
 185 ## ${configdirs} is directories we build using the host tools.
 186 ## ${target_configdirs} is directories we build using the target tools.
 187 configdirs=`echo ${host_libs} ${host_tools}`
 188 target_configdirs=`echo ${target_libraries} ${target_tools}`
 189 build_configdirs=`echo ${build_libs} ${build_tools}`
 190
 191 m4_divert_text([PARSE_ARGS],
 192 [case $srcdir in
 193   *" "*)
 194 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 195     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 196 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 197     ;;
 198 esac
 199 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 200 ])
 201
 202 ################################################################################
 203
 204 srcname="gnu development package"
 205
 206 # This gets set non-empty for some net releases of packages.
 207 appdirs=""
 208
 209 # Define is_cross_compiler to save on calls to 'test'.
 210 is_cross_compiler=
 211 if test x"${host}" = x"${target}" ; then
 212   is_cross_compiler=no
 213 else
 214   is_cross_compiler=yes
 215 fi
 216
 217 # Find the build and target subdir names.
 218 GCC_TOPLEV_SUBDIRS
 219 # Be sure to cover against remnants of an in-tree build.
 220 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 221   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 222 Use a pristine source tree when building in a separate tree])
 223 fi
 224
 225 # Skipdirs are removed silently.
 226 skipdirs=
 227 # Noconfigdirs are removed loudly.
 228 noconfigdirs=""
 229
 230 use_gnu_ld=
 231 # Make sure we don't let GNU ld be added if we didn't want it.
 232 if test x$with_gnu_ld = xno ; then
 233   use_gnu_ld=no
 234   noconfigdirs="$noconfigdirs ld gold"
 235 fi
 236
 237 use_gnu_as=
 238 # Make sure we don't let GNU as be added if we didn't want it.
 239 if test x$with_gnu_as = xno ; then
 240   use_gnu_as=no
 241   noconfigdirs="$noconfigdirs gas"
 242 fi
 243
 244 use_included_zlib=
 245 AC_ARG_WITH(system-zlib,
 246 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 247 # Make sure we don't let ZLIB be added if we didn't want it.
 248 if test x$with_system_zlib = xyes ; then
 249   use_included_zlib=no
 250   noconfigdirs="$noconfigdirs zlib"
 251 fi
 252
 253 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 254 # is provided.
 255 if test x$with_system_readline = xyes ; then
 256   noconfigdirs="$noconfigdirs readline"
 257 fi
 258
 259 AC_ARG_WITH(zstd,
 260 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 261
 262 # some tools are so dependent upon X11 that if we're not building with X,
 263 # it's not even worth trying to configure, much less build, that tool.
 264
 265 case ${with_x} in
 266   yes | "") ;; # the default value for this tree is that X11 is available
 267   no)
 268     skipdirs="${skipdirs} tk itcl libgui"
 269     # We won't be able to build gdbtk without X.
 270     enable_gdbtk=no
 271     ;;
 272   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 273 esac
 274
 275 # Some are only suitable for cross toolchains.
 276 # Remove these if host=target.
 277 cross_only="target-libgloss target-newlib target-opcodes"
 278
 279 case $is_cross_compiler in
 280   no) skipdirs="${skipdirs} ${cross_only}" ;;
 281 esac
 282
 283 # If both --with-headers and --with-libs are specified, default to
 284 # --without-newlib.
 285 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 286    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 287   if test x"${with_newlib}" = x ; then
 288     with_newlib=no
 289   fi
 290 fi
 291
 292 # Recognize --with-newlib/--without-newlib.
 293 case ${with_newlib} in
 294   no) skipdirs="${skipdirs} target-newlib" ;;
 295   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 296 esac
 297
 298 AC_ARG_ENABLE(as-accelerator-for,
 299 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 300                 [build as offload target compiler.
 301                 Specify offload host triple by ARG])])
 302
 303 AC_ARG_ENABLE(offload-targets,
 304 [AS_HELP_STRING([--enable-offload-targets=LIST],
 305                 [enable offloading to devices from comma-separated LIST of
 306                 TARGET[=DIR]. Use optional path to find offload target compiler
 307                 during the build])],
 308 [
 309   if test x"$enable_offload_targets" = x; then
 310     AC_MSG_ERROR([no offload targets specified])
 311   fi
 312 ], [enable_offload_targets=])
 313
 314 AC_ARG_ENABLE(offload-defaulted,
 315 [AS_HELP_STRING([--enable-offload-defaulted]
 316                 [If enabled, configured but not installed offload compilers and
 317                 libgomp plugins are silently ignored.  Useful for distribution
 318                 compilers where those are in separate optional packages.])],
 319 [enable_offload_defaulted=$enableval],
 320 [enable_offload_defaulted=])
 321
 322 # Handle --enable-gold, --enable-ld.
 323 # --disable-gold [--enable-ld]
 324 #     Build only ld.  Default option.
 325 # --enable-gold [--enable-ld]
 326 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 327 #     as "ld.bfd" and "ld".
 328 # --enable-gold=default [--enable-ld]
 329 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 330 #     install ld as "ld.bfd".
 331 # --enable-gold[=default] --disable-ld
 332 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 333 # --enable-gold --enable-ld=default
 334 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 335 #     and ld.bfd).
 336 #     In other words, ld is default
 337 # --enable-gold=default --enable-ld=default
 338 #     Error.
 339
 340 default_ld=
 341 AC_ARG_ENABLE(gold,
 342 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 343                 [build gold @<:@ARG={default,yes,no}@:>@])],
 344 ENABLE_GOLD=$enableval,
 345 ENABLE_GOLD=no)
 346 case "${ENABLE_GOLD}" in
 347   yes|default)
 348     # Check for ELF target.
 349     is_elf=no
 350     case "${target}" in
 351       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 352       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 353       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 354       | *-*-solaris2* | *-*-nto* | *-*-nacl* | *-*-haiku*)
 355         case "${target}" in
 356           *-*-linux*aout* | *-*-linux*oldld*)
 357             ;;
 358           *)
 359             is_elf=yes
 360             ;;
 361         esac
 362     esac
 363
 364     if test "$is_elf" = "yes"; then
 365       # Check for target supported by gold.
 366       case "${target}" in
 367         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 368         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 369           configdirs="$configdirs gold"
 370           if test x${ENABLE_GOLD} = xdefault; then
 371             default_ld=gold
 372           fi
 373           ENABLE_GOLD=yes
 374           ;;
 375       esac
 376     fi
 377     ;;
 378   no)
 379     ;;
 380   *)
 381     AC_MSG_ERROR([invalid --enable-gold argument])
 382     ;;
 383 esac
 384
 385 AC_ARG_ENABLE(ld,
 386 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 387                 [build ld @<:@ARG={default,yes,no}@:>@])],
 388 ENABLE_LD=$enableval,
 389 ENABLE_LD=yes)
 390
 391 case "${ENABLE_LD}" in
 392   default)
 393     if test x${default_ld} != x; then
 394       AC_MSG_ERROR([either gold or ld can be the default ld])
 395     fi
 396     ;;
 397   yes)
 398     ;;
 399   no)
 400     if test x${ENABLE_GOLD} != xyes; then
 401       AC_MSG_WARN([neither ld nor gold are enabled])
 402     fi
 403     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 404     ;;
 405   *)
 406     AC_MSG_ERROR([invalid --enable-ld argument])
 407     ;;
 408 esac
 409
 410 AC_ARG_ENABLE(gprofng,
 411 [AS_HELP_STRING([[--enable-gprofng[=ARG]]],
 412                 [build gprofng @<:@ARG={yes,no}@:>@])],
 413 enable_gprofng=$enableval,
 414 enable_gprofng=yes)
 415 if test "$enable_gprofng" = "yes"; then
 416   case "${target}" in
 417     *-musl*)
 418       ;;
 419     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux* | riscv64-*-linux*)
 420     configdirs="$configdirs gprofng"
 421     ;;
 422   esac
 423 fi
 424
 425
 426 # PR gas/19109
 427 # Decide the default method for compressing debug sections.
 428 # Provide a configure time option to override our default.
 429 AC_ARG_ENABLE(compressed_debug_sections,
 430 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 431                 [Enable compressed debug sections for gas, gold or ld by
 432                  default])],
 433 [
 434   if test x"$enable_compressed_debug_sections" = xyes; then
 435     AC_MSG_ERROR([no program with compressed debug sections specified])
 436   fi
 437 ], [enable_compressed_debug_sections=])
 438
 439 # Select default compression algorithm.
 440 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 441 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 442                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 443 [], [default_compressed_debug_sections_algorithm=])
 444
 445 # Configure extra directories which are host specific
 446
 447 case "${host}" in
 448   *-cygwin*)
 449     configdirs="$configdirs libtermcap" ;;
 450 esac
 451
 452 # A target can indicate whether a language isn't supported for some reason.
 453 # Only spaces may be used in this macro; not newlines or tabs.
 454 unsupported_languages=
 455
 456 # Remove more programs from consideration, based on the host or
 457 # target this usually means that a port of the program doesn't
 458 # exist yet.
 459
 460 case "${host}" in
 461   i[[3456789]]86-*-msdosdjgpp*)
 462     noconfigdirs="$noconfigdirs tcl tk itcl"
 463     ;;
 464 esac
 465
 466 # Default to --disable-year2038 until we can handle differences between
 467 # projects that use gnulib (which understands year 2038) and projects that
 468 # do not (like BFD).
 469 AC_ARG_ENABLE(year2038,
 470 AS_HELP_STRING([--enable-year2038],
 471   [enable support for timestamps past the year 2038]),
 472 ENABLE_YEAR2038=$enableval,
 473 ENABLE_YEAR2038=no)
 474 enable_year2038=
 475 if test "${ENABLE_YEAR2038}" = "no" ; then
 476   enable_year2038=no
 477 fi
 478
 479 AC_ARG_ENABLE(libquadmath,
 480 AS_HELP_STRING([--disable-libquadmath],
 481   [do not build libquadmath directory]),
 482 ENABLE_LIBQUADMATH=$enableval,
 483 ENABLE_LIBQUADMATH=yes)
 484 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 485   noconfigdirs="$noconfigdirs target-libquadmath"
 486 fi
 487
 488
 489 AC_ARG_ENABLE(libquadmath-support,
 490 AS_HELP_STRING([--disable-libquadmath-support],
 491   [disable libquadmath support for Fortran]),
 492 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 493 ENABLE_LIBQUADMATH_SUPPORT=yes)
 494 enable_libquadmath_support=
 495 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 496   enable_libquadmath_support=no
 497 fi
 498
 499
 500 AC_ARG_ENABLE(libada,
 501 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 502 ENABLE_LIBADA=$enableval,
 503 ENABLE_LIBADA=yes)
 504 if test "${ENABLE_LIBADA}" != "yes" ; then
 505   noconfigdirs="$noconfigdirs gnattools"
 506 fi
 507
 508 AC_ARG_ENABLE(libgm2,
 509 [AS_HELP_STRING([--enable-libgm2], [build libgm2 directory])],
 510 ENABLE_LIBGM2=$enableval,
 511 ENABLE_LIBGM2=no)
 512 if test "${ENABLE_LIBGM2}" != "yes" ; then
 513   noconfigdirs="$noconfigdirs gm2tools"
 514 fi
 515
 516 AC_ARG_ENABLE(libssp,
 517 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 518 ENABLE_LIBSSP=$enableval,
 519 ENABLE_LIBSSP=yes)
 520
 521 AC_ARG_ENABLE(libstdcxx,
 522 AS_HELP_STRING([--disable-libstdcxx],
 523   [do not build libstdc++-v3 directory]),
 524 ENABLE_LIBSTDCXX=$enableval,
 525 ENABLE_LIBSTDCXX=default)
 526 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 527   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 528 fi]
 529
 530 # Enable libgomp by default on hosted POSIX systems, and a few others.
 531 if test x$enable_libgomp = x ; then
 532     case "${target}" in
 533     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 534         ;;
 535     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 536         ;;
 537     *-*-solaris2* | *-*-hpux11*)
 538         ;;
 539     *-*-darwin* | *-*-aix*)
 540         ;;
 541     nvptx*-*-* | amdgcn*-*-*)
 542         ;;
 543     *)
 544         noconfigdirs="$noconfigdirs target-libgomp"
 545         ;;
 546     esac
 547 fi
 548
 549 # Disable libatomic on unsupported systems.
 550 if test -d ${srcdir}/libatomic; then
 551     if test x$enable_libatomic = x; then
 552         AC_MSG_CHECKING([for libatomic support])
 553         if (srcdir=${srcdir}/libatomic; \
 554                 . ${srcdir}/configure.tgt; \
 555                 test -n "$UNSUPPORTED")
 556         then
 557             AC_MSG_RESULT([no])
 558             noconfigdirs="$noconfigdirs target-libatomic"
 559         else
 560             AC_MSG_RESULT([yes])
 561         fi
 562     fi
 563 fi
 564
 565 # Disable libitm on unsupported systems.
 566 if test -d ${srcdir}/libitm; then
 567     if test x$enable_libitm = x; then
 568         AC_MSG_CHECKING([for libitm support])
 569         if (srcdir=${srcdir}/libitm; \
 570                 . ${srcdir}/configure.tgt; \
 571                 test -n "$UNSUPPORTED")
 572         then
 573             AC_MSG_RESULT([no])
 574             noconfigdirs="$noconfigdirs target-libitm"
 575         else
 576             AC_MSG_RESULT([yes])
 577         fi
 578     fi
 579 fi
 580
 581 # Disable libsanitizer on unsupported systems.
 582 if test -d ${srcdir}/libsanitizer; then
 583     if test x$enable_libsanitizer = x; then
 584         AC_MSG_CHECKING([for libsanitizer support])
 585         if (srcdir=${srcdir}/libsanitizer; \
 586                 . ${srcdir}/configure.tgt; \
 587                 test -n "$UNSUPPORTED")
 588         then
 589             AC_MSG_RESULT([no])
 590             noconfigdirs="$noconfigdirs target-libsanitizer"
 591         else
 592             AC_MSG_RESULT([yes])
 593         fi
 594     fi
 595 fi
 596
 597 # Disable libvtv on unsupported systems.
 598 if test -d ${srcdir}/libvtv; then
 599     if test x$enable_libvtv = x; then
 600         AC_MSG_CHECKING([for libvtv support])
 601         if (srcdir=${srcdir}/libvtv; \
 602                 . ${srcdir}/configure.tgt; \
 603                 test "$VTV_SUPPORTED" != "yes")
 604         then
 605             AC_MSG_RESULT([no])
 606             noconfigdirs="$noconfigdirs target-libvtv"
 607         else
 608             AC_MSG_RESULT([yes])
 609         fi
 610     fi
 611 fi
 612
 613 # Disable libquadmath for some systems.
 614 case "${target}" in
 615   avr-*-*)
 616     noconfigdirs="$noconfigdirs target-libquadmath"
 617     ;;
 618   # libquadmath is unused on AIX and libquadmath build process use of
 619   # LD_LIBRARY_PATH can break AIX bootstrap.
 620   powerpc-*-aix* | rs6000-*-aix*)
 621     noconfigdirs="$noconfigdirs target-libquadmath"
 622     ;;
 623 esac
 624
 625 # Disable libssp for some systems.
 626 case "${target}" in
 627   avr-*-*)
 628     # No hosted I/O support.
 629     noconfigdirs="$noconfigdirs target-libssp"
 630     ;;
 631   bpf-*-*)
 632     noconfigdirs="$noconfigdirs target-libssp"
 633     ;;
 634   powerpc-*-aix* | rs6000-*-aix*)
 635     noconfigdirs="$noconfigdirs target-libssp"
 636     ;;
 637   pru-*-*)
 638     # No hosted I/O support.
 639     noconfigdirs="$noconfigdirs target-libssp"
 640     ;;
 641   rl78-*-*)
 642     # libssp uses a misaligned load to trigger a fault, but the RL78
 643     # doesn't fault for those - instead, it gives a build-time error
 644     # for explicit misaligned loads.
 645     noconfigdirs="$noconfigdirs target-libssp"
 646     ;;
 647   visium-*-*)
 648     # No hosted I/O support.
 649     noconfigdirs="$noconfigdirs target-libssp"
 650     ;;
 651 esac
 652
 653 # Disable libstdc++-v3 for some systems.
 654 # Allow user to override this if they pass --enable-libstdcxx
 655 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 656   case "${target}" in
 657     *-*-vxworks*)
 658       # VxWorks uses the Dinkumware C++ library.
 659       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 660       ;;
 661     amdgcn*-*-*)
 662       # Not ported/fails to build when using newlib.
 663       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 664       ;;
 665     arm*-wince-pe*)
 666       # the C++ libraries don't build on top of CE's C libraries
 667       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 668       ;;
 669     avr-*-*)
 670       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 671       ;;
 672     bpf-*-*)
 673       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 674       ;;
 675     ft32-*-*)
 676       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 677       ;;
 678   esac
 679 fi
 680
 681 # Disable C++ on systems where it is known to not work.
 682 # For testing, you can override this with --enable-languages=c++.
 683 case ,${enable_languages}, in
 684   *,c++,*)
 685     ;;
 686   *)
 687       case "${target}" in
 688         bpf-*-*)
 689           unsupported_languages="$unsupported_languages c++"
 690           ;;
 691       esac
 692       ;;
 693 esac
 694
 695 # Disable Objc on systems where it is known to not work.
 696 # For testing, you can override this with --enable-languages=objc.
 697 case ,${enable_languages}, in
 698   *,objc,*)
 699     ;;
 700   *)
 701       case "${target}" in
 702         bpf-*-*)
 703           unsupported_languages="$unsupported_languages objc"
 704           ;;
 705       esac
 706       ;;
 707 esac
 708
 709 # Disable D on systems where it is known to not work.
 710 # For testing, you can override this with --enable-languages=d.
 711 case ,${enable_languages}, in
 712   *,d,*)
 713     ;;
 714   *)
 715     case "${target}" in
 716       bpf-*-*)
 717         unsupported_languages="$unsupported_languages d"
 718         ;;
 719     esac
 720     ;;
 721 esac
 722
 723 # Disable libphobos on unsupported systems.
 724 # For testing, you can override this with --enable-libphobos.
 725 if test -d ${srcdir}/libphobos; then
 726     if test x$enable_libphobos = x; then
 727         AC_MSG_CHECKING([for libphobos support])
 728         if (srcdir=${srcdir}/libphobos; \
 729                 . ${srcdir}/configure.tgt; \
 730                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 731         then
 732             AC_MSG_RESULT([no])
 733             noconfigdirs="$noconfigdirs target-libphobos"
 734         else
 735             AC_MSG_RESULT([yes])
 736         fi
 737     fi
 738 fi
 739
 740 # Disable Fortran for some systems.
 741 case "${target}" in
 742   mmix-*-*)
 743     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 744     unsupported_languages="$unsupported_languages fortran"
 745     ;;
 746   bpf-*-*)
 747     unsupported_languages="$unsupported_languages fortran"
 748     ;;
 749 esac
 750
 751 # Disable libffi for some systems.
 752 case "${target}" in
 753   powerpc-*-darwin*)
 754     ;;
 755   i[[3456789]]86-*-darwin*)
 756     ;;
 757   x86_64-*-darwin[[912]]*)
 758     ;;
 759   *-*-darwin*)
 760     noconfigdirs="$noconfigdirs target-libffi"
 761     ;;
 762   *-*-netware*)
 763     noconfigdirs="$noconfigdirs target-libffi"
 764     ;;
 765   *-*-phoenix*)
 766     noconfigdirs="$noconfigdirs target-libffi"
 767     ;;
 768   *-*-rtems*)
 769     noconfigdirs="$noconfigdirs target-libffi"
 770     ;;
 771   *-*-tpf*)
 772     noconfigdirs="$noconfigdirs target-libffi"
 773     ;;
 774   *-*-uclinux*)
 775     noconfigdirs="$noconfigdirs target-libffi"
 776     ;;
 777   *-*-vxworks*)
 778     noconfigdirs="$noconfigdirs target-libffi"
 779     ;;
 780   aarch64*-*-freebsd*)
 781     noconfigdirs="$noconfigdirs target-libffi"
 782     ;;
 783   alpha*-*-*vms*)
 784     noconfigdirs="$noconfigdirs target-libffi"
 785     ;;
 786   arm*-*-freebsd*)
 787     noconfigdirs="$noconfigdirs target-libffi"
 788     ;;
 789   arm-wince-pe)
 790     noconfigdirs="$noconfigdirs target-libffi"
 791     ;;
 792   arm*-*-symbianelf*)
 793     noconfigdirs="$noconfigdirs target-libffi"
 794     ;;
 795   bpf-*-*)
 796     noconfigdirs="$noconfigdirs target-libffi"
 797     ;;
 798   cris-*-* | crisv32-*-*)
 799     case "${target}" in
 800       *-*-linux*)
 801         ;;
 802       *) # See PR46792 regarding target-libffi.
 803         noconfigdirs="$noconfigdirs target-libffi";;
 804     esac
 805     ;;
 806   hppa*64*-*-hpux*)
 807     noconfigdirs="$noconfigdirs target-libffi"
 808     ;;
 809   hppa*-hp-hpux11*)
 810     ;;
 811   hppa*-*-hpux*)
 812     noconfigdirs="$noconfigdirs target-libffi"
 813     ;;
 814   ia64*-*-*vms*)
 815     noconfigdirs="$noconfigdirs target-libffi"
 816     ;;
 817   i[[3456789]]86-w64-mingw*)
 818     noconfigdirs="$noconfigdirs target-libffi"
 819     ;;
 820   i[[3456789]]86-*-mingw*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   x86_64-*-mingw*)
 824     noconfigdirs="$noconfigdirs target-libffi"
 825     ;;
 826   mmix-*-*)
 827     noconfigdirs="$noconfigdirs target-libffi"
 828     ;;
 829   powerpc-*-aix*)
 830     ;;
 831   rs6000-*-aix*)
 832     ;;
 833   ft32-*-*)
 834     noconfigdirs="$noconfigdirs target-libffi"
 835     ;;
 836   *-*-lynxos*)
 837     noconfigdirs="$noconfigdirs target-libffi"
 838     ;;
 839 esac
 840
 841 # Disable the go frontend on systems where it is known to not work. Please keep
 842 # this in sync with contrib/config-list.mk.
 843 case "${target}" in
 844 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 845     unsupported_languages="$unsupported_languages go"
 846     ;;
 847 esac
 848
 849 # Only allow gdbserver on some systems.
 850 if test -d ${srcdir}/gdbserver; then
 851     if test x$enable_gdbserver = x; then
 852         AC_MSG_CHECKING([for gdbserver support])
 853         if (srcdir=${srcdir}/gdbserver; \
 854                 . ${srcdir}/configure.srv; \
 855                 test -n "$UNSUPPORTED")
 856         then
 857             AC_MSG_RESULT([no])
 858             noconfigdirs="$noconfigdirs gdbserver"
 859         else
 860             AC_MSG_RESULT([yes])
 861         fi
 862     fi
 863 fi
 864
 865 # Disable libgo for some systems where it is known to not work.
 866 # For testing, you can easily override this with --enable-libgo.
 867 if test x$enable_libgo = x; then
 868     case "${target}" in
 869     *-*-darwin*)
 870         # PR 46986
 871         noconfigdirs="$noconfigdirs target-libgo"
 872         ;;
 873     *-*-cygwin* | *-*-mingw*)
 874         noconfigdirs="$noconfigdirs target-libgo"
 875         ;;
 876     bpf-*-*)
 877         noconfigdirs="$noconfigdirs target-libgo"
 878         ;;
 879     esac
 880 fi
 881
 882 # Default libgloss CPU subdirectory.
 883 libgloss_dir="$target_cpu"
 884
 885 case "${target}" in
 886   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 887     libgloss_dir=wince
 888     ;;
 889   aarch64*-*-* )
 890     libgloss_dir=aarch64
 891     ;;
 892   arm*-*-*)
 893     libgloss_dir=arm
 894     ;;
 895   cris-*-* | crisv32-*-*)
 896     libgloss_dir=cris
 897     ;;
 898   kvx-*-elf)
 899     libgloss_dir=kvx-elf
 900     ;;
 901   kvx-*-mbr)
 902     libgloss_dir=kvx-mbr
 903     ;;
 904   kvx-*-cos)
 905     libgloss_dir=kvx-cos
 906     ;;
 907   hppa*-*-*)
 908     libgloss_dir=pa
 909     ;;
 910   i[[3456789]]86-*-*)
 911     libgloss_dir=i386
 912     ;;
 913   loongarch*-*-*)
 914     libgloss_dir=loongarch
 915     ;;
 916   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 917     libgloss_dir=m68hc11
 918     ;;
 919   m68*-*-* | fido-*-*)
 920     libgloss_dir=m68k
 921     ;;
 922   mips*-*-*)
 923     libgloss_dir=mips
 924     ;;
 925   powerpc*-*-*)
 926     libgloss_dir=rs6000
 927     ;;
 928   pru-*-*)
 929     libgloss_dir=pru
 930     ;;
 931   sparc*-*-*)
 932     libgloss_dir=sparc
 933     ;;
 934 esac
 935
 936 # Disable newlib and libgloss for various target OSes.
 937 case "${target}" in
 938   alpha*-dec-osf*)
 939     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 940     ;;
 941   i[[3456789]]86-*-linux*)
 942     # This section makes it possible to build newlib natively on linux.
 943     # If we are using a cross compiler then don't configure newlib.
 944     if test x${is_cross_compiler} != xno ; then
 945       noconfigdirs="$noconfigdirs target-newlib"
 946     fi
 947     noconfigdirs="$noconfigdirs target-libgloss"
 948     # If we are not using a cross compiler, do configure newlib.
 949     # Note however, that newlib will only be configured in this situation
 950     # if the --with-newlib option has been given, because otherwise
 951     # 'target-newlib' will appear in skipdirs.
 952     ;;
 953   i[[3456789]]86-*-rdos*)
 954     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 955     ;;
 956   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 957     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 958     ;;
 959   sparc-*-sunos4*)
 960     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 961     ;;
 962   bpf-*-*)
 963     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 964     ;;
 965   *-*-aix*)
 966     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 967     ;;
 968   *-*-beos*)
 969     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 970     ;;
 971   *-*-chorusos)
 972     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 973     ;;
 974   *-*-dragonfly*)
 975     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 976     ;;
 977   *-*-freebsd*)
 978     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 979     ;;
 980   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 981     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 982     ;;
 983   *-*-lynxos*)
 984     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 985     ;;
 986   *-*-mingw*)
 987     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 988     ;;
 989   *-*-netbsd*)
 990     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 991     ;;
 992   *-*-netware*)
 993     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 994     ;;
 995   *-*-tpf*)
 996     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 997     ;;
 998   *-*-uclinux*)
 999     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1000     ;;
1001   *-*-vxworks*)
1002     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1003     ;;
1004 esac
1005
1006 case "${target}" in
1007   *-*-chorusos)
1008     ;;
1009   aarch64-*-darwin*)
1010     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1011     noconfigdirs="$noconfigdirs sim target-rda"
1012     ;;
1013   amdgcn*-*-*)
1014     ;;
1015   arm-*-darwin*)
1016     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1017     noconfigdirs="$noconfigdirs sim target-rda"
1018     ;;
1019   powerpc-*-darwin*)
1020     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1021     noconfigdirs="$noconfigdirs sim target-rda"
1022     ;;
1023   i[[3456789]]86-*-darwin*)
1024     noconfigdirs="$noconfigdirs ld gprof"
1025     noconfigdirs="$noconfigdirs sim target-rda"
1026     ;;
1027   x86_64-*-darwin[[912]]*)
1028     noconfigdirs="$noconfigdirs ld gas gprof"
1029     noconfigdirs="$noconfigdirs sim target-rda"
1030     ;;
1031   *-*-darwin*)
1032     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1033     noconfigdirs="$noconfigdirs sim target-rda"
1034     ;;
1035   *-*-dragonfly*)
1036     ;;
1037   *-*-freebsd*)
1038     if test "x$with_gmp" = x \
1039         && ! test -d ${srcdir}/gmp \
1040         && test -f /usr/local/include/gmp.h; then
1041       with_gmp=/usr/local
1042     fi
1043     ;;
1044   *-*-kaos*)
1045     # Remove unsupported stuff on all kaOS configurations.
1046     noconfigdirs="$noconfigdirs target-libgloss"
1047     ;;
1048   *-*-netbsd*)
1049     ;;
1050   *-*-netware*)
1051     ;;
1052   *-*-phoenix*)
1053     noconfigdirs="$noconfigdirs target-libgloss"
1054     ;;
1055   *-*-rtems*)
1056     noconfigdirs="$noconfigdirs target-libgloss"
1057     ;;
1058     # The tpf target doesn't support gdb yet.
1059   *-*-tpf*)
1060     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1061     ;;
1062   *-*-uclinux*)
1063     noconfigdirs="$noconfigdirs target-rda"
1064     ;;
1065   *-*-vxworks*)
1066     ;;
1067   alpha*-dec-osf*)
1068     # ld works, but does not support shared libraries.
1069     # gas doesn't generate exception information.
1070     noconfigdirs="$noconfigdirs gas ld"
1071     ;;
1072   alpha*-*-*vms*)
1073     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1074     ;;
1075   alpha*-*-*)
1076     # newlib is not 64 bit ready
1077     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1078     ;;
1079   bpf-*-*)
1080     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1081     ;;
1082   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1083     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1084     ;;
1085   arc*-*-*)
1086     noconfigdirs="$noconfigdirs sim"
1087     ;;
1088   arm-*-pe*)
1089     noconfigdirs="$noconfigdirs target-libgloss"
1090     ;;
1091   arm-*-riscix*)
1092     noconfigdirs="$noconfigdirs ld target-libgloss"
1093     ;;
1094   avr-*-*)
1095     if test x${with_avrlibc} != xno; then
1096       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1097     fi
1098     ;;
1099   c4x-*-* | tic4x-*-*)
1100     noconfigdirs="$noconfigdirs target-libgloss"
1101     ;;
1102   tic54x-*-*)
1103     noconfigdirs="$noconfigdirs target-libgloss gdb"
1104     ;;
1105   d10v-*-*)
1106     noconfigdirs="$noconfigdirs target-libgloss"
1107     ;;
1108   d30v-*-*)
1109     noconfigdirs="$noconfigdirs gdb"
1110     ;;
1111   fr30-*-elf*)
1112     noconfigdirs="$noconfigdirs gdb"
1113     ;;
1114   ft32-*-*)
1115     noconfigdirs="$noconfigdirs target-rda gprof"
1116     ;;
1117   moxie-*-*)
1118     noconfigdirs="$noconfigdirs"
1119     ;;
1120   h8300*-*-*)
1121     noconfigdirs="$noconfigdirs target-libgloss"
1122     ;;
1123   h8500-*-*)
1124     noconfigdirs="$noconfigdirs target-libgloss"
1125     ;;
1126   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1127     ;;
1128   hppa*64*-*-hpux*)
1129     noconfigdirs="$noconfigdirs gdb"
1130     ;;
1131   hppa*-*-hpux11*)
1132     noconfigdirs="$noconfigdirs gdb ld"
1133     ;;
1134   hppa*64*-*-linux*)
1135     ;;
1136   hppa*-*-linux*)
1137     ;;
1138   hppa*-*-*elf* | \
1139   hppa*-*-lites* | \
1140   hppa*-*-openbsd* | \
1141   hppa*64*-*-*)
1142     ;;
1143   hppa*-*-pro*)
1144     ;;
1145   hppa*-*-*)
1146     noconfigdirs="$noconfigdirs ld"
1147     ;;
1148   i960-*-*)
1149     noconfigdirs="$noconfigdirs gdb"
1150     ;;
1151   ia64*-*-elf*)
1152     # No gdb support yet.
1153     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1154     ;;
1155   ia64*-**-hpux*)
1156     # No ld support yet.
1157     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1158     ;;
1159   ia64*-*-*vms*)
1160     # No ld support yet.
1161     noconfigdirs="$noconfigdirs libgui itcl ld"
1162     ;;
1163   i[[3456789]]86-w64-mingw*)
1164     ;;
1165   i[[3456789]]86-*-mingw*)
1166     target_configdirs="$target_configdirs target-winsup"
1167     ;;
1168   *-*-cygwin*)
1169     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1170     noconfigdirs="$noconfigdirs target-libgloss"
1171     # always build newlib if winsup directory is present.
1172     if test -d "$srcdir/winsup/cygwin"; then
1173       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1174     elif test -d "$srcdir/newlib"; then
1175       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1176     fi
1177     ;;
1178   i[[3456789]]86-*-pe)
1179     noconfigdirs="$noconfigdirs target-libgloss"
1180     ;;
1181   i[[3456789]]86-*-sco3.2v5*)
1182     # The linker does not yet know about weak symbols in COFF,
1183     # and is not configured to handle mixed ELF and COFF.
1184     noconfigdirs="$noconfigdirs ld target-libgloss"
1185     ;;
1186   i[[3456789]]86-*-sco*)
1187     noconfigdirs="$noconfigdirs gprof target-libgloss"
1188     ;;
1189   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1190     noconfigdirs="$noconfigdirs target-libgloss"
1191     ;;
1192   i[[3456789]]86-*-sysv4*)
1193     noconfigdirs="$noconfigdirs target-libgloss"
1194     ;;
1195   i[[3456789]]86-*-beos*)
1196     noconfigdirs="$noconfigdirs gdb"
1197     ;;
1198   i[[3456789]]86-*-rdos*)
1199     noconfigdirs="$noconfigdirs gdb"
1200     ;;
1201   kvx-*-*)
1202     noconfigdirs="$noconfigdirs gdb gdbserver sim"
1203     ;;
1204   mmix-*-*)
1205     noconfigdirs="$noconfigdirs gdb"
1206     ;;
1207   mt-*-*)
1208     noconfigdirs="$noconfigdirs sim"
1209     ;;
1210   nfp-*-*)
1211     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1212     noconfigdirs="$noconfigdirs $target_libraries"
1213     ;;
1214   pdp11-*-*)
1215     noconfigdirs="$noconfigdirs gdb gprof"
1216     ;;
1217   powerpc-*-aix*)
1218     # copied from rs6000-*-* entry
1219     noconfigdirs="$noconfigdirs gprof"
1220     ;;
1221   powerpc*-*-winnt* | powerpc*-*-pe*)
1222     target_configdirs="$target_configdirs target-winsup"
1223     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1224     # always build newlib.
1225     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1226     ;;
1227     # This is temporary until we can link against shared libraries
1228   powerpcle-*-solaris*)
1229     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1230     ;;
1231   powerpc-*-beos*)
1232     noconfigdirs="$noconfigdirs gdb"
1233     ;;
1234   rs6000-*-lynxos*)
1235     noconfigdirs="$noconfigdirs gprof"
1236     ;;
1237   rs6000-*-aix*)
1238     noconfigdirs="$noconfigdirs gprof"
1239     ;;
1240   rs6000-*-*)
1241     noconfigdirs="$noconfigdirs gprof"
1242     ;;
1243   m68k-apollo-*)
1244     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1245     ;;
1246   microblaze*)
1247     noconfigdirs="$noconfigdirs gprof"
1248     ;;
1249   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1250     if test x$with_newlib = xyes; then
1251       noconfigdirs="$noconfigdirs gprof"
1252     fi
1253     ;;
1254   mips*-*-irix5*)
1255     noconfigdirs="$noconfigdirs gprof target-libgloss"
1256     ;;
1257   mips*-*-irix6*)
1258     noconfigdirs="$noconfigdirs gprof target-libgloss"
1259     ;;
1260   mips*-*-bsd*)
1261     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1262     ;;
1263   mips*-*-linux*)
1264     ;;
1265   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1266   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1267     noconfigdirs="$noconfigdirs ld gas gprof"
1268     ;;
1269   mips*-*-*)
1270     noconfigdirs="$noconfigdirs gprof"
1271     ;;
1272   nvptx*-*-*)
1273     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1274     ;;
1275   sh-*-*)
1276     case "${target}" in
1277       sh*-*-elf)
1278          ;;
1279       *)
1280          noconfigdirs="$noconfigdirs target-libgloss" ;;
1281     esac
1282     ;;
1283   sparc-*-sunos4*)
1284     if test x${is_cross_compiler} = xno ; then
1285            use_gnu_ld=no
1286     fi
1287     ;;
1288   tic6x-*-*)
1289     noconfigdirs="$noconfigdirs sim"
1290     ;;
1291   tilepro*-*-* | tilegx*-*-*)
1292     noconfigdirs="$noconfigdirs sim"
1293     ;;
1294   v810-*-*)
1295     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1296     ;;
1297   vax-*-*)
1298     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1299     ;;
1300   wasm32-*-*)
1301     noconfigdirs="$noconfigdirs ld"
1302     ;;
1303   loongarch*-*-linux*)
1304     ;;
1305   loongarch*-*-*)
1306     noconfigdirs="$noconfigdirs gprof"
1307     ;;
1308 esac
1309
1310 # If we aren't building newlib, then don't build libgloss, since libgloss
1311 # depends upon some newlib header files.
1312 case "${noconfigdirs}" in
1313   *target-libgloss*) ;;
1314   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1315 esac
1316
1317 # Work in distributions that contain no compiler tools, like Autoconf.
1318 host_makefile_frag=/dev/null
1319 if test -d ${srcdir}/config ; then
1320 case "${host}" in
1321   i[[3456789]]86-*-msdosdjgpp*)
1322     host_makefile_frag="config/mh-djgpp"
1323     ;;
1324   *-cygwin*)
1325     ACX_CHECK_CYGWIN_CAT_WORKS
1326     host_makefile_frag="config/mh-cygwin"
1327     ;;
1328   *-mingw*)
1329     host_makefile_frag="config/mh-mingw"
1330     ;;
1331   alpha*-linux*)
1332     host_makefile_frag="config/mh-alpha-linux"
1333     ;;
1334   hppa*-hp-hpux*)
1335     host_makefile_frag="config/mh-pa"
1336     ;;
1337   hppa*-*)
1338     host_makefile_frag="config/mh-pa"
1339     ;;
1340   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1341     host_makefile_frag="config/mh-darwin"
1342     ;;
1343   powerpc-*-aix*)
1344     host_makefile_frag="config/mh-ppc-aix"
1345     ;;
1346   rs6000-*-aix*)
1347     host_makefile_frag="config/mh-ppc-aix"
1348     ;;
1349 esac
1350 fi
1351
1352 if test "${build}" != "${host}" ; then
1353   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1354   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1355   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1356   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1357   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1358   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1359   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1360   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1361   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1362   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1363   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1364   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1365   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1366   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1367   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1368 else
1369   AR_FOR_BUILD="\$(AR)"
1370   AS_FOR_BUILD="\$(AS)"
1371   CC_FOR_BUILD="\$(CC)"
1372   CXX_FOR_BUILD="\$(CXX)"
1373   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1374   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1375   GOC_FOR_BUILD="\$(GOC)"
1376   GDC_FOR_BUILD="\$(GDC)"
1377   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1378   LD_FOR_BUILD="\$(LD)"
1379   NM_FOR_BUILD="\$(NM)"
1380   RANLIB_FOR_BUILD="\$(RANLIB)"
1381   WINDRES_FOR_BUILD="\$(WINDRES)"
1382   WINDMC_FOR_BUILD="\$(WINDMC)"
1383 fi
1384
1385 AC_PROG_CC_C99
1386 AC_PROG_CXX
1387
1388 # We must set the default linker to the linker used by gcc for the correct
1389 # operation of libtool.  If LD is not defined and we are using gcc, try to
1390 # set the LD default to the ld used by gcc.
1391 if test -z "$LD"; then
1392   if test "$GCC" = yes; then
1393     case $build in
1394     *-*-mingw*)
1395       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1396     *)
1397       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1398     esac
1399     case $gcc_prog_ld in
1400     # Accept absolute paths.
1401     [[\\/]* | [A-Za-z]:[\\/]*)]
1402       LD="$gcc_prog_ld" ;;
1403     esac
1404   fi
1405 fi
1406
1407 # Check whether -static-libstdc++ -static-libgcc is supported.
1408 have_static_libs=no
1409 if test "$GCC" = yes; then
1410   saved_LDFLAGS="$LDFLAGS"
1411
1412   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1413   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1414   AC_LANG_PUSH(C++)
1415   AC_LINK_IFELSE([AC_LANG_SOURCE([
1416 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1417 #error -static-libstdc++ not implemented
1418 #endif
1419 int main() {}])],
1420     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1421     [AC_MSG_RESULT([no])])
1422   AC_LANG_POP(C++)
1423
1424   LDFLAGS="$saved_LDFLAGS"
1425 fi
1426
1427 ACX_PROG_GNAT
1428 ACX_PROG_GDC
1429 ACX_PROG_CMP_IGNORE_INITIAL
1430
1431 AC_ARG_ENABLE([bootstrap],
1432 [AS_HELP_STRING([--enable-bootstrap],
1433                 [enable bootstrapping @<:@yes if native build@:>@])],,
1434 enable_bootstrap=default)
1435
1436 # Issue errors and warnings for invalid/strange bootstrap combinations.
1437 if test -r $srcdir/gcc/configure; then
1438   have_compiler=yes
1439 else
1440   have_compiler=no
1441 fi
1442
1443 case "$have_compiler:$host:$target:$enable_bootstrap" in
1444   *:*:*:no) ;;
1445
1446   # Default behavior.  Enable bootstrap if we have a compiler
1447   # and we are in a native configuration.
1448   yes:$build:$build:default)
1449     enable_bootstrap=yes ;;
1450
1451   *:*:*:default)
1452     enable_bootstrap=no ;;
1453
1454   # We have a compiler and we are in a native configuration, bootstrap is ok
1455   yes:$build:$build:yes)
1456     ;;
1457
1458   # Other configurations, but we have a compiler.  Assume the user knows
1459   # what he's doing.
1460   yes:*:*:yes)
1461     AC_MSG_WARN([trying to bootstrap a cross compiler])
1462     ;;
1463
1464   # No compiler: if they passed --enable-bootstrap explicitly, fail
1465   no:*:*:yes)
1466     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1467
1468   # Fail if wrong command line
1469   *)
1470     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1471     ;;
1472 esac
1473
1474 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1475 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1476 # require C++11 (or higher).
1477 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1478   CXX="$CXX -std=c++11"
1479 elif test "$have_compiler" = yes; then
1480   AX_CXX_COMPILE_STDCXX(11)
1481
1482   if test "${build}" != "${host}"; then
1483     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1484   fi
1485 fi
1486
1487 AC_ARG_ENABLE([pgo-build],
1488 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1489                 [enable the PGO build])],
1490 [enable_pgo_build=$enableval],
1491 [enable_pgo_build=no])
1492
1493 # Issue errors and warnings for invalid/strange PGO build combinations.
1494 case "$have_compiler:$host:$target:$enable_pgo_build" in
1495   *:*:*:no) ;;
1496
1497   # Allow the PGO build only if we aren't building a compiler and
1498   # we are in a native configuration.
1499   no:$build:$build:yes | no:$build:$build:lto) ;;
1500
1501   # Disallow the PGO bootstrap if we are building a compiler.
1502   yes:*:*:yes | yes:*:*:lto)
1503     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1504
1505   *)
1506     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1507     ;;
1508 esac
1509
1510 if test "$enable_pgo_build" != "no"; then
1511   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1512   old_CFLAGS="$CFLAGS"
1513   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1514   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1515   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1516                     [PGO_BUILD_GEN_CFLAGS=])
1517   CFLAGS="$old_CFLAGS"
1518   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1519     AC_MSG_RESULT([yes])
1520     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1521   else
1522     AC_MSG_RESULT([no])
1523     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1524   fi
1525
1526   if test "$enable_pgo_build" = "lto"; then
1527     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1528     old_CFLAGS="$CFLAGS"
1529     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1530     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1531     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1532                       [PGO_BUILD_LTO_CFLAGS=])
1533     CFLAGS="$old_CFLAGS"
1534     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1535       AC_MSG_RESULT([yes])
1536     else
1537       AC_MSG_RESULT([no])
1538       AC_MSG_WARN([LTO is disabled for the PGO build])
1539     fi
1540   fi
1541 fi
1542 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1543 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1544 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1545
1546 # Used for setting $lt_cv_objdir
1547 _LT_CHECK_OBJDIR
1548
1549 # Check for GMP, MPFR and MPC
1550 require_gmp=no
1551 require_mpc=no
1552 if test -d ${srcdir}/gcc ; then
1553   require_gmp=yes
1554   require_mpc=yes
1555 fi
1556 if test -d ${srcdir}/gdb ; then
1557   if test "x$enable_gdb" != xno; then
1558    require_gmp=yes
1559   fi
1560 fi
1561
1562 gmplibs="-lmpfr -lgmp"
1563 if test x"$require_mpc" = "xyes" ; then
1564   gmplibs="-lmpc $gmplibs"
1565 fi
1566 gmpinc=
1567 have_gmp=no
1568
1569 # Specify a location for mpc
1570 # check for this first so it ends up on the link line before mpfr.
1571 AC_ARG_WITH(mpc,
1572 [AS_HELP_STRING([--with-mpc=PATH],
1573                 [specify prefix directory for installed MPC package.
1574                  Equivalent to --with-mpc-include=PATH/include
1575                  plus --with-mpc-lib=PATH/lib])])
1576 AC_ARG_WITH(mpc-include,
1577 [AS_HELP_STRING([--with-mpc-include=PATH],
1578                 [specify directory for installed MPC include files])])
1579 AC_ARG_WITH(mpc-lib,
1580 [AS_HELP_STRING([--with-mpc-lib=PATH],
1581                 [specify directory for the installed MPC library])])
1582
1583 if test "x$with_mpc" != x; then
1584   gmplibs="-L$with_mpc/lib $gmplibs"
1585   gmpinc="-I$with_mpc/include $gmpinc"
1586 fi
1587 if test "x$with_mpc_include" != x; then
1588   gmpinc="-I$with_mpc_include $gmpinc"
1589 fi
1590 if test "x$with_mpc_lib" != x; then
1591   gmplibs="-L$with_mpc_lib $gmplibs"
1592 fi
1593 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1594   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1595   gmpinc='-I$$s/mpc/src '"$gmpinc"
1596   # Do not test the mpc version.  Assume that it is sufficient, since
1597   # it is in the source tree, and the library has not been built yet
1598   # but it would be included on the link line in the version check below
1599   # hence making the test fail.
1600   have_gmp=yes
1601 fi
1602
1603 # Specify a location for mpfr
1604 # check for this first so it ends up on the link line before gmp.
1605 AC_ARG_WITH(mpfr,
1606 [AS_HELP_STRING([--with-mpfr=PATH],
1607                 [specify prefix directory for installed MPFR package.
1608                  Equivalent to --with-mpfr-include=PATH/include
1609                  plus --with-mpfr-lib=PATH/lib])])
1610 AC_ARG_WITH(mpfr-include,
1611 [AS_HELP_STRING([--with-mpfr-include=PATH],
1612                 [specify directory for installed MPFR include files])])
1613 AC_ARG_WITH(mpfr-lib,
1614 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1615                 [specify directory for the installed MPFR library])])
1616
1617 if test "x$with_mpfr" != x; then
1618   gmplibs="-L$with_mpfr/lib $gmplibs"
1619   gmpinc="-I$with_mpfr/include $gmpinc"
1620 fi
1621 if test "x$with_mpfr_include" != x; then
1622   gmpinc="-I$with_mpfr_include $gmpinc"
1623 fi
1624 if test "x$with_mpfr_lib" != x; then
1625   gmplibs="-L$with_mpfr_lib $gmplibs"
1626 fi
1627 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1628   # MPFR v3.1.0 moved the sources into a src sub-directory.
1629   if ! test -d ${srcdir}/mpfr/src; then
1630     AC_MSG_ERROR([dnl
1631 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1632   fi
1633   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1634   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1635   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1636   # Do not test the mpfr version.  Assume that it is sufficient, since
1637   # it is in the source tree, and the library has not been built yet
1638   # but it would be included on the link line in the version check below
1639   # hence making the test fail.
1640   have_gmp=yes
1641 fi
1642
1643 # Specify a location for gmp
1644 AC_ARG_WITH(gmp,
1645 [AS_HELP_STRING([--with-gmp=PATH],
1646                 [specify prefix directory for the installed GMP package.
1647                  Equivalent to --with-gmp-include=PATH/include
1648                  plus --with-gmp-lib=PATH/lib])])
1649 AC_ARG_WITH(gmp-include,
1650 [AS_HELP_STRING([--with-gmp-include=PATH],
1651                 [specify directory for installed GMP include files])])
1652 AC_ARG_WITH(gmp-lib,
1653 [AS_HELP_STRING([--with-gmp-lib=PATH],
1654                 [specify directory for the installed GMP library])])
1655
1656
1657 if test "x$with_gmp" != x; then
1658   gmplibs="-L$with_gmp/lib $gmplibs"
1659   gmpinc="-I$with_gmp/include $gmpinc"
1660 fi
1661 if test "x$with_gmp_include" != x; then
1662   gmpinc="-I$with_gmp_include $gmpinc"
1663 fi
1664 if test "x$with_gmp_lib" != x; then
1665   gmplibs="-L$with_gmp_lib $gmplibs"
1666 fi
1667 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1668   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1669   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1670   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1671   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1672   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1673   # Do not test the gmp version.  Assume that it is sufficient, since
1674   # it is in the source tree, and the library has not been built yet
1675   # but it would be included on the link line in the version check below
1676   # hence making the test fail.
1677   have_gmp=yes
1678 fi
1679
1680 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1681   have_gmp=yes
1682   saved_CFLAGS="$CFLAGS"
1683   CFLAGS="$CFLAGS $gmpinc"
1684   # Check for the recommended and required versions of GMP.
1685   AC_MSG_CHECKING([for the correct version of gmp.h])
1686   AC_TRY_COMPILE([#include "gmp.h"],[
1687   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1688   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1689   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1690   choke me
1691   #endif
1692   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1693   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1694   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1695   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1696   choke me
1697   #endif
1698   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1699    [AC_MSG_RESULT([no]); have_gmp=no])
1700
1701   # If we have GMP, check the MPFR version.
1702   if test x"$have_gmp" = xyes; then
1703     # Check for the recommended and required versions of MPFR.
1704     AC_MSG_CHECKING([for the correct version of mpfr.h])
1705     AC_TRY_COMPILE([#include <gmp.h>
1706     #include <mpfr.h>],[
1707     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1708     choke me
1709     #endif
1710     ], [AC_TRY_COMPILE([#include <gmp.h>
1711     #include <mpfr.h>],[
1712     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1713     choke me
1714     #endif
1715     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1716      [AC_MSG_RESULT([no]); have_gmp=no])
1717   fi
1718
1719   # Check for the MPC header version.
1720   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1721     # Check for the recommended and required versions of MPC.
1722     AC_MSG_CHECKING([for the correct version of mpc.h])
1723     AC_TRY_COMPILE([#include <mpc.h>],[
1724     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1725     choke me
1726     #endif
1727     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1728     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1729     choke me
1730     #endif
1731     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1732      [AC_MSG_RESULT([no]); have_gmp=no])
1733   fi
1734
1735   # Now check the MPFR library.
1736   if test x"$have_gmp" = xyes; then
1737     saved_LIBS="$LIBS"
1738     LIBS="$LIBS $gmplibs"
1739     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1740     AC_TRY_LINK([#include <mpfr.h>],[
1741     mpfr_t n;
1742     mpfr_t x;
1743     int t;
1744     mpfr_init (n);
1745     mpfr_init (x);
1746     mpfr_atan2 (n, n, x, MPFR_RNDN);
1747     mpfr_erfc (n, x, MPFR_RNDN);
1748     mpfr_subnormalize (x, t, MPFR_RNDN);
1749     mpfr_clear(n);
1750     mpfr_clear(x);
1751     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1752     LIBS="$saved_LIBS"
1753   fi
1754
1755   # Now check the MPC library
1756   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1757     saved_LIBS="$LIBS"
1758     LIBS="$LIBS $gmplibs"
1759     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1760     AC_TRY_LINK([#include <mpc.h>],[
1761     mpc_t c;
1762     mpc_init2 (c, 53);
1763     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1764     mpc_cosh (c, c, MPC_RNDNN);
1765     mpc_pow (c, c, c, MPC_RNDNN);
1766     mpc_acosh (c, c, MPC_RNDNN);
1767     mpc_clear (c);
1768     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1769     LIBS="$saved_LIBS"
1770   fi
1771
1772   CFLAGS="$saved_CFLAGS"
1773
1774 # The library versions listed in the error message below should match
1775 # the HARD-minimums enforced above.
1776   if test x$have_gmp != xyes; then
1777     if test -d ${srcdir}/gcc ; then
1778       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1779 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1780 their locations.  Source code for these libraries can be found at
1781 their respective hosting sites as well as at
1782 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1783 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1784 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1785 make sure that you have installed both the libraries and the header
1786 files.  They may be located in separate packages.])
1787     else
1788       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1789 Try the --with-gmp and/or --with-mpfr options to specify
1790 their locations.  If you obtained GMP and/or MPFR from a vendor
1791 distribution package, make sure that you have installed both the libraries
1792 and the header files.  They may be located in separate packages.])
1793     fi
1794   fi
1795 fi
1796
1797 # Flags needed for both GMP, MPFR and/or MPC.
1798 AC_SUBST(gmplibs)
1799 AC_SUBST(gmpinc)
1800 AC_SUBST(extra_mpfr_configure_flags)
1801 AC_SUBST(extra_mpc_gmp_configure_flags)
1802 AC_SUBST(extra_mpc_mpfr_configure_flags)
1803 AC_SUBST(extra_isl_gmp_configure_flags)
1804
1805 # Libraries to use for stage1 or when not bootstrapping.
1806 AC_ARG_WITH(stage1-libs,
1807 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1808 [if test "$withval" = "no" -o "$withval" = "yes"; then
1809    stage1_libs=
1810  else
1811    stage1_libs=$withval
1812  fi],
1813 [stage1_libs=])
1814 AC_SUBST(stage1_libs)
1815
1816 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1817 # default is yes if gcc is being built; no otherwise.  The reason for
1818 # this default is that gdb is sometimes linked against GNU Source
1819 # Highlight, which is a shared library that uses C++ exceptions.  In
1820 # this case, -static-libstdc++ will cause crashes.
1821 AC_ARG_WITH(static-standard-libraries,
1822 [AS_HELP_STRING([--with-static-standard-libraries],
1823                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1824 [], [with_static_standard_libraries=auto])
1825 if test "$with_static_standard_libraries" = auto; then
1826   with_static_standard_libraries=$have_compiler
1827 fi
1828
1829 # Linker flags to use for stage1 or when not bootstrapping.
1830 AC_ARG_WITH(stage1-ldflags,
1831 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1832 [if test "$withval" = "no" -o "$withval" = "yes"; then
1833    stage1_ldflags=
1834  else
1835    stage1_ldflags=$withval
1836  fi],
1837 [stage1_ldflags=
1838  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1839  # if supported.  But if the user explicitly specified the libraries to use,
1840  # trust that they are doing what they want.
1841  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1842      -a "$have_static_libs" = yes; then
1843    stage1_ldflags="-static-libstdc++ -static-libgcc"
1844  fi])
1845 AC_SUBST(stage1_ldflags)
1846
1847 # Libraries to use for stage2 and later builds.
1848 AC_ARG_WITH(boot-libs,
1849 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1850 [if test "$withval" = "no" -o "$withval" = "yes"; then
1851    poststage1_libs=
1852  else
1853    poststage1_libs=$withval
1854  fi],
1855 [poststage1_libs=])
1856 AC_SUBST(poststage1_libs)
1857
1858 # Linker flags to use for stage2 and later builds.
1859 AC_ARG_WITH(boot-ldflags,
1860 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1861                 [linker flags for stage2 and later])],
1862 [if test "$withval" = "no" -o "$withval" = "yes"; then
1863    poststage1_ldflags=
1864  else
1865    poststage1_ldflags=$withval
1866  fi],
1867 [poststage1_ldflags=
1868  # In stages 2 and 3, default to linking libstdc++ and libgcc
1869  # statically.  But if the user explicitly specified the libraries to
1870  # use, trust that they are doing what they want.
1871  if test "$poststage1_libs" = ""; then
1872    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1873  fi])
1874 case $target in
1875   *-darwin2* | *-darwin1[[56789]]*)
1876     # For these versions, we default to using embedded rpaths.
1877     if test "x$enable_darwin_at_rpath" != "xno"; then
1878       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1879     fi
1880   ;;
1881   *-darwin*)
1882     # For these versions, we only use embedded rpaths on demand.
1883     if test "x$enable_darwin_at_rpath" = "xyes"; then
1884       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1885     fi
1886   ;;
1887 esac
1888 AC_SUBST(poststage1_ldflags)
1889
1890 # GCC GRAPHITE dependency isl.
1891 # Basic setup is inlined here, actual checks are in config/isl.m4
1892
1893 AC_ARG_WITH(isl,
1894   [AS_HELP_STRING(
1895    [--with-isl=PATH],
1896    [Specify prefix directory for the installed isl package.
1897     Equivalent to --with-isl-include=PATH/include
1898     plus --with-isl-lib=PATH/lib])])
1899
1900 # Treat --without-isl as a request to disable
1901 # GRAPHITE support and skip all following checks.
1902 if test "x$with_isl" != "xno"; then
1903   # Check for isl
1904   dnl Provide configure switches and initialize islinc & isllibs
1905   dnl with user input.
1906   ISL_INIT_FLAGS
1907   dnl The versions of isl that work for Graphite
1908   ISL_CHECK_VERSION()
1909   dnl Only execute fail-action, if isl has been requested.
1910   ISL_IF_FAILED([
1911     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1912 fi
1913
1914 # If the isl check failed, disable builds of in-tree variant of isl
1915 if test "x$with_isl" = xno ||
1916    test "x$gcc_cv_isl" = xno; then
1917   noconfigdirs="$noconfigdirs isl"
1918   islinc=
1919 fi
1920
1921 AC_SUBST(isllibs)
1922 AC_SUBST(islinc)
1923
1924 # Check for LTO support.
1925 AC_ARG_ENABLE(lto,
1926 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1927 enable_lto=$enableval,
1928 enable_lto=yes; default_enable_lto=yes)
1929
1930 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1931   build_lto_plugin=yes
1932 ],[if test x"$default_enable_lto" = x"yes" ; then
1933     case $target in
1934       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1935       # On other non-ELF platforms, LTO has yet to be validated.
1936       *) enable_lto=no ;;
1937     esac
1938   else
1939   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1940   # It would also be nice to check the binutils support, but we don't
1941   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1942   # warn during gcc/ subconfigure; unless you're bootstrapping with
1943   # -flto it won't be needed until after installation anyway.
1944     case $target in
1945       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1946       *) if test x"$enable_lto" = x"yes"; then
1947         AC_MSG_ERROR([LTO support is not enabled for this target.])
1948         fi
1949       ;;
1950     esac
1951   fi
1952   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1953   # Build it unless LTO was explicitly disabled.
1954   case $target in
1955     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1956     *) ;;
1957   esac
1958 ])
1959
1960 AC_ARG_ENABLE(linker-plugin-configure-flags,
1961   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1962     [additional flags for configuring linker plugins @<:@none@:>@])],
1963   extra_linker_plugin_configure_flags=$enableval,
1964   extra_linker_plugin_configure_flags=)
1965 AC_SUBST(extra_linker_plugin_configure_flags)
1966 AC_ARG_ENABLE(linker-plugin-flags,
1967   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1968     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1969   extra_linker_plugin_flags=$enableval,
1970   extra_linker_plugin_flags=)
1971 AC_SUBST(extra_linker_plugin_flags)
1972
1973 # Handle --enable-host-pie
1974 # If host PIE executables are the default (or must be forced on) for some host,
1975 # we must pass that configuration to the gcc directory.
1976 gcc_host_pie=
1977 AC_ARG_ENABLE(host-pie,
1978 [AS_HELP_STRING([--enable-host-pie],
1979                 [build position independent host executables])],
1980 [host_pie=$enableval
1981  case $host in
1982    *-*-darwin2*)
1983      if test x$host_pie != xyes ; then
1984        # for Darwin20+ this is required.
1985        AC_MSG_WARN([PIE executables are required for the configured host, host-pie setting ignored.])
1986        host_pie=yes
1987        gcc_host_pie=--enable-host-pie
1988      fi ;;
1989   *) ;;
1990  esac],
1991 [case $host in
1992   *-*-darwin2*)
1993     # Default to PIE (mandatory for aarch64).
1994     host_pie=yes
1995     gcc_host_pie=--enable-host-pie
1996     ;;
1997   *) host_pie=no ;;
1998  esac])
1999
2000 AC_SUBST(host_pie)
2001 AC_SUBST(gcc_host_pie)
2002
2003 # Enable --enable-host-shared.
2004 # Checked early to determine whether jit is an 'all' language
2005 AC_ARG_ENABLE(host-shared,
2006 [AS_HELP_STRING([--enable-host-shared],
2007                 [build host code as shared libraries])],
2008 [host_shared=$enableval
2009  case $host in
2010    x86_64-*-darwin* | aarch64-*-darwin*)
2011      if test x$host_shared != xyes ; then
2012        # PIC is the default, and actually cannot be switched off.
2013        AC_MSG_WARN([PIC code is required for the configured host; host-shared setting ignored.])
2014        host_shared=yes
2015      fi ;;
2016    *-*-darwin*)
2017      if test x$host_pie = xyes -a x$host_shared != xyes ; then
2018        AC_MSG_WARN([PIC code is required for PIE host executables host-shared setting ignored.])
2019        host_shared=yes
2020      fi ;;
2021   *) ;;
2022  esac],
2023 [case $host in
2024   # 64B x86_64 and Aarch64 Darwin default to PIC.
2025   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
2026   # 32B and powerpc64 Darwin must use PIC to link PIE exes.
2027   *-*-darwin*) host_shared=$host_pie ;;
2028   *) host_shared=no;;
2029  esac])
2030
2031 AC_SUBST(host_shared)
2032
2033 if test x$host_shared = xyes; then
2034   case $host in
2035     *-*-darwin*)
2036       # Since host shared is the default for 64b Darwin, and also enabled for
2037       # host_pie, ensure that we present the PIE flag when host_pie is active.
2038       if test x$host_pie = xyes; then
2039         PICFLAG=-fPIE
2040       fi
2041       ;;
2042     *)
2043       PICFLAG=-fPIC
2044       ;;
2045   esac
2046 elif test x$host_pie = xyes; then
2047   PICFLAG=-fPIE
2048 else
2049   PICFLAG=
2050 fi
2051
2052 AC_SUBST(PICFLAG)
2053
2054 # If we are building PIC/PIE host executables, and we are building dependent
2055 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
2056 # code.
2057 host_libs_picflag=
2058 if test "$host_shared" = "yes" -o "$host_pie" = "yes"; then
2059 host_libs_picflag='--with-pic'
2060 fi
2061 AC_SUBST(host_libs_picflag)
2062
2063 # By default, C and C++ are the only stage 1 languages.
2064 stage1_languages=,c,
2065
2066 # Target libraries that we bootstrap.
2067 bootstrap_target_libs=,target-libgcc,
2068
2069 # Figure out what language subdirectories are present.
2070 # Look if the user specified --enable-languages="..."; if not, use
2071 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2072 # go away some day.
2073 # NB:  embedded tabs in this IF block -- do not untabify
2074 if test -d ${srcdir}/gcc; then
2075   if test x"${enable_languages+set}" != xset; then
2076     if test x"${LANGUAGES+set}" = xset; then
2077       enable_languages="${LANGUAGES}"
2078         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
2079     else
2080       enable_languages=default
2081     fi
2082   else
2083     if test x"${enable_languages}" = x ||
2084        test x"${enable_languages}" = xyes;
2085        then
2086       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2087       exit 1
2088     fi
2089   fi
2090   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2091
2092   # 'f95' is the old name for the 'fortran' language. We issue a warning
2093   # and make the substitution.
2094   case ,${enable_languages}, in
2095     *,f95,*)
2096       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2097       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2098       ;;
2099   esac
2100
2101   # If bootstrapping, C++ must be enabled.
2102   case ",$enable_languages,:$enable_bootstrap" in
2103     *,c++,*:*) ;;
2104     *:yes)
2105       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2106         enable_languages="${enable_languages},c++"
2107       else
2108         AC_MSG_ERROR([bootstrapping requires c++ sources])
2109       fi
2110       ;;
2111   esac
2112
2113   # First scan to see if an enabled language requires some other language.
2114   # We assume that a given config-lang.in will list all the language
2115   # front ends it requires, even if some are required indirectly.
2116   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2117     case ${lang_frag} in
2118       ..) ;;
2119       # The odd quoting in the next line works around
2120       # an apparent bug in bash 1.12 on linux.
2121       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2122       *)
2123         # From the config-lang.in, get $language, $lang_requires, and
2124         # $lang_requires_boot_languages.
2125         language=
2126         lang_requires=
2127         lang_requires_boot_languages=
2128         # set srcdir during sourcing lang_frag to the gcc dir.
2129         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2130         # polutes this shell
2131         saved_srcdir=${srcdir}
2132         srcdir=${srcdir}/gcc . ${lang_frag}
2133         srcdir=${saved_srcdir}
2134         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2135           case ,${enable_languages}, in
2136             *,$other,*) ;;
2137             *,default,*) ;;
2138             *,all,*) ;;
2139             *,$language,*)
2140               echo " \`$other' language required by \`$language'; enabling" 1>&2
2141               enable_languages="${enable_languages},${other}"
2142               ;;
2143           esac
2144         done
2145         for other in ${lang_requires_boot_languages} ; do
2146           if test "$other" != "c"; then
2147             case ,${enable_stage1_languages}, in
2148               *,$other,*) ;;
2149               *,default,*) ;;
2150               *,all,*) ;;
2151               *)
2152                 case ,${enable_languages}, in
2153                   *,$language,*)
2154                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2155                     enable_stage1_languages="$enable_stage1_languages,${other}"
2156                     ;;
2157                 esac
2158                 ;;
2159             esac
2160           fi
2161         done
2162         ;;
2163     esac
2164   done
2165
2166   new_enable_languages=,c,
2167
2168   # If LTO is enabled, add the LTO front end.
2169   if test "$enable_lto" = "yes" ; then
2170     case ,${enable_languages}, in
2171       *,lto,*) ;;
2172       *) enable_languages="${enable_languages},lto" ;;
2173     esac
2174     if test "${build_lto_plugin}" = "yes" ; then
2175       configdirs="$configdirs lto-plugin"
2176     fi
2177   fi
2178
2179   # If we're building an offloading compiler, add the LTO front end.
2180   if test x"$enable_as_accelerator_for" != x ; then
2181     case ,${enable_languages}, in
2182       *,lto,*) ;;
2183       *) enable_languages="${enable_languages},lto" ;;
2184     esac
2185   fi
2186
2187   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2188   potential_languages=,c,
2189
2190   enabled_target_libs=
2191   disabled_target_libs=
2192
2193   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2194     case ${lang_frag} in
2195       ..) ;;
2196       # The odd quoting in the next line works around
2197       # an apparent bug in bash 1.12 on linux.
2198       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2199       *)
2200         # From the config-lang.in, get $language, $target_libs,
2201         # $lang_dirs, $boot_language, and $build_by_default
2202         language=
2203         target_libs=
2204         lang_dirs=
2205         subdir_requires=
2206         boot_language=no
2207         build_by_default=yes
2208         # set srcdir during sourcing.  See above about save & restore
2209         saved_srcdir=${srcdir}
2210         srcdir=${srcdir}/gcc . ${lang_frag}
2211         srcdir=${saved_srcdir}
2212         if test x${language} = x; then
2213           echo "${lang_frag} doesn't set \$language." 1>&2
2214           exit 1
2215         fi
2216
2217         if test "$language" = "c++"; then
2218           boot_language=yes
2219         fi
2220
2221         add_this_lang=no
2222         # C is always enabled, so no need to add it again
2223         if test "$language" != "c"; then
2224           case ,${enable_languages}, in
2225             *,${language},*)
2226               # Language was explicitly selected; include it
2227               add_this_lang=yes
2228               ;;
2229             *,all,*)
2230               # All languages are enabled
2231               add_this_lang=all
2232               ;;
2233             *,default,*)
2234               # 'default' was selected, select it if it is a default language
2235               add_this_lang=${build_by_default}
2236               ;;
2237           esac
2238         fi
2239
2240         # Disable languages that need other directories if these aren't available.
2241         for i in $subdir_requires; do
2242           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2243           case ${add_this_lang} in
2244             yes)
2245               # Specifically requested language; tell them.
2246               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2247               ;;
2248             all)
2249               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2250               add_this_lang=unsupported
2251               ;;
2252             *)
2253               # Silently disable.
2254               add_this_lang=unsupported
2255               ;;
2256           esac
2257         done
2258
2259         # Disable Ada if no preexisting GNAT is available.
2260         case ${add_this_lang}:${language}:${have_gnat} in
2261           yes:ada:no)
2262             # Specifically requested language; tell them.
2263             AC_MSG_ERROR([GNAT is required to build $language])
2264             ;;
2265           all:ada:no)
2266             AC_MSG_WARN([GNAT is required to build $language])
2267             add_this_lang=unsupported
2268             ;;
2269           *:ada:no)
2270             # Silently disable.
2271             add_this_lang=unsupported
2272             ;;
2273         esac
2274
2275         # Disable D if no preexisting GDC is available.
2276         case ${add_this_lang}:${language}:${have_gdc} in
2277           yes:d:no)
2278             # Specifically requested language; tell them.
2279             AC_MSG_ERROR([GDC is required to build $language])
2280            ;;
2281           all:d:no)
2282             AC_MSG_WARN([GDC is required to build $language])
2283             add_this_lang=unsupported
2284             ;;
2285           *:d:no)
2286             # Silently disable.
2287             add_this_lang=unsupported
2288             ;;
2289         esac
2290
2291         # Disable jit if -enable-host-shared not specified
2292         # but not if building for Mingw. All code in Windows
2293         # is position independent code (PIC).
2294         case $target in
2295           *mingw*) ;;
2296           *)
2297           case ${add_this_lang}:${language}:${host_shared} in
2298             yes:jit:no)
2299                    # PR jit/64780: explicitly specify --enable-host-shared
2300             AC_MSG_ERROR([
2301 Enabling language "jit" requires --enable-host-shared.
2302
2303 --enable-host-shared typically slows the rest of the compiler down by
2304 a few %, so you must explicitly enable it.
2305
2306 If you want to build both the jit and the regular compiler, it is often
2307 best to do this via two separate configure/builds, in separate
2308 directories, to avoid imposing the performance cost of
2309 --enable-host-shared on the regular compiler.])
2310                     ;;
2311             all:jit:no)
2312               AC_MSG_WARN([--enable-host-shared required to build $language])
2313               add_this_lang=unsupported
2314               ;;
2315             *:jit:no)
2316               # Silently disable.
2317               add_this_lang=unsupported
2318               ;;
2319                 esac
2320           ;;
2321         esac
2322
2323         # Disable a language that is unsupported by the target.
2324         case "${add_this_lang}: $unsupported_languages " in
2325           no:*) ;;
2326           unsupported:*) ;;
2327           *:*" $language "*)
2328             AC_MSG_WARN([${language} not supported for this target])
2329             add_this_lang=unsupported
2330             ;;
2331         esac
2332
2333         case $add_this_lang in
2334           unsupported)
2335             # Remove language-dependent dirs.
2336             disabled_target_libs="$disabled_target_libs $target_libs"
2337             noconfigdirs="$noconfigdirs $lang_dirs"
2338             ;;
2339           no)
2340             # Remove language-dependent dirs; still show language as supported.
2341             disabled_target_libs="$disabled_target_libs $target_libs"
2342             noconfigdirs="$noconfigdirs $lang_dirs"
2343             potential_languages="${potential_languages}${language},"
2344             ;;
2345           all|yes)
2346             new_enable_languages="${new_enable_languages}${language},"
2347             potential_languages="${potential_languages}${language},"
2348             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2349             enabled_target_libs="$enabled_target_libs $target_libs"
2350             case "${boot_language}:,$enable_stage1_languages," in
2351               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2352                 # Add to (comma-separated) list of stage 1 languages.
2353                 case ",$stage1_languages," in
2354                   *,$language,* | ,yes, | ,all,) ;;
2355                   *) stage1_languages="${stage1_languages}${language}," ;;
2356                 esac
2357                 # We need to bootstrap any supporting libraries.
2358                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2359                 ;;
2360             esac
2361             ;;
2362         esac
2363         ;;
2364     esac
2365   done
2366
2367   # Add target libraries which are only needed for disabled languages
2368   # to noconfigdirs.
2369   if test -n "$disabled_target_libs"; then
2370     for dir in $disabled_target_libs; do
2371       case " $enabled_target_libs " in
2372       *" ${dir} "*) ;;
2373       *) noconfigdirs="$noconfigdirs $dir" ;;
2374       esac
2375     done
2376   fi
2377
2378   AC_ARG_ENABLE(stage1-languages,
2379   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2380                   [choose additional languages to build during
2381                   stage1.  Mostly useful for compiler development])],
2382   [case ,${enable_stage1_languages}, in
2383     ,no,|,,)
2384       # Set it to something that will have no effect in the loop below
2385       enable_stage1_languages=c ;;
2386     ,yes,)
2387       enable_stage1_languages=`echo $new_enable_languages | \
2388         sed -e "s/^,//" -e "s/,$//" ` ;;
2389     *,all,*)
2390       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2391         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2392   esac
2393
2394   # Add "good" languages from enable_stage1_languages to stage1_languages,
2395   # while "bad" languages go in missing_languages.  Leave no duplicates.
2396   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2397     case $potential_languages in
2398       *,$i,*)
2399         case $stage1_languages in
2400           *,$i,*) ;;
2401           *) stage1_languages="$stage1_languages$i," ;;
2402         esac ;;
2403       *)
2404         case $missing_languages in
2405           *,$i,*) ;;
2406           *) missing_languages="$missing_languages$i," ;;
2407         esac ;;
2408      esac
2409   done])
2410
2411   # Remove leading/trailing commas that were added for simplicity
2412   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2413   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2414   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2415   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2416
2417   if test "x$missing_languages" != x; then
2418     AC_MSG_ERROR([
2419 The following requested languages could not be built: ${missing_languages}
2420 Supported languages are: ${potential_languages}])
2421   fi
2422   if test "x$new_enable_languages" != "x$enable_languages"; then
2423     echo The following languages will be built: ${new_enable_languages}
2424     enable_languages="$new_enable_languages"
2425   fi
2426
2427   AC_SUBST(stage1_languages)
2428   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2429 fi
2430
2431 # Handle --disable-<component> generically.
2432 for dir in $configdirs $build_configdirs $target_configdirs ; do
2433   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2434   varname=`echo $dirname | sed -e s/+/_/g`
2435   if eval test x\${enable_${varname}} "=" xno ; then
2436     noconfigdirs="$noconfigdirs $dir"
2437   fi
2438 done
2439
2440 # Check for Boehm's garbage collector
2441 AC_ARG_ENABLE(objc-gc,
2442 [AS_HELP_STRING([--enable-objc-gc],
2443                 [enable use of Boehm's garbage collector with the
2444                  GNU Objective-C runtime])])
2445 AC_ARG_WITH([target-bdw-gc],
2446 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2447                 [specify prefix directory for installed bdw-gc package.
2448                  Equivalent to --with-target-bdw-gc-include=PATH/include
2449                  plus --with-target-bdw-gc-lib=PATH/lib])])
2450 AC_ARG_WITH([target-bdw-gc-include],
2451 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2452                 [specify directories for installed bdw-gc include files])])
2453 AC_ARG_WITH([target-bdw-gc-lib],
2454 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2455                 [specify directories for installed bdw-gc library])])
2456
2457 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2458   AC_MSG_CHECKING([for bdw garbage collector])
2459   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2460     dnl no bdw-gw options, assume default locations
2461     AC_MSG_RESULT([using bdw-gc in default locations])
2462   else
2463     dnl bdw-gw options, first error checking, complete checking in libobjc
2464     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2465       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2466     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2467       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2468     else
2469       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2470     fi
2471   fi
2472 esac
2473
2474 # Disable libitm, libsanitizer, libvtv if we're not building C++
2475 case ,${enable_languages}, in
2476   *,c++,*)
2477     # Disable libitm, libsanitizer if we're not building libstdc++
2478     case "${noconfigdirs}" in
2479       *target-libstdc++-v3*)
2480         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2481         ;;
2482       *) ;;
2483     esac
2484     ;;
2485   *)
2486     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2487     ;;
2488 esac
2489
2490 case ,${enable_languages}, in
2491   *,rust,*)
2492     case " ${noconfigdirs} " in
2493       *\ target-libstdc++-v3\ *)
2494         # Disable target libgrust if we're not building target libstdc++.
2495         noconfigdirs="$noconfigdirs target-libgrust"
2496         ;;
2497     esac
2498     ;;
2499 esac
2500
2501 # If gcc/ is not in the source tree then we'll not be building a
2502 # target compiler, assume in that case we don't want to build any
2503 # target libraries or tools.
2504 #
2505 # This was added primarily for the benefit for binutils-gdb who reuse
2506 # this configure script, but don't always have target tools available.
2507 if test ! -d ${srcdir}/gcc; then
2508    skipdirs="${skipdirs} ${target_configdirs}"
2509 fi
2510
2511 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2512 # $build_configdirs and $target_configdirs.
2513 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2514
2515 notsupp=""
2516 for dir in . $skipdirs $noconfigdirs ; do
2517   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2518   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2519     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2520     if test -r $srcdir/$dirname/configure ; then
2521       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2522         true
2523       else
2524         notsupp="$notsupp $dir"
2525       fi
2526     fi
2527   fi
2528   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2529     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2530     if test -r $srcdir/$dirname/configure ; then
2531       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2532         true
2533       else
2534         notsupp="$notsupp $dir"
2535       fi
2536     fi
2537   fi
2538   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2539     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2540     if test -r $srcdir/$dirname/configure ; then
2541       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2542         true
2543       else
2544         notsupp="$notsupp $dir"
2545       fi
2546     fi
2547   fi
2548 done
2549
2550 # Quietly strip out all directories which aren't configurable in this tree.
2551 # This relies on all configurable subdirectories being autoconfiscated, which
2552 # is now the case.
2553 build_configdirs_all="$build_configdirs"
2554 build_configdirs=
2555 for i in ${build_configdirs_all} ; do
2556   j=`echo $i | sed -e s/build-//g`
2557   if test -f ${srcdir}/$j/configure ; then
2558     build_configdirs="${build_configdirs} $i"
2559   fi
2560 done
2561
2562 configdirs_all="$configdirs"
2563 configdirs=
2564 for i in ${configdirs_all} ; do
2565   if test -f ${srcdir}/$i/configure ; then
2566     configdirs="${configdirs} $i"
2567   fi
2568 done
2569
2570 target_configdirs_all="$target_configdirs"
2571 target_configdirs=
2572 for i in ${target_configdirs_all} ; do
2573   j=`echo $i | sed -e s/target-//g`
2574   if test -f ${srcdir}/$j/configure ; then
2575     target_configdirs="${target_configdirs} $i"
2576   fi
2577 done
2578
2579 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2580 # so we have to add it after the preceding checks.
2581 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2582 then
2583   case " $configdirs " in
2584     *" libiberty "*)
2585       # If we can build libiberty, we can also build libiberty-linker-plugin.
2586       configdirs="$configdirs libiberty-linker-plugin"
2587       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2588         --with-libiberty=../libiberty-linker-plugin";;
2589     *)
2590       AC_MSG_ERROR([libiberty missing]);;
2591   esac
2592 fi
2593
2594 # Sometimes we have special requirements for the host libiberty.
2595 extra_host_libiberty_configure_flags=
2596 case " $configdirs " in
2597   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2598     # When these are to be built as shared libraries, the same applies to
2599     # libiberty.
2600     extra_host_libiberty_configure_flags=--enable-shared
2601     ;;
2602 esac
2603 AC_SUBST(extra_host_libiberty_configure_flags)
2604
2605 # Sometimes we have special requirements for the host zlib.
2606 extra_host_zlib_configure_flags=
2607 case " $configdirs " in
2608   *" bfd "*)
2609     # When bfd is to be built as a shared library, the same applies to
2610     # zlib.
2611     if test "$enable_shared" = "yes"; then
2612       extra_host_zlib_configure_flags=--enable-host-shared
2613     fi
2614     ;;
2615 esac
2616 AC_SUBST(extra_host_zlib_configure_flags)
2617
2618 # Produce a warning message for the subdirs we can't configure.
2619 # This isn't especially interesting in the Cygnus tree, but in the individual
2620 # FSF releases, it's important to let people know when their machine isn't
2621 # supported by the one or two programs in a package.
2622
2623 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2624   # If $appdirs is non-empty, at least one of those directories must still
2625   # be configured, or we error out.  (E.g., if the gas release supports a
2626   # specified target in some subdirs but not the gas subdir, we shouldn't
2627   # pretend that all is well.)
2628   if test -n "$appdirs" ; then
2629     for dir in $appdirs ; do
2630       if test -r $dir/Makefile.in ; then
2631         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2632           appdirs=""
2633           break
2634         fi
2635         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2636           appdirs=""
2637           break
2638         fi
2639       fi
2640     done
2641     if test -n "$appdirs" ; then
2642       echo "*** This configuration is not supported by this package." 1>&2
2643       exit 1
2644     fi
2645   fi
2646   # Okay, some application will build, or we don't care to check.  Still
2647   # notify of subdirs not getting built.
2648   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2649   echo "    ${notsupp}" 1>&2
2650   echo "    (Any other directories should still work fine.)" 1>&2
2651 fi
2652
2653 case "$host" in
2654   *msdosdjgpp*)
2655     enable_gdbtk=no ;;
2656 esac
2657
2658 # To find our prefix, in gcc_cv_tool_prefix.
2659 ACX_TOOL_DIRS
2660
2661 copy_dirs=
2662
2663 AC_ARG_WITH([build-sysroot],
2664   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2665                   [use sysroot as the system root during the build])],
2666   [if test x"$withval" != x ; then
2667      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2668    fi],
2669   [SYSROOT_CFLAGS_FOR_TARGET=])
2670 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2671
2672 AC_ARG_WITH([debug-prefix-map],
2673   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2674                   [map A to B, C to D ... in debug information])],
2675   [if test x"$withval" != x; then
2676      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2677      for debug_map in $withval; do
2678        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2679      done
2680    fi],
2681   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2682 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2683
2684 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2685 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2686 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2687 # We want to ensure that TARGET libraries (which we know are built with
2688 # gcc) are built with "-O2 -g", so include those options when setting
2689 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2690 if test "x$CFLAGS_FOR_TARGET" = x; then
2691   if test "x${is_cross_compiler}" = xyes; then
2692     CFLAGS_FOR_TARGET="-g -O2"
2693   else
2694     CFLAGS_FOR_TARGET=$CFLAGS
2695     case " $CFLAGS " in
2696       *" -O2 "*) ;;
2697       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2698     esac
2699     case " $CFLAGS " in
2700       *" -g "* | *" -g3 "*) ;;
2701       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2702     esac
2703   fi
2704 fi
2705 AC_SUBST(CFLAGS_FOR_TARGET)
2706
2707 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2708   if test "x${is_cross_compiler}" = xyes; then
2709     CXXFLAGS_FOR_TARGET="-g -O2"
2710   else
2711     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2712     case " $CXXFLAGS " in
2713       *" -O2 "*) ;;
2714       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2715     esac
2716     case " $CXXFLAGS " in
2717       *" -g "* | *" -g3 "*) ;;
2718       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2719     esac
2720   fi
2721 fi
2722 AC_SUBST(CXXFLAGS_FOR_TARGET)
2723
2724 AC_SUBST(LDFLAGS_FOR_TARGET)
2725
2726 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2727 # the named directory are copied to $(tooldir)/sys-include.
2728 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2729   if test x${is_cross_compiler} = xno ; then
2730     echo 1>&2 '***' --with-headers is only supported when cross compiling
2731     exit 1
2732   fi
2733   if test x"${with_headers}" != xyes ; then
2734     x=${gcc_cv_tool_prefix}
2735     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2736   fi
2737 fi
2738
2739 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2740 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2741 # are permitted.
2742 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2743   if test x${is_cross_compiler} = xno ; then
2744     echo 1>&2 '***' --with-libs is only supported when cross compiling
2745     exit 1
2746   fi
2747   if test x"${with_libs}" != xyes ; then
2748     # Copy the libraries in reverse order, so that files in the first named
2749     # library override files in subsequent libraries.
2750     x=${gcc_cv_tool_prefix}
2751     for l in ${with_libs}; do
2752       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2753     done
2754   fi
2755 fi
2756
2757 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2758 #
2759 # This is done by determining whether or not the appropriate directory
2760 # is available, and by checking whether or not specific configurations
2761 # have requested that this magic not happen.
2762 #
2763 # The command line options always override the explicit settings in
2764 # configure.ac, and the settings in configure.ac override this magic.
2765 #
2766 # If the default for a toolchain is to use GNU as and ld, and you don't
2767 # want to do that, then you should use the --without-gnu-as and
2768 # --without-gnu-ld options for the configure script.  Similarly, if
2769 # the default is to use the included zlib and you don't want to do that,
2770 # you should use the --with-system-zlib option for the configure script.
2771
2772 if test x${use_gnu_as} = x &&
2773    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2774   with_gnu_as=yes
2775   extra_host_args="$extra_host_args --with-gnu-as"
2776 fi
2777
2778 if test x${use_gnu_ld} = x &&
2779    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2780   with_gnu_ld=yes
2781   extra_host_args="$extra_host_args --with-gnu-ld"
2782 fi
2783
2784 if test x${use_included_zlib} = x &&
2785    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2786   :
2787 else
2788   with_system_zlib=yes
2789   extra_host_args="$extra_host_args --with-system-zlib"
2790 fi
2791
2792 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2793 # can detect this case.
2794
2795 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2796   with_newlib=yes
2797   extra_host_args="$extra_host_args --with-newlib"
2798 fi
2799
2800 # Handle ${copy_dirs}
2801 set fnord ${copy_dirs}
2802 shift
2803 while test $# != 0 ; do
2804   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2805     :
2806   else
2807     echo Copying $1 to $2
2808
2809     # Use the install script to create the directory and all required
2810     # parent directories.
2811     if test -d $2 ; then
2812       :
2813     else
2814       echo >config.temp
2815       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2816     fi
2817
2818     # Copy the directory, assuming we have tar.
2819     # FIXME: Should we use B in the second tar?  Not all systems support it.
2820     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2821
2822     # It is the responsibility of the user to correctly adjust all
2823     # symlinks.  If somebody can figure out how to handle them correctly
2824     # here, feel free to add the code.
2825
2826     echo $1 > $2/COPIED
2827   fi
2828   shift; shift
2829 done
2830
2831 # Determine a target-dependent exec_prefix that the installed
2832 # gcc will search in.  Keep this list sorted by triplet, with
2833 # the *-*-osname triplets last.
2834 md_exec_prefix=
2835 case "${target}" in
2836   i[[34567]]86-pc-msdosdjgpp*)
2837     md_exec_prefix=/dev/env/DJDIR/bin
2838     ;;
2839   *-*-hpux* | \
2840   *-*-nto-qnx* | \
2841   *-*-solaris2*)
2842     md_exec_prefix=/usr/ccs/bin
2843     ;;
2844 esac
2845
2846 extra_arflags_for_target=
2847 extra_nmflags_for_target=
2848 extra_ranlibflags_for_target=
2849 target_makefile_frag=/dev/null
2850 case "${target}" in
2851   spu-*-*)
2852     target_makefile_frag="config/mt-spu"
2853     ;;
2854   loongarch*-*linux* | loongarch*-*gnu*)
2855     target_makefile_frag="config/mt-loongarch-gnu"
2856     ;;
2857   loongarch*-*elf*)
2858     target_makefile_frag="config/mt-loongarch-elf"
2859     ;;
2860   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2861     target_makefile_frag="config/mt-sde"
2862     ;;
2863   mipsisa*-*-elfoabi*)
2864     target_makefile_frag="config/mt-mips-elfoabi"
2865     ;;
2866   mips*-*-*linux* | mips*-*-gnu*)
2867     target_makefile_frag="config/mt-mips-gnu"
2868     ;;
2869   nios2-*-elf*)
2870     target_makefile_frag="config/mt-nios2-elf"
2871     ;;
2872   *-*-linux-android*)
2873     target_makefile_frag="config/mt-android"
2874     ;;
2875   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2876     target_makefile_frag="config/mt-gnu"
2877     ;;
2878   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2879     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2880     # commands to handle both 32-bit and 64-bit objects.  These flags are
2881     # harmless if we're using GNU nm or ar.
2882     extra_arflags_for_target=" -X32_64"
2883     extra_nmflags_for_target=" -B -X32_64"
2884     ;;
2885 esac
2886
2887 alphaieee_frag=/dev/null
2888 case $target in
2889   alpha*-*-*)
2890     # This just makes sure to use the -mieee option to build target libs.
2891     # This should probably be set individually by each library.
2892     alphaieee_frag="config/mt-alphaieee"
2893     ;;
2894 esac
2895
2896 # If --enable-target-optspace always use -Os instead of -O2 to build
2897 # the target libraries, similarly if it is not specified, use -Os
2898 # on selected platforms.
2899 ospace_frag=/dev/null
2900 case "${enable_target_optspace}:${target}" in
2901   yes:*)
2902     ospace_frag="config/mt-ospace"
2903     ;;
2904   :d30v-*)
2905     ospace_frag="config/mt-d30v"
2906     ;;
2907   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2908     ospace_frag="config/mt-ospace"
2909     ;;
2910   no:* | :*)
2911     ;;
2912   *)
2913     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2914     ;;
2915 esac
2916
2917 # Some systems (e.g., one of the i386-aix systems the gas testers are
2918 # using) don't handle "\$" correctly, so don't use it here.
2919 tooldir='${exec_prefix}'/${target_noncanonical}
2920 build_tooldir=${tooldir}
2921
2922 # Create a .gdbinit file which runs the one in srcdir
2923 # and tells GDB to look there for source files.
2924
2925 if test -r ${srcdir}/.gdbinit ; then
2926   case ${srcdir} in
2927     .) ;;
2928     *) cat > ./.gdbinit <<EOF
2929 # ${NO_EDIT}
2930 dir ${srcdir}
2931 dir .
2932 source ${srcdir}/.gdbinit
2933 EOF
2934     ;;
2935   esac
2936 fi
2937
2938 # Make sure that the compiler is able to generate an executable.  If it
2939 # can't, we are probably in trouble.  We don't care whether we can run the
2940 # executable--we might be using a cross compiler--we only care whether it
2941 # can be created.  At this point the main configure script has set CC.
2942 we_are_ok=no
2943 echo "int main () { return 0; }" > conftest.c
2944 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2945 if test $? = 0 ; then
2946   if test -s conftest || test -s conftest.exe ; then
2947     we_are_ok=yes
2948   fi
2949 fi
2950 case $we_are_ok in
2951   no)
2952     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2953     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2954     rm -f conftest*
2955     exit 1
2956     ;;
2957 esac
2958 rm -f conftest*
2959
2960 # Decide which environment variable is used to find dynamic libraries.
2961 case "${host}" in
2962   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2963   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2964   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2965   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2966 esac
2967
2968 # On systems where the dynamic library environment variable is PATH,
2969 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2970 # built executables to PATH.
2971 if test "$RPATH_ENVVAR" = PATH; then
2972   GCC_SHLIB_SUBDIR=/shlib
2973 else
2974   GCC_SHLIB_SUBDIR=
2975 fi
2976
2977 # Adjust the toplevel makefile according to whether bootstrap was selected.
2978 case $enable_bootstrap in
2979   yes)
2980     bootstrap_suffix=bootstrap
2981     BUILD_CONFIG=bootstrap-debug
2982     ;;
2983   no)
2984     bootstrap_suffix=no-bootstrap
2985     BUILD_CONFIG=
2986     ;;
2987 esac
2988
2989 AC_MSG_CHECKING(for default BUILD_CONFIG)
2990
2991 AC_ARG_WITH([build-config],
2992   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2993                   [use config/NAME.mk build configuration])],
2994   [case $with_build_config in
2995    yes) with_build_config= ;;
2996    no) with_build_config= BUILD_CONFIG= ;;
2997    esac])
2998
2999 if test "x${with_build_config}" != x; then
3000   BUILD_CONFIG=$with_build_config
3001 else
3002   case $BUILD_CONFIG in
3003   bootstrap-debug)
3004     if echo "int f (void) { return 0; }" > conftest.c &&
3005        ${CC} -c conftest.c &&
3006        mv conftest.o conftest.o.g0 &&
3007        ${CC} -c -g conftest.c &&
3008        mv conftest.o conftest.o.g &&
3009        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
3010       :
3011     else
3012       BUILD_CONFIG=
3013     fi
3014     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
3015     ;;
3016   esac
3017 fi
3018 AC_MSG_RESULT($BUILD_CONFIG)
3019 AC_SUBST(BUILD_CONFIG)
3020
3021 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
3022 AC_MSG_CHECKING([for --enable-vtable-verify])
3023 AC_ARG_ENABLE(vtable-verify,
3024 [AS_HELP_STRING([--enable-vtable-verify],
3025                 [Enable vtable verification feature])],
3026 [case "$enableval" in
3027  yes) enable_vtable_verify=yes ;;
3028  no)  enable_vtable_verify=no ;;
3029  *)   enable_vtable_verify=no;;
3030  esac],
3031 [enable_vtable_verify=no])
3032 AC_MSG_RESULT($enable_vtable_verify)
3033
3034 # Record target_configdirs and the configure arguments for target and
3035 # build configuration in Makefile.
3036 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
3037 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
3038 bootstrap_fixincludes=no
3039
3040 # If we are building libgomp, bootstrap it.
3041 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
3042   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
3043 fi
3044
3045 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
3046 # or bootstrap-ubsan, bootstrap it.
3047 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
3048   case "$BUILD_CONFIG" in
3049     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
3050       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
3051       bootstrap_fixincludes=yes
3052       ;;
3053   esac
3054 fi
3055
3056 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
3057 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
3058    test "$enable_vtable_verify" != no; then
3059   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
3060 fi
3061
3062 # If we are building libatomic and the list of enabled languages includes the
3063 # D frontend, bootstrap it.
3064 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
3065   case ,${enable_languages}, in
3066     *,d,*)
3067       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
3068       ;;
3069   esac
3070 fi
3071
3072 # Determine whether gdb needs tk/tcl or not.
3073 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
3074 # and in that case we want gdb to be built without tk.  Ugh!
3075 # In fact I believe gdb is the *only* package directly dependent on tk,
3076 # so we should be able to put the 'maybe's in unconditionally and
3077 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
3078 # 100% sure that that's safe though.
3079
3080 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
3081 case "$enable_gdbtk" in
3082   no)
3083     GDB_TK="" ;;
3084   yes)
3085     GDB_TK="${gdb_tk}" ;;
3086   *)
3087     # Only add the dependency on gdbtk when GDBtk is part of the gdb
3088     # distro.  Eventually someone will fix this and move Insight, nee
3089     # gdbtk to a separate directory.
3090     if test -d ${srcdir}/gdb/gdbtk ; then
3091       GDB_TK="${gdb_tk}"
3092     else
3093       GDB_TK=""
3094     fi
3095     ;;
3096 esac
3097 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
3098 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
3099
3100 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
3101 # else does, only include them if one of these is built.  The Makefile
3102 # provides the ordering, so it's enough here to add to the list.
3103 case " ${configdirs} " in
3104   *\ gdb\ *)
3105     configdirs="${configdirs} gnulib gdbsupport"
3106     ;;
3107   *\ gdbserver\ *)
3108     configdirs="${configdirs} gnulib gdbsupport"
3109     ;;
3110   *\ sim\ *)
3111     configdirs="${configdirs} gnulib"
3112     ;;
3113 esac
3114
3115 # Strip out unwanted targets.
3116
3117 # While at that, we remove Makefiles if we were started for recursive
3118 # configuration, so that the top-level Makefile reconfigures them,
3119 # like we used to do when configure itself was recursive.
3120
3121 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3122 # but now we're fixing up the Makefile ourselves with the additional
3123 # commands passed to AC_CONFIG_FILES.  Use separate variables
3124 # extrasub-{build,host,target} not because there is any reason to split
3125 # the substitutions up that way, but only to remain below the limit of
3126 # 99 commands in a script, for HP-UX sed.
3127
3128 # Do not nest @if/@endif or @unless/@endunless pairs, because
3129 # configure will not warn you at all.
3130
3131 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3132   yes:yes:*\ gold\ *:*,c++,*) ;;
3133   yes:yes:*\ gold\ *:*)
3134     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3135     ;;
3136 esac
3137
3138 extrasub_build=
3139 for module in ${build_configdirs} ; do
3140   if test -z "${no_recursion}" \
3141      && test -f ${build_subdir}/${module}/Makefile; then
3142     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3143     rm -f ${build_subdir}/${module}/Makefile
3144   fi
3145   extrasub_build="$extrasub_build
3146 /^@if build-$module\$/d
3147 /^@endif build-$module\$/d
3148 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3149 /^@if build-$module-$bootstrap_suffix\$/d
3150 /^@endif build-$module-$bootstrap_suffix\$/d
3151 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3152 done
3153 extrasub_host=
3154 for module in ${configdirs} ; do
3155   if test -z "${no_recursion}"; then
3156     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3157       if test -f ${file}; then
3158         echo 1>&2 "*** removing ${file} to force reconfigure"
3159         rm -f ${file}
3160       fi
3161     done
3162   fi
3163   case ${module},${bootstrap_fixincludes} in
3164     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3165     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3166   esac
3167   extrasub_host="$extrasub_host
3168 /^@if $module\$/d
3169 /^@endif $module\$/d
3170 /^@unless $module\$/,/^@endunless $module\$/d
3171 /^@if $module-$host_bootstrap_suffix\$/d
3172 /^@endif $module-$host_bootstrap_suffix\$/d
3173 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3174 done
3175 extrasub_target=
3176 for module in ${target_configdirs} ; do
3177   if test -z "${no_recursion}" \
3178      && test -f ${target_subdir}/${module}/Makefile; then
3179     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3180     rm -f ${target_subdir}/${module}/Makefile
3181   fi
3182
3183   # We only bootstrap target libraries listed in bootstrap_target_libs.
3184   case $bootstrap_target_libs in
3185     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3186     *) target_bootstrap_suffix=no-bootstrap ;;
3187   esac
3188
3189   extrasub_target="$extrasub_target
3190 /^@if target-$module\$/d
3191 /^@endif target-$module\$/d
3192 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3193 /^@if target-$module-$target_bootstrap_suffix\$/d
3194 /^@endif target-$module-$target_bootstrap_suffix\$/d
3195 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3196 done
3197
3198 # Do the final fixup along with target modules.
3199 extrasub_target="$extrasub_target
3200 /^@if /,/^@endif /d
3201 /^@unless /d
3202 /^@endunless /d"
3203
3204 if test "$enable_pgo_build" != "no"; then
3205   extrasub_build="$extrasub_build
3206 /^@if pgo-build\$/d
3207 /^@endif pgo-build\$/d"
3208 fi
3209
3210 # Create the serialization dependencies.  This uses a temporary file.
3211
3212 AC_ARG_ENABLE([serial-configure],
3213 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3214                 [force sequential configuration of
3215                  sub-packages for the host, target or build
3216                  machine, or all sub-packages])])
3217
3218 case ${enable_serial_configure} in
3219   yes)
3220     enable_serial_build_configure=yes
3221     enable_serial_host_configure=yes
3222     enable_serial_target_configure=yes
3223     ;;
3224 esac
3225
3226 # These force 'configure's to be done one at a time, to avoid problems
3227 # with contention over a shared config.cache.
3228 rm -f serdep.tmp
3229 if test "x${enable_serial_build_configure}" = xyes || test "x${enable_serial_host_configure}" = xyes || test "x${enable_serial_target_configure}" = xyes; then
3230 echo '# serdep.tmp' > serdep.tmp
3231 fi
3232 olditem=
3233 test "x${enable_serial_build_configure}" = xyes &&
3234 for item in ${build_configdirs} ; do
3235   case ${olditem} in
3236     "") ;;
3237     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3238   esac
3239   olditem=${item}
3240 done
3241 olditem=
3242 test "x${enable_serial_host_configure}" = xyes &&
3243 for item in ${configdirs} ; do
3244   case ${olditem} in
3245     "") ;;
3246     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3247   esac
3248   olditem=${item}
3249 done
3250 olditem=
3251 test "x${enable_serial_target_configure}" = xyes &&
3252 for item in ${target_configdirs} ; do
3253   case ${olditem} in
3254     "") ;;
3255     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3256   esac
3257   olditem=${item}
3258 done
3259 serialization_dependencies=serdep.tmp
3260 AC_SUBST_FILE(serialization_dependencies)
3261
3262 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3263 # target, nonopt, and variable assignments.  These are the ones we
3264 # might not want to pass down to subconfigures.  The exception being
3265 # --cache-file=/dev/null, which is used to turn off the use of cache
3266 # files altogether, and which should be passed on to subconfigures.
3267 # Also strip program-prefix, program-suffix, and program-transform-name,
3268 # so that we can pass down a consistent program-transform-name.
3269 hbaseargs=
3270 bbaseargs=
3271 tbaseargs=
3272 keep_next=no
3273 skip_next=no
3274 eval "set -- $ac_configure_args"
3275 for ac_arg
3276 do
3277   if test X"$skip_next" = X"yes"; then
3278     skip_next=no
3279     continue
3280   fi
3281   if test X"$keep_next" = X"yes"; then
3282     case $ac_arg in
3283       *\'*)
3284         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3285     esac
3286     hbaseargs="$hbaseargs '$ac_arg'"
3287     bbaseargs="$bbaseargs '$ac_arg'"
3288     tbaseargs="$tbaseargs '$ac_arg'"
3289     keep_next=no
3290     continue
3291   fi
3292
3293   # Handle separated arguments.  Based on the logic generated by
3294   # autoconf 2.59.
3295   case $ac_arg in
3296     *=* | --config-cache | -C | -disable-* | --disable-* \
3297       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3298       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3299       | -with-* | --with-* | -without-* | --without-* | --x)
3300       separate_arg=no
3301       ;;
3302     -*)
3303       separate_arg=yes
3304       ;;
3305     *)
3306       separate_arg=no
3307       ;;
3308   esac
3309
3310   skip_targ=no
3311   skip_barg=no
3312   case $ac_arg in
3313 changequote(,)
3314   --with-* | --without-*)
3315     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3316
3317     case $libopt in
3318     *[-_]include)
3319       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3320       ;;
3321     *[-_]lib)
3322       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3323       ;;
3324     *[-_]prefix)
3325       lib=`echo "$libopt" | sed 's,[-_]prefix$,,'`
3326       ;;
3327     *[-_]type)
3328       lib=`echo "$libopt" | sed 's,[-_]type$,,'`
3329       ;;
3330     *)
3331       lib=$libopt
3332       ;;
3333     esac
3334 changequote([,])
3335
3336     case $lib in
3337     mpc | mpfr | gmp | isl)
3338       # If we're processing --with-$lib, --with-$lib-include or
3339       # --with-$lib-lib, for one of the libs above, and target is
3340       # different from host, don't pass the current argument to any
3341       # target library's configure.
3342       if test x$is_cross_compiler = xyes; then
3343         skip_targ=yes
3344       fi
3345       ;;
3346     libintl | libiconv)
3347       # We don't want libintl (and co.) in anything but the host arguments.
3348       skip_targ=yes
3349       skip_barg=yes
3350       ;;
3351     esac
3352     ;;
3353   esac
3354
3355   case "$ac_arg" in
3356     --cache-file=/dev/null | \
3357     -cache-file=/dev/null )
3358       # Handled here to avoid the test to skip args below.
3359       hbaseargs="$hbaseargs '$ac_arg'"
3360       bbaseargs="$bbaseargs '$ac_arg'"
3361       tbaseargs="$tbaseargs '$ac_arg'"
3362       # Assert: $separate_arg should always be no.
3363       keep_next=$separate_arg
3364       ;;
3365     --no*)
3366       continue
3367       ;;
3368     --c* | \
3369     --sr* | \
3370     --ho* | \
3371     --bu* | \
3372     --t* | \
3373     --program-* | \
3374     -cache_file* | \
3375     -srcdir* | \
3376     -host* | \
3377     -build* | \
3378     -target* | \
3379     -program-prefix* | \
3380     -program-suffix* | \
3381     -program-transform-name* )
3382       skip_next=$separate_arg
3383       continue
3384       ;;
3385     -*)
3386       # An option.  Add it.
3387       case $ac_arg in
3388         *\'*)
3389           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3390       esac
3391       hbaseargs="$hbaseargs '$ac_arg'"
3392       if test X"$skip_barg" = Xno; then
3393         bbaseargs="$bbaseargs '$ac_arg'"
3394       fi
3395       if test X"$skip_targ" = Xno; then
3396         tbaseargs="$tbaseargs '$ac_arg'"
3397       fi
3398       keep_next=$separate_arg
3399       ;;
3400     *)
3401       # Either a variable assignment, or a nonopt (triplet).  Don't
3402       # pass it down; let the Makefile handle this.
3403       continue
3404       ;;
3405   esac
3406 done
3407 # Remove the initial space we just introduced and, as these will be
3408 # expanded by make, quote '$'.
3409 hbaseargs=`echo "x$hbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3410 bbaseargs=`echo "x$bbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3411
3412 # Add in --program-transform-name, after --program-prefix and
3413 # --program-suffix have been applied to it.  Autoconf has already
3414 # doubled dollar signs and backslashes in program_transform_name; we want
3415 # the backslashes un-doubled, and then the entire thing wrapped in single
3416 # quotes, because this will be expanded first by make and then by the shell.
3417 # Also, because we want to override the logic in subdir configure scripts to
3418 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3419 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3420 ${program_transform_name}
3421 EOF_SED
3422 gcc_transform_name=`cat conftestsed.out`
3423 rm -f conftestsed.out
3424 hbaseargs="$hbaseargs --program-transform-name='${gcc_transform_name}'"
3425 bbaseargs="$bbaseargs --program-transform-name='${gcc_transform_name}'"
3426 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3427 if test "$silent" = yes; then
3428   bbaseargs="$bbaseargs --silent"
3429   hbaseargs="$hbaseargs --silent"
3430   tbaseargs="$tbaseargs --silent"
3431 fi
3432
3433 bbaseargs="$bbaseargs --disable-option-checking"
3434 hbaseargs="$hbaseargs --disable-option-checking"
3435 tbaseargs="$tbaseargs --disable-option-checking"
3436
3437 if test "$enable_year2038" = no; then
3438   bbaseargs="$bbaseargs --disable-year2038"
3439   hbaseargs="$hbaseargs --disable-year2038"
3440   tbaseargs="$tbaseargs --disable-year2038"
3441 fi
3442
3443 # Record and document user additions to sub configure arguments.
3444 AC_ARG_VAR([build_configargs],
3445            [additional configure arguments for build directories])
3446 AC_ARG_VAR([host_configargs],
3447            [additional configure arguments for host directories])
3448 AC_ARG_VAR([target_configargs],
3449            [additional configure arguments for target directories])
3450
3451 # For the build-side libraries, we just need to pretend we're native,
3452 # and not use the same cache file.  Multilibs are neither needed nor
3453 # desired.  We can't even use the same cache file for all build-side
3454 # libraries, as they're compiled differently; some with C, some with
3455 # C++ or with different feature-enabling options.
3456 build_configargs="$build_configargs --cache-file=./config.cache ${bbaseargs}"
3457
3458 # For host modules, accept cache file option, or specification as blank.
3459 case "${cache_file}" in
3460 "") # empty
3461   cache_file_option="" ;;
3462 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3463   cache_file_option="--cache-file=${cache_file}" ;;
3464 *) # relative path
3465   cache_file_option="--cache-file=../${cache_file}" ;;
3466 esac
3467
3468 # Host dirs don't like to share a cache file either, horribly enough.
3469 # This seems to be due to autoconf 2.5x stupidity.
3470 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${hbaseargs}"
3471
3472 target_configargs="$target_configargs ${tbaseargs}"
3473
3474 # Passing a --with-cross-host argument lets the target libraries know
3475 # whether they are being built with a cross-compiler or being built
3476 # native.  However, it would be better to use other mechanisms to make the
3477 # sorts of decisions they want to make on this basis.  Please consider
3478 # this option to be deprecated.  FIXME.
3479 if test x${is_cross_compiler} = xyes ; then
3480   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3481 fi
3482
3483 # Special user-friendly check for native x86_64-linux build, if
3484 # multilib is not explicitly enabled.
3485 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3486   x86_64-*linux*:yes:$build:$build:)
3487     # Make sure we have a development environment that handles 32-bit
3488     dev64=no
3489     echo "int main () { return 0; }" > conftest.c
3490     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3491     if test $? = 0 ; then
3492       if test -s conftest || test -s conftest.exe ; then
3493         dev64=yes
3494       fi
3495     fi
3496     rm -f conftest*
3497     if test x${dev64} != xyes ; then
3498       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3499     fi
3500     ;;
3501 esac
3502
3503 # Default to --enable-multilib.
3504 if test x${enable_multilib} = x ; then
3505   target_configargs="--enable-multilib ${target_configargs}"
3506 fi
3507
3508 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3509 # changed from the earlier setting of with_newlib.
3510 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3511   target_configargs="--with-newlib ${target_configargs}"
3512 fi
3513
3514 # Different target subdirs use different values of certain variables
3515 # (notably CXX).  Worse, multilibs use *lots* of different values.
3516 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3517 # it doesn't automatically accept command-line overrides of them.
3518 # This means it's not safe for target subdirs to share a cache file,
3519 # which is disgusting, but there you have it.  Hopefully this can be
3520 # fixed in future.  It's still worthwhile to use a cache file for each
3521 # directory.  I think.
3522
3523 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3524 # We need to pass --target, as newer autoconf's requires consistency
3525 # for target_alias and gcc doesn't manage it consistently.
3526 target_configargs="--cache-file=./config.cache ${target_configargs}"
3527
3528 FLAGS_FOR_TARGET=
3529 case " $target_configdirs " in
3530  *" newlib "*)
3531   case " $target_configargs " in
3532   *" --with-newlib "*)
3533    case "$target" in
3534     *-cygwin*)
3535       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3536       ;;
3537    esac
3538
3539    # If we're not building GCC, don't discard standard headers.
3540    if test -d ${srcdir}/gcc; then
3541      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3542
3543      if test "${build}" != "${host}"; then
3544        # On Canadian crosses, CC_FOR_TARGET will have already been set
3545        # by `configure', so we won't have an opportunity to add -Bgcc/
3546        # to it.  This is right: we don't want to search that directory
3547        # for binaries, but we want the header files in there, so add
3548        # them explicitly.
3549        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3550
3551        # Someone might think of using the pre-installed headers on
3552        # Canadian crosses, in case the installed compiler is not fully
3553        # compatible with the compiler being built.  In this case, it
3554        # would be better to flag an error than risking having
3555        # incompatible object files being constructed.  We can't
3556        # guarantee that an error will be flagged, but let's hope the
3557        # compiler will do it, when presented with incompatible header
3558        # files.
3559      fi
3560    fi
3561
3562    case "${target}-${is_cross_compiler}" in
3563    i[[3456789]]86-*-linux*-no)
3564       # Here host == target, so we don't need to build gcc,
3565       # so we don't want to discard standard headers.
3566       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3567       ;;
3568    *)
3569       # If we're building newlib, use its generic headers last, but search
3570       # for any libc-related directories first (so make it the last -B
3571       # switch).
3572       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3573
3574       # If we're building libgloss, find the startup file, simulator library
3575       # and linker script.
3576       case " $target_configdirs " in
3577         *" libgloss "*)
3578         # Look for startup file, simulator library and maybe linker script.
3579         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3580         # Look for libnosys.a in case the target needs it.
3581         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3582         # Most targets have the linker script in the source directory.
3583         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3584         ;;
3585       esac
3586       ;;
3587    esac
3588    ;;
3589   esac
3590   ;;
3591 esac
3592
3593 case "$target" in
3594   x86_64-*mingw* | *-w64-mingw*)
3595   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3596   # however, use a symlink named 'mingw' in ${prefix} .
3597     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3598     ;;
3599   *-mingw*)
3600   # MinGW can't be handled as Cygwin above since it does not use newlib.
3601     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3602     ;;
3603 esac
3604
3605 # Allow the user to override the flags for
3606 # our build compiler if desired.
3607 if test x"${build}" = x"${host}" ; then
3608   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3609   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3610   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3611   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3612 fi
3613
3614 # On Canadian crosses, we'll be searching the right directories for
3615 # the previously-installed cross compiler, so don't bother to add
3616 # flags for directories within the install tree of the compiler
3617 # being built; programs in there won't even run.
3618 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3619   # Search for pre-installed headers if nothing else fits.
3620   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3621 fi
3622
3623 if test "x${use_gnu_ld}" = x &&
3624    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3625   # Arrange for us to find uninstalled linker scripts.
3626   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3627 fi
3628
3629 # Search for other target-specific linker scripts and such.
3630 case "${target}" in
3631   mep*)
3632     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3633     ;;
3634   # The VxWorks support for shared libraries is getting in
3635   # incrementally.  Make sure it doesn't get activated implicitly:
3636   *vxworks*)
3637     if test "${enable_shared-unset}" = unset ; then
3638       enable_shared=no
3639       # So the build of libraries knows ...
3640       target_configargs="${target_configargs} --disable-shared"
3641       # So gcc knows ...
3642       host_configargs="${host_configargs} --disable-shared"
3643     fi
3644     ;;
3645 esac
3646
3647 # Makefile fragments.
3648 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3649 do
3650   eval fragval=\$$frag
3651   if test $fragval != /dev/null; then
3652     eval $frag=${srcdir}/$fragval
3653   fi
3654 done
3655 AC_SUBST_FILE(host_makefile_frag)
3656 AC_SUBST_FILE(target_makefile_frag)
3657 AC_SUBST_FILE(alphaieee_frag)
3658 AC_SUBST_FILE(ospace_frag)
3659
3660 # Miscellanea: directories, flags, etc.
3661 AC_SUBST(RPATH_ENVVAR)
3662 AC_SUBST(GCC_SHLIB_SUBDIR)
3663 AC_SUBST(tooldir)
3664 AC_SUBST(build_tooldir)
3665 AC_SUBST(CONFIGURE_GDB_TK)
3666 AC_SUBST(GDB_TK)
3667 AC_SUBST(INSTALL_GDB_TK)
3668
3669 # Build module lists & subconfigure args.
3670 AC_SUBST(build_configargs)
3671 AC_SUBST(build_configdirs)
3672
3673 # Host module lists & subconfigure args.
3674 AC_SUBST(host_configargs)
3675 AC_SUBST(configdirs)
3676 AC_SUBST(target_configdirs)
3677
3678 # Target module lists & subconfigure args.
3679 AC_SUBST(target_configargs)
3680
3681
3682 # Build tools.
3683 AC_SUBST(AR_FOR_BUILD)
3684 AC_SUBST(AS_FOR_BUILD)
3685 AC_SUBST(CC_FOR_BUILD)
3686 AC_SUBST(CFLAGS_FOR_BUILD)
3687 AC_SUBST(CPP_FOR_BUILD)
3688 AC_SUBST(CPPFLAGS_FOR_BUILD)
3689 AC_SUBST(CXXFLAGS_FOR_BUILD)
3690 AC_SUBST(CXX_FOR_BUILD)
3691 AC_SUBST(DLLTOOL_FOR_BUILD)
3692 AC_SUBST(DSYMUTIL_FOR_BUILD)
3693 AC_SUBST(GFORTRAN_FOR_BUILD)
3694 AC_SUBST(GOC_FOR_BUILD)
3695 AC_SUBST(GDC_FOR_BUILD)
3696 AC_SUBST(LDFLAGS_FOR_BUILD)
3697 AC_SUBST(LD_FOR_BUILD)
3698 AC_SUBST(NM_FOR_BUILD)
3699 AC_SUBST(RANLIB_FOR_BUILD)
3700 AC_SUBST(WINDMC_FOR_BUILD)
3701 AC_SUBST(WINDRES_FOR_BUILD)
3702
3703 # Generate default definitions for YACC, M4, LEX and other programs that run
3704 # on the build machine.  These are used if the Makefile can't locate these
3705 # programs in objdir.
3706 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3707
3708 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3709 case " $build_configdirs " in
3710   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3711 esac
3712
3713 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3714 case " $build_configdirs " in
3715   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3716 esac
3717
3718 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3719 case " $build_configdirs " in
3720   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3721 esac
3722
3723 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3724 case " $build_configdirs " in
3725   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3726   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3727 esac
3728
3729 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3730 case " $build_configdirs " in
3731   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3732 esac
3733
3734 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3735 case " $build_configdirs " in
3736   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3737   *)
3738 changequote(,)
3739     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3740     # higher, else we use the "missing" dummy.
3741     if ${MAKEINFO} --version \
3742        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3743       :
3744     else
3745       MAKEINFO="$MISSING makeinfo"
3746     fi
3747     ;;
3748 changequote([,])
3749 esac
3750
3751 # FIXME: expect and dejagnu may become build tools?
3752
3753 AC_CHECK_PROGS(EXPECT, expect, expect)
3754 case " $configdirs " in
3755   *" expect "*)
3756     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3757     ;;
3758 esac
3759
3760 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3761 case " $configdirs " in
3762   *" dejagnu "*)
3763     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3764     ;;
3765 esac
3766
3767
3768 # Host tools.
3769 NCN_STRICT_CHECK_TOOLS(AR, ar)
3770 NCN_STRICT_CHECK_TOOLS(AS, as)
3771 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3772 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3773 NCN_STRICT_CHECK_TOOLS(LD, ld)
3774 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3775 NCN_STRICT_CHECK_TOOLS(NM, nm)
3776 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3777 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3778 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3779 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3780 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3781 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3782 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3783 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3784 AC_SUBST(CC)
3785 AC_SUBST(CXX)
3786 AC_SUBST(CFLAGS)
3787 AC_SUBST(CXXFLAGS)
3788 AC_SUBST(GDC)
3789 AC_SUBST(GDCFLAGS)
3790 GDCFLAGS=${GDCFLAGS-${CFLAGS}}
3791 AC_SUBST(PKG_CONFIG_PATH)
3792
3793 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3794 AR_PLUGIN_OPTION=
3795 RANLIB_PLUGIN_OPTION=
3796 if test -n "$PLUGIN_OPTION"; then
3797   if $AR --help 2>&1 | grep -q "\--plugin"; then
3798     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3799   fi
3800   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3801     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3802   fi
3803 fi
3804 AC_SUBST(AR_PLUGIN_OPTION)
3805 AC_SUBST(RANLIB_PLUGIN_OPTION)
3806
3807 # Target tools.
3808 AC_ARG_WITH([build-time-tools],
3809   [AS_HELP_STRING([--with-build-time-tools=PATH],
3810                   [use given path to find target tools during the build])],
3811   [case x"$withval" in
3812      x/*) ;;
3813      *)
3814        with_build_time_tools=
3815        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3816        ;;
3817    esac],
3818   [with_build_time_tools=])
3819
3820 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3821 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3822 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3823 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3824 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3825 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3826 NCN_STRICT_CHECK_TARGET_TOOLS(GM2_FOR_TARGET, gm2)
3827
3828 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3829 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3830 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3831 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3832 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3833 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3834 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3835 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3836 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3837 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3838 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3839 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3840 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3841 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3842 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3843
3844 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3845
3846 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3847 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3848 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3849 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3850 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3851                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3852                 c++)
3853 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3854                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3855                 c++)
3856 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3857 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3858 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3859 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3860                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3861 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3862                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3863 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3864                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3865 GCC_TARGET_TOOL(gm2, GM2_FOR_TARGET, GM2,
3866                 [gcc/gm2 -B$$r/$(HOST_SUBDIR)/gcc/], m2)
3867 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3868 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3869 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3870 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3871 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3872 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3873 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3874 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3875 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3876 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3877 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3878
3879 AC_SUBST(FLAGS_FOR_TARGET)
3880 AC_SUBST(RAW_CXX_FOR_TARGET)
3881
3882 # Certain tools may need extra flags.
3883 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3884 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3885 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3886
3887 # When building target libraries, except in a Canadian cross, we use
3888 # the same toolchain as the compiler we just built.
3889 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3890 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3891 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3892 if test $host = $build; then
3893   case " $configdirs " in
3894     *" gcc "*)
3895       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3896       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3897       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3898       ;;
3899   esac
3900 fi
3901
3902 AC_SUBST(COMPILER_AS_FOR_TARGET)
3903 AC_SUBST(COMPILER_LD_FOR_TARGET)
3904 AC_SUBST(COMPILER_NM_FOR_TARGET)
3905
3906 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3907 AC_ARG_ENABLE(maintainer-mode,
3908 [AS_HELP_STRING([--enable-maintainer-mode],
3909                 [enable make rules and dependencies not useful
3910                  (and sometimes confusing) to the casual installer])],
3911       USE_MAINTAINER_MODE=$enableval,
3912       USE_MAINTAINER_MODE=no)
3913 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3914 AC_SUBST(MAINTAINER_MODE_TRUE)
3915 AC_SUBST(MAINTAINER_MODE_FALSE)
3916 if test "$USE_MAINTAINER_MODE" = yes; then
3917   MAINTAINER_MODE_TRUE=
3918   MAINTAINER_MODE_FALSE='#'
3919 else
3920   MAINTAINER_MODE_TRUE='#'
3921   MAINTAINER_MODE_FALSE=
3922 fi
3923 MAINT=$MAINTAINER_MODE_TRUE
3924 AC_SUBST(MAINT)dnl
3925
3926 # ---------------------
3927 # GCC bootstrap support
3928 # ---------------------
3929
3930 # Stage specific cflags for build.
3931 stage1_cflags="-g"
3932 case $build in
3933   vax-*-*)
3934     case ${GCC} in
3935       yes) stage1_cflags="-g -Wa,-J" ;;
3936       *) stage1_cflags="-g -J" ;;
3937     esac ;;
3938 esac
3939
3940 AC_SUBST(stage1_cflags)
3941
3942 # Enable --enable-checking in stage1 of the compiler.
3943 AC_ARG_ENABLE(stage1-checking,
3944 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3945                 [choose additional checking for stage1 of the compiler])],
3946 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3947 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3948   # For --disable-checking or implicit --enable-checking=release, avoid
3949   # setting --enable-checking=gc in the default stage1 checking for LTO
3950   # bootstraps.  See PR62077.
3951   case $BUILD_CONFIG in
3952     *lto*)
3953       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3954     *)
3955       stage1_checking=--enable-checking=yes,types;;
3956   esac
3957   if test "x$enable_checking" = x && \
3958      test -d ${srcdir}/gcc && \
3959      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3960     stage1_checking=--enable-checking=yes,types,extra
3961   fi
3962 else
3963   stage1_checking=--enable-checking=$enable_checking,types
3964 fi])
3965 AC_SUBST(stage1_checking)
3966
3967 # Enable -Werror in bootstrap stage2 and later.
3968 AC_ARG_ENABLE(werror,
3969 [AS_HELP_STRING([--enable-werror],
3970                 [enable -Werror in bootstrap stage2 and later])],
3971 [
3972 case ${enable_werror} in
3973   yes) stage2_werror_flag="--enable-werror-always" ;;
3974   *) stage2_werror_flag="" ;;
3975 esac
3976 ],
3977 [
3978 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3979   case $BUILD_CONFIG in
3980   bootstrap-debug)
3981       stage2_werror_flag="--enable-werror-always" ;;
3982   "")
3983       stage2_werror_flag="--enable-werror-always" ;;
3984   esac
3985 fi
3986 ])
3987
3988 AC_SUBST(stage2_werror_flag)
3989
3990 # Specify what files to not compare during bootstrap.
3991
3992 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3993 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/M2Version*"
3994 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/SYSTEM*"
3995 compare_exclusions="$compare_exclusions | gcc/m2/gm2version*"
3996 case "$target" in
3997   hppa*64*-*-hpux*) ;;
3998   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3999 esac
4000 AC_SUBST(compare_exclusions)
4001
4002 AC_CONFIG_FILES([Makefile],
4003   [sed "$extrasub_build" Makefile |
4004    sed "$extrasub_host" |
4005    sed "$extrasub_target" > mf$$
4006    mv -f mf$$ Makefile],
4007   [extrasub_build="$extrasub_build"
4008    extrasub_host="$extrasub_host"
4009    extrasub_target="$extrasub_target"])
4010 AC_OUTPUT