gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2024 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 m4_include([../bfd/version.m4])
  24 AC_INIT([gas], [BFD_VERSION])
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32
  33 AM_INIT_AUTOMAKE
  34 AM_SILENT_RULES([yes])
  35
  36 AC_PROG_CC
  37 AC_USE_SYSTEM_EXTENSIONS
  38
  39 LT_INIT
  40 ACX_LARGEFILE
  41 ACX_PROG_CMP_IGNORE_INITIAL
  42
  43 AC_ARG_ENABLE(targets,
  44 [  --enable-targets        alternative target configurations besides the primary],
  45 [case "${enableval}" in
  46   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  47             ;;
  48   no)       enable_targets= ;;
  49   *)        enable_targets=$enableval ;;
  50 esac])dnl
  51
  52 ac_checking=
  53 . ${srcdir}/../bfd/development.sh
  54 test "$development" = true && ac_checking=yes
  55 AC_ARG_ENABLE(checking,
  56 [  --enable-checking       enable run-time checks],
  57 [case "${enableval}" in
  58   no|none)  ac_checking= ;;
  59   *)        ac_checking=yes ;;
  60 esac])dnl
  61 if test x$ac_checking != x ; then
  62   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  63 fi
  64
  65 # PR gas/19109
  66 # Decide the default method for compressing debug sections.
  67 ac_default_compressed_debug_sections=unset
  68 # Provide a configure time option to override our default.
  69 AC_ARG_ENABLE(compressed_debug_sections,
  70               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  71               [compress debug sections by default]),
  72 [case ,"${enableval}", in
  73   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  74   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  75   *)   ac_default_compressed_debug_sections=unset ;;
  76 esac])dnl
  77
  78 # Select default compression algorithm.
  79 ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_GABI_ZLIB
  80 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
  81               AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
  82               [Default compression algorithm for --enable-compressed-debug-sections.]),
  83 [case "${enableval}" in
  84    zstd) ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_ZSTD ;;
  85 esac])dnl
  86
  87 # PR gas/19520
  88 # Decide if x86 assembler should generate relax relocations.
  89 ac_default_x86_relax_relocations=unset
  90 # Provide a configure time option to override our default.
  91 AC_ARG_ENABLE(x86_relax_relocations,
  92               AS_HELP_STRING([--enable-x86-relax-relocations],
  93               [generate x86 relax relocations by default]),
  94 [case "${enableval}" in
  95   no)  ac_default_x86_relax_relocations=0 ;;
  96 esac])dnl
  97
  98 # Decide if ELF assembler should generate common symbols with the
  99 # STT_COMMON type.
 100 ac_default_elf_stt_common=unset
 101 # Provide a configure time option to override our default.
 102 AC_ARG_ENABLE(elf_stt_common,
 103               AS_HELP_STRING([--enable-elf-stt-common],
 104               [generate ELF common symbols with STT_COMMON type by default]),
 105 [case "${enableval}" in
 106   yes)  ac_default_elf_stt_common=1 ;;
 107 esac])dnl
 108
 109
 110 # Decide if the ELF assembler should default to generating
 111 # GNU Build notes if none are provided by the input.
 112 ac_default_generate_build_notes=0
 113 # Provide a configuration option to override the default.
 114 AC_ARG_ENABLE(generate_build_notes,
 115               AS_HELP_STRING([--enable-generate-build-notes],
 116               [generate GNU Build notes if none are provided by the input]),
 117 [case "${enableval}" in
 118   yes)  ac_default_generate_build_notes=1 ;;
 119   no)   ac_default_generate_build_notes=0 ;;
 120 esac])dnl
 121
 122 # Decide if the MIPS assembler should default to enable MIPS fix Loongson3
 123 # LLSC errata.
 124 ac_default_mips_fix_loongson3_llsc=unset
 125 # Provide a configuration option to override the default.
 126 AC_ARG_ENABLE(mips-fix-loongson3-llsc,
 127              AS_HELP_STRING([--enable-mips-fix-loongson3-llsc],
 128              [enable MIPS fix Loongson3 LLSC errata]),
 129 [case "${enableval}" in
 130   yes)  ac_default_mips_fix_loongson3_llsc=1 ;;
 131   no)   ac_default_mips_fix_loongson3_llsc=0 ;;
 132 esac])dnl
 133
 134 # Decide if the x86 ELF assembler should default to generating GNU x86
 135 # used ISA and feature properties.
 136 ac_default_generate_x86_used_note=unset
 137 # Provide a configuration option to override the default.
 138 AC_ARG_ENABLE(x86-used-note,
 139               AS_HELP_STRING([--enable-x86-used-note],
 140               [generate GNU x86 used ISA and feature properties]),
 141 [case "${enableval}" in
 142   yes)  ac_default_generate_x86_used_note=1 ;;
 143   no)   ac_default_generate_x86_used_note=0 ;;
 144 esac])dnl
 145
 146 # Decide if the RISC-V ELF assembler should default to generating attribute.
 147 ac_default_generate_riscv_attr=unset
 148 # Provide a configuration option to override the default.
 149 AC_ARG_ENABLE(default-riscv-attribute,
 150               AS_HELP_STRING([--enable-default-riscv-attribute],
 151               [generate RISC-V arch attribute by default]),
 152 [case "${enableval}" in
 153   yes)  ac_default_generate_riscv_attr=1 ;;
 154   no)   ac_default_generate_riscv_attr=0 ;;
 155 esac])dnl
 156
 157 using_cgen=no
 158
 159 AM_BINUTILS_WARNINGS
 160
 161 # Generate a header file
 162 AC_CONFIG_HEADERS(config.h:config.in)
 163
 164 dnl Option --with-cpu=TYPE allows configure type control of the default
 165 dnl cpu type within the assembler.  Currently only the ARC target
 166 dnl supports this feature, but others may be added in the future.
 167 AC_ARG_WITH(cpu,
 168             AS_HELP_STRING([--with-cpu=CPU],
 169             [default cpu variant is CPU (currently only supported on ARC)]),
 170             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 171                                 "${with_cpu}",
 172                                 [Target specific CPU.])],
 173             [])
 174
 175 # PR 14072
 176 AH_VERBATIM([00_CONFIG_H_CHECK],
 177 [/* Check that config.h is #included before system headers
 178    (this works only for glibc, but that should be enough).  */
 179 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 180 #  error config.h must be #included before system headers
 181 #endif
 182 #define __CONFIG_H__ 1])
 183
 184 # If we are on a DOS filesystem, we must use gdb.ini rather than
 185 # .gdbinit.
 186 case "${host}" in
 187   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 188     GDBINIT="gdb.ini"
 189     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 190     ;;
 191   *)
 192     GDBINIT=".gdbinit"
 193     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 194     ;;
 195 esac
 196 AC_SUBST(GDBINIT)
 197
 198 #We need this for the host.
 199 AC_C_BIGENDIAN
 200
 201 te_file=generic
 202
 203 # Makefile target for installing gas in $(tooldir)/bin.
 204 install_tooldir=install-exec-tooldir
 205
 206 canon_targets=""
 207 all_targets=no
 208 if test -n "$enable_targets" ; then
 209   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 210     if test $t = "all"; then
 211       all_targets=yes
 212       continue
 213     fi
 214     result=`$ac_config_sub $t 2>/dev/null`
 215     if test -n "$result" ; then
 216       canon_targets="$canon_targets $result"
 217 #    else
 218 #      # Permit "all", etc.  We don't support it yet though.
 219 #      canon_targets="$canon_targets $t"
 220     fi
 221   done
 222   GAS_UNIQ(canon_targets)
 223 fi
 224
 225 emulations=""
 226
 227 for this_target in $target $canon_targets ; do
 228
 229     targ=${this_target}
 230     . ${srcdir}/configure.tgt
 231
 232     case ${target_cpu} in
 233       crisv32)
 234         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 235                            [Default CRIS architecture.])
 236         ;;
 237     esac
 238
 239     if test ${this_target} = $target ; then
 240       target_cpu_type=${cpu_type}
 241     elif test ${target_cpu_type} != ${cpu_type} ; then
 242       continue
 243     fi
 244
 245     generic_target=${cpu_type}-${target_vendor}-${target_os}
 246     case ${generic_target} in
 247       i386-*-msdosdjgpp* \
 248       | i386-*-go32*)
 249         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 250         ;;
 251
 252       i386-*-linux-* | x86_64-*-linux-*)
 253         if test ${this_target} = $target \
 254            && test ${ac_default_generate_x86_used_note} = unset; then
 255           ac_default_generate_x86_used_note=1
 256         fi
 257         ;;
 258
 259       i386-*-solaris2 \
 260       | x86_64-*-solaris2 \
 261       | i386-*-solaris2.[[0-9]] \
 262       | i386-*-solaris2.1[[01]] \
 263       | x86_64-*-solaris2.1[[01]])
 264         if test ${this_target} = $target \
 265            && test ${ac_default_x86_relax_relocations} = unset; then
 266           ac_default_x86_relax_relocations=0
 267         fi
 268         ;;
 269
 270       microblaze*)
 271         ;;
 272
 273 changequote(,)dnl
 274       ppc-*-aix5.[01]*)
 275         ;;
 276       ppc-*-aix[5-9].*)
 277 changequote([,])dnl
 278         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 279                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 280         ;;
 281       ppc-*-solaris*)
 282         if test ${this_target} = $target; then
 283           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 284                     [Define if default target is PowerPC Solaris.])
 285         fi
 286         if test x${endian} = xbig; then
 287           AC_MSG_ERROR(Solaris must be configured little endian)
 288         fi
 289         ;;
 290     esac
 291
 292     if test ${this_target} = $target ; then
 293       endian_def=
 294       if test x${endian} = xbig; then
 295         endian_def=1
 296       elif test x${endian} = xlittle; then
 297         endian_def=0
 298       fi
 299       if test x${endian_def} != x; then
 300         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 301                            [Define as 1 if big endian.])
 302       fi
 303     fi
 304
 305 # Other random stuff.
 306
 307     case ${cpu_type} in
 308       mips)
 309         # Set mips_cpu to the name of the default CPU.
 310         case ${target_cpu} in
 311           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 312             mips_cpu=from-abi
 313             ;;
 314           mipsisa32 | mipsisa32el)
 315             mips_cpu=mips32
 316             ;;
 317           mipsisa32r2 | mipsisa32r2el)
 318             mips_cpu=mips32r2
 319             ;;
 320           mipsisa32r3 | mipsisa32r3el)
 321             mips_cpu=mips32r3
 322             ;;
 323           mipsisa32r5 | mipsisa32r5el)
 324             mips_cpu=mips32r5
 325             ;;
 326           mipsisa32r6 | mipsisa32r6el)
 327             mips_cpu=mips32r6
 328             ;;
 329           mipsisa64 | mipsisa64el)
 330             mips_cpu=mips64
 331             ;;
 332           mipsisa64r2 | mipsisa64r2el)
 333             mips_cpu=mips64r2
 334             ;;
 335           mipsisa64r3 | mipsisa64r3el)
 336             mips_cpu=mips64r3
 337             ;;
 338           mipsisa64r5 | mipsisa64r5el)
 339             mips_cpu=mips64r5
 340             ;;
 341           mipsisa64r6 | mipsisa64r6el)
 342             mips_cpu=mips64r6
 343             ;;
 344           mipstx39 | mipstx39el)
 345             mips_cpu=r3900
 346             ;;
 347           mips64vr | mips64vrel)
 348             mips_cpu=vr4100
 349             ;;
 350           mipsisa32r2* | mipsisa64r2*)
 351 changequote(,)dnl
 352             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 353 changequote([,])dnl
 354             ;;
 355           mipsisa32r6* | mipsisa64r6*)
 356 changequote(,)dnl
 357             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 358 changequote([,])dnl
 359             ;;
 360           mips64* | mipsisa64* | mipsisa32*)
 361 changequote(,)dnl
 362             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 363 changequote([,])dnl
 364             ;;
 365           mips*)
 366 changequote(,)dnl
 367             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 368 changequote([,])dnl
 369             ;;
 370           *)
 371             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 372             ;;
 373         esac
 374         # See whether it's appropriate to set EF_MIPS_ABI_O32 for o32
 375         # binaries.  It's a GNU extension that some OSes don't understand.
 376         case ${target} in
 377           *-*-irix*)
 378             use_ef_mips_abi_o32=0
 379             ;;
 380           *)
 381             use_ef_mips_abi_o32=1
 382             ;;
 383         esac
 384         # If Vendor is IMG, then MIPSr6 is used
 385         case ${target} in
 386           mips*-img-*)
 387             mips_cpu=mips32r6
 388             ;;
 389         esac
 390         # Decide whether to generate 32-bit or 64-bit code by default.
 391         # Used to resolve -march=from-abi when an embedded ABI is selected.
 392         case ${target} in
 393           mips64*-*-* | mipsisa64*-*-*)
 394             mips_default_64bit=1
 395             ;;
 396           *)
 397             mips_default_64bit=0
 398             ;;
 399         esac
 400         # Decide which ABI to target by default.
 401         case ${target} in
 402           mips64*-openbsd* | mips64*-linux-gnuabi64)
 403             mips_default_abi=N64_ABI
 404             ;;
 405           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 406           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 407             mips_default_abi=N32_ABI
 408             ;;
 409           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 410             mips_default_abi=O32_ABI
 411             ;;
 412           *)
 413             mips_default_abi=NO_ABI
 414             ;;
 415         esac
 416         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 417                            [Default CPU for MIPS targets. ])
 418         AC_DEFINE_UNQUOTED(USE_EF_MIPS_ABI_O32, $use_ef_mips_abi_o32,
 419                            [Allow use of EF_MIPS_ABI_O32 on MIPS targets. ])
 420         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 421                            [Generate 64-bit code by default on MIPS targets. ])
 422         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 423                            [Choose a default ABI for MIPS targets. ])
 424         ;;
 425     esac
 426
 427     # Do we need the opcodes library?
 428     case ${cpu_type} in
 429       vax | tic30 | i386 | arm)
 430         ;;
 431
 432       *)
 433         need_opcodes=yes
 434
 435         case "${enable_shared}" in
 436         yes) shared_opcodes=true ;;
 437         *opcodes*) shared_opcodes=true ;;
 438         *) shared_opcodes=false ;;
 439         esac
 440         ;;
 441     esac
 442
 443     # Any other special object files needed ?
 444     case ${cpu_type} in
 445
 446       bfin)
 447         for f in config/bfin-parse.o config/bfin-lex-wrapper.o; do
 448           case " $extra_objects " in
 449             *" $f "*) ;;
 450             *) extra_objects="$extra_objects $f" ;;
 451           esac
 452         done
 453         ;;
 454
 455       bpf)
 456         if test $this_target = $target ; then
 457           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 458         fi
 459         ;;
 460       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 461         using_cgen=yes
 462         ;;
 463
 464       loongarch)
 465         for f in config/loongarch-parse.o config/loongarch-lex-wrapper.o; do
 466           case " $extra_objects " in
 467             *" $f "*) ;;
 468             *) extra_objects="$extra_objects $f" ;;
 469           esac
 470         done
 471         # --target=loongarch[32|64]-*-*.  */
 472         if test $this_target = $target ; then
 473           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 474         fi
 475         ;;
 476
 477       m32c)
 478         using_cgen=yes
 479         ;;
 480       frv)
 481         using_cgen=yes
 482         ;;
 483       kvx)
 484         for f in config/kvx-parse.o; do
 485           case " $extra_objects " in
 486             *" $f "*) ;;
 487             *) extra_objects="$extra_objects $f" ;;
 488           esac
 489         done
 490         ;;
 491       m68k)
 492         f=config/m68k-parse.o
 493         case " $extra_objects " in
 494           *" $f "*) ;;
 495           *) extra_objects="$extra_objects $f" ;;
 496         esac
 497         ;;
 498
 499       mep)
 500         using_cgen=yes
 501         ;;
 502
 503       mips)
 504         for f in itbl-parse.o itbl-lex-wrapper.o itbl-ops.o; do
 505           case " $extra_objects " in
 506             *" $f "*) ;;
 507             *) extra_objects="$extra_objects $f" ;;
 508           esac
 509         done
 510         ;;
 511
 512       mt)
 513         using_cgen=yes
 514         ;;
 515
 516       nds32)
 517         # setup NDS32_LINUX_TOOLCHAIN definition
 518         if test "linux" = $em; then
 519           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 1,
 520             [Define value for nds32_linux_toolchain])
 521         else
 522           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 0,
 523             [Define default value for nds32_linux_toolchain])
 524         fi
 525
 526         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 527         # based on arch_name.
 528         AC_MSG_CHECKING(for default configuration of --with-arch)
 529         if test "x${with_arch}" != x; then
 530           case ${with_arch} in
 531             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 532               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 533                                  [Define value for nds32_arch_name])
 534               ;;
 535             *)
 536               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 537               ;;
 538           esac
 539         fi
 540         AC_MSG_RESULT($with_arch)
 541
 542         # Decide features one by one.
 543         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 544         if test "x${enable_dx_regs}" = xyes; then
 545           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 546                     [Define value for nds32_dx_regs])
 547         else
 548           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 549                     [Define default value for nds32_dx_regs])
 550         fi
 551         AC_MSG_RESULT($enable_dx_regs)
 552
 553         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 554         if test "x${enable_perf_ext}" = xno; then
 555           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 556                     [Define value for nds32_perf_ext])
 557         else
 558           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 559                     [Define default value for nds32_perf_ext])
 560         fi
 561         AC_MSG_RESULT($enable_perf_ext)
 562
 563         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 564         if test "x${enable_perf_ext2}" = xno; then
 565           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 566                     [Define value for nds32_perf_ext2])
 567         else
 568           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 569                     [Define default value for nds32_perf_ext2])
 570         fi
 571         AC_MSG_RESULT($enable_perf_ext2)
 572
 573         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 574         if test "x${enable_string_ext}" = xno; then
 575           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 576                     [Define value for nds32_string_ext])
 577         else
 578           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 579                     [Define default value for nds32_string_ext])
 580         fi
 581         AC_MSG_RESULT($enable_string_ext)
 582
 583         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 584         if test "x${enable_audio_ext}" = xno; then
 585           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 586                     [Define value for nds32_audio_ext])
 587         else
 588           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 589                     [Define default value for nds32_audio_ext])
 590         fi
 591         AC_MSG_RESULT($enable_audio_ext)
 592
 593         AC_MSG_CHECKING(for default configuration of --enable-dsp-ext)
 594         if test "x${enable_dsp_ext}" = xno; then
 595           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 0,
 596                     [Define value for nds32_dsp_ext])
 597         else
 598           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 1,
 599                     [Define default value for nds32_dsp_ext])
 600         fi
 601         AC_MSG_RESULT($enable_dsp_ext)
 602
 603         AC_MSG_CHECKING(for default configuration of --enable-zol-ext)
 604         if test "x${enable_zol_ext}" = xno; then
 605           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 0,
 606                     [Define value for nds32_zol_ext])
 607         else
 608           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 1,
 609                     [Define default value for nds32_zol_ext])
 610         fi
 611         AC_MSG_RESULT($enable_zol_ext)
 612         ;;
 613
 614       aarch64 | i386 | s390 | sparc)
 615         if test $this_target = $target ; then
 616           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 617         fi
 618         ;;
 619
 620       riscv)
 621         # --target=riscv[32|64]-*-*.  */
 622         if test $this_target = $target ; then
 623           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 624         fi
 625
 626         # --with-arch=<value>.  The syntax of <value> is same as Gas option -march.
 627         AC_MSG_CHECKING(for default configuration of --with-arch)
 628         if test "x${with_arch}" != x; then
 629         AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ARCH_WITH_EXT, "$with_arch",
 630                            [Define default value for RISC-V -march.])
 631         fi
 632         AC_MSG_RESULT($with_arch)
 633
 634         # --with-isa-spec=[2.2|20190608|20191213].
 635         AC_MSG_CHECKING(for default configuration of --with-isa-spec)
 636         if test "x${with_isa_spec}" != x; then
 637           AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ISA_SPEC, "$with_isa_spec",
 638                              [Define default value for RISC-V -misa-spec.])
 639         fi
 640         AC_MSG_RESULT($with_isa_spec)
 641
 642         # --with-priv-spec=[1.9.1|1.10|1.11|1.12].
 643         AC_MSG_CHECKING(for default configuration of --with-priv-spec)
 644         if test "x${with_priv_spec}" != x; then
 645           AC_DEFINE_UNQUOTED(DEFAULT_RISCV_PRIV_SPEC, "$with_priv_spec",
 646                              [Define default value for RISC-V -mpriv-spec])
 647         fi
 648         AC_MSG_RESULT($with_priv_spec)
 649         ;;
 650
 651       rl78)
 652         f=config/rl78-parse.o
 653         case " $extra_objects " in
 654           *" $f "*) ;;
 655           *) extra_objects="$extra_objects $f" ;;
 656         esac
 657         ;;
 658
 659       rx)
 660         f=config/rx-parse.o
 661         case " $extra_objects " in
 662           *" $f "*) ;;
 663           *) extra_objects="$extra_objects $f" ;;
 664         esac
 665         ;;
 666
 667       xstormy16)
 668         using_cgen=yes
 669         ;;
 670
 671       xtensa)
 672         f=config/xtensa-relax.o
 673         case " $extra_objects " in
 674           *" $f "*) ;;
 675           *) extra_objects="$extra_objects $f" ;;
 676         esac
 677         ;;
 678
 679       *)
 680         ;;
 681     esac
 682
 683     if test $using_cgen = yes ; then
 684         f=cgen.o
 685         case " $extra_objects " in
 686           *" $f "*) ;;
 687           *) extra_objects="$extra_objects $f" ;;
 688         esac
 689     fi
 690
 691 # See if we really can support this configuration with the emulation code.
 692
 693     if test $this_target = $target ; then
 694       obj_format=$fmt
 695       te_file=$em
 696     fi
 697
 698     case ${te_file} in
 699       vms)
 700         f=config/te-vms.o
 701         case " $extra_objects " in
 702           *" $f "*) ;;
 703           *) extra_objects="$extra_objects $f" ;;
 704         esac ;;
 705     esac
 706
 707 # From target name and format, produce a list of supported emulations.
 708
 709     case ${generic_target}-${fmt} in
 710       mips-*-*-*)       case "$endian" in
 711                         big)    emulation="mipsbelf mipslelf mipself" ;;
 712                         *)      emulation="mipslelf mipsbelf mipself" ;;
 713                         esac ;;
 714       # i386-pc-pe-coff != i386-pc-coff.
 715       i386-*-pe-coff)   ;;
 716       # Uncommenting the next line will turn on support for i386 AOUT
 717       # for the default linux configuration
 718       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 719       #
 720       i386-*-aout)      emulation="i386aout" ;;
 721       i386-*-coff)      emulation="i386coff" ;;
 722       i386-*-elf)       emulation="i386elf" ;;
 723
 724       # Always all formats.  The first stated emulation becomes the default.
 725       cris-*-*aout*)    emulation="crisaout criself" ;;
 726       cris-*-*)         emulation="criself crisaout" ;;
 727     esac
 728
 729     emulations="$emulations $emulation"
 730
 731 done
 732
 733 if test ${ac_default_x86_relax_relocations} = unset; then
 734   ac_default_x86_relax_relocations=1
 735 fi
 736 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 737   $ac_default_x86_relax_relocations,
 738   [Define to 1 if you want to generate x86 relax relocations by default.])
 739
 740 if test ${ac_default_elf_stt_common} = unset; then
 741   ac_default_elf_stt_common=0
 742 fi
 743 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 744   $ac_default_elf_stt_common,
 745   [Define to 1 if you want to generate ELF common symbols with the
 746    STT_COMMON type by default.])
 747
 748 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_BUILD_NOTES,
 749   $ac_default_generate_build_notes,
 750   [Define to 1 if you want to generate GNU Build attribute notes
 751    by default, if none are contained in the input.])
 752
 753 if test ${ac_default_generate_x86_used_note} = unset; then
 754   ac_default_generate_x86_used_note=0
 755 fi
 756 AC_DEFINE_UNQUOTED(DEFAULT_X86_USED_NOTE,
 757   $ac_default_generate_x86_used_note,
 758   [Define to 1 if you want to generate GNU x86 used ISA and feature
 759    properties by default.])
 760
 761 if test ${ac_default_generate_riscv_attr} = unset; then
 762   ac_default_generate_riscv_attr=1
 763 fi
 764
 765 AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ATTR,
 766   $ac_default_generate_riscv_attr,
 767   [Define to 1 if you want to generate RISC-V arch attribute by default.])
 768
 769 if test ${ac_default_mips_fix_loongson3_llsc} = unset; then
 770   ac_default_mips_fix_loongson3_llsc=0
 771 fi
 772 AC_DEFINE_UNQUOTED(DEFAULT_MIPS_FIX_LOONGSON3_LLSC,
 773   $ac_default_mips_fix_loongson3_llsc,
 774   [Define to 1 if you want to fix Loongson3 LLSC Errata by default.])
 775
 776 if test x$ac_default_compressed_debug_sections = xyes ; then
 777   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 778 fi
 779
 780 AC_DEFINE_UNQUOTED(DEFAULT_COMPRESSED_DEBUG_ALGORITHM, $ac_default_compressed_debug_sections_algorithm,
 781                    [Default compression algorithm for --enable-compressed-debug-sections.])
 782
 783 # Turn on all targets if possible
 784 if test ${all_targets} = "yes"; then
 785   case ${target_cpu_type} in
 786   i386)
 787     case ${obj_format} in
 788     aout)
 789       emulations="$emulations i386coff i386elf"
 790       ;;
 791     coff)
 792       emulations="$emulations i386aout i386elf"
 793     ;;
 794     elf)
 795       emulations="$emulations i386aout i386coff"
 796       ;;
 797     esac
 798   ;;
 799   x86_64)
 800     case ${obj_format} in
 801     aout)
 802       emulations="$emulations i386coff i386elf"
 803       ;;
 804     coff)
 805       emulations="$emulations i386aout i386elf"
 806     ;;
 807     elf)
 808       emulations="$emulations i386aout i386coff"
 809       ;;
 810     esac
 811   ;;
 812   esac
 813 fi
 814
 815 # PE code has way too many macros tweaking behaviour
 816 case ${te_file} in
 817   pe*) emulations="" ;;
 818 esac
 819
 820 # Assign floating point type.  Most processors with FP support
 821 # IEEE FP.  On those that don't support FP at all, usually IEEE
 822 # is emulated.
 823 case ${target_cpu} in
 824   vax | pdp11 ) atof=vax ;;
 825   *)            atof=ieee ;;
 826 esac
 827
 828 case "${obj_format}" in
 829   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 830 esac
 831
 832 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 833 cgen_cpu_prefix=""
 834 if test $using_cgen = yes ; then
 835   case ${target_cpu} in
 836     or1knd)
 837        cgen_cpu_prefix=or1k ;;
 838     *) cgen_cpu_prefix=${target_cpu} ;;
 839   esac
 840   AC_SUBST(cgen_cpu_prefix)
 841   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 842 fi
 843
 844 dnl
 845 dnl Make sure the desired support files exist.
 846 dnl
 847
 848 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 849   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 850 fi
 851
 852 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 853   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 854 fi
 855
 856 # Some COFF configurations want these random other flags set.
 857 case ${obj_format} in
 858   coff)
 859     case ${target_cpu_type} in
 860       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 861       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 862     esac
 863     ;;
 864 esac
 865
 866 # Getting this done right is going to be a bitch.  Each configuration specified
 867 # with --enable-targets=... should be checked for environment, format, cpu
 868 # setting.
 869 #
 870 # For each configuration, the necessary object file support code must be linked
 871 # in.  This might be only one, it might be up to four.  The necessary emulation
 872 # code needs to be provided, too.
 873 #
 874 # And then there's "--enable-targets=all"....
 875 #
 876 # For now, just always do it for MIPS ELF configurations.  Sigh.
 877
 878 formats="${obj_format}"
 879 emfiles=""
 880 EMULATIONS=""
 881 GAS_UNIQ(emulations)
 882 for em in . $emulations ; do
 883   case $em in
 884     .)  continue ;;
 885     mipsbelf | mipslelf | mipself)
 886         fmt=elf   file=mipself ;;
 887     *coff)
 888         fmt=coff  file=$em ;;
 889     *aout)
 890         fmt=aout file=$em ;;
 891     *elf)
 892         fmt=elf file=$em ;;
 893   esac
 894   formats="$formats $fmt"
 895   emfiles="$emfiles config/e-$file.o"
 896   EMULATIONS="$EMULATIONS &$em,"
 897 done
 898 GAS_UNIQ(formats)
 899 GAS_UNIQ(emfiles)
 900 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 901   for fmt in $formats ; do
 902     case $fmt in
 903       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 904       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 905       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 906       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 907       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 908       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 909     esac
 910     extra_objects="$extra_objects config/obj-$fmt.o"
 911   done
 912   obj_format=multi
 913 fi
 914 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 915   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 916   # e-mipself has more than one emulation per file, e-i386* has just one at the
 917   # moment.  If only one emulation is specified, then don't define
 918   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 919   case "${obj_format}${emfiles}" in
 920     multi* | *mipself*)
 921       extra_objects="$extra_objects $emfiles"
 922       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 923   esac
 924 fi
 925 AC_SUBST(extra_objects)
 926 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 927 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 928                    [Default emulation.])
 929
 930 reject_dev_configs=yes
 931
 932 case ${reject_dev_configs}-${dev} in
 933   yes-yes) # Oops.
 934     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 935     ;;
 936 esac
 937
 938 AC_SUBST(target_cpu_type)
 939 AC_SUBST(obj_format)
 940 AC_SUBST(te_file)
 941 AC_SUBST(install_tooldir)
 942 AC_SUBST(atof)
 943 dnl AC_SUBST(emulation)
 944
 945 # do we need the opcodes library?
 946 case "${need_opcodes}" in
 947 yes)
 948   OPCODES_LIB=../opcodes/libopcodes.la
 949   ;;
 950 esac
 951
 952 AC_SUBST(OPCODES_LIB)
 953
 954 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 955 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 956 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 957 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 958 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 959
 960 AC_PROG_YACC
 961 AM_PROG_LEX
 962
 963 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 964 ZW_GNU_GETTEXT_SISTER_DIR
 965 AM_PO_SUBDIRS
 966
 967 AM_MAINTAINER_MODE
 968 AM_CONDITIONAL(GENINSRC_NEVER, false)
 969 AC_EXEEXT
 970
 971 AC_CHECK_HEADERS(memory.h sys/stat.h sys/types.h unistd.h)
 972
 973 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 974 # people who are not cross-compiling but are compiling cross-assemblers.
 975 AC_MSG_CHECKING(whether compiling a cross-assembler)
 976 if test "${host}" = "${target}"; then
 977   cross_gas=no
 978 else
 979   cross_gas=yes
 980   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 981 fi
 982 AC_MSG_RESULT($cross_gas)
 983
 984 AC_CHECK_FUNCS(strsignal)
 985
 986 AM_LC_MESSAGES
 987
 988 # do we need the math library?
 989 case "${need_libm}" in
 990 yes)
 991   LT_LIB_M
 992   AC_SUBST(LIBM)
 993   ;;
 994 esac
 995
 996 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 997 # enough, but on some of those systems, the assert macro relies on requoting
 998 # working properly!
 999 GAS_WORKING_ASSERT
1000
1001 # On some systems, the system header files may not declare malloc, realloc,
1002 # and free.  There are places where gas needs these functions to have been
1003 # declared -- such as when taking their addresses.
1004 gas_test_headers="
1005 #ifdef HAVE_MEMORY_H
1006 #include <memory.h>
1007 #endif
1008 #include <string.h>
1009 #include <stdlib.h>
1010 #ifdef HAVE_UNISTD_H
1011 #include <unistd.h>
1012 #endif
1013 "
1014
1015 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
1016 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
1017 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
1018 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
1019 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
1020 if test $gas_cv_decl_getopt_unistd_h = yes; then
1021   AC_DEFINE([HAVE_DECL_GETOPT], 1,
1022             [Is the prototype for getopt in <unistd.h> in the expected format?])
1023 fi
1024
1025 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1026 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
1027
1028 AC_CHECK_DECLS([asprintf, mempcpy, stpcpy])
1029
1030 BFD_BINARY_FOPEN
1031
1032 # Link in zlib/zstd if we can.  This allows us to write compressed debug sections.
1033 AM_ZLIB
1034 AC_ZSTD
1035
1036 # Support for VMS timestamps via cross compile
1037
1038 if test "$ac_cv_header_time_h" = yes; then
1039   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
1040 fi
1041
1042 if test "$ac_cv_header_sys_stat_h" = yes; then
1043     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
1044     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
1045 fi
1046
1047
1048 dnl Required for html, pdf, install-pdf and install-html targets.
1049 AC_SUBST(datarootdir)
1050 AC_SUBST(docdir)
1051 AC_SUBST(htmldir)
1052 AC_SUBST(pdfdir)
1053
1054 dnl This must come last.
1055
1056 dnl We used to make symlinks to files in the source directory, but now
1057 dnl we just use the right name for .c files, and create .h files in
1058 dnl the build directory which include the right .h file.  Make sure
1059 dnl the old symlinks don't exist, so that a reconfigure in an existing
1060 dnl directory behaves reasonably.
1061
1062 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
1063 AC_CONFIG_COMMANDS([default],
1064 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1065  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1066  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1067  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1068  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1069  if test "x$cgen_cpu_prefix" != x ; then
1070    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1071  fi],
1072 [target_cpu_type=${target_cpu_type}
1073  cgen_cpu_prefix=${cgen_cpu_prefix}
1074  obj_format=${obj_format}
1075  te_file=${te_file}])
1076
1077 AC_OUTPUT
1078
1079 GNU_MAKE_JOBSERVER