ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2020 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([ld], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29 AM_MAINTAINER_MODE
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_GREP
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37
  38 LT_INIT
  39 ACX_LARGEFILE
  40
  41 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  42 AC_ARG_ENABLE(targets,
  43 [  --enable-targets        alternative target configurations],
  44 [case "${enableval}" in
  45   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  46             ;;
  47   no)       enable_targets= ;;
  48   *)        enable_targets=$enableval ;;
  49 esac])dnl
  50 AC_ARG_ENABLE(64-bit-bfd,
  51 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  52 [case "${enableval}" in
  53   yes)  want64=true  ;;
  54   no)   want64=false ;;
  55   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  56 esac],[want64=false])dnl
  57
  58 AC_ARG_WITH(sysroot,
  59 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  60 [
  61  case ${with_sysroot} in
  62  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  63  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  64  esac
  65
  66  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  67  use_sysroot=yes
  68
  69  if test "x$prefix" = xNONE; then
  70   test_prefix=/usr/local
  71  else
  72   test_prefix=$prefix
  73  fi
  74  if test "x$exec_prefix" = xNONE; then
  75   test_exec_prefix=$test_prefix
  76  else
  77   test_exec_prefix=$exec_prefix
  78  fi
  79  case ${TARGET_SYSTEM_ROOT} in
  80  "${test_prefix}"|"${test_prefix}/"*|\
  81  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  82  '${prefix}'|'${prefix}/'*|\
  83  '${exec_prefix}'|'${exec_prefix}/'*)
  84    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  85    TARGET_SYSTEM_ROOT_DEFINE="$t"
  86    ;;
  87  esac
  88 ], [
  89  use_sysroot=no
  90  TARGET_SYSTEM_ROOT=
  91  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  92 ])
  93 AC_SUBST(use_sysroot)
  94 AC_SUBST(TARGET_SYSTEM_ROOT)
  95 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  96
  97 dnl Use --enable-gold to decide if this linker should be the default.
  98 dnl "install_as_default" is set to false if gold is the default linker.
  99 dnl "installed_linker" is the installed BFD linker name.
 100 AC_ARG_ENABLE(gold,
 101 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 102 [case "${enableval}" in
 103  default)
 104    install_as_default=no
 105    installed_linker=ld.bfd
 106    ;;
 107  yes|no)
 108    install_as_default=yes
 109    installed_linker=ld.bfd
 110    ;;
 111  *)
 112    AC_MSG_ERROR([invalid --enable-gold argument])
 113    ;;
 114  esac],
 115 [install_as_default=yes
 116  installed_linker=ld.bfd])
 117 AC_SUBST(install_as_default)
 118 AC_SUBST(installed_linker)
 119
 120 AC_ARG_ENABLE([got],
 121 AS_HELP_STRING([--enable-got=<type>],
 122                [GOT handling scheme (target, single, negative, multigot)]),
 123 [case "${enableval}" in
 124   target | single | negative | multigot)  got_handling=$enableval ;;
 125   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 126 esac],
 127 [got_handling=target])
 128
 129 case "${got_handling}" in
 130   target)
 131     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 132               [Define to choose default GOT handling scheme]) ;;
 133   single)
 134     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 135               [Define to choose default GOT handling scheme]) ;;
 136   negative)
 137     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 138               [Define to choose default GOT handling scheme]) ;;
 139   multigot)
 140     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 141               [Define to choose default GOT handling scheme]) ;;
 142   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 143 esac
 144
 145 # PR gas/19109
 146 # Decide the default method for compressing debug sections.
 147 ac_default_compressed_debug_sections=unset
 148 # Provide a configure time option to override our default.
 149 AC_ARG_ENABLE(compressed_debug_sections,
 150               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 151               [compress debug sections by default])],
 152 [case ,"${enableval}", in
 153   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 154   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 155 esac])dnl
 156
 157 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 158 ac_default_new_dtags=unset
 159 # Provide a configure time option to override our default.
 160 AC_ARG_ENABLE(new_dtags,
 161               AS_HELP_STRING([--enable-new-dtags],
 162               [set DT_RUNPATH instead of DT_RPATH by default])],
 163 [case "${enableval}" in
 164   yes) ac_default_new_dtags=1 ;;
 165   no) ac_default_new_dtags=0 ;;
 166 esac])dnl
 167
 168 # Decide if -z relro should be enabled in ELF linker by default.
 169 ac_default_ld_z_relro=unset
 170 # Provide a configure time option to override our default.
 171 AC_ARG_ENABLE(relro,
 172               AS_HELP_STRING([--enable-relro],
 173               [enable -z relro in ELF linker by default]),
 174 [case "${enableval}" in
 175   yes)  ac_default_ld_z_relro=1 ;;
 176   no)  ac_default_ld_z_relro=0 ;;
 177 esac])dnl
 178
 179 # Decide if -z separate-code should be enabled in ELF linker by default.
 180 ac_default_ld_z_separate_code=unset
 181 AC_ARG_ENABLE(separate-code,
 182               AS_HELP_STRING([--enable-separate-code],
 183               [enable -z separate-code in ELF linker by default]),
 184 [case "${enableval}" in
 185   yes) ac_default_ld_z_separate_code=1 ;;
 186   no) ac_default_ld_z_separate_code=0 ;;
 187 esac])
 188
 189 # Decide which "--hash-style" to use by default
 190 # Provide a configure time option to override our default.
 191 AC_ARG_ENABLE([default-hash-style],
 192 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 193                [use this default hash style]),
 194 [case "${enable_default_hash_style}" in
 195   sysv | gnu | both) ;;
 196   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 197 esac],
 198 [case "${target}" in
 199   # Enable gnu hash only on GNU targets, but not mips
 200   mips*-*-*) enable_default_hash_style=sysv ;;
 201   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 202   *) enable_default_hash_style=sysv ;;
 203 esac])
 204
 205 case "${enable_default_hash_style}" in
 206   sysv | both) ac_default_emit_sysv_hash=1 ;;
 207   *) ac_default_emit_sysv_hash=0 ;;
 208 esac
 209
 210 case "${enable_default_hash_style}" in
 211   gnu | both) ac_default_emit_gnu_hash=1 ;;
 212   *) ac_default_emit_gnu_hash=0 ;;
 213 esac
 214
 215 AM_BINUTILS_WARNINGS
 216
 217 AM_LC_MESSAGES
 218
 219 AC_CONFIG_HEADERS([config.h:config.in])
 220
 221 # PR 14072
 222 AH_VERBATIM([00_CONFIG_H_CHECK],
 223 [/* Check that config.h is #included before system headers
 224    (this works only for glibc, but that should be enough).  */
 225 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 226 #  error config.h must be #included before system headers
 227 #endif
 228 #define __CONFIG_H__ 1])
 229
 230 if test -z "$target" ; then
 231     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 232 fi
 233 if test -z "$host" ; then
 234     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 235 fi
 236
 237 # host-specific stuff:
 238
 239 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 240 ZW_GNU_GETTEXT_SISTER_DIR
 241 AM_PO_SUBDIRS
 242
 243 AC_EXEEXT
 244
 245 AC_PROG_YACC
 246 AM_PROG_LEX
 247
 248 AM_MAINTAINER_MODE
 249 AM_CONDITIONAL(GENINSRC_NEVER, false)
 250 ACX_PROG_CMP_IGNORE_INITIAL
 251
 252 . ${srcdir}/configure.host
 253
 254 AC_SUBST(HDEFINES)
 255 AC_SUBST(NATIVE_LIB_DIRS)
 256
 257 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 258 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 259 ACX_HEADER_STRING
 260 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 261 AC_CHECK_FUNCS(open lseek close)
 262 AC_HEADER_DIRENT
 263
 264 dnl AC_CHECK_HEADERS(sys/mman.h)
 265 AC_FUNC_MMAP
 266
 267 AC_SEARCH_LIBS([dlopen], [dl])
 268 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$plugins = xyes])
 269
 270 AC_ARG_ENABLE(initfini-array,
 271 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 272 [case "${enableval}" in
 273  yes|no) ;;
 274  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 275  esac], [enable_initfini_array=yes])
 276 AC_SUBST(enable_initfini_array)
 277 if test $enable_initfini_array = yes; then
 278   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 279     [Define .init_array/.fini_array sections are available and working.])
 280 fi
 281
 282 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 283 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 284 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 285 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 286 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 287 if test $ld_cv_decl_getopt_unistd_h = yes; then
 288   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 289             [Is the prototype for getopt in <unistd.h> in the expected format?])
 290 fi
 291
 292 BFD_BINARY_FOPEN
 293
 294 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 295
 296 # Link in zlib if we can.  This allows us to read and write
 297 # compressed CTF sections.
 298 AM_ZLIB
 299
 300 # When converting linker scripts into strings for use in emulation
 301 # files, use astring.sed if the compiler supports ANSI string
 302 # concatenation, or ostring.sed otherwise.  This is to support the
 303 # broken Microsoft MSVC compiler, which limits the length of string
 304 # constants, while still supporting pre-ANSI compilers which do not
 305 # support string concatenation.
 306 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 307 AC_CACHE_VAL(ld_cv_string_concatenation,
 308 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 309   ld_cv_string_concatenation=yes,
 310   ld_cv_string_concatenation=no)])
 311 AC_MSG_RESULT($ld_cv_string_concatenation)
 312 if test "$ld_cv_string_concatenation" = "yes"; then
 313   STRINGIFY=astring.sed
 314 else
 315   STRINGIFY=ostring.sed
 316 fi
 317 AC_SUBST(STRINGIFY)
 318
 319 # target-specific stuff:
 320
 321 all_targets=
 322 EMUL=
 323 all_emuls=
 324 all_emul_extras=
 325 all_libpath=
 326 TDIRS=
 327
 328 # If the host is 64-bit, then we enable 64-bit targets by default.
 329 # This is consistent with what ../bfd/configure.ac does.
 330 if test x${want64} = xfalse; then
 331   AC_CHECK_SIZEOF(void *)
 332   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 333     want64=true
 334   fi
 335 fi
 336
 337 elf_list_options=FALSE
 338 elf_shlib_list_options=FALSE
 339 elf_plt_unwind_list_options=FALSE
 340 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 341 do
 342   if test "$targ_alias" = "all"; then
 343     all_targets=true
 344     elf_list_options=TRUE
 345     elf_shlib_list_options=TRUE
 346     elf_plt_unwind_list_options=TRUE
 347   else
 348     # Canonicalize the secondary target names.
 349     result=`$ac_config_sub $targ_alias 2>/dev/null`
 350     if test -n "$result"; then
 351         targ=$result
 352     else
 353         targ=$targ_alias
 354     fi
 355
 356     . ${srcdir}/configure.tgt
 357
 358     if test "$targ" = "$target"; then
 359       EMUL=$targ_emul
 360     fi
 361
 362     if test x${want64} = xfalse; then
 363       . ${srcdir}/../bfd/config.bfd
 364     fi
 365
 366     if test x${want64} = xtrue; then
 367       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 368       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 369     fi
 370
 371     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 372         case " $all_emuls " in
 373         *" e${i}.o "*) ;;
 374         *)
 375           all_emuls="$all_emuls e${i}.o"
 376           eval result=\$tdir_$i
 377           test -z "$result" && result=$targ_alias
 378           TDIRS="$TDIRS
 379 tdir_$i=$result"
 380           case "${i}" in
 381           *elf*)
 382             elf_list_options=TRUE
 383             ;;
 384           *)
 385             if $GREP "TEMPLATE_NAME=elf" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 386               elf_list_options=TRUE
 387             fi
 388             ;;
 389           esac
 390           if test "$elf_list_options" = "TRUE"; then
 391             source_sh()
 392             {
 393               . $1
 394             }
 395             source_sh ${srcdir}/emulparams/${i}.sh
 396             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 397               elf_shlib_list_options=TRUE
 398             fi
 399             if test x${PLT_UNWIND} = xyes; then
 400               elf_plt_unwind_list_options=TRUE
 401             fi
 402           fi
 403           ;;
 404         esac
 405     done
 406
 407     for i in $targ_emul $targ_extra_libpath; do
 408         case " $all_libpath " in
 409         *" ${i} "*) ;;
 410         *)
 411           if test -z "$all_libpath"; then
 412             all_libpath=${i}
 413           else
 414             all_libpath="$all_libpath ${i}"
 415           fi
 416           ;;
 417         esac
 418     done
 419
 420     for i in $targ_extra_ofiles; do
 421         case " $all_emul_extras " in
 422         *" ${i} "*) ;;
 423         *)
 424           all_emul_extras="$all_emul_extras ${i}"
 425           ;;
 426         esac
 427     done
 428
 429   fi
 430 done
 431
 432 if test x$ac_default_compressed_debug_sections = xyes ; then
 433   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 434 fi
 435
 436 if test "${ac_default_new_dtags}" = unset; then
 437   ac_default_new_dtags=0
 438 fi
 439 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 440   $ac_default_new_dtags,
 441   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 442
 443 if test "${ac_default_ld_z_relro}" = unset; then
 444   ac_default_ld_z_relro=0
 445 fi
 446 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 447   $ac_default_ld_z_relro,
 448   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 449
 450 if test "${ac_default_ld_z_separate_code}" = unset; then
 451   ac_default_ld_z_separate_code=0
 452 fi
 453 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 454   $ac_default_ld_z_separate_code,
 455   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 456
 457 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 458   [$ac_default_emit_sysv_hash],
 459   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 460
 461 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 462   [$ac_default_emit_gnu_hash],
 463   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 464
 465 AC_SUBST(elf_list_options)
 466 AC_SUBST(elf_shlib_list_options)
 467 AC_SUBST(elf_plt_unwind_list_options)
 468 AC_SUBST(EMUL)
 469
 470 AC_SUBST(TDIRS)
 471 AM_SUBST_NOTMAKE(TDIRS)
 472
 473 if test x${all_targets} = xtrue; then
 474   if test x${want64} = xtrue; then
 475     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 476     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 477   else
 478     EMULATION_OFILES='$(ALL_EMULATIONS)'
 479     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 480   fi
 481 else
 482   EMULATION_OFILES=$all_emuls
 483   EMUL_EXTRA_OFILES=$all_emul_extras
 484 fi
 485 AC_SUBST(EMULATION_OFILES)
 486 AC_SUBST(EMUL_EXTRA_OFILES)
 487 AC_SUBST(LIB_PATH)
 488
 489 EMULATION_LIBPATH=$all_libpath
 490 AC_SUBST(EMULATION_LIBPATH)
 491
 492 if test x${enable_static} = xno; then
 493   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 494   TESTCTFLIB="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
 495 else
 496   TESTBFDLIB="../bfd/.libs/libbfd.a"
 497   TESTCTFLIB="../libctf/.libs/libctf.a"
 498 fi
 499 AC_SUBST(TESTBFDLIB)
 500 AC_SUBST(TESTCTFLIB)
 501
 502 target_vendor=${target_vendor=$host_vendor}
 503 case "$target_vendor" in
 504   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 505   *)  EXTRA_SHLIB_EXTENSION= ;;
 506 esac
 507
 508 case "$target_os" in
 509   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 510 esac
 511
 512 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 513   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 514    [Additional extension a shared object might have.])
 515 fi
 516
 517 AC_CONFIG_COMMANDS([default],
 518 [[
 519 case "$srcdir" in
 520   .) srcdirpre= ;;
 521   *) srcdirpre='$(srcdir)/' ;;
 522 esac
 523 POFILES=
 524 GMOFILES=
 525 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 526   if test $lang != dummy; then
 527     POFILES="$POFILES $srcdirpre$lang.po"
 528     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 529   fi
 530 done
 531 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 532     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 533     -e "s,@POFILES@,$POFILES," \
 534     -e "s,@GMOFILES@,$GMOFILES," \
 535     po/Makefile.in > po/Makefile]],[[]])
 536
 537 dnl Required by html, pdf, install-pdf and install-html
 538 AC_SUBST(datarootdir)
 539 AC_SUBST(docdir)
 540 AC_SUBST(htmldir)
 541 AC_SUBST(pdfdir)
 542
 543 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 544 AC_OUTPUT