binutils/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2022 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 m4_include([../config/debuginfod.m4])
  22 AC_INIT([binutils], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ar.c)
  24
  25 AC_CANONICAL_TARGET
  26
  27 AM_INIT_AUTOMAKE
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34 LT_INIT
  35 ACX_LARGEFILE
  36
  37 ac_checking=
  38 . ${srcdir}/../bfd/development.sh
  39 test "$development" = true && ac_checking=yes
  40 AC_ARG_ENABLE(checking,
  41 [  --enable-checking       enable run-time checks],
  42 [case "${enableval}" in
  43   no|none)  ac_checking= ;;
  44   *)        ac_checking=yes ;;
  45 esac])dnl
  46 if test x$ac_checking != x ; then
  47   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  48 fi
  49
  50 AC_ARG_ENABLE(targets,
  51 [  --enable-targets        alternative target configurations],
  52 [case "${enableval}" in
  53   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  54             ;;
  55   no)       enable_targets= ;;
  56   *)        enable_targets=$enableval ;;
  57 esac])dnl
  58
  59
  60 AC_ARG_ENABLE(deterministic-archives,
  61 [AS_HELP_STRING([--enable-deterministic-archives],
  62                 [ar and ranlib default to -D behavior])], [
  63 if test "${enableval}" = no; then
  64   default_ar_deterministic=0
  65 else
  66   default_ar_deterministic=1
  67 fi], [default_ar_deterministic=0])
  68
  69 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  70                    [Should ar and ranlib use -D behavior by default?])
  71
  72
  73 AC_ARG_ENABLE(default-strings-all,
  74 [AS_HELP_STRING([--disable-default-strings-all],
  75                 [strings defaults to --data behavior])], [
  76 if test "${enableval}" = no; then
  77   default_strings_all=0
  78 else
  79   default_strings_all=1
  80 fi], [default_strings_all=1])
  81
  82 AC_DEFINE_UNQUOTED(DEFAULT_STRINGS_ALL, $default_strings_all,
  83                    [Should strings use -a behavior by default?])
  84
  85
  86 AC_ARG_ENABLE(f-for-ifunc-symbols,
  87 [AS_HELP_STRING([--enable-f-for-ifunc-symbols],
  88         [Have nm use F and f for global and local ifunc symbols])], [
  89 if test "${enableval}" = no; then
  90   default_f_for_ifunc=0
  91 else
  92   default_f_for_ifunc=1
  93 fi], [default_f_for_ifunc=0])
  94
  95 AC_DEFINE_UNQUOTED(DEFAULT_F_FOR_IFUNC_SYMBOLS, $default_f_for_ifunc,
  96                    [Have nm use F and f for global and local ifunc symbols])
  97
  98
  99 AC_ARG_ENABLE(follow-debug-links,
 100 [AS_HELP_STRING([--enable-follow-debug-links],
 101         [Have readelf and objdump follow debug links by default])], [
 102 if test "${enableval}" = no; then
 103   default_for_follow_links=0
 104 else
 105   default_for_follow_links=1
 106 fi], [default_for_follow_links=1])
 107
 108 AC_DEFINE_UNQUOTED(DEFAULT_FOR_FOLLOW_LINKS, $default_for_follow_links,
 109                    [Have readelf and objdump follow debug links by default])
 110
 111
 112 AC_DEBUGINFOD
 113
 114 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 115 if test "${enable_libctf}" = yes; then
 116     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 117 fi
 118 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 119
 120 AM_BINUTILS_WARNINGS
 121
 122 AC_CONFIG_HEADERS(config.h:config.in)
 123
 124 AH_VERBATIM([00_CONFIG_H_CHECK],
 125 [/* Check that config.h is #included before system headers
 126    (this works only for glibc, but that should be enough).  */
 127 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 128 #  error config.h must be #included before system headers
 129 #endif
 130 #define __CONFIG_H__ 1])
 131
 132 if test -z "$target" ; then
 133     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 134 fi
 135 if test -z "$host" ; then
 136     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 137 fi
 138
 139 AC_PROG_YACC
 140 AM_PROG_LEX
 141
 142 ALL_LINGUAS="bg ca da es fi fr hr id it ja pt ro ru rw sk sr sv tr uk vi zh_CN zh_TW"
 143 ZW_GNU_GETTEXT_SISTER_DIR
 144 AM_PO_SUBDIRS
 145
 146 AM_MAINTAINER_MODE
 147 AM_CONDITIONAL(GENINSRC_NEVER, false)
 148 AC_EXEEXT
 149 if test -n "$EXEEXT"; then
 150   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
 151             [Does the platform use an executable suffix?])
 152 fi
 153 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
 154                    [Suffix used for executables, if any.])
 155
 156 # host-specific stuff:
 157
 158 HDEFINES=
 159
 160 . ${srcdir}/../bfd/configure.host
 161
 162 AC_SUBST(HDEFINES)
 163 AR=${AR-ar}
 164 AC_SUBST(AR)
 165 AC_PROG_RANLIB
 166 AC_PROG_INSTALL
 167
 168 BFD_CC_FOR_BUILD
 169
 170 DEMANGLER_NAME=c++filt
 171 case "${host}" in
 172   *-*-go32* | *-*-msdos*)
 173     DEMANGLER_NAME=cxxfilt
 174 esac
 175 AC_SUBST(DEMANGLER_NAME)
 176
 177 # We use headers from include/ that check various HAVE_*_H macros, thus
 178 # should ensure they are set by configure.  This is true even when C99
 179 # guarantees they are available.
 180 # plugin-api.h tests HAVE_STDINT_H and HAVE_INTTYPES_H
 181 # Besides those, we need to check anything used in binutils/ not in C99.
 182 AC_CHECK_HEADERS(fcntl.h inttypes.h stdint.h sys/file.h \
 183                  sys/stat.h sys/time.h sys/types.h unistd.h)
 184 AC_HEADER_SYS_WAIT
 185 AC_FUNC_MMAP
 186 AC_CHECK_FUNCS(getc_unlocked mkdtemp mkstemp utimensat utimes)
 187
 188 AC_MSG_CHECKING([for mbstate_t])
 189 AC_TRY_COMPILE([#include <wchar.h>],
 190 [mbstate_t teststate;],
 191 have_mbstate_t=yes, have_mbstate_t=no)
 192 AC_MSG_RESULT($have_mbstate_t)
 193 if test x"$have_mbstate_t" = xyes; then
 194   AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 195 fi
 196
 197 # Copied from gnulib stat-time.m4.
 198 # We should just switch over to using gnulib.
 199 AC_CHECK_MEMBERS([struct stat.st_atim.tv_nsec],
 200   [AC_CACHE_CHECK([whether struct stat.st_atim is of type struct timespec],
 201      [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec],
 202      [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 203         [[
 204           #include <sys/types.h>
 205           #include <sys/stat.h>
 206           #if HAVE_SYS_TIME_H
 207           # include <sys/time.h>
 208           #endif
 209           #include <time.h>
 210           struct timespec ts;
 211           struct stat st;
 212         ]],
 213         [[
 214           st.st_atim = ts;
 215         ]])],
 216         [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=yes],
 217         [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=no])])
 218    if test $ac_cv_typeof_struct_stat_st_atim_is_struct_timespec = yes; then
 219      AC_DEFINE([TYPEOF_STRUCT_STAT_ST_ATIM_IS_STRUCT_TIMESPEC], [1],
 220        [Define to 1 if the type of the st_atim member of a struct stat is
 221         struct timespec.])
 222    fi],
 223   [AC_CHECK_MEMBERS([struct stat.st_atimespec.tv_nsec], [],
 224      [AC_CHECK_MEMBERS([struct stat.st_atimensec], [],
 225         [AC_CHECK_MEMBERS([struct stat.st_atim.st__tim.tv_nsec], [], [],
 226            [#include <sys/types.h>
 227             #include <sys/stat.h>])],
 228         [#include <sys/types.h>
 229          #include <sys/stat.h>])],
 230      [#include <sys/types.h>
 231       #include <sys/stat.h>])],
 232   [#include <sys/types.h>
 233    #include <sys/stat.h>])
 234
 235 # Some systems have frexp only in -lm, not in -lc.
 236 AC_SEARCH_LIBS(frexp, m)
 237
 238 AM_LC_MESSAGES
 239
 240 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 241 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 242 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 243 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 244 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 245 if test $bu_cv_decl_getopt_unistd_h = yes; then
 246   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 247             [Is the prototype for getopt in <unistd.h> in the expected format?])
 248 fi
 249
 250 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 251 # by default.
 252 AC_MSG_CHECKING([for utime.h])
 253 AC_CACHE_VAL(bu_cv_header_utime_h,
 254 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 255 #ifdef HAVE_TIME_H
 256 #include <time.h>
 257 #endif
 258 #include <utime.h>],
 259 [struct utimbuf s;])],
 260 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 261 AC_MSG_RESULT($bu_cv_header_utime_h)
 262 if test $bu_cv_header_utime_h = yes; then
 263   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 264 fi
 265
 266 AC_CHECK_DECLS([asprintf, environ, getc_unlocked, stpcpy, strnlen])
 267
 268 # Link in zlib/zstd if we can.  This allows us to read compressed debug
 269 # sections.  This is used only by readelf.c (objdump uses bfd for
 270 # reading compressed sections).
 271 AM_ZLIB
 272 AC_ZSTD
 273
 274 BFD_BINARY_FOPEN
 275
 276 # Support for the msgpack C library.
 277 AC_ARG_WITH([msgpack],
 278             AC_HELP_STRING([--with-msgpack], [Enable msgpack support (auto/yes/no)]),
 279             [],
 280             [with_msgpack=auto])
 281
 282 AS_IF([test "$with_msgpack" != no],
 283   [PKG_CHECK_MODULES(MSGPACK, msgpack,
 284     [AC_DEFINE([HAVE_MSGPACK], [1], [Define to 1 if msgpack is available.])],
 285     [AS_IF([test "$with_msgpack" = yes],
 286       [AC_MSG_ERROR([--with-msgpack was given, but msgpack is missing or unusable.])])])])
 287
 288 # target-specific stuff:
 289
 290 # Canonicalize the secondary target names.
 291 if test -n "$enable_targets"; then
 292     for targ in `echo $enable_targets | sed 's/,/ /g'`
 293     do
 294         result=`$ac_config_sub $targ 2>/dev/null`
 295         if test -n "$result"; then
 296             canon_targets="$canon_targets $result"
 297         else
 298             # Allow targets that config.sub doesn't recognize, like "all".
 299             canon_targets="$canon_targets $targ"
 300         fi
 301     done
 302 fi
 303
 304 AC_CHECK_HEADER(iconv.h)
 305 AM_ICONV
 306
 307 all_targets=false
 308 BUILD_SRCONV=
 309 BUILD_DLLTOOL=
 310 DLLTOOL_DEFS=
 311 DLLTOOL_DEFAULT=
 312 BUILD_WINDRES=
 313 BUILD_WINDMC=
 314 BUILD_DLLWRAP=
 315 BUILD_MISC=
 316 BUILD_INSTALL_MISC=
 317 OBJDUMP_DEFS=
 318 OBJDUMP_PRIVATE_VECTORS=
 319 OBJDUMP_PRIVATE_OFILES=
 320 od_vectors=
 321
 322 for targ in $target $canon_targets
 323 do
 324     if test "x$targ" = "xall"; then
 325         all_targets=true
 326         BUILD_SRCONV='$(SRCONV_PROG)'
 327         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 328         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 329         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 330         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 331         if test -z "$DLLTOOL_DEFAULT"; then
 332           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 333         fi
 334         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 335         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 336         od_vectors="$od_vectors objdump_private_desc_xcoff"
 337     else
 338         case $targ in
 339         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 340         esac
 341
 342         case $targ in
 343         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 344           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 345           if test -z "$DLLTOOL_DEFAULT"; then
 346             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 347           fi
 348           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 349           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 350           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 351           ;;
 352         arm-*-pe*)
 353           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 354           if test -z "$DLLTOOL_DEFAULT"; then
 355             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 356           fi
 357           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 358           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 359           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 360           ;;
 361         x86_64-*-mingw* | x86_64-*-cygwin*)
 362           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 363           if test -z "$DLLTOOL_DEFAULT"; then
 364             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 365           fi
 366           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 367           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 368           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 369           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 370           ;;
 371 changequote(,)dnl
 372         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32**)
 373 changequote([,])dnl
 374           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 375           if test -z "$DLLTOOL_DEFAULT"; then
 376             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 377           fi
 378           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 379           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 380           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 381           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 382           ;;
 383 changequote(,)dnl
 384         i[3-7]86-*-interix)
 385 changequote([,])dnl
 386           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 387           if test -z "$DLLTOOL_DEFAULT"; then
 388             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 389           fi
 390           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 391           ;;
 392 changequote(,)dnl
 393         powerpc*-aix5.[01])
 394 changequote([,])dnl
 395           ;;
 396 changequote(,)dnl
 397         powerpc*-aix[5-9].*)
 398 changequote([,])dnl
 399           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 400           ;;
 401         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 402           case "$BUILD_INSTALL_MISC" in
 403             *embedspu*) ;;
 404             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 405           esac
 406           ;;
 407         sh*-*-pe)
 408           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 409           if test -z "$DLLTOOL_DEFAULT"; then
 410             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 411           fi
 412           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 413           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 414           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 415           ;;
 416         spu-*-*)
 417           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 418           ;;
 419         mips*-*-pe)
 420           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 421           if test -z "$DLLTOOL_DEFAULT"; then
 422             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 423           fi
 424           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 425           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 426           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 427           ;;
 428         mcore-*-pe)
 429           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 430           if test -z "$DLLTOOL_DEFAULT"; then
 431             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 432           fi
 433           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 434           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 435           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 436           ;;
 437         mcore-*-elf)
 438           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 439           if test -z "$DLLTOOL_DEFAULT"; then
 440             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 441           fi
 442           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 443           ;;
 444         mep-*)
 445           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 446           ;;
 447         esac
 448
 449         # Add objdump private vectors.
 450         case $targ in
 451         avr-*-*)
 452           od_vectors="$od_vectors objdump_private_desc_elf32_avr"
 453           ;;
 454         powerpc*-*-aix* | rs6000-*-aix*)
 455           od_vectors="$od_vectors objdump_private_desc_xcoff"
 456           ;;
 457         *-*-darwin*)
 458           od_vectors="$od_vectors objdump_private_desc_mach_o"
 459           ;;
 460         esac
 461     fi
 462 done
 463
 464 # Uniq objdump private vector, build objdump target ofiles.
 465 od_files=
 466 f=""
 467 for i in $od_vectors ; do
 468     case " $f " in
 469     *" $i "*) ;;
 470     *)
 471         f="$f $i"
 472         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 473         case $i in
 474         objdump_private_desc_elf32_avr)
 475             od_files="$od_files od-elf32_avr" ;;
 476         objdump_private_desc_xcoff)
 477             od_files="$od_files od-xcoff" ;;
 478         objdump_private_desc_mach_o)
 479             od_files="$od_files od-macho" ;;
 480         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 481         esac
 482         ;;
 483     esac
 484 done
 485
 486 # Uniq objdump target ofiles
 487 f=""
 488 for i in $od_files ; do
 489     case " $f " in
 490     *" $i "*) ;;
 491     *)
 492         f="$f $i"
 493         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 494         ;;
 495     esac
 496 done
 497
 498 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 499
 500 if test "${with_windres+set}" = set; then
 501           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 502 fi
 503
 504 if test "${with_windmc+set}" = set; then
 505           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 506 fi
 507
 508 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 509
 510 AC_SUBST(BUILD_SRCONV)
 511 AC_SUBST(BUILD_DLLTOOL)
 512 AC_SUBST(DLLTOOL_DEFS)
 513 AC_SUBST(BUILD_WINDRES)
 514 AC_SUBST(BUILD_WINDMC)
 515 AC_SUBST(BUILD_DLLWRAP)
 516 AC_SUBST(BUILD_MISC)
 517 AC_SUBST(BUILD_INSTALL_MISC)
 518 AC_SUBST(OBJDUMP_DEFS)
 519 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 520
 521 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 522
 523 targ=$target
 524 . $srcdir/../bfd/config.bfd
 525 if test "x$targ_underscore" = "xyes"; then
 526     UNDERSCORE=1
 527 else
 528     UNDERSCORE=0
 529 fi
 530 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 531  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 532
 533 # Emulation
 534 targ=$target
 535 . ${srcdir}/configure.tgt
 536 EMULATION=$targ_emul
 537 EMULATION_VECTOR=$targ_emul_vector
 538
 539 AC_SUBST(EMULATION)
 540 AC_SUBST(EMULATION_VECTOR)
 541
 542 # Required for html and install-html
 543 AC_SUBST(datarootdir)
 544 AC_SUBST(docdir)
 545 AC_SUBST(htmldir)
 546 AC_SUBST(pdfdir)
 547
 548 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 549 AC_OUTPUT
 550
 551 GNU_MAKE_JOBSERVER