gnulib/import/m4/fchdir.m4

   1 # fchdir.m4 serial 27
   2 dnl Copyright (C) 2006-2022 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FCHDIR],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  11   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  12
  13   AC_CHECK_DECLS_ONCE([fchdir])
  14   if test $ac_cv_have_decl_fchdir = no; then
  15     HAVE_DECL_FCHDIR=0
  16   fi
  17
  18   AC_REQUIRE([gl_TEST_FCHDIR])
  19   if test $HAVE_FCHDIR = 0; then
  20     AC_DEFINE([REPLACE_FCHDIR], [1],
  21       [Define to 1 if gnulib's fchdir() replacement is used.])
  22     dnl We must also replace anything that can manipulate a directory fd,
  23     dnl to keep our bookkeeping up-to-date.  We don't have to replace
  24     dnl fstatat, since no platform has fstatat but lacks fchdir.
  25     AC_CACHE_CHECK([whether open can visit directories],
  26       [gl_cv_func_open_directory_works],
  27       [AC_RUN_IFELSE(
  28          [AC_LANG_PROGRAM(
  29             [[#include <fcntl.h>
  30             ]GL_MDA_DEFINES],
  31             [[return open(".", O_RDONLY) < 0;]])],
  32          [gl_cv_func_open_directory_works=yes],
  33          [gl_cv_func_open_directory_works=no],
  34          [case "$host_os" in
  35                              # Guess yes on Linux systems.
  36             linux-* | linux) gl_cv_func_open_directory_works="guessing yes" ;;
  37                              # Guess yes on glibc systems.
  38             *-gnu* | gnu*)   gl_cv_func_open_directory_works="guessing yes" ;;
  39                              # Guess no on native Windows.
  40             mingw*)          gl_cv_func_open_directory_works="guessing no" ;;
  41                              # If we don't know, obey --enable-cross-guesses.
  42             *)               gl_cv_func_open_directory_works="$gl_cross_guess_normal" ;;
  43           esac
  44          ])])
  45     case "$gl_cv_func_open_directory_works" in
  46       *yes) ;;
  47       *)
  48         AC_DEFINE([REPLACE_OPEN_DIRECTORY], [1], [Define to 1 if open() should
  49 work around the inability to open a directory.])
  50         ;;
  51     esac
  52   fi
  53 ])
  54
  55 # Determine whether to use the overrides in lib/fchdir.c.
  56 AC_DEFUN([gl_TEST_FCHDIR],
  57 [
  58   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  59   AC_CHECK_FUNCS_ONCE([fchdir])
  60   if test $ac_cv_func_fchdir = no; then
  61     HAVE_FCHDIR=0
  62   fi
  63 ])
  64
  65 # Prerequisites of lib/fchdir.c.
  66 AC_DEFUN([gl_PREREQ_FCHDIR], [:])